tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2013 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 # m4_null_if(VAL, IF-TRUE, IF-FALSE)
  24 # ----------------------------------
  25 # If VAL evaluates to empty or 0, run IF-TRUE, otherwise IF-FALSE.
  26 m4_define([m4_null_if],
  27 [m4_case(m4_quote($1),
  28          [0], [$2],
  29          [],  [$2],
  30          [$3])])
  31
  32 # AT_SETUP_STRIP(TITLE)
  33 # ---------------------
  34 # Abbreviate the TITLE to be passed to AT_SETUP.
  35 m4_define([AT_SETUP_STRIP],
  36 [m4_bpatsubsts([$1],
  37       [%\(language\|skeleton\) "?\([^\" ]*\)"?],
  38         [\2],
  39       [%define "?\([-A-Za-z0-9_.]+\)"? \("\([^\" ]+\)"\|\([-A-Za-z0-9_.]+\)\)],
  40         [\1=\3\4],
  41       [%define "?\([-A-Za-z0-9_.]+\)"?],
  42         [\1])dnl
  43 ])
  44
  45
  46 ## ------------- ##
  47 ## Basic tests.  ##
  48 ## ------------- ##
  49
  50 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  51 # ------------------------------------------
  52 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  53 # taken in "slurp" mode, i.e., one can match end-of-lines.
  54 m4_define([AT_MATCHES_CHECK],
  55 [AT_CHECK([$PERL -0777 -ne '
  56 my $count = 0;
  57 s{$2}{ ++$count; "" }gem;
  58 printf "$count\n";' $1], [0], [$3
  59 ])])
  60
  61
  62 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  63 # ------------------------------------------------
  64 # Don't interfere with caller's files.
  65 m4_divert_text([PREPARE_TESTS],
  66 [at_save_special_files ()
  67 {
  68   for at_save_file in stderr experr expout
  69   do
  70     test ! -f at-bison-check-$at_save_file.bak ||
  71       as_fn_error 1 "fatal error: back-up on top of a back-up"
  72     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  73   done
  74 }
  75
  76 at_restore_special_files ()
  77 {
  78   for at_save_file in stderr experr expout
  79   do
  80     test ! -f at-bison-check-$at_save_file.bak ||
  81       mv at-bison-check-$at_save_file.bak $at_save_file
  82   done
  83 }
  84 ])
  85
  86 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  87 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  88
  89
  90
  91 ## ------------------------------- ##
  92 ## Macros decoding Bison options.  ##
  93 ## ------------------------------- ##
  94
  95 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  96 # ----------------------------------------------------------------
  97 # Pushdef AT(_LOC)?_(FIRST|LAST)_(LINE|COLUMN).
  98 m4_define([AT_LOC_PUSHDEF],
  99 [m4_pushdef([AT_FIRST_LINE],  [$1])
 100 m4_pushdef([AT_FIRST_COLUMN], [$2])
 101 m4_pushdef([AT_LAST_LINE],    [$3])
 102 m4_pushdef([AT_LAST_COLUMN],  [$4])
 103 m4_pushdef([AT_LOC_FIRST_LINE],   [AT_LOC.AT_FIRST_LINE])
 104 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.AT_FIRST_COLUMN])
 105 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.AT_LAST_LINE])
 106 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.AT_LAST_COLUMN])])
 107
 108 # AT_LOC_POPDEF
 109 # -------------
 110 # Popdef AT(_LOC)?_(FIRST|LAST)_(LINE|COLUMN).
 111 m4_define([AT_LOC_POPDEF],
 112 [m4_popdef([AT_LOC_FIRST_LINE])
 113 m4_popdef([AT_LOC_FIRST_COLUMN])
 114 m4_popdef([AT_LOC_LAST_LINE])
 115 m4_popdef([AT_LOC_LAST_COLUMN])
 116 m4_popdef([AT_FIRST_LINE])
 117 m4_popdef([AT_FIRST_COLUMN])
 118 m4_popdef([AT_LAST_LINE])
 119 m4_popdef([AT_LAST_COLUMN])
 120 ])
 121
 122
 123
 124 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
 125 # -----------------------------------------
 126 m4_define([AT_BISON_OPTION_PUSHDEFS],
 127 [m4_divert_text([KILL],
 128                 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])])
 129
 130
 131 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
 132 # --------------------------------------------------
 133 # This macro works around the impossibility to define macros
 134 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 135 # This sucks hard, GNU M4 should really provide M5-like $$1.
 136 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 137 [m4_if([$1$2], $[1]$[2], [],
 138        [m4_fatal([$0: Invalid arguments: $@])])dnl
 139 m4_pushdef([AT_DEFINES_IF],
 140 [m4_bmatch([$3], [%defines], [$1], [$2])])
 141 m4_pushdef([AT_DEBUG_IF],
 142 [m4_bmatch([$3], [%debug\|%define parse.trace], [$1], [$2])])
 143 m4_pushdef([AT_SKEL_CC_IF],
 144 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 145 m4_pushdef([AT_SKEL_JAVA_IF],
 146 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 147 # The target language: "c", "c++", or "java".
 148 m4_pushdef([AT_LANG],
 149 [AT_SKEL_JAVA_IF([java],
 150                  [AT_SKEL_CC_IF([c++],
 151                                 [c])])])
 152 m4_pushdef([AT_GLR_IF],
 153 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 154 m4_pushdef([AT_LALR1_CC_IF],
 155 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 156 m4_pushdef([AT_GLR_CC_IF],
 157 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 158 # Using yacc.c?
 159 m4_pushdef([AT_YACC_IF],
 160 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 161 m4_pushdef([AT_LEXPARAM_IF],
 162 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 163 m4_pushdef([AT_LOCATION_IF],
 164 [m4_bmatch([$3], [%locations], [$1], [$2])])
 165 m4_pushdef([AT_LOCATION_TYPE_IF],
 166 [m4_bmatch([$3], [%define \(api\.location\.type\|location_type\)], [$1], [$2])])
 167 m4_pushdef([AT_PARAM_IF],
 168 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 169 # Comma-terminated list of formals parse-parameters.
 170 # E.g., %parse-param { int x } %parse-param {int y} -> "int x, int y, ".
 171 # FIXME: Support grouped parse-param.
 172 m4_pushdef([AT_PARSE_PARAMS])
 173 m4_bpatsubst([$3], [%parse-param { *\([^{}]*[^{} ]\) *}],
 174              [m4_append([AT_PARSE_PARAMS], [\1, ])])
 175
 176 m4_pushdef([AT_PURE_IF],
 177 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 178            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 179            [$2])])
 180 # AT_NAME_PREFIX: also consider api.namespace.
 181 m4_pushdef([AT_NAME_PREFIX],
 182 [m4_bmatch([$3], [\(%define api\.\(namespace\|prefix\)\|%name-prefix\) ".*"],
 183            [m4_bregexp([$3], [\(%define api\.\(namespace\|prefix\)\|%name-prefix\) "\([^""]*\)"], [\3])],
 184            [yy])])
 185 m4_pushdef([AT_TOKEN_CTOR_IF],
 186 [m4_bmatch([$3], [%define api.token.constructor], [$1], [$2])])
 187 m4_pushdef([AT_TOKEN_PREFIX],
 188 [m4_bmatch([$3], [%define api.token.prefix ".*"],
 189            [m4_bregexp([$3], [%define api.token.prefix "\(.*\)"], [\1])])])
 190 m4_pushdef([AT_API_prefix],
 191 [m4_bmatch([$3], [%define api\.prefix ".*"],
 192            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 193            [yy])])
 194 m4_pushdef([AT_API_PREFIX],
 195 [m4_toupper(AT_API_prefix)])
 196 # yyerror receives the location if %location, and if the parser is pure. For
 197 # historical reasons, with the "yacc.c" skeleton, the location is not passed
 198 # unless an additional "%parse-param" is present, or if the purity is defined
 199 # as "full".
 200 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 201 [AT_LOCATION_IF([AT_PURE_IF([m4_bmatch([$3],
 202                                        m4_quote(m4_join([\|],
 203                                                         [%define api.pure "?full"?],
 204                                                         [%glr-parser],
 205                                                         [%parse-param],
 206                                                         [%skeleton "?glr.c"?])),
 207                                        [$1], [$2])],
 208                             [$2])],
 209                     [$2])])
 210
 211 # yyerror always sees the locations (when activated) if the parser is impure.
 212 # When the parser is pure, yyerror sees the location if it is received as an
 213 # argument.
 214 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 215 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_YYERROR_ARG_LOC_IF([$1], [$2])],
 216                                         [$1])],
 217                             [$1])],
 218                 [$2])])
 219
 220 # The interface is pure: either because %define api.pure, or because we
 221 # are using the C++ parsers.
 222 m4_pushdef([AT_PURE_LEX_IF],
 223 [AT_PURE_IF([$1],
 224             [AT_SKEL_CC_IF([$1], [$2])])])
 225
 226 m4_pushdef([AT_YYSTYPE],
 227 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 228                [AT_API_PREFIX[STYPE]])])
 229 m4_pushdef([AT_YYLTYPE],
 230 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 231                [AT_API_PREFIX[LTYPE]])])
 232
 233
 234 AT_PURE_LEX_IF(
 235 [m4_pushdef([AT_LOC], [(*llocp)])
 236  m4_pushdef([AT_VAL], [(*lvalp)])
 237  m4_pushdef([AT_YYLEX_FORMALS],
 238             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 239  m4_pushdef([AT_YYLEX_ARGS],
 240             [lvalp[]AT_LOCATION_IF([, llocp])])
 241  m4_pushdef([AT_USE_LEX_ARGS],
 242             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 243  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 244             [AT_YYLEX_FORMALS, ])
 245  m4_pushdef([AT_YYLEX_PRE_ARGS],
 246             [AT_YYLEX_ARGS, ])
 247 ],
 248 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 249  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 250  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 251  m4_pushdef([AT_YYLEX_ARGS],        [])
 252  m4_pushdef([AT_USE_LEX_ARGS],    [])
 253  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 254  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 255 ])
 256
 257 # Handle the different types of location components.
 258
 259 AT_SKEL_CC_IF(
 260   [AT_LOCATION_TYPE_IF(
 261     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 262     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 263   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 264
 265
 266 AT_GLR_IF([AT_KEYWORDS([glr])])
 267 ])# _AT_BISON_OPTION_PUSHDEFS
 268
 269
 270 # AT_BISON_OPTION_POPDEFS
 271 # -----------------------
 272 m4_define([AT_BISON_OPTION_POPDEFS],
 273 [m4_divert_text([KILL],
 274 [m4_popdef([AT_YYLEX_PRE_ARGS])
 275 m4_popdef([AT_YYLEX_PRE_FORMALS])
 276 m4_popdef([AT_USE_LEX_ARGS])
 277 m4_popdef([AT_YYLEX_ARGS])
 278 m4_popdef([AT_YYLEX_FORMALS])
 279 m4_popdef([AT_YYLTYPE])
 280 m4_popdef([AT_YYSTYPE])
 281 m4_popdef([AT_VAL])
 282 m4_popdef([AT_LOC])
 283 m4_popdef([AT_PURE_LEX_IF])
 284 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 285 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 286 m4_popdef([AT_API_PREFIX])
 287 m4_popdef([AT_API_prefix])
 288 m4_popdef([AT_TOKEN_PREFIX])
 289 m4_popdef([AT_TOKEN_CTOR_IF])
 290 m4_popdef([AT_NAME_PREFIX])
 291 m4_popdef([AT_LOCATION_TYPE_IF])
 292 m4_popdef([AT_LOCATION_IF])
 293 m4_popdef([AT_PARSE_PARAMS])
 294 m4_popdef([AT_PARAM_IF])
 295 m4_popdef([AT_LEXPARAM_IF])
 296 m4_popdef([AT_YACC_IF])
 297 m4_popdef([AT_GLR_IF])
 298 m4_popdef([AT_SKEL_CC_IF])
 299 m4_popdef([AT_LANG])
 300 m4_popdef([AT_SKEL_JAVA_IF])
 301 m4_popdef([AT_GLR_CC_IF])
 302 m4_popdef([AT_LALR1_CC_IF])
 303 m4_popdef([AT_DEFINES_IF])
 304 m4_popdef([AT_DEBUG_IF])
 305 AT_LOC_POPDEF])dnl
 306 ])# AT_BISON_OPTION_POPDEFS
 307
 308
 309
 310 ## -------------------------- ##
 311 ## Generating Grammar Files.  ##
 312 ## -------------------------- ##
 313
 314 # AT_DATA_SOURCE_PROLOGUE
 315 # ------------------------
 316 # The prologue that should be included in any source code that is
 317 # meant to be compiled.
 318 m4_define([AT_DATA_SOURCE_PROLOGUE],
 319 [[#include <config.h>
 320 /* We don't need perfect functions for these tests. */
 321 #undef malloc
 322 #undef memcmp
 323 #undef realloc
 324 ]])
 325
 326 # AT_DATA_GRAMMAR_PROLOGUE
 327 # ------------------------
 328 # The prologue that should be included in any grammar which parser is
 329 # meant to be compiled.
 330 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 331 [[%code top {
 332 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 333 [}
 334 ]])
 335
 336 # AT_DATA_SOURCE(NAME, CONTENT)
 337 # -----------------------------
 338 # Generate the file NAME, which CONTENT is preceded by
 339 # AT_DATA_SOURCE_PROLOGUE.
 340 m4_define([AT_DATA_SOURCE],
 341 [AT_DATA([$1],
 342 [AT_DATA_SOURCE_PROLOGUE
 343 $2])
 344 ])
 345
 346 # AT_DATA_GRAMMAR(NAME, CONTENT)
 347 # ------------------------------
 348 # Generate the file NAME, which CONTENT is preceded by
 349 # AT_DATA_GRAMMAR_PROLOGUE.
 350 m4_define([AT_DATA_GRAMMAR],
 351 [AT_DATA([$1],
 352 [AT_DATA_GRAMMAR_PROLOGUE
 353 $2])
 354 ])
 355
 356 # AT_YYLEX_PROTOTYPE
 357 # AT_YYLEX_DECLARE_EXTERN
 358 # AT_YYLEX_DECLARE
 359 # AT_YYLEX_DEFINE([INPUT], [ACTION])
 360 # ----------------------------------
 361 # INPUT can be empty, or in double quotes, or a list (in braces).
 362 # ACTION may compute yylval for instance, using "res" as token type,
 363 # and "toknum" as the number of calls to yylex (starting at 0).
 364 m4_define([AT_YYLEX_PROTOTYPE],
 365 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 366 ])
 367
 368 m4_define([AT_YYLEX_DECLARE_EXTERN],
 369 [AT_YYLEX_PROTOTYPE;dnl
 370 ])
 371
 372 m4_define([AT_YYLEX_DECLARE],
 373 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 374 ])
 375
 376 m4_define([AT_YYLEX_DEFINE],
 377 [[#include <assert.h>
 378 static
 379 ]AT_YYLEX_PROTOTYPE[
 380 {
 381   ]m4_bmatch([$1], [^\(".*"\)?$],
 382              [[static char const input[] = ]m4_default([$1], [""])],
 383              [[static int const input[] = ]$1])[;
 384   static size_t toknum = 0;
 385   int res;
 386   ]AT_USE_LEX_ARGS[;
 387   assert (toknum < sizeof input / sizeof input[0]);
 388   res = input[toknum++];
 389   ]$2[;]AT_LOCATION_IF([[
 390   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 391   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 392   return res;
 393 }]dnl
 394 ])
 395
 396 # AT_YYERROR_FORMALS
 397 # AT_YYERROR_PROTOTYPE
 398 # AT_YYERROR_DECLARE_EXTERN
 399 # AT_YYERROR_DECLARE
 400 # AT_YYERROR_DEFINE
 401 # -------------------------
 402 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 403 m4_define([AT_YYERROR_FORMALS],
 404 [m4_case(AT_LANG,
 405 [c], [AT_YYERROR_ARG_LOC_IF([AT_YYLTYPE const * const llocp, ])AT_PARSE_PARAMS [const char *msg]])[]dnl
 406 ])
 407
 408 m4_define([AT_YYERROR_PROTOTYPE],
 409 [m4_case(AT_LANG,
 410 [c], [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])[]dnl
 411 ])
 412
 413 m4_define([AT_YYERROR_DECLARE_EXTERN],
 414 [m4_case(AT_LANG,
 415 [c], [AT_YYERROR_PROTOTYPE;])[]dnl
 416 ])
 417
 418 m4_define([AT_YYERROR_DECLARE],
 419 [m4_case(AT_LANG,
 420 [c], [static AT_YYERROR_DECLARE_EXTERN])[]dnl
 421 ])
 422
 423 m4_define([AT_YYERROR_DEFINE],
 424 [m4_case(AT_LANG,
 425 [c], [[#include <stdio.h>
 426 /* A C error reporting function.  */
 427 static
 428 ]AT_YYERROR_PROTOTYPE[
 429 {]m4_bpatsubst(m4_defn([AT_PARSE_PARAMS]),
 430               [[^,]+[^A-Za-z_0-9]\([A-Za-z_][A-Za-z_0-9]*\), *], [
 431   YYUSE(\1);])dnl
 432 AT_YYERROR_SEES_LOC_IF([[
 433   YY_LOCATION_PRINT (stderr, ]AT_LOC[);
 434   fprintf (stderr, ": ");]])[
 435   fprintf (stderr, "%s\n", msg);
 436 }]],
 437 [c++], [[/* A C++ error reporting function.  */
 438 void
 439 ]AT_NAME_PREFIX[::parser::error (]AT_LOCATION_IF([[const location_type& l, ]])[const std::string& m)
 440 {
 441   std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 442 }]],
 443 [java], [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 444 {
 445     if (l == null)
 446       System.err.println (s);
 447     else
 448       System.err.println (l + ": " + s);
 449   }
 450 ]], [[
 451   public void yyerror (String s)
 452   {
 453     System.err.println (s);
 454   }]])],
 455 [m4_fatal([$0: invalid language: ]AT_LANG)])dnl
 456 ])
 457
 458
 459 # AT_MAIN_DEFINE
 460 # --------------
 461 m4_define([AT_MAIN_DEFINE],
 462 [m4_case(AT_LANG,
 463 [c],
 464 [[#include <stdlib.h> /* getenv. */
 465 #include <string.h> /* strcmp. */
 466 int
 467 main (int argc, char const* argv[])
 468 {]AT_DEBUG_IF([[
 469   if (getenv("YYDEBUG")
 470       || (argc == 2
 471           && (!strcmp (argv[1], "-d") || !strcmp (argv[1], "--debug"))))
 472     yydebug |= 1;]], [[
 473   (void) argc;
 474   (void) argv;]])[
 475   return ]AT_NAME_PREFIX[parse ();
 476 }]],
 477 [c++],
 478 [[#include <cstdlib> // getenv.
 479 #include <cstring> // strcmp.
 480 int
 481 main (int argc, char const* argv[])
 482 {
 483   ]AT_NAME_PREFIX[::parser p;]AT_DEBUG_IF([[
 484   if (getenv("YYDEBUG")
 485       || (argc == 2
 486           && (!strcmp (argv[1], "-d") || !strcmp (argv[1], "--debug"))))
 487     p.set_debug_level (true);]], [[
 488   (void) argc;
 489   (void) argv;]])[
 490   return p.parse ();
 491 }]],
 492 [java],
 493 [[class input
 494 {
 495   public static void main (String args[]) throws IOException
 496   {
 497     YYParser p = new YYParser ();
 498     p.parse ();
 499   }
 500 }]])])
 501
 502
 503 ## --------------- ##
 504 ## Running Bison.  ##
 505 ## --------------- ##
 506
 507 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 508 # -------------------------------------------------
 509 # High-level routine that may call bison several times, under different
 510 # conditions.
 511 #
 512 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 513 # shell constructs (such as redirection or pipes) that would prevent
 514 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 515 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 516 #
 517 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 518 # Bison in the test suite.  For now it ensures that:
 519 #
 520 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 521 #      a non-zero exit status since Bison doesn't always try to free all memory
 522 #      in that case.
 523 #
 524 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 525 #      --graph and --report=all output for every working grammar.
 526 #
 527 #   3. If stderr contains a warning, -Werror and --warnings=error
 528 #      convert the warning to an error.
 529 #
 530 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 531 m4_define([AT_BISON_CHECK],
 532 [m4_null_if([$2], [AT_BISON_CHECK_XML($@)])
 533 AT_BISON_CHECK_NO_XML($@)])
 534
 535 # AT_BISON_CHECK_(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 536 # --------------------------------------------------
 537 # Low-level macro to run bison once.
 538 m4_define([AT_BISON_CHECK_],
 539 [AT_CHECK(AT_QUELL_VALGRIND[[ bison -fno-caret ]]$@)])
 540
 541
 542 # AT_BISON_CHECK_WARNINGS(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 543 # ----------------------------------------------------------
 544 # Check that warnings (if some are expected) are correctly
 545 # turned into errors with -Werror, etc.
 546 m4_define([AT_BISON_CHECK_WARNINGS],
 547 [m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 548       [m4_null_if([$2], [AT_BISON_CHECK_WARNINGS_($@)])])])
 549
 550 m4_define([AT_BISON_CHECK_WARNINGS_],
 551 [[# Defining POSIXLY_CORRECT causes bison to complain if options are
 552 # added after the grammar file name, so skip these checks in that
 553 # case.
 554 if test "$POSIXLY_CORRECT_IS_EXPORTED" = false; then
 555           ]AT_SAVE_SPECIAL_FILES[
 556
 557   # To avoid expanding it repeatedly, store specified stdout.
 558   ]AT_DATA([expout], [$3])[
 559
 560   # Run with -Werror.
 561   ]AT_BISON_CHECK_([$1[ -Werror]], [[1]], [expout], [stderr])[
 562
 563   # Build expected stderr up to and including the "warnings being
 564   # treated as errors" message.
 565   ]AT_DATA([[experr]], [$4])[
 566   $PERL -pi -e 's{(.*): warning: (.*)\[-W(.*)\]$}
 567                  {$][1: error: $][2\@<:@-Werror=$][3@:>@}' experr
 568   ]AT_CHECK([[sed 's,.*/$,,' stderr 1>&2]], [[0]], [[]], [experr])[
 569
 570   # Now check --warnings=error.
 571   cp stderr experr
 572   ]AT_BISON_CHECK_([$1[ --warnings=error]], [[1]], [expout], [experr])[
 573
 574   # Now check -Wnone and --warnings=none by making sure that
 575   # -Werror doesn't change the exit status when -Wnone or
 576   # --warnings=none is specified.
 577   ]AT_BISON_CHECK_([$1[ -Wnone -Werror]], [[0]], [expout])[
 578   ]AT_BISON_CHECK_([$1[ --warnings=none -Werror]], [[0]], [expout])[
 579
 580   ]AT_RESTORE_SPECIAL_FILES[
 581 fi]dnl
 582 ])
 583
 584 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 585 # --------------------------------------------------------
 586 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 587 # when a tortured grammar's XML is known to be too large for xsltproc to
 588 # handle.
 589 m4_define([AT_BISON_CHECK_NO_XML],
 590 [AT_CHECK(m4_null_if([$2], [], [AT_QUELL_VALGRIND ])[[bison -fno-caret ]]$@)
 591 AT_BISON_CHECK_WARNINGS($@)])
 592
 593 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 594 # -----------------------------------------------------
 595 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 596 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 597 # have a non-zero exit status.
 598 m4_define([AT_BISON_CHECK_XML],
 599 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 600   AT_SAVE_SPECIAL_FILES
 601   [mkdir xml-tests]
 602   m4_pushdef([AT_BISON_ARGS],
 603              [m4_bpatsubsts([[$1]],
 604                             [--report(-file)?=[^][ ]*], [],
 605                             [--graph=[^][ ]*], [],
 606                             [--xml=[^][ ]*], [])])dnl
 607   # Don't combine these Bison invocations since we want to be sure that
 608   # --report=all isn't required to get the full XML file.
 609   AT_BISON_CHECK_([[--report=all --report-file=xml-tests/test.output \
 610              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 611            [[0]], [ignore], [ignore])
 612   AT_BISON_CHECK_([[--xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 613            [[0]], [ignore], [ignore])
 614   m4_popdef([AT_BISON_ARGS])dnl
 615   [cp xml-tests/test.output expout]
 616   AT_CHECK([[$XSLTPROC \
 617              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 618              xml-tests/test.xml]], [[0]], [expout])
 619   [sort xml-tests/test.dot > expout]
 620   AT_CHECK([[$XSLTPROC \
 621              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 622              xml-tests/test.xml | sort]], [[0]], [expout])
 623   [rm -rf xml-tests expout]
 624   AT_RESTORE_SPECIAL_FILES
 625 [fi]])
 626
 627 # AT_QUELL_VALGRIND
 628 # -----------------
 629 # Put this before a Bison invocation to keep Valgrind from complaining about
 630 # reachable memory.
 631 #
 632 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 633 # The triple quoting below will cause test cases to fail if you do.  If you do
 634 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 635 # will then fail to shell-escape its contents when attempting to print them.
 636 # The testsuite verbose output, at least, will be incorrect, but nothing may
 637 # fail to make sure you notice.
 638 m4_define([AT_QUELL_VALGRIND],
 639 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 640
 641
 642
 643 ## ------------------------ ##
 644 ## Compiling C, C++ Files.  ##
 645 ## ------------------------ ##
 646
 647
 648 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 649 # ----------------------------------------
 650 # Compile SOURCES into OUTPUT.
 651 #
 652 # If OUTPUT does not contain '.', assume that we are linking too,
 653 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 654 # with trailing .o removed, and ".c" appended.
 655 m4_define([AT_COMPILE],
 656 [AT_CHECK([$BISON_C_WORKS], 0, ignore, ignore)
 657 AT_CHECK(m4_join([ ],
 658                   [$CC $CFLAGS $CPPFLAGS],
 659                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 660                   [-o $1],
 661                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 662                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 663            0, [ignore], [ignore])])
 664
 665 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 666 # ---------------------------------------------
 667 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 668 # ignore the test.
 669 #
 670 # If OUTPUT does not contain '.', assume that we are linking too,
 671 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 672 # with trailing .o removed, and ".cc" appended.
 673 m4_define([AT_COMPILE_CXX],
 674 [AT_KEYWORDS(c++)
 675 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 676 AT_CHECK(m4_join([ ],
 677                  [$CXX $CXXFLAGS $CPPFLAGS],
 678                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 679                  [-o $1],
 680                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 681                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 682          0, [ignore], [ignore])])
 683
 684 # AT_JAVA_COMPILE(SOURCES)
 685 # ------------------------
 686 # Compile SOURCES into Java class files.  Skip the test if java or javac
 687 # is not installed.
 688 m4_define([AT_JAVA_COMPILE],
 689 [AT_KEYWORDS(java)
 690 AT_SKIP_IF([[test -z "$CONF_JAVAC"]])
 691 AT_SKIP_IF([[test -z "$CONF_JAVA"]])
 692 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 693          [[0]], [ignore], [ignore])])
 694
 695 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 696 # --------------------------------------------
 697 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 698 #
 699 # If OUTPUT does not contain '.', assume that we are linking too,
 700 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 701 # with trailing .o removed, and ".c"/".cc" appended.
 702 m4_define([AT_LANG_COMPILE],
 703 [m4_case(AT_LANG,
 704 [c],    [AT_COMPILE([$1], [$2])],
 705 [c++],  [AT_COMPILE_CXX([$1], [$2])],
 706 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 707         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 708 ])
 709
 710 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 711 # -------------------------------------------
 712 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 713 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 714 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 715 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 716 # AT_SKEL_JAVA_IF.
 717 m4_define([AT_FULL_COMPILE],
 718 [m4_case(AT_LANG,
 719 [java],
 720   [AT_BISON_CHECK([-o $1.java $1.y])
 721    AT_LANG_COMPILE([$1],
 722                     m4_join([ ],
 723                             [$1.java],
 724                             m4_ifval($2, [[$1-$2.java]]),
 725                            m4_ifval($3, [[$1-$3.java]])))],
 726 [c++],
 727   [AT_BISON_CHECK([-o $1.cc $1.y])
 728    AT_LANG_COMPILE([$1],
 729                      m4_join([ ],
 730                              [$1.cc],
 731                              m4_ifval($2, [[$1-$2.cc]]),
 732                            m4_ifval($3, [[$1-$3.cc]])))],
 733 [c],
 734   [AT_BISON_CHECK([-o $1.c $1.y])
 735    AT_LANG_COMPILE([$1],
 736                   m4_join([ ],
 737                           [$1.c],
 738                           m4_ifval($2, [[$1-$2.c]]),
 739                            m4_ifval($3, [[$1-$3.c]])))])
 740 ])
 741
 742
 743
 744 # AT_SKIP_IF_CANNOT_LINK_C_AND_CXX
 745 # --------------------------------
 746 # Check that we can link together C and C++ objects.
 747 m4_define([AT_SKIP_IF_CANNOT_LINK_C_AND_CXX],
 748 [AT_DATA([c-and-cxx.h],
 749 [[#ifdef __cplusplus
 750 extern "C"
 751 {
 752 #endif
 753   int fortytwo (void);
 754 #ifdef __cplusplus
 755 }
 756 #endif
 757 ]])
 758 AT_DATA([c-only.c],
 759 [[#include "c-and-cxx.h"
 760 int
 761 main (void)
 762 {
 763   return fortytwo () == 42 ? 0 : 1;
 764 }
 765 ]])
 766 AT_DATA([cxx-only.cc],
 767 [[#include "c-and-cxx.h"
 768 int fortytwo ()
 769 {
 770   return 42;
 771 }
 772 ]])
 773 AT_COMPILE([c-only.o], [c-only.c])
 774 AT_COMPILE_CXX([cxx-only.o], [cxx-only.cc])
 775 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS $LDFLAGS c-only.o cxx-only.o -o c-and-cxx ||
 776           exit 77], [ignore], [ignore])
 777 AT_PARSER_CHECK([./c-and-cxx])
 778 ])
 779
 780
 781 ## ---------------------------- ##
 782 ## Running a generated parser.  ##
 783 ## ---------------------------- ##
 784
 785
 786 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 787 # ------------------------------------------------------------
 788 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 789 #
 790 # Get rid of spurious messages when compiled with --coverage:
 791 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 792 m4_define([AT_PARSER_CHECK],
 793 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 794 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 795          [0], [], [$4])
 796 ])
 797
 798
 799 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 800 # -----------------------------------------------------------------
 801 m4_define([AT_JAVA_PARSER_CHECK],
 802 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 803
 804
 805 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 806 #                          DECLS, GRAMMAR, INPUT,
 807 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 808 #                          [OTHER-CHECKS],
 809 #                          [PARSER-EXIT-VALUE],
 810 #                          [PARSER-STDOUT], [PARSER-STDERR])
 811 # -------------------------------------------------------------
 812 # Using TITLE as the test group title, check the generated parser tables
 813 # and parser for a specified grammar file under a condition labeled by
 814 # COND-VALUE.
 815 #
 816 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 817 # recognized attribute is described below where it is relevant.
 818 #
 819 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 820 # the grammar file.  Insert basic yyerror, yylex, and main function
 821 # definitions as well.  Hardcode yylex to return the (possibly empty)
 822 # comma-delimited series of tokens in INPUT followed by token 0.
 823 #
 824 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 825 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 826 # On the bison command-line, specify `--report=all --defines'.  Check
 827 # that Bison exits with value 0, has no stdout, and has stderr
 828 # BISON-STDERR.
 829 #
 830 # If TEST-SPEC contains the attribute `last-state', check that the value
 831 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 832 # the grammar; in other words, check the number of states (minus one).
 833 # Otherwise, check that everything in the `.output' file starting with
 834 # the definition of state 0 is the same as the entire value of
 835 # TABLES-OR-LAST-STATE.
 836 #
 837 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 838 # `.output' file, which is named `input.output', and/or grammar file,
 839 # which is named `input.y'.
 840 #
 841 # Finally, compile the generated parser and then run it using
 842 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 843 # PARSER-STDERR as the 2nd-4th arguments.
 844 #
 845 # As a precondition, you must properly double-quote all arguments that
 846 # are to be interpreted as strings.
 847 #
 848 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 849 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 850 # first argument.  This is useful, for example, when wrapping multiple
 851 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 852 # condition, in another macro.
 853 #
 854 # For example:
 855 #
 856 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 857 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 858 #   # ---------------------------------------------------------------------
 859 #   m4_define([AT_TEST_SYNTAX_ERROR],
 860 #   [
 861 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 862 #                              [[last-state]],
 863 #                              [[%error-verbose ]$2], [$3], [$4],
 864 #                              [[]], [$5], [], [$6], [$7], [$8])
 865 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 866 #                              [[last-state]],
 867 #                              [$2], [$3], [$4],
 868 #                              [[]], [$5], [], [$6], [$7], [$8])
 869 #   ])
 870 #
 871 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 872 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 873 #                        [[3]],
 874 #                        [[1]], [[]],
 875 #                        [AT_COND_CASE([[no verbose]],
 876 #                                      [[syntax error
 877 #   ]],
 878 #                                      [[syntax error, unexpected 'b', expecting $end
 879 #   ]])])
 880 m4_define([AT_TEST_TABLES_AND_PARSE],
 881 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 882
 883 AT_SETUP([$1])
 884 AT_BISON_OPTION_PUSHDEFS([$4])
 885 AT_DATA_GRAMMAR([[input.y]],
 886 [[%code {
 887   #include <stdio.h>
 888   ]AT_YYERROR_DECLARE[
 889   ]AT_YYLEX_DECLARE[
 890 }
 891
 892 ]$4[
 893
 894 %%
 895
 896 ]$5[
 897
 898 %%
 899 ]AT_YYERROR_DEFINE[
 900 static int
 901 yylex (void)
 902 {
 903   static int const input[] = {
 904     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 905   };
 906   static int const *inputp = input;
 907   return *inputp++;
 908 }
 909
 910 int
 911 main (void)
 912 {
 913   return yyparse ();
 914 }
 915 ]])
 916
 917 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 918 # expanding macros, so it corrupts some special characters in the
 919 # macros.  To avoid this, expand now and pass it the result with proper
 920 # string quotation.  Assume args 7 through 12 expand to properly quoted
 921 # strings.
 922
 923 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 924       [AT_BISON_CHECK],
 925       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 926                                [0], [], m4_dquote($7))
 927
 928 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 929       [AT_CHECK([[sed -n '/^State 0$/,$p' input.output]], [[0]],
 930                 m4_dquote($8))],
 931       [AT_CHECK([[sed -n 's/^State //p' input.output | tail -1]], [[0]],
 932                 m4_dquote($8)[[
 933 ]])])
 934
 935 $9
 936
 937 # Canonical LR generates very large tables, resulting in very long
 938 # files with #line directives that may overflow what the standards
 939 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 940 # will issue an error.
 941 #
 942 # There is no "" around `wc` since some indent the result.
 943 m4_bmatch([$4], [%define lr.type canonical-lr],
 944 [if test 32767 -lt `wc -l < input.c`; then
 945   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 946   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 947 fi])
 948 AT_COMPILE([[input]])
 949
 950 AT_PARSER_CHECK([[./input]],
 951                 m4_ifval([$10], [m4_dquote($10)]),
 952                 m4_ifval([$11], [m4_dquote($11)]),
 953                 m4_ifval([$12], [m4_dquote($12)]))
 954
 955 AT_BISON_OPTION_POPDEFS
 956 AT_CLEANUP
 957
 958 m4_popdef([AT_COND_CASE])])
 959
 960
 961
 962
 963 ## ----------------------- ##
 964 ## Launch the test suite.  ##
 965 ## ----------------------- ##
 966
 967 AT_INIT
 968
 969 # AT_SETUP([TITLE])
 970 # -----------------
 971 # Redefine AT_SETUP to be more concise.  Must be done after AT_INIT.
 972 m4_copy_force([AT_SETUP], [B4_SETUP])
 973 m4_define([AT_SETUP],
 974 [B4_SETUP(m4_expand([AT_SETUP_STRIP([[$1]])]))])
 975
 976 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 977 # options are processed, so we don't know the value of CXX and
 978 # CXXFLAGS yet.
 979 #
 980 # Note that it also means that command line values for CXX and
 981 # CXXFLAGS will not be propagated to CC and CFLAGS.
 982 AT_ARG_OPTION([compile-c-with-cxx],
 983               [compile C parsers with the C++ compiler])
 984
 985 AT_COLOR_TESTS
 986
 987 AT_TESTED([bison])