tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2013 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 # m4_null_if(VAL, IF-TRUE, IF-FALSE)
  24 # ----------------------------------
  25 # If VAL evaluates to empty or 0, run IF-TRUE, otherwise IF-FALSE.
  26 m4_define([m4_null_if],
  27 [m4_case(m4_quote($1),
  28          [0], [$2],
  29          [],  [$2],
  30          [$3])])
  31
  32 # AT_SETUP_STRIP(TITLE)
  33 # ---------------------
  34 # Abbreviate the TITLE to be passed to AT_SETUP.  Remove new-lines
  35 # that completely break AT_SETUP.
  36 m4_define([AT_SETUP_STRIP],
  37 [m4_bpatsubsts([$1],
  38       [%\(language\|skeleton\) "?\([^\" ]*\)"?],
  39         [\2],
  40       [%define "?\([-A-Za-z0-9_.]+\)"? \("[^\"]+"\|[-A-Za-z0-9_.]+\)],
  41         [\1=\2],
  42       [%define "?\([-A-Za-z0-9_.]+\)"?],
  43         [\1],
  44       [ *
  45 + *],    [ ])dnl
  46 ])
  47
  48
  49 ## ------------- ##
  50 ## Basic tests.  ##
  51 ## ------------- ##
  52
  53 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  54 # ------------------------------------------
  55 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  56 # taken in "slurp" mode, i.e., one can match end-of-lines.
  57 m4_define([AT_MATCHES_CHECK],
  58 [AT_CHECK([$PERL -0777 -ne '
  59 my $count = 0;
  60 s{$2}{ ++$count; "" }gem;
  61 printf "$count\n";' $1], [0], [$3
  62 ])])
  63
  64
  65 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  66 # ------------------------------------------------
  67 # Don't interfere with caller's files.
  68 m4_divert_text([PREPARE_TESTS],
  69 [at_save_special_files ()
  70 {
  71   for at_save_file in stderr experr expout
  72   do
  73     test ! -f at-bison-check-$at_save_file.bak ||
  74       as_fn_error 1 "fatal error: back-up on top of a back-up"
  75     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  76   done
  77 }
  78
  79 at_restore_special_files ()
  80 {
  81   for at_save_file in stderr experr expout
  82   do
  83     test ! -f at-bison-check-$at_save_file.bak ||
  84       mv at-bison-check-$at_save_file.bak $at_save_file
  85   done
  86 }
  87 ])
  88
  89 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  90 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  91
  92
  93
  94 ## ------------------------------- ##
  95 ## Macros decoding Bison options.  ##
  96 ## ------------------------------- ##
  97
  98 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  99 # ----------------------------------------------------------------
 100 # Pushdef AT(_LOC)?_(FIRST|LAST)_(LINE|COLUMN).
 101 m4_define([AT_LOC_PUSHDEF],
 102 [m4_pushdef([AT_FIRST_LINE],  [$1])
 103 m4_pushdef([AT_FIRST_COLUMN], [$2])
 104 m4_pushdef([AT_LAST_LINE],    [$3])
 105 m4_pushdef([AT_LAST_COLUMN],  [$4])
 106 m4_pushdef([AT_LOC_FIRST_LINE],   [AT_LOC.AT_FIRST_LINE])
 107 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.AT_FIRST_COLUMN])
 108 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.AT_LAST_LINE])
 109 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.AT_LAST_COLUMN])])
 110
 111 # AT_LOC_POPDEF
 112 # -------------
 113 # Popdef AT(_LOC)?_(FIRST|LAST)_(LINE|COLUMN).
 114 m4_define([AT_LOC_POPDEF],
 115 [m4_popdef([AT_LOC_FIRST_LINE])
 116 m4_popdef([AT_LOC_FIRST_COLUMN])
 117 m4_popdef([AT_LOC_LAST_LINE])
 118 m4_popdef([AT_LOC_LAST_COLUMN])
 119 m4_popdef([AT_FIRST_LINE])
 120 m4_popdef([AT_FIRST_COLUMN])
 121 m4_popdef([AT_LAST_LINE])
 122 m4_popdef([AT_LAST_COLUMN])
 123 ])
 124
 125
 126
 127 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
 128 # -----------------------------------------
 129 m4_define([AT_BISON_OPTION_PUSHDEFS],
 130 [m4_divert_text([KILL],
 131                 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])])
 132
 133
 134 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
 135 # --------------------------------------------------
 136 # This macro works around the impossibility to define macros
 137 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 138 # This sucks hard, GNU M4 should really provide M5-like $$1.
 139 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 140 [m4_if([$1$2], $[1]$[2], [],
 141        [m4_fatal([$0: Invalid arguments: $@])])dnl
 142 m4_pushdef([AT_DEFINES_IF],
 143 [m4_bmatch([$3], [%defines], [$1], [$2])])
 144 m4_pushdef([AT_DEBUG_IF],
 145 [m4_bmatch([$3], [%debug\|%define parse.trace], [$1], [$2])])
 146 m4_pushdef([AT_SKEL_CC_IF],
 147 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 148 m4_pushdef([AT_SKEL_JAVA_IF],
 149 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 150 # The target language: "c", "c++", or "java".
 151 m4_pushdef([AT_LANG],
 152 [AT_SKEL_JAVA_IF([java],
 153                  [AT_SKEL_CC_IF([c++],
 154                                 [c])])])
 155 m4_pushdef([AT_GLR_IF],
 156 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 157 m4_pushdef([AT_LALR1_CC_IF],
 158 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 159 m4_pushdef([AT_GLR_CC_IF],
 160 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 161 # Using yacc.c?
 162 m4_pushdef([AT_YACC_IF],
 163 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 164 m4_pushdef([AT_LEXPARAM_IF],
 165 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 166 m4_pushdef([AT_LOCATION_IF],
 167 [m4_bmatch([$3], [%locations], [$1], [$2])])
 168 m4_pushdef([AT_LOCATION_TYPE_IF],
 169 [m4_bmatch([$3], [%define \(api\.location\.type\|location_type\)], [$1], [$2])])
 170 m4_pushdef([AT_PARAM_IF],
 171 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 172 # Comma-terminated list of formals parse-parameters.
 173 # E.g., %parse-param { int x } %parse-param {int y} -> "int x, int y, ".
 174 # FIXME: Support grouped parse-param.
 175 m4_pushdef([AT_PARSE_PARAMS])
 176 m4_bpatsubst([$3], [%parse-param { *\([^{}]*[^{} ]\) *}],
 177              [m4_append([AT_PARSE_PARAMS], [\1, ])])
 178
 179 m4_pushdef([AT_PURE_IF],
 180 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 181            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 182            [$2])])
 183 # AT_NAME_PREFIX: also consider api.namespace.
 184 m4_pushdef([AT_NAME_PREFIX],
 185 [m4_bmatch([$3], [\(%define api\.\(namespace\|prefix\)\|%name-prefix\) ".*"],
 186            [m4_bregexp([$3], [\(%define api\.\(namespace\|prefix\)\|%name-prefix\) "\([^""]*\)"], [\3])],
 187            [yy])])
 188 m4_pushdef([AT_TOKEN_CTOR_IF],
 189 [m4_bmatch([$3], [%define api\.token\.constructor], [$1], [$2])])
 190 m4_pushdef([AT_TOKEN_PREFIX],
 191 [m4_bmatch([$3], [%define api\.token\.prefix ".*"],
 192            [m4_bregexp([$3], [%define api\.token\.prefix "\(.*\)"], [\1])])])
 193 m4_pushdef([AT_VARIANT_IF],
 194 [m4_bmatch([$3], [%define api\.value\.type "?variant"?], [$1], [$2])])
 195 m4_pushdef([AT_API_prefix],
 196 [m4_bmatch([$3], [%define api\.prefix ".*"],
 197            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 198            [yy])])
 199 m4_pushdef([AT_API_PREFIX],
 200 [m4_toupper(AT_API_prefix)])
 201 # yyerror receives the location if %location, and if the parser is pure. For
 202 # historical reasons, with the "yacc.c" skeleton, the location is not passed
 203 # unless an additional "%parse-param" is present, or if the purity is defined
 204 # as "full".
 205 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 206 [AT_LOCATION_IF([AT_PURE_IF([m4_bmatch([$3],
 207                                        m4_quote(m4_join([\|],
 208                                                         [%define api\.pure "?full"?],
 209                                                         [%glr-parser],
 210                                                         [%parse-param],
 211                                                         [%skeleton "?glr.c"?])),
 212                                        [$1], [$2])],
 213                             [$2])],
 214                     [$2])])
 215
 216 # yyerror always sees the locations (when activated) if the parser is impure.
 217 # When the parser is pure, yyerror sees the location if it is received as an
 218 # argument.
 219 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 220 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_YYERROR_ARG_LOC_IF([$1], [$2])],
 221                                         [$1])],
 222                             [$1])],
 223                 [$2])])
 224
 225 # The interface is pure: either because %define api.pure, or because we
 226 # are using the C++ parsers.
 227 m4_pushdef([AT_PURE_LEX_IF],
 228 [AT_PURE_IF([$1],
 229             [AT_SKEL_CC_IF([$1], [$2])])])
 230
 231 m4_pushdef([AT_YYSTYPE],
 232 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 233                [AT_API_PREFIX[STYPE]])])
 234 m4_pushdef([AT_YYLTYPE],
 235 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 236                [AT_API_PREFIX[LTYPE]])])
 237
 238
 239 AT_PURE_LEX_IF(
 240 [m4_pushdef([AT_LOC], [(*llocp)])
 241  m4_pushdef([AT_VAL], [(*lvalp)])
 242  m4_pushdef([AT_YYLEX_FORMALS],
 243             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 244  m4_pushdef([AT_YYLEX_ARGS],
 245             [lvalp[]AT_LOCATION_IF([, llocp])])
 246  m4_pushdef([AT_USE_LEX_ARGS],
 247             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 248  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 249             [AT_YYLEX_FORMALS, ])
 250  m4_pushdef([AT_YYLEX_PRE_ARGS],
 251             [AT_YYLEX_ARGS, ])
 252 ],
 253 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 254  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 255  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 256  m4_pushdef([AT_YYLEX_ARGS],        [])
 257  m4_pushdef([AT_USE_LEX_ARGS],    [])
 258  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 259  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 260 ])
 261
 262 # Handle the different types of location components.
 263
 264 AT_SKEL_CC_IF(
 265   [AT_LOCATION_TYPE_IF(
 266     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 267     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 268   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 269
 270
 271 AT_GLR_IF([AT_KEYWORDS([glr])])
 272 ])# _AT_BISON_OPTION_PUSHDEFS
 273
 274
 275 # AT_BISON_OPTION_POPDEFS
 276 # -----------------------
 277 m4_define([AT_BISON_OPTION_POPDEFS],
 278 [m4_divert_text([KILL],
 279 [m4_popdef([AT_YYLEX_PRE_ARGS])
 280 m4_popdef([AT_YYLEX_PRE_FORMALS])
 281 m4_popdef([AT_USE_LEX_ARGS])
 282 m4_popdef([AT_YYLEX_ARGS])
 283 m4_popdef([AT_YYLEX_FORMALS])
 284 m4_popdef([AT_YYLTYPE])
 285 m4_popdef([AT_YYSTYPE])
 286 m4_popdef([AT_VAL])
 287 m4_popdef([AT_LOC])
 288 m4_popdef([AT_PURE_LEX_IF])
 289 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 290 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 291 m4_popdef([AT_API_PREFIX])
 292 m4_popdef([AT_API_prefix])
 293 m4_popdef([AT_VARIANT_IF])
 294 m4_popdef([AT_TOKEN_PREFIX])
 295 m4_popdef([AT_TOKEN_CTOR_IF])
 296 m4_popdef([AT_NAME_PREFIX])
 297 m4_popdef([AT_LOCATION_TYPE_IF])
 298 m4_popdef([AT_LOCATION_IF])
 299 m4_popdef([AT_PARSE_PARAMS])
 300 m4_popdef([AT_PARAM_IF])
 301 m4_popdef([AT_LEXPARAM_IF])
 302 m4_popdef([AT_YACC_IF])
 303 m4_popdef([AT_GLR_IF])
 304 m4_popdef([AT_SKEL_CC_IF])
 305 m4_popdef([AT_LANG])
 306 m4_popdef([AT_SKEL_JAVA_IF])
 307 m4_popdef([AT_GLR_CC_IF])
 308 m4_popdef([AT_LALR1_CC_IF])
 309 m4_popdef([AT_DEFINES_IF])
 310 m4_popdef([AT_DEBUG_IF])
 311 AT_LOC_POPDEF])dnl
 312 ])# AT_BISON_OPTION_POPDEFS
 313
 314
 315
 316 ## -------------------------- ##
 317 ## Generating Grammar Files.  ##
 318 ## -------------------------- ##
 319
 320 # AT_DATA_SOURCE_PROLOGUE
 321 # ------------------------
 322 # The prologue that should be included in any source code that is
 323 # meant to be compiled.
 324 m4_define([AT_DATA_SOURCE_PROLOGUE],
 325 [[#include <config.h>
 326 /* We don't need perfect functions for these tests. */
 327 #undef malloc
 328 #undef memcmp
 329 #undef realloc
 330 ]])
 331
 332 # AT_DATA_GRAMMAR_PROLOGUE
 333 # ------------------------
 334 # The prologue that should be included in any grammar which parser is
 335 # meant to be compiled.
 336 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 337 [[%code top {
 338 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 339 [}
 340 ]])
 341
 342 # AT_DATA_SOURCE(NAME, CONTENT)
 343 # -----------------------------
 344 # Generate the file NAME, which CONTENT is preceded by
 345 # AT_DATA_SOURCE_PROLOGUE.
 346 m4_define([AT_DATA_SOURCE],
 347 [AT_DATA([$1],
 348 [AT_DATA_SOURCE_PROLOGUE
 349 $2])
 350 ])
 351
 352 # AT_DATA_GRAMMAR(NAME, CONTENT)
 353 # ------------------------------
 354 # Generate the file NAME, which CONTENT is preceded by
 355 # AT_DATA_GRAMMAR_PROLOGUE.
 356 m4_define([AT_DATA_GRAMMAR],
 357 [AT_DATA([$1],
 358 [AT_DATA_GRAMMAR_PROLOGUE
 359 $2])
 360 ])
 361
 362 # AT_YYLEX_PROTOTYPE
 363 # AT_YYLEX_DECLARE_EXTERN
 364 # AT_YYLEX_DECLARE
 365 # AT_YYLEX_DEFINE([INPUT], [ACTION])
 366 # ----------------------------------
 367 # INPUT can be empty, or in double quotes, or a list (in braces).
 368 # ACTION may compute yylval for instance, using "res" as token type,
 369 # and "toknum" as the number of calls to yylex (starting at 0).
 370 m4_define([AT_YYLEX_PROTOTYPE],
 371 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 372 ])
 373
 374 m4_define([AT_YYLEX_DECLARE_EXTERN],
 375 [AT_YYLEX_PROTOTYPE;dnl
 376 ])
 377
 378 m4_define([AT_YYLEX_DECLARE],
 379 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 380 ])
 381
 382 m4_define([AT_YYLEX_DEFINE],
 383 [[#include <assert.h>
 384 static
 385 ]AT_YYLEX_PROTOTYPE[
 386 {
 387   ]m4_bmatch([$1], [^\(".*"\)?$],
 388              [[static char const input[] = ]m4_default([$1], [""])],
 389              [[static int const input[] = ]$1])[;
 390   static size_t toknum = 0;
 391   int res;
 392   ]AT_USE_LEX_ARGS[;
 393   assert (toknum < sizeof input / sizeof input[0]);
 394   res = input[toknum++];
 395   ]$2[;]AT_LOCATION_IF([[
 396   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 397   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 398   return res;
 399 }]dnl
 400 ])
 401
 402 # AT_YYERROR_FORMALS
 403 # AT_YYERROR_PROTOTYPE
 404 # AT_YYERROR_DECLARE_EXTERN
 405 # AT_YYERROR_DECLARE
 406 # AT_YYERROR_DEFINE
 407 # -------------------------
 408 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 409 m4_define([AT_YYERROR_FORMALS],
 410 [m4_case(AT_LANG,
 411 [c], [AT_YYERROR_ARG_LOC_IF([AT_YYLTYPE const * const llocp, ])AT_PARSE_PARAMS [const char *msg]])[]dnl
 412 ])
 413
 414 m4_define([AT_YYERROR_PROTOTYPE],
 415 [m4_case(AT_LANG,
 416 [c], [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])[]dnl
 417 ])
 418
 419 m4_define([AT_YYERROR_DECLARE_EXTERN],
 420 [m4_case(AT_LANG,
 421 [c], [AT_YYERROR_PROTOTYPE;])[]dnl
 422 ])
 423
 424 m4_define([AT_YYERROR_DECLARE],
 425 [m4_case(AT_LANG,
 426 [c], [#include <stdio.h>
 427 ]AT_LOCATION_IF([[
 428 #if defined ]AT_YYLTYPE[_IS_TRIVIAL && ]AT_YYLTYPE[_IS_TRIVIAL
 429 static unsigned location_print (FILE *yyo, ]AT_YYLTYPE[ const * const yylocp);
 430 # ifndef LOCATION_PRINT
 431 #  define LOCATION_PRINT(File, Loc) location_print (File, &(Loc))
 432 # endif
 433 #endif
 434 ]])[
 435 static AT_YYERROR_DECLARE_EXTERN])[]dnl
 436 ])
 437
 438 m4_define([AT_YYERROR_DEFINE],
 439 [m4_case(AT_LANG,
 440 [c], [[
 441 ]AT_LOCATION_IF([[
 442 # if defined ]AT_YYLTYPE[_IS_TRIVIAL && ]AT_YYLTYPE[_IS_TRIVIAL
 443 /* Print *YYLOCP on YYO. */
 444 __attribute__((__unused__))
 445 static unsigned
 446 location_print (FILE *yyo, ]AT_YYLTYPE[ const * const yylocp)
 447 {
 448   unsigned res = 0;
 449   int end_col = 0 != yylocp->last_column ? yylocp->last_column - 1 : 0;
 450   if (0 <= yylocp->first_line)
 451     {
 452       res += fprintf (yyo, "%d", yylocp->first_line);
 453       if (0 <= yylocp->first_column)
 454         res += fprintf (yyo, ".%d", yylocp->first_column);
 455     }
 456   if (0 <= yylocp->last_line)
 457     {
 458       if (yylocp->first_line < yylocp->last_line)
 459         {
 460           res += fprintf (yyo, "-%d", yylocp->last_line);
 461           if (0 <= end_col)
 462             res += fprintf (yyo, ".%d", end_col);
 463         }
 464       else if (0 <= end_col && yylocp->first_column < end_col)
 465         res += fprintf (yyo, "-%d", end_col);
 466     }
 467   return res;
 468 }
 469 #endif
 470 ]])[
 471 /* A C error reporting function.  */
 472 static
 473 ]AT_YYERROR_PROTOTYPE[
 474 {]m4_bpatsubst(m4_defn([AT_PARSE_PARAMS]),
 475               [[^,]+[^A-Za-z_0-9]\([A-Za-z_][A-Za-z_0-9]*\), *], [
 476   YYUSE(\1);])dnl
 477 AT_YYERROR_SEES_LOC_IF([[
 478   LOCATION_PRINT (stderr, ]AT_LOC[);
 479   fprintf (stderr, ": ");]])[
 480   fprintf (stderr, "%s\n", msg);
 481 }]],
 482 [c++], [[/* A C++ error reporting function.  */
 483 void
 484 ]AT_NAME_PREFIX[::parser::error (]AT_LOCATION_IF([[const location_type& l, ]])[const std::string& m)
 485 {
 486   std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 487 }]],
 488 [java], [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 489 {
 490     if (l == null)
 491       System.err.println (s);
 492     else
 493       System.err.println (l + ": " + s);
 494   }
 495 ]], [[
 496   public void yyerror (String s)
 497   {
 498     System.err.println (s);
 499   }]])],
 500 [m4_fatal([$0: invalid language: ]AT_LANG)])dnl
 501 ])
 502
 503
 504 # AT_MAIN_DEFINE
 505 # --------------
 506 m4_define([AT_MAIN_DEFINE],
 507 [m4_case(AT_LANG,
 508 [c],
 509 [[#include <stdlib.h> /* getenv. */
 510 #include <string.h> /* strcmp. */
 511 int
 512 main (int argc, char const* argv[])
 513 {]AT_DEBUG_IF([[
 514   if (getenv("YYDEBUG")
 515       || (argc == 2
 516           && (!strcmp (argv[1], "-d") || !strcmp (argv[1], "--debug"))))
 517     yydebug |= 1;]], [[
 518   (void) argc;
 519   (void) argv;]])[
 520   return ]AT_NAME_PREFIX[parse ();
 521 }]],
 522 [c++],
 523 [[#include <cstdlib> // getenv.
 524 #include <cstring> // strcmp.
 525 int
 526 main (int argc, char const* argv[])
 527 {
 528   ]AT_NAME_PREFIX[::parser p;]AT_DEBUG_IF([[
 529   if (getenv("YYDEBUG")
 530       || (argc == 2
 531           && (!strcmp (argv[1], "-d") || !strcmp (argv[1], "--debug"))))
 532     p.set_debug_level (true);]], [[
 533   (void) argc;
 534   (void) argv;]])[
 535   return p.parse ();
 536 }]],
 537 [java],
 538 [[class input
 539 {
 540   public static void main (String args[]) throws IOException
 541   {
 542     YYParser p = new YYParser ();
 543     p.parse ();
 544   }
 545 }]])])
 546
 547
 548 ## --------------- ##
 549 ## Running Bison.  ##
 550 ## --------------- ##
 551
 552 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 553 # -------------------------------------------------
 554 # High-level routine that may call bison several times, under different
 555 # conditions.
 556 #
 557 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 558 # shell constructs (such as redirection or pipes) that would prevent
 559 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 560 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 561 #
 562 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 563 # Bison in the test suite.  For now it ensures that:
 564 #
 565 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 566 #      a non-zero exit status since Bison doesn't always try to free all memory
 567 #      in that case.
 568 #
 569 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 570 #      --graph and --report=all output for every working grammar.
 571 #
 572 #   3. If stderr contains a warning, -Werror and --warnings=error
 573 #      convert the warning to an error.
 574 #
 575 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 576 m4_define([AT_BISON_CHECK],
 577 [m4_null_if([$2], [AT_BISON_CHECK_XML($@)])
 578 AT_BISON_CHECK_NO_XML($@)])
 579
 580 # AT_BISON_CHECK_(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 581 # --------------------------------------------------
 582 # Low-level macro to run bison once.
 583 m4_define([AT_BISON_CHECK_],
 584 [AT_CHECK(AT_QUELL_VALGRIND[[ bison -fno-caret ]]$@)])
 585
 586
 587 # AT_BISON_CHECK_WARNINGS(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 588 # ----------------------------------------------------------
 589 # Check that warnings (if some are expected) are correctly
 590 # turned into errors with -Werror, etc.
 591 m4_define([AT_BISON_CHECK_WARNINGS],
 592 [m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 593       [m4_null_if([$2], [AT_BISON_CHECK_WARNINGS_($@)])])])
 594
 595 m4_define([AT_BISON_CHECK_WARNINGS_],
 596 [[# Defining POSIXLY_CORRECT causes bison to complain if options are
 597 # added after the grammar file name, so skip these checks in that
 598 # case.
 599 if test "$POSIXLY_CORRECT_IS_EXPORTED" = false; then
 600           ]AT_SAVE_SPECIAL_FILES[
 601
 602   # To avoid expanding it repeatedly, store specified stdout.
 603   ]AT_DATA([expout], [$3])[
 604
 605   # Run with -Werror.
 606   ]AT_BISON_CHECK_([$1[ -Werror]], [[1]], [expout], [stderr])[
 607
 608   # Build expected stderr up to and including the "warnings being
 609   # treated as errors" message.
 610   ]AT_DATA([[experr]], [$4])[
 611   $PERL -pi -e 's{(.*): warning: (.*)\[-W(.*)\]$}
 612                  {$][1: error: $][2\@<:@-Werror=$][3@:>@}' experr
 613   ]AT_CHECK([[sed 's,.*/$,,' stderr 1>&2]], [[0]], [[]], [experr])[
 614
 615   # Now check --warnings=error.
 616   cp stderr experr
 617   ]AT_BISON_CHECK_([$1[ --warnings=error]], [[1]], [expout], [experr])[
 618
 619   # Now check -Wnone and --warnings=none by making sure that
 620   # -Werror doesn't change the exit status when -Wnone or
 621   # --warnings=none is specified.
 622   ]AT_BISON_CHECK_([$1[ -Wnone -Werror]], [[0]], [expout])[
 623   ]AT_BISON_CHECK_([$1[ --warnings=none -Werror]], [[0]], [expout])[
 624
 625   ]AT_RESTORE_SPECIAL_FILES[
 626 fi]dnl
 627 ])
 628
 629 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 630 # --------------------------------------------------------
 631 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 632 # when a tortured grammar's XML is known to be too large for xsltproc to
 633 # handle.
 634 m4_define([AT_BISON_CHECK_NO_XML],
 635 [AT_CHECK(m4_null_if([$2], [], [AT_QUELL_VALGRIND ])[[bison -fno-caret ]]$@)
 636 AT_BISON_CHECK_WARNINGS($@)])
 637
 638 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 639 # -----------------------------------------------------
 640 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 641 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 642 # have a non-zero exit status.
 643 m4_define([AT_BISON_CHECK_XML],
 644 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 645   AT_SAVE_SPECIAL_FILES
 646   [mkdir xml-tests]
 647   m4_pushdef([AT_BISON_ARGS],
 648              [m4_bpatsubsts([[$1]],
 649                             [--report(-file)?=[^][ ]*], [],
 650                             [--graph=[^][ ]*], [],
 651                             [--xml=[^][ ]*], [])])dnl
 652   # Don't combine these Bison invocations since we want to be sure that
 653   # --report=all isn't required to get the full XML file.
 654   AT_BISON_CHECK_([[--report=all --report-file=xml-tests/test.output \
 655              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 656            [[0]], [ignore], [ignore])
 657   AT_BISON_CHECK_([[--xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 658            [[0]], [ignore], [ignore])
 659   m4_popdef([AT_BISON_ARGS])dnl
 660   [cp xml-tests/test.output expout]
 661   AT_CHECK([[$XSLTPROC \
 662              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 663              xml-tests/test.xml]], [[0]], [expout])
 664   [sort xml-tests/test.dot > expout]
 665   AT_CHECK([[$XSLTPROC \
 666              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 667              xml-tests/test.xml | sort]], [[0]], [expout])
 668   [rm -rf xml-tests expout]
 669   AT_RESTORE_SPECIAL_FILES
 670 [fi]])
 671
 672 # AT_QUELL_VALGRIND
 673 # -----------------
 674 # Put this before a Bison invocation to keep Valgrind from complaining about
 675 # reachable memory.
 676 #
 677 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 678 # The triple quoting below will cause test cases to fail if you do.  If you do
 679 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 680 # will then fail to shell-escape its contents when attempting to print them.
 681 # The testsuite verbose output, at least, will be incorrect, but nothing may
 682 # fail to make sure you notice.
 683 m4_define([AT_QUELL_VALGRIND],
 684 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 685
 686
 687
 688 ## ------------------------ ##
 689 ## Compiling C, C++ Files.  ##
 690 ## ------------------------ ##
 691
 692
 693 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 694 # ----------------------------------------
 695 # Compile SOURCES into OUTPUT.
 696 #
 697 # If OUTPUT does not contain '.', assume that we are linking too,
 698 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 699 # with trailing .o removed, and ".c" appended.
 700 m4_define([AT_COMPILE],
 701 [AT_CHECK([$BISON_C_WORKS], 0, ignore, ignore)
 702 AT_CHECK(m4_join([ ],
 703                   [$CC $CFLAGS $CPPFLAGS],
 704                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 705                   [-o $1],
 706                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 707                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 708            0, [ignore], [ignore])])
 709
 710 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 711 # ---------------------------------------------
 712 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 713 # ignore the test.
 714 #
 715 # If OUTPUT does not contain '.', assume that we are linking too,
 716 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 717 # with trailing .o removed, and ".cc" appended.
 718 m4_define([AT_COMPILE_CXX],
 719 [AT_KEYWORDS(c++)
 720 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 721 AT_CHECK(m4_join([ ],
 722                  [$CXX $CXXFLAGS $CPPFLAGS],
 723                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 724                  [-o $1],
 725                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 726                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 727          0, [ignore], [ignore])])
 728
 729 # AT_JAVA_COMPILE(SOURCES)
 730 # ------------------------
 731 # Compile SOURCES into Java class files.  Skip the test if java or javac
 732 # is not installed.
 733 m4_define([AT_JAVA_COMPILE],
 734 [AT_KEYWORDS(java)
 735 AT_SKIP_IF([[test -z "$CONF_JAVAC"]])
 736 AT_SKIP_IF([[test -z "$CONF_JAVA"]])
 737 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 738          [[0]], [ignore], [ignore])])
 739
 740 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 741 # --------------------------------------------
 742 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 743 #
 744 # If OUTPUT does not contain '.', assume that we are linking too,
 745 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 746 # with trailing .o removed, and ".c"/".cc" appended.
 747 m4_define([AT_LANG_COMPILE],
 748 [m4_case(AT_LANG,
 749 [c],    [AT_COMPILE([$1], [$2])],
 750 [c++],  [AT_COMPILE_CXX([$1], [$2])],
 751 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 752         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 753 ])
 754
 755 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 756 # -------------------------------------------
 757 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 758 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 759 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 760 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 761 # AT_SKEL_JAVA_IF.
 762 m4_define([AT_FULL_COMPILE],
 763 [m4_case(AT_LANG,
 764 [java],
 765   [AT_BISON_CHECK([-o $1.java $1.y])
 766    AT_LANG_COMPILE([$1],
 767                     m4_join([ ],
 768                             [$1.java],
 769                             m4_ifval($2, [[$1-$2.java]]),
 770                            m4_ifval($3, [[$1-$3.java]])))],
 771 [c++],
 772   [AT_BISON_CHECK([-o $1.cc $1.y])
 773    AT_LANG_COMPILE([$1],
 774                      m4_join([ ],
 775                              [$1.cc],
 776                              m4_ifval($2, [[$1-$2.cc]]),
 777                            m4_ifval($3, [[$1-$3.cc]])))],
 778 [c],
 779   [AT_BISON_CHECK([-o $1.c $1.y])
 780    AT_LANG_COMPILE([$1],
 781                   m4_join([ ],
 782                           [$1.c],
 783                           m4_ifval($2, [[$1-$2.c]]),
 784                            m4_ifval($3, [[$1-$3.c]])))])
 785 ])
 786
 787
 788
 789 # AT_SKIP_IF_CANNOT_LINK_C_AND_CXX
 790 # --------------------------------
 791 # Check that we can link together C and C++ objects.
 792 m4_define([AT_SKIP_IF_CANNOT_LINK_C_AND_CXX],
 793 [AT_DATA([c-and-cxx.h],
 794 [[#ifdef __cplusplus
 795 extern "C"
 796 {
 797 #endif
 798   int fortytwo (void);
 799 #ifdef __cplusplus
 800 }
 801 #endif
 802 ]])
 803 AT_DATA([c-only.c],
 804 [[#include "c-and-cxx.h"
 805 int
 806 main (void)
 807 {
 808   return fortytwo () == 42 ? 0 : 1;
 809 }
 810 ]])
 811 AT_DATA([cxx-only.cc],
 812 [[#include "c-and-cxx.h"
 813 int fortytwo ()
 814 {
 815   return 42;
 816 }
 817 ]])
 818 AT_COMPILE([c-only.o], [c-only.c])
 819 AT_COMPILE_CXX([cxx-only.o], [cxx-only.cc])
 820 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS $LDFLAGS c-only.o cxx-only.o -o c-and-cxx ||
 821           exit 77], [ignore], [ignore])
 822 AT_PARSER_CHECK([./c-and-cxx])
 823 ])
 824
 825
 826 ## ---------------------------- ##
 827 ## Running a generated parser.  ##
 828 ## ---------------------------- ##
 829
 830
 831 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 832 # ------------------------------------------------------------
 833 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 834 #
 835 # Get rid of spurious messages when compiled with --coverage:
 836 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 837 m4_define([AT_PARSER_CHECK],
 838 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 839 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 840          [0], [], [$4])
 841 ])
 842
 843
 844 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 845 # -----------------------------------------------------------------
 846 m4_define([AT_JAVA_PARSER_CHECK],
 847 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 848
 849
 850 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 851 #                          DECLS, GRAMMAR, INPUT,
 852 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 853 #                          [OTHER-CHECKS],
 854 #                          [PARSER-EXIT-VALUE],
 855 #                          [PARSER-STDOUT], [PARSER-STDERR])
 856 # -------------------------------------------------------------
 857 # Using TITLE as the test group title, check the generated parser tables
 858 # and parser for a specified grammar file under a condition labeled by
 859 # COND-VALUE.
 860 #
 861 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 862 # recognized attribute is described below where it is relevant.
 863 #
 864 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 865 # the grammar file.  Insert basic yyerror, yylex, and main function
 866 # definitions as well.  Hardcode yylex to return the (possibly empty)
 867 # comma-delimited series of tokens in INPUT followed by token 0.
 868 #
 869 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 870 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 871 # On the bison command-line, specify `--report=all --defines'.  Check
 872 # that Bison exits with value 0, has no stdout, and has stderr
 873 # BISON-STDERR.
 874 #
 875 # If TEST-SPEC contains the attribute `last-state', check that the value
 876 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 877 # the grammar; in other words, check the number of states (minus one).
 878 # Otherwise, check that everything in the `.output' file starting with
 879 # the definition of state 0 is the same as the entire value of
 880 # TABLES-OR-LAST-STATE.
 881 #
 882 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 883 # `.output' file, which is named `input.output', and/or grammar file,
 884 # which is named `input.y'.
 885 #
 886 # Finally, compile the generated parser and then run it using
 887 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 888 # PARSER-STDERR as the 2nd-4th arguments.
 889 #
 890 # As a precondition, you must properly double-quote all arguments that
 891 # are to be interpreted as strings.
 892 #
 893 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 894 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 895 # first argument.  This is useful, for example, when wrapping multiple
 896 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 897 # condition, in another macro.
 898 #
 899 # For example:
 900 #
 901 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 902 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 903 #   # ---------------------------------------------------------------------
 904 #   m4_define([AT_TEST_SYNTAX_ERROR],
 905 #   [
 906 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 907 #                              [[last-state]],
 908 #                              [[%error-verbose ]$2], [$3], [$4],
 909 #                              [[]], [$5], [], [$6], [$7], [$8])
 910 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 911 #                              [[last-state]],
 912 #                              [$2], [$3], [$4],
 913 #                              [[]], [$5], [], [$6], [$7], [$8])
 914 #   ])
 915 #
 916 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 917 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 918 #                        [[3]],
 919 #                        [[1]], [[]],
 920 #                        [AT_COND_CASE([[no verbose]],
 921 #                                      [[syntax error
 922 #   ]],
 923 #                                      [[syntax error, unexpected 'b', expecting $end
 924 #   ]])])
 925 m4_define([AT_TEST_TABLES_AND_PARSE],
 926 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 927
 928 AT_SETUP([$1])
 929 AT_BISON_OPTION_PUSHDEFS([$4])
 930 AT_DATA_GRAMMAR([[input.y]],
 931 [[%code {
 932   ]AT_YYERROR_DECLARE[
 933   ]AT_YYLEX_DECLARE[
 934 }
 935
 936 ]$4[
 937
 938 %%
 939
 940 ]$5[
 941
 942 %%
 943 ]AT_YYERROR_DEFINE[
 944 static int
 945 yylex (void)
 946 {
 947   static int const input[] = {
 948     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 949   };
 950   static int const *inputp = input;
 951   return *inputp++;
 952 }
 953
 954 ]AT_MAIN_DEFINE[
 955 ]])
 956
 957 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 958 # expanding macros, so it corrupts some special characters in the
 959 # macros.  To avoid this, expand now and pass it the result with proper
 960 # string quotation.  Assume args 7 through 12 expand to properly quoted
 961 # strings.
 962
 963 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 964       [AT_BISON_CHECK],
 965       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 966                                [0], [], m4_dquote($7))
 967
 968 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 969       [AT_CHECK([[sed -n '/^State 0$/,$p' input.output]], [[0]],
 970                 m4_dquote($8))],
 971       [AT_CHECK([[sed -n 's/^State //p' input.output | tail -1]], [[0]],
 972                 m4_dquote($8)[[
 973 ]])])
 974
 975 $9
 976
 977 # Canonical LR generates very large tables, resulting in very long
 978 # files with #line directives that may overflow what the standards
 979 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 980 # will issue an error.
 981 #
 982 # There is no "" around `wc` since some indent the result.
 983 m4_bmatch([$4], [%define lr.type canonical-lr],
 984 [if test 32767 -lt `wc -l < input.c`; then
 985   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 986   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 987 fi])
 988 AT_COMPILE([[input]])
 989
 990 AT_PARSER_CHECK([[./input]],
 991                 m4_ifval([$10], [m4_dquote($10)]),
 992                 m4_ifval([$11], [m4_dquote($11)]),
 993                 m4_ifval([$12], [m4_dquote($12)]))
 994
 995 AT_BISON_OPTION_POPDEFS
 996 AT_CLEANUP
 997
 998 m4_popdef([AT_COND_CASE])])
 999
1000
1001
1002
1003 ## ----------------------- ##
1004 ## Launch the test suite.  ##
1005 ## ----------------------- ##
1006
1007 AT_INIT
1008
1009 # AT_SETUP([TITLE])
1010 # -----------------
1011 # Redefine AT_SETUP to be more concise.  Must be done after AT_INIT.
1012 m4_copy_force([AT_SETUP], [B4_SETUP])
1013 m4_define([AT_SETUP],
1014 [B4_SETUP(m4_expand([AT_SETUP_STRIP([[$1]])]))])
1015
1016 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
1017 # options are processed, so we don't know the value of CXX and
1018 # CXXFLAGS yet.
1019 #
1020 # Note that it also means that command line values for CXX and
1021 # CXXFLAGS will not be propagated to CC and CFLAGS.
1022 AT_ARG_OPTION([compile-c-with-cxx],
1023               [compile C parsers with the C++ compiler])
1024
1025 AT_COLOR_TESTS
1026
1027 AT_TESTED([bison])