src/scan-skel.l

   1 /* Scan Bison Skeletons.                                       -*- C -*-
   2
   3    Copyright (C) 2001, 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    Bison is free software; you can redistribute it and/or modify it
   8    under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2, or (at your option)
  10    any later version.
  11
  12    Bison is distributed in the hope that it will be useful, but
  13    WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with Bison; see the file COPYING.  If not, write to the Free
  19    Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301, USA.  */
  21
  22 %option nodefault noyywrap nounput never-interactive debug
  23 %option prefix="skel_" outfile="lex.yy.c"
  24
  25 %{
  26 #include "system.h"
  27
  28 #include <error.h>
  29 #include <quotearg.h>
  30
  31 #include "complain.h"
  32 #include "getargs.h"
  33 #include "files.h"
  34
  35 int skel_lex (void);
  36
  37 /* Pacify "gcc -Wmissing-prototypes" when flex 2.5.31 is used.  */
  38 int skel_get_lineno (void);
  39 FILE *skel_get_in (void);
  40 FILE *skel_get_out (void);
  41 int skel_get_leng (void);
  42 char *skel_get_text (void);
  43 void skel_set_lineno (int);
  44 void skel_set_in (FILE *);
  45 void skel_set_out (FILE *);
  46 int skel_get_debug (void);
  47 void skel_set_debug (int);
  48 int skel_lex_destroy (void);
  49
  50 #define QPUTS(String) \
  51    fputs (quotearg_style (c_quoting_style, (String)), yyout)
  52
  53 %}
  54 %%
  55
  56 %{
  57   int lineno IF_LINT (= 0);
  58   char *outname = NULL;
  59 %}
  60
  61 "@output ".*\n {
  62   char const *filename = yytext + sizeof "@output " - 1;
  63   yytext[yyleng - 1] = '\0';
  64
  65   if (*filename == '@')
  66     {
  67       if (strcmp (filename, "@output_header_name@") == 0)
  68         filename = spec_defines_file;
  69       else if (strcmp (filename, "@output_parser_name@") == 0)
  70         filename = parser_file_name;
  71       else
  72         fatal ("invalid token in skeleton: %s", yytext);
  73     }
  74
  75   if (outname)
  76     {
  77       free (outname);
  78       xfclose (yyout);
  79     }
  80   outname = xstrdup (filename);
  81   yyout = xfopen (outname, "w");
  82   lineno = 1;
  83 }
  84
  85 "@@"       fputc ('@', yyout);
  86 "@{"       fputc ('[', yyout);
  87 "@}"       fputc (']', yyout);
  88
  89 "@oline@"  fprintf (yyout, "%d", lineno + 1);
  90 "@ofile@"  QPUTS (outname);
  91 "@output_parser_name@"  QPUTS (parser_file_name);
  92 "@output_header_name@"  QPUTS (spec_defines_file);
  93
  94   /* This pattern must not match more than the previous @ patterns. */
  95 @[^{}@\n]* fatal ("invalid @ in skeleton: %s", yytext);
  96 \n         lineno++; ECHO;
  97 [^@\n]+    ECHO;
  98
  99 <<EOF>> {
 100   if (outname)
 101     {
 102       free (outname);
 103       xfclose (yyout);
 104     }
 105   return EOF;
 106 }
 107 %%
 108
 109 /*------------------------.
 110 | Scan a Bison skeleton.  |
 111 `------------------------*/
 112
 113 void scan_skel (FILE *);
 114
 115 void
 116 scan_skel (FILE *in)
 117 {
 118   skel_in = in;
 119   skel__flex_debug = trace_flag & trace_skeleton;
 120   skel_lex ();
 121   /* Reclaim Flex's buffers.  */
 122   yy_delete_buffer (YY_CURRENT_BUFFER);
 123 }