src/scan-skel.l

   1 /* Scan Bison Skeletons.                                       -*- C -*-
   2
   3    Copyright (C) 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    Bison is free software; you can redistribute it and/or modify it
   8    under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2, or (at your option)
  10    any later version.
  11
  12    Bison is distributed in the hope that it will be useful, but
  13    WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with Bison; see the file COPYING.  If not, write to the Free
  19    Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20    02111-1307, USA.  */
  21
  22 %option nodefault noyywrap nounput never-interactive debug
  23 %option prefix="skel_" outfile="lex.yy.c"
  24
  25 %{
  26 #include "system.h"
  27
  28 #include <error.h>
  29 #include <quotearg.h>
  30
  31 #include "complain.h"
  32 #include "getargs.h"
  33 #include "files.h"
  34
  35 int skel_lex (void);
  36
  37 #define QPUTS(String) \
  38    fputs (quotearg_style (c_quoting_style, (String)), yyout)
  39
  40 %}
  41 %%
  42
  43 %{
  44   int lineno IF_LINT (= 0);
  45   char *outname = NULL;
  46 %}
  47
  48 "@output ".*\n {
  49   char const *filename = yytext + sizeof "@output " - 1;
  50   yytext[yyleng - 1] = '\0';
  51
  52   if (*filename == '@')
  53     {
  54       if (strcmp (filename, "@output_header_name@") == 0)
  55         filename = spec_defines_file;
  56       else if (strcmp (filename, "@output_parser_name@") == 0)
  57         filename = parser_file_name;
  58       else
  59         fatal ("invalid token in skeleton: %s", yytext);
  60     }
  61
  62   free (outname);
  63   outname = xstrdup (filename);
  64   xfclose (yyout);
  65   yyout = xfopen (outname, "w");
  66   lineno = 1;
  67 }
  68
  69 "@@"       fputc ('@', yyout);
  70 "@{"       fputc ('[', yyout);
  71 "@}"       fputc (']', yyout);
  72
  73 "@oline@"  fprintf (yyout, "%d", lineno + 1);
  74 "@ofile@"  QPUTS (outname);
  75 "@output_parser_name@"  QPUTS (parser_file_name);
  76 "@output_header_name@"  QPUTS (spec_defines_file);
  77
  78   /* This pattern must not match more than the previous @ patterns. */
  79 @[^{}@\n]* fatal ("invalid @ in skeleton: %s", yytext);
  80 \n         lineno++; ECHO;
  81 [^@\n]+    ECHO;
  82
  83 <<EOF>>    xfclose (yyout); free (outname); return EOF;
  84 %%
  85
  86 /*------------------------.
  87 | Scan a Bison skeleton.  |
  88 `------------------------*/
  89
  90 void scan_skel (FILE *);
  91
  92 void
  93 scan_skel (FILE *in)
  94 {
  95   skel_in = in;
  96   skel__flex_debug = trace_flag & trace_skeleton;
  97   skel_lex ();
  98   /* Reclaim Flex's buffers.  */
  99   yy_delete_buffer (YY_CURRENT_BUFFER);
 100 }