data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4 # Copyright (C) 2002, 2004, 2005, 2006, 2007, 2008 Free Software Foundation,
   5 # Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 ## ---------------- ##
  22 ## Identification.  ##
  23 ## ---------------- ##
  24
  25 # b4_copyright(TITLE, [YEARS])
  26 # ----------------------------
  27 # If YEARS are not defined, use b4_copyright_years.
  28 m4_define([b4_copyright],
  29 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  30
  31 b4_comment([$1
  32
  33 ]m4_dquote(m4_text_wrap([Copyright (C)
  34 ]m4_ifval([$2], [[$2]], [m4_defn([b4_copyright_years])])[
  35 Free Software Foundation, Inc.]))[
  36
  37 This program is free software: you can redistribute it and/or modify
  38 it under the terms of the GNU General Public License as published by
  39 the Free Software Foundation, either version 3 of the License, or
  40 (at your option) any later version.
  41
  42 This program is distributed in the hope that it will be useful,
  43 but WITHOUT ANY WARRANTY; without even the implied warranty of
  44 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  45 GNU General Public License for more details.
  46
  47 You should have received a copy of the GNU General Public License
  48 along with this program.  If not, see <http://www.gnu.org/licenses/>.])
  49
  50 b4_comment([As a special exception, you may create a larger work that contains
  51 part or all of the Bison parser skeleton and distribute that work
  52 under terms of your choice, so long as that work isn't itself a
  53 parser generator using the skeleton or a modified version thereof
  54 as a parser skeleton.  Alternatively, if you modify or redistribute
  55 the parser skeleton itself, you may (at your option) remove this
  56 special exception, which will cause the skeleton and the resulting
  57 Bison output files to be licensed under the GNU General Public
  58 License without this special exception.
  59
  60 This special exception was added by the Free Software Foundation in
  61 version 2.2 of Bison.])])
  62
  63
  64 ## ---------------- ##
  65 ## Error handling.  ##
  66 ## ---------------- ##
  67
  68 # The following error handling macros print error directives that should not
  69 # become arguments of other macro invocations since they would likely then be
  70 # mangled.  Thus, they print to stdout directly.
  71
  72 # b4_cat(TEXT)
  73 # ------------
  74 # Write TEXT to stdout.  Precede the final newline with an @ so that it's
  75 # escaped.  For example:
  76 #
  77 #   b4_cat([[@complain(invalid input@)]])
  78 m4_define([b4_cat],
  79 [m4_syscmd([cat <<'_m4eof'
  80 ]m4_bpatsubst(m4_dquote($1), [_m4eof], [_m4@`eof])[@
  81 _m4eof
  82 ])dnl
  83 m4_if(m4_sysval, [0], [], [m4_fatal([$0: cannot write to stdout])])])
  84
  85 # b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
  86 # -------------------------------------------
  87 # Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to stdout.
  88 #
  89 # For example:
  90 #
  91 #   b4_error([[warn]], [[invalid value for `%s': %s]], [[foo]], [[3]])
  92 m4_define([b4_error],
  93 [b4_cat([[@]$1[(]$2[]]dnl
  94 [m4_if([$#], [2], [],
  95        [m4_foreach([b4_arg],
  96                    m4_dquote(m4_shift(m4_shift($@))),
  97                    [[@,]b4_arg])])[@)]])])
  98
  99 # b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
 100 # ----------------------------------------------------------
 101 # Write @KIND_at(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 102 #
 103 # For example:
 104 #
 105 #   b4_error_at([[complain]], [[input.y:2.3]], [[input.y:5.4]],
 106 #               [[invalid %s]], [[foo]])
 107 m4_define([b4_error_at],
 108 [b4_cat([[@]$1[_at(]$2[@,]$3[@,]$4[]]dnl
 109 [m4_if([$#], [4], [],
 110        [m4_foreach([b4_arg],
 111                    m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
 112                    [[@,]b4_arg])])[@)]])])
 113
 114 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
 115 # ------------------------------------
 116 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 117 #
 118 # For example:
 119 #
 120 #   b4_warn([[invalid value for `%s': %s]], [[foo]], [[3]])
 121 #
 122 # As a simple test suite, this:
 123 #
 124 #   m4_divert(-1)
 125 #   m4_define([asdf], [ASDF])
 126 #   m4_define([fsa], [FSA])
 127 #   m4_define([fdsa], [FDSA])
 128 #   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
 129 #   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
 130 #   b4_warn()
 131 #   b4_warn(1)
 132 #   b4_warn(1, 2)
 133 #
 134 # Should produce this without newlines:
 135 #
 136 #   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
 137 #   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
 138 #   @warn(@)
 139 #   @warn(1@)
 140 #   @warn(1@,2@)
 141 m4_define([b4_warn],
 142 [b4_error([[warn]], $@)])
 143
 144 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 145 # ---------------------------------------------------
 146 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 147 #
 148 # For example:
 149 #
 150 #   b4_warn_at([[input.y:2.3]], [[input.y:5.4]], [[invalid %s]], [[foo]])
 151 m4_define([b4_warn_at],
 152 [b4_error_at([[warn]], $@)])
 153
 154 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 155 # ----------------------------------------
 156 # Write @complain(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 157 #
 158 # See b4_warn example.
 159 m4_define([b4_complain],
 160 [b4_error([[complain]], $@)])
 161
 162 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 163 # -------------------------------------------------------
 164 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 165 #
 166 # See b4_warn_at example.
 167 m4_define([b4_complain_at],
 168 [b4_error_at([[complain]], $@)])
 169
 170 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 171 # -------------------------------------
 172 # Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 173 #
 174 # See b4_warn example.
 175 m4_define([b4_fatal],
 176 [b4_error([[fatal]], $@)dnl
 177 m4_exit(1)])
 178
 179 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 180 # ----------------------------------------------------
 181 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 182 #
 183 # See b4_warn_at example.
 184 m4_define([b4_fatal_at],
 185 [b4_error_at([[fatal]], $@)dnl
 186 m4_exit(1)])
 187
 188
 189 ## ---------------- ##
 190 ## Default values.  ##
 191 ## ---------------- ##
 192
 193 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 194 m4_define_default([b4_pre_prologue], [])
 195 m4_define_default([b4_post_prologue], [])
 196 m4_define_default([b4_epilogue], [])
 197 m4_define_default([b4_parse_param], [])
 198
 199 # The initial column and line.
 200 m4_define_default([b4_location_initial_column], [1])
 201 m4_define_default([b4_location_initial_line],   [1])
 202
 203
 204 ## ------------ ##
 205 ## Data Types.  ##
 206 ## ------------ ##
 207
 208 # b4_ints_in(INT1, INT2, LOW, HIGH)
 209 # ---------------------------------
 210 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 211 m4_define([b4_ints_in],
 212 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 213
 214
 215
 216 ## ------------------ ##
 217 ## Decoding options.  ##
 218 ## ------------------ ##
 219
 220 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 221 # -----------------------------------
 222 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 223 m4_define([b4_flag_if],
 224 [m4_case(b4_$1_flag,
 225          [0], [$3],
 226          [1], [$2],
 227          [m4_fatal([invalid $1 value: ]$1)])])
 228
 229
 230 # b4_define_flag_if(FLAG)
 231 # -----------------------
 232 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 233 # value of the Boolean FLAG.
 234 m4_define([b4_define_flag_if],
 235 [_b4_define_flag_if($[1], $[2], [$1])])
 236
 237 # _b4_define_flag_if($1, $2, FLAG)
 238 # --------------------------------
 239 # This macro works around the impossibility to define macros
 240 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 241 # This sucks hard, GNU M4 should really provide M5 like $$1.
 242 m4_define([_b4_define_flag_if],
 243 [m4_if([$1$2], $[1]$[2], [],
 244        [m4_fatal([$0: Invalid arguments: $@])])dnl
 245 m4_define([b4_$3_if],
 246           [b4_flag_if([$3], [$1], [$2])])])
 247
 248
 249 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 250 # -----------------------------
 251 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 252 b4_define_flag_if([defines])            # Whether headers are requested.
 253 b4_define_flag_if([error_verbose])      # Whether error are verbose.
 254 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 255 b4_define_flag_if([locations])          # Whether locations are tracked.
 256 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 257 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 258
 259
 260 ## ------------------------- ##
 261 ## Assigning token numbers.  ##
 262 ## ------------------------- ##
 263
 264
 265 ## ----------- ##
 266 ## Synclines.  ##
 267 ## ----------- ##
 268
 269 # b4_basename(NAME)
 270 # -----------------
 271 # Similar to POSIX basename; the differences don't matter here.
 272 # Beware that NAME is not evaluated.
 273 m4_define([b4_basename],
 274 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 275
 276
 277 # b4_syncline(LINE, FILE)
 278 # -----------------------
 279 m4_define([b4_syncline],
 280 [b4_flag_if([synclines], [
 281 b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 282 b4_sync_start([$1], [$2])])])
 283
 284 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 285 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 286
 287 # b4_user_code(USER-CODE)
 288 # -----------------------
 289 # Emit code from the user, ending it with synclines.
 290 m4_define([b4_user_code],
 291 [$1
 292 b4_syncline([@oline@], [@ofile@])])
 293
 294
 295 # b4_define_user_code(MACRO)
 296 # --------------------------
 297 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 298 m4_define([b4_define_user_code],
 299 [m4_define([b4_user_$1],
 300 [b4_user_code([b4_$1])])])
 301
 302
 303 # b4_user_actions
 304 # b4_user_initial_action
 305 # b4_user_post_prologue
 306 # b4_user_pre_prologue
 307 # b4_user_stype
 308 # ----------------------
 309 # Macros that issue user code, ending with synclines.
 310 b4_define_user_code([actions])
 311 b4_define_user_code([initial_action])
 312 b4_define_user_code([post_prologue])
 313 b4_define_user_code([pre_prologue])
 314 b4_define_user_code([stype])
 315
 316
 317 # b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
 318 # --------------------------------------------------------
 319 # Warn if any name of type WHAT is used by the user (as recorded in USER-LIST)
 320 # but is not used by Bison (as recorded by macros in the namespace
 321 # BISON-NAMESPACE).
 322 #
 323 # USER-LIST must expand to a list specifying all grammar occurrences of all
 324 # names of type WHAT.   Each item in the list must be a triplet specifying one
 325 # occurrence: name, start boundary, and end boundary.  Empty string names are
 326 # fine.  An empty list is fine.
 327 #
 328 # For example, to define b4_foo_user_names to be used for USER-LIST with three
 329 # name occurrences and with correct quoting:
 330 #
 331 #   m4_define([b4_foo_user_names],
 332 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 333 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 334 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 335 #
 336 # The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
 337 # is used by Bison (in the front-end or in the skeleton).  Empty string names
 338 # are fine, but it would be ugly for Bison to actually use one.
 339 #
 340 # For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
 341 # the names bar and baz are used by Bison:
 342 #
 343 #   m4_define([b4_foo_bison_names(bar)])
 344 #   m4_define([b4_foo_bison_names(baz)])
 345 #
 346 # To invoke b4_check_user_names with TYPE foo, with USER-LIST
 347 # b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
 348 # quoting:
 349 #
 350 #   b4_check_user_names([[foo]], [b4_foo_user_names],
 351 #                       [[b4_foo_bison_names]])
 352 m4_define([b4_check_user_names],
 353 [m4_foreach([b4_occurrence], $2,
 354 [m4_pushdef([b4_occurrence], b4_occurrence)dnl
 355 m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
 356 m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
 357 m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
 358 m4_ifndef($3[(]m4_quote(b4_user_name)[)],
 359           [b4_warn_at([b4_start], [b4_end],
 360                       [[%s `%s' is not used]],
 361                       [$1], [b4_user_name])])[]dnl
 362 m4_popdef([b4_occurrence])dnl
 363 m4_popdef([b4_user_name])dnl
 364 m4_popdef([b4_start])dnl
 365 m4_popdef([b4_end])dnl
 366 ])])
 367
 368 # b4_percent_define_get(VARIABLE)
 369 # -------------------------------
 370 # Mimic muscle_percent_define_get in ../src/muscle_tab.h exactly.  That is, if
 371 # the %define variable VARIABLE is defined, emit its value.  Also, record
 372 # Bison's usage of VARIABLE by defining
 373 # b4_percent_define_bison_variables(VARIABLE).
 374 #
 375 # For example:
 376 #
 377 #   b4_percent_define_get([[foo]])
 378 m4_define([b4_percent_define_get],
 379 [m4_define([b4_percent_define_bison_variables(]$1[)])dnl
 380 m4_ifdef([b4_percent_define(]$1[)], [m4_indir([b4_percent_define(]$1[)])])])
 381
 382 # b4_percent_define_get_loc(VARIABLE)
 383 # -----------------------------------
 384 # Mimic muscle_percent_define_get_loc in ../src/muscle_tab.h exactly.  That is,
 385 # if the %define variable VARIABLE is undefined, complain fatally since that's
 386 # a Bison or skeleton error.  Otherwise, return its definition location in a
 387 # form approriate for the first two arguments of b4_warn_at, b4_complain_at, or
 388 # b4_fatal_at.  Don't record this as a Bison usage of VARIABLE as there's no
 389 # reason to suspect that the user-supplied value has yet influenced the output.
 390 #
 391 # For example:
 392 #
 393 #   b4_complain_at(b4_percent_define_get_loc([[foo]]), [[invalid foo]])
 394 m4_define([b4_percent_define_get_loc],
 395 [m4_ifdef([b4_percent_define_loc(]$1[)],
 396           [m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
 397 b4_loc[]dnl
 398 m4_popdef([b4_loc])],
 399           [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_get_loc]], [$1])])])
 400
 401 # b4_percent_define_get_syncline(VARIABLE)
 402 # ----------------------------------------
 403 # Mimic muscle_percent_define_get_syncline in ../src/muscle_tab.h exactly.
 404 # That is, if the %define variable VARIABLE is undefined, complain fatally
 405 # since that's a Bison or skeleton error.  Otherwise, return its definition
 406 # location as a b4_syncline invocation.  Don't record this as a Bison usage of
 407 # VARIABLE as there's no reason to suspect that the user-supplied value has yet
 408 # influenced the output.
 409 #
 410 # For example:
 411 #
 412 #   b4_percent_define_get_syncline([[foo]])
 413 m4_define([b4_percent_define_get_syncline],
 414 [m4_ifdef([b4_percent_define_syncline(]$1[)],
 415           [m4_indir([b4_percent_define_syncline(]$1[)])],
 416           [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_get_syncline]], [$1])])])
 417
 418 # b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
 419 # ------------------------------------------------------
 420 # Mimic muscle_percent_define_ifdef in ../src/muscle_tab.h exactly.  That is,
 421 # if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
 422 # IF-FALSE.  Also, record Bison's usage of VARIABLE by defining
 423 # b4_percent_define_bison_variables(VARIABLE).
 424 #
 425 # For example:
 426 #
 427 #   b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
 428 m4_define([b4_percent_define_ifdef],
 429 [m4_ifdef([b4_percent_define(]$1[)],
 430           [m4_define([b4_percent_define_bison_variables(]$1[)])$2],
 431           [$3])])
 432
 433 # b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
 434 # --------------------------------------------------------
 435 # Mimic muscle_percent_define_flag_if in ../src/muscle_tab.h exactly.  That is,
 436 # if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
 437 # If it is defined to "false", expand IF-FALSE.  Complain if it is undefined
 438 # (a Bison or skeleton error since the default value should have been set
 439 # already) or defined to any other value (possibly a user error).  Also, record
 440 # Bison's usage of VARIABLE by defining
 441 # b4_percent_define_bison_variables(VARIABLE).
 442 #
 443 # For example:
 444 #
 445 #   b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
 446 m4_define([b4_percent_define_flag_if],
 447 [b4_percent_define_ifdef([$1],
 448   [m4_case(b4_percent_define_get([$1]),
 449            [], [$2], [true], [$2], [false], [$3],
 450            [m4_expand_once([b4_complain_at(b4_percent_define_get_loc([$1]),
 451                                            [[invalid value for %%define Boolean variable `%s']],
 452                                            [$1])],
 453                            [[b4_percent_define_flag_if($1)]])])],
 454   [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_flag_if]], [$1])])])
 455
 456 # b4_percent_define_default(VARIABLE, DEFAULT)
 457 # --------------------------------------------
 458 # Mimic muscle_percent_define_default in ../src/muscle_tab.h exactly.  That is,
 459 # if the %define variable VARIABLE is undefined, set its value to DEFAULT.
 460 # Don't record this as a Bison usage of VARIABLE as there's no reason to
 461 # suspect that the value has yet influenced the output.
 462 #
 463 # For example:
 464 #
 465 #   b4_percent_define_default([[foo]], [[default value]])
 466 m4_define([b4_percent_define_default],
 467 [m4_ifndef([b4_percent_define(]$1[)],
 468            [m4_define([b4_percent_define(]$1[)], [$2])dnl
 469             m4_define([b4_percent_define_loc(]$1[)],
 470                       [[[[[Bison:b4_percent_define_default]:1.0]], [[[Bison:b4_percent_define_default]:1.0]]]])dnl
 471             m4_define([b4_percent_define_syncline(]$1[)],
 472                       [[]b4_syncline(1, [["[Bison:b4_percent_define_default]"]])[
 473 ]])])])
 474
 475 # b4_percent_define_check_values(VALUES)
 476 # --------------------------------------
 477 # Mimic muscle_percent_define_check_values in ../src/muscle_tab.h exactly
 478 # except that the VALUES structure is more appropriate for M4.  That is, VALUES
 479 # is a list of sublists of strings.  For each sublist, the first string is the
 480 # name of a %define variable, and all remaining strings in that sublist are the
 481 # valid values for that variable.  Complain if such a variable is undefined (a
 482 # Bison error since the default value should have been set already) or defined
 483 # to any other value (possibly a user error).  Don't record this as a Bison
 484 # usage of the variable as there's no reason to suspect that the value has yet
 485 # influenced the output.
 486 #
 487 # For example:
 488 #
 489 #   b4_percent_define_check_values([[[[foo]], [[foo-value1]], [[foo-value2]]]],
 490 #                                  [[[[bar]], [[bar-value1]]]])
 491 m4_define([b4_percent_define_check_values],
 492 [m4_foreach([b4_sublist], m4_quote($@),
 493             [_b4_percent_define_check_values(b4_sublist)])])
 494
 495 m4_define([_b4_percent_define_check_values],
 496 [m4_ifdef([b4_percent_define(]$1[)],
 497   [m4_pushdef([b4_good_value], [0])dnl
 498    m4_if($#, 1, [],
 499          [m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 500                      [m4_if(m4_indir([b4_percent_define(]$1[)]), b4_value,
 501                             [m4_define([b4_good_value], [1])])])])dnl
 502    m4_if(b4_good_value, [0],
 503          [b4_complain_at(b4_percent_define_get_loc([$1]),
 504                          [[invalid value for %%define variable `%s': `%s']],
 505                          [$1],
 506                          m4_dquote(m4_indir([b4_percent_define(]$1[)])))])dnl
 507    m4_popdef([b4_good_value])],
 508   [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_check_values]], [$1])])])
 509
 510 # b4_percent_code_get([QUALIFIER])
 511 # --------------------------------
 512 # If any %code blocks for QUALIFIER are defined, emit them beginning with a
 513 # comment and ending with synclines and a newline.  If QUALIFIER is not
 514 # specified or empty, do this for the unqualified %code blocks.  Also, record
 515 # Bison's usage of QUALIFIER (if specified) by defining
 516 # b4_percent_code_bison_qualifiers(QUALIFIER).
 517 #
 518 # For example, to emit any unqualified %code blocks followed by any %code
 519 # blocks for the qualifier foo:
 520 #
 521 #   b4_percent_code_get
 522 #   b4_percent_code_get([[foo]])
 523 m4_define([b4_percent_code_get],
 524 [m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
 525 m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
 526 m4_ifdef(b4_macro_name,
 527 [b4_comment([m4_if([$#], [0], [[Unqualified %code]],
 528                    [["%code ]$1["]])[ blocks.]])
 529 b4_user_code([m4_indir(b4_macro_name)])
 530 ])dnl
 531 m4_popdef([b4_macro_name])])
 532
 533 # b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
 534 # -----------------------------------------------------
 535 # If any %code blocks for QUALIFIER (or unqualified %code blocks if
 536 # QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
 537 # Also, record Bison's usage of QUALIFIER (if specified) by defining
 538 # b4_percent_code_bison_qualifiers(QUALIFIER).
 539 m4_define([b4_percent_code_ifdef],
 540 [m4_ifdef([b4_percent_code(]$1[)],
 541           [m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
 542           [$3])])
 543
 544
 545 ## ----------------------------------------------------------- ##
 546 ## After processing the skeletons, check that all the user's   ##
 547 ## %define variables and %code qualifiers were used by Bison.  ##
 548 ## ----------------------------------------------------------- ##
 549
 550 m4_define([b4_check_user_names_wrap],
 551 [m4_ifdef([b4_percent_]$1[_user_]$2[s],
 552           [b4_check_user_names([[%]$1 $2],
 553                                [b4_percent_]$1[_user_]$2[s],
 554                                [[b4_percent_]$1[_bison_]$2[s]])])])
 555
 556 m4_wrap_lifo([
 557 b4_check_user_names_wrap([[define]], [[variable]])
 558 b4_check_user_names_wrap([[code]], [[qualifier]])
 559 ])