configure.in

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  16 # 02111-1307  USA
  17
  18 # We need a recent Autoconf to run a recent Autotest.
  19 AC_PREREQ(2.52e)
  20
  21 AC_INIT([GNU Bison], [1.49a], [bug-bison@gnu.org])
  22 AC_CONFIG_AUX_DIR(config)
  23
  24 AM_INIT_AUTOMAKE([bison], [1.49a])
  25 AM_CONFIG_HEADER(config.h:config.hin)
  26
  27 # Initialize the test suite.
  28 AC_CONFIG_TESTDIR(tests)
  29 AC_CONFIG_FILES(tests/Makefile tests/atlocal)
  30 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
  31 # Needed by tests/atlocal.in.
  32 AC_SUBST([GCC])
  33
  34 # Checks for programs.
  35 AC_PROG_CC
  36 AC_MINIX
  37 AC_ISC_POSIX
  38 AM_PROG_CC_STDC
  39 AC_PROG_RANLIB
  40 # GNU M4 is needed to build the testsuite.
  41 BISON_AC_PROG_GNU_M4
  42 if test "$ac_cv_prog_gnu_m4" != yes; then
  43   missing_dir=`cd $ac_aux_dir && pwd`
  44   M4="$missing_dir/missing m4"
  45 fi
  46
  47 AC_ARG_ENABLE(gcc-warnings,
  48 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  49 [case "${enableval}" in
  50    yes|no) ;;
  51    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  52  esac],
  53               [enableval=no])
  54 if test "${enableval}" = yes; then
  55   BISON_WARNING(-Wall)
  56   BISON_WARNING(-W)
  57   BISON_WARNING(-Wbad-function-cast)
  58   BISON_WARNING(-Wcast-align)
  59   BISON_WARNING(-Wcast-qual)
  60   BISON_WARNING(-Wformat)
  61   BISON_WARNING(-Wmissing-declarations)
  62   BISON_WARNING(-Wmissing-prototypes)
  63   BISON_WARNING(-Wnested-externs)
  64   BISON_WARNING(-Wshadow)
  65   BISON_WARNING(-Wstrict-prototypes)
  66   BISON_WARNING(-Wwrite-strings)
  67   CFLAGS="$CFLAGS $WARNING_CFLAGS"
  68 fi
  69
  70 # Checks for libraries.
  71 AC_DEFINE([_GNU_SOURCE],1,[Define to 1 for GNU C library extensions.])
  72
  73 # Checks for header files.
  74 AC_HEADER_STDC
  75 AC_CHECK_HEADERS(ctype.h locale.h memory.h stdlib.h string.h unistd.h)
  76
  77 # Checks for typedefs.
  78
  79 # Checks for structures.
  80
  81 # Checks for compiler characteristics.
  82 AC_C_CONST
  83 AC_C_INLINE
  84 AM_C_PROTOTYPES
  85
  86 # Checks for library functions.
  87 AC_FUNC_ALLOCA
  88 AC_CHECK_FUNCS(mkstemp setlocale)
  89 AC_CHECK_DECLS([stpcpy, strndup, strnlen, memchr])
  90 AC_REPLACE_FUNCS(stpcpy strndup strnlen strspn memchr)
  91 jm_FUNC_MALLOC
  92 jm_FUNC_REALLOC
  93 jm_PREREQ_QUOTEARG
  94 jm_PREREQ_ERROR
  95 AM_WITH_DMALLOC
  96
  97 ALL_LINGUAS="de es et fr ja nl tr ru"
  98 AM_GNU_GETTEXT(, need-ngettext)
  99
 100 # This is necessary so that .o files in LIBOBJS are also built via
 101 # the ANSI2KNR-filtering rules.
 102 LIB@&t@OBJS=`echo $LIB@&t@OBJS|sed 's/\.o /\$U.o /g;s/\.o$/\$U.o/'`
 103 AC_SUBST(LIB@&t@OBJS)
 104
 105 AC_OUTPUT([Makefile
 106            config/Makefile
 107            intl/Makefile po/Makefile.in
 108            lib/Makefile src/Makefile doc/Makefile
 109            m4/Makefile])