src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation,
   4    Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 #include <config.h>
  22 #include "system.h"
  23
  24 #include <strverscmp.h>
  25
  26 #include "complain.h"
  27 #include "conflicts.h"
  28 #include "files.h"
  29 #include "getargs.h"
  30 #include "gram.h"
  31 #include "muscle_tab.h"
  32 #include "quotearg.h"
  33 #include "reader.h"
  34 #include "symlist.h"
  35 #include "scan-gram.h"
  36 #include "scan-code.h"
  37
  38 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  39 static YYLTYPE lloc_default (YYLTYPE const *, int);
  40
  41 #define YY_LOCATION_PRINT(File, Loc) \
  42           location_print (File, Loc)
  43
  44 static void version_check (location const *loc, char const *version);
  45
  46 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  47    FIXME: depends on the undocumented availability of YYLLOC.  */
  48 #undef  yyerror
  49 #define yyerror(Msg) \
  50         gram_error (&yylloc, Msg)
  51 static void gram_error (location const *, char const *);
  52
  53 static char const *char_name (char);
  54
  55 /** Add a lex-param or a parse-param.
  56  *
  57  * \param type  \a lex_param or \a parse_param
  58  * \param decl  the formal argument
  59  * \param loc   the location in the source.
  60  */
  61 static void add_param (char const *type, char *decl, location loc);
  62
  63
  64 static symbol_class current_class = unknown_sym;
  65 static uniqstr current_type = NULL;
  66 static symbol *current_lhs;
  67 static location current_lhs_location;
  68 static int current_prec = 0;
  69
  70 #define YYTYPE_INT16 int_fast16_t
  71 #define YYTYPE_INT8 int_fast8_t
  72 #define YYTYPE_UINT16 uint_fast16_t
  73 #define YYTYPE_UINT8 uint_fast8_t
  74 %}
  75
  76 %debug
  77 %verbose
  78 %defines
  79 %locations
  80 %pure-parser
  81 %error-verbose
  82 %name-prefix="gram_"
  83 %expect 0
  84
  85 %initial-action
  86 {
  87   /* Bison's grammar can initial empty locations, hence a default
  88      location is needed. */
  89   boundary_set (&@$.start, current_file, 1, 1);
  90   boundary_set (&@$.end, current_file, 1, 1);
  91 }
  92
  93 %union
  94 {
  95   symbol *symbol;
  96   symbol_list *list;
  97   int integer;
  98   char const *chars;
  99   char *code;
 100   assoc assoc;
 101   uniqstr uniqstr;
 102   unsigned char character;
 103 };
 104
 105 /* Define the tokens together with their human representation.  */
 106 %token GRAM_EOF 0 "end of file"
 107 %token STRING     "string"
 108 %token INT        "integer"
 109
 110 %token PERCENT_TOKEN       "%token"
 111 %token PERCENT_NTERM       "%nterm"
 112
 113 %token PERCENT_TYPE        "%type"
 114 %token PERCENT_DESTRUCTOR  "%destructor"
 115 %token PERCENT_PRINTER     "%printer"
 116
 117 %token PERCENT_LEFT        "%left"
 118 %token PERCENT_RIGHT       "%right"
 119 %token PERCENT_NONASSOC    "%nonassoc"
 120
 121 %token PERCENT_PREC          "%prec"
 122 %token PERCENT_DPREC         "%dprec"
 123 %token PERCENT_MERGE         "%merge"
 124
 125
 126 /*----------------------.
 127 | Global Declarations.  |
 128 `----------------------*/
 129
 130 %token
 131   PERCENT_CODE            "%code"
 132   PERCENT_DEBUG           "%debug"
 133   PERCENT_DEFAULT_PREC    "%default-prec"
 134   PERCENT_DEFINE          "%define"
 135   PERCENT_DEFINES         "%defines"
 136   PERCENT_ERROR_VERBOSE   "%error-verbose"
 137   PERCENT_EXPECT          "%expect"
 138   PERCENT_EXPECT_RR       "%expect-rr"
 139   PERCENT_FILE_PREFIX     "%file-prefix"
 140   PERCENT_GLR_PARSER      "%glr-parser"
 141   PERCENT_INITIAL_ACTION  "%initial-action"
 142   PERCENT_LANGUAGE        "%language"
 143   PERCENT_LEX_PARAM       "%lex-param"
 144   PERCENT_LOCATIONS       "%locations"
 145   PERCENT_NAME_PREFIX     "%name-prefix"
 146   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 147   PERCENT_NO_LINES        "%no-lines"
 148   PERCENT_NONDETERMINISTIC_PARSER
 149                           "%nondeterministic-parser"
 150   PERCENT_OUTPUT          "%output"
 151   PERCENT_PARSE_PARAM     "%parse-param"
 152   PERCENT_PURE_PARSER     "%pure-parser"
 153   PERCENT_REQUIRE         "%require"
 154   PERCENT_SKELETON        "%skeleton"
 155   PERCENT_START           "%start"
 156   PERCENT_TOKEN_TABLE     "%token-table"
 157   PERCENT_VERBOSE         "%verbose"
 158   PERCENT_YACC            "%yacc"
 159 ;
 160
 161 %token BRACED_CODE     "{...}"
 162 %token CHAR            "char"
 163 %token EPILOGUE        "epilogue"
 164 %token EQUAL           "="
 165 %token ID              "identifier"
 166 %token ID_COLON        "identifier:"
 167 %token PERCENT_PERCENT "%%"
 168 %token PIPE            "|"
 169 %token PROLOGUE        "%{...%}"
 170 %token SEMICOLON       ";"
 171 %token TYPE            "type"
 172 %token TYPE_TAG_ANY    "<*>"
 173 %token TYPE_TAG_NONE   "<>"
 174
 175 %type <character> CHAR
 176 %printer { fputs (char_name ($$), stderr); } CHAR
 177
 178 /* braceless is not to be used for rule or symbol actions, as it
 179    calls code_props_plain_init.  */
 180 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 181 %type <code> "{...}"
 182 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 183          STRING
 184 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 185          braceless content.opt "{...}" "%{...%}" EPILOGUE
 186
 187 %type <uniqstr> TYPE ID ID_COLON variable
 188 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 189 %printer { fputs ($$, stderr); } ID variable
 190 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 191
 192 %type <integer> INT
 193 %printer { fprintf (stderr, "%d", $$); } INT
 194
 195 %type <symbol> id id_colon symbol string_as_id
 196 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 197 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 198
 199 %type <assoc> precedence_declarator
 200 %type <list>  symbols.1 generic_symlist generic_symlist_item
 201 %%
 202
 203 input:
 204   prologue_declarations "%%" grammar epilogue.opt
 205 ;
 206
 207
 208         /*------------------------------------.
 209         | Declarations: before the first %%.  |
 210         `------------------------------------*/
 211
 212 prologue_declarations:
 213   /* Nothing */
 214 | prologue_declarations prologue_declaration
 215 ;
 216
 217 prologue_declaration:
 218   grammar_declaration
 219 | "%{...%}"
 220     {
 221       code_props plain_code;
 222       code_props_plain_init (&plain_code, $1, @1);
 223       code_props_translate_code (&plain_code);
 224       gram_scanner_last_string_free ();
 225       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 226                         plain_code.code, @1);
 227       code_scanner_last_string_free ();
 228     }
 229 | "%debug"                         { debug_flag = true; }
 230 | "%define" variable content.opt
 231     {
 232       muscle_percent_define_insert ($2, @2, $3);
 233     }
 234 | "%defines"                       { defines_flag = true; }
 235 | "%defines" STRING
 236     {
 237       defines_flag = true;
 238       spec_defines_file = xstrdup ($2);
 239     }
 240 | "%error-verbose"                 { error_verbose = true; }
 241 | "%expect" INT                    { expected_sr_conflicts = $2; }
 242 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 243 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 244 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 245 | "%glr-parser"
 246     {
 247       nondeterministic_parser = true;
 248       glr_parser = true;
 249     }
 250 | "%initial-action" "{...}"
 251     {
 252       code_props action;
 253       code_props_symbol_action_init (&action, $2, @2);
 254       code_props_translate_code (&action);
 255       gram_scanner_last_string_free ();
 256       muscle_code_grow ("initial_action", action.code, @2);
 257       code_scanner_last_string_free ();
 258     }
 259 | "%language" STRING            { language_argmatch ($2, 1, &@1); }
 260 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 261 | "%locations"                  { locations_flag = true; }
 262 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 263 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 264 | "%no-lines"                   { no_lines_flag = true; }
 265 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 266 | "%output" STRING              { spec_outfile = $2; }
 267 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 268 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 269 | "%pure-parser"
 270     {
 271       /* %pure-parser is deprecated in favor of `%define api.pure', so use
 272          `%define api.pure' in a backward-compatible manner here.  First, don't
 273          complain if %pure-parser is specified multiple times.  */
 274       if (!muscle_find_const ("percent_define(api.pure)"))
 275         muscle_percent_define_insert ("api.pure", @1, "");
 276       /* In all cases, use api.pure now so that the backend doesn't complain if
 277          the skeleton ignores api.pure, but do warn now if there's a previous
 278          conflicting definition from an actual %define.  */
 279       if (!muscle_percent_define_flag_if ("api.pure"))
 280         muscle_percent_define_insert ("api.pure", @1, "");
 281     }
 282 | "%require" STRING             { version_check (&@2, $2); }
 283 | "%skeleton" STRING
 284     {
 285       char const *skeleton_user = $2;
 286       if (strchr (skeleton_user, '/'))
 287         {
 288           size_t dir_length = strlen (current_file);
 289           char *skeleton_build;
 290           while (dir_length && current_file[dir_length - 1] != '/')
 291             --dir_length;
 292           while (dir_length && current_file[dir_length - 1] == '/')
 293             --dir_length;
 294           skeleton_build =
 295             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 296           if (dir_length > 0)
 297             {
 298               strncpy (skeleton_build, current_file, dir_length);
 299               skeleton_build[dir_length++] = '/';
 300             }
 301           strcpy (skeleton_build + dir_length, skeleton_user);
 302           skeleton_user = uniqstr_new (skeleton_build);
 303           free (skeleton_build);
 304         }
 305       skeleton_arg (skeleton_user, 1, &@1);
 306     }
 307 | "%token-table"                { token_table_flag = true; }
 308 | "%verbose"                    { report_flag = report_states; }
 309 | "%yacc"                       { yacc_flag = true; }
 310 | /*FIXME: Err?  What is this horror doing here? */ ";"
 311 ;
 312
 313 grammar_declaration:
 314   precedence_declaration
 315 | symbol_declaration
 316 | "%start" symbol
 317     {
 318       grammar_start_symbol_set ($2, @2);
 319     }
 320 | "%destructor" "{...}" generic_symlist
 321     {
 322       symbol_list *list;
 323       for (list = $3; list; list = list->next)
 324         symbol_list_destructor_set (list, $2, @2);
 325       symbol_list_free ($3);
 326     }
 327 | "%printer" "{...}" generic_symlist
 328     {
 329       symbol_list *list;
 330       for (list = $3; list; list = list->next)
 331         symbol_list_printer_set (list, $2, @2);
 332       symbol_list_free ($3);
 333     }
 334 | "%default-prec"
 335     {
 336       default_prec = true;
 337     }
 338 | "%no-default-prec"
 339     {
 340       default_prec = false;
 341     }
 342 | "%code" braceless
 343     {
 344       /* Do not invoke muscle_percent_code_grow here since it invokes
 345          muscle_user_name_list_grow.  */
 346       muscle_code_grow ("percent_code()", $2, @2);
 347       code_scanner_last_string_free ();
 348     }
 349 | "%code" ID braceless
 350     {
 351       muscle_percent_code_grow ($2, @2, $3, @3);
 352       code_scanner_last_string_free ();
 353     }
 354 ;
 355
 356
 357 /*----------*
 358  | %union.  |
 359  *----------*/
 360
 361 %token PERCENT_UNION "%union";
 362
 363 union_name:
 364   /* Nothing. */ {}
 365 | ID             { muscle_code_grow ("union_name", $1, @1); }
 366 ;
 367
 368 grammar_declaration:
 369   "%union" union_name braceless
 370     {
 371       union_seen = true;
 372       muscle_code_grow ("stype", $3, @3);
 373       code_scanner_last_string_free ();
 374     }
 375 ;
 376
 377
 378
 379
 380 symbol_declaration:
 381   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 382     {
 383       current_class = unknown_sym;
 384       current_type = NULL;
 385     }
 386 | "%token" { current_class = token_sym; } symbol_defs.1
 387     {
 388       current_class = unknown_sym;
 389       current_type = NULL;
 390     }
 391 | "%type" TYPE symbols.1
 392     {
 393       symbol_list *list;
 394       tag_seen = true;
 395       for (list = $3; list; list = list->next)
 396         symbol_type_set (list->content.sym, $2, @2);
 397       symbol_list_free ($3);
 398     }
 399 ;
 400
 401 precedence_declaration:
 402   precedence_declarator type.opt symbols.1
 403     {
 404       symbol_list *list;
 405       ++current_prec;
 406       for (list = $3; list; list = list->next)
 407         {
 408           symbol_type_set (list->content.sym, current_type, @2);
 409           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 410         }
 411       symbol_list_free ($3);
 412       current_type = NULL;
 413     }
 414 ;
 415
 416 precedence_declarator:
 417   "%left"     { $$ = left_assoc; }
 418 | "%right"    { $$ = right_assoc; }
 419 | "%nonassoc" { $$ = non_assoc; }
 420 ;
 421
 422 type.opt:
 423   /* Nothing. */ { current_type = NULL; }
 424 | TYPE           { current_type = $1; tag_seen = true; }
 425 ;
 426
 427 /* One or more symbols to be %typed. */
 428 symbols.1:
 429   symbol
 430     { $$ = symbol_list_sym_new ($1, @1); }
 431 | symbols.1 symbol
 432     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 433 ;
 434
 435 generic_symlist:
 436   generic_symlist_item { $$ = $1; }
 437 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 438 ;
 439
 440 generic_symlist_item:
 441   symbol            { $$ = symbol_list_sym_new ($1, @1); }
 442 | TYPE              { $$ = symbol_list_type_new ($1, @1); }
 443 | "<*>"             { $$ = symbol_list_default_tagged_new (@1); }
 444 | "<>"             { $$ = symbol_list_default_tagless_new (@1); }
 445 ;
 446
 447 /* One token definition.  */
 448 symbol_def:
 449   TYPE
 450      {
 451        current_type = $1;
 452        tag_seen = true;
 453      }
 454 | id
 455      {
 456        symbol_class_set ($1, current_class, @1, true);
 457        symbol_type_set ($1, current_type, @1);
 458      }
 459 | id INT
 460     {
 461       symbol_class_set ($1, current_class, @1, true);
 462       symbol_type_set ($1, current_type, @1);
 463       symbol_user_token_number_set ($1, $2, @2);
 464     }
 465 | id string_as_id
 466     {
 467       symbol_class_set ($1, current_class, @1, true);
 468       symbol_type_set ($1, current_type, @1);
 469       symbol_make_alias ($1, $2, @$);
 470     }
 471 | id INT string_as_id
 472     {
 473       symbol_class_set ($1, current_class, @1, true);
 474       symbol_type_set ($1, current_type, @1);
 475       symbol_user_token_number_set ($1, $2, @2);
 476       symbol_make_alias ($1, $3, @$);
 477     }
 478 ;
 479
 480 /* One or more symbol definitions. */
 481 symbol_defs.1:
 482   symbol_def
 483 | symbol_defs.1 symbol_def
 484 ;
 485
 486
 487         /*------------------------------------------.
 488         | The grammar section: between the two %%.  |
 489         `------------------------------------------*/
 490
 491 grammar:
 492   rules_or_grammar_declaration
 493 | grammar rules_or_grammar_declaration
 494 ;
 495
 496 /* As a Bison extension, one can use the grammar declarations in the
 497    body of the grammar.  */
 498 rules_or_grammar_declaration:
 499   rules
 500 | grammar_declaration ";"
 501 | error ";"
 502     {
 503       yyerrok;
 504     }
 505 ;
 506
 507 rules:
 508   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 509 ;
 510
 511 rhses.1:
 512   rhs                { grammar_current_rule_end (@1); }
 513 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 514 | rhses.1 ";"
 515 ;
 516
 517 rhs:
 518   /* Nothing.  */
 519     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 520 | rhs symbol
 521     { grammar_current_rule_symbol_append ($2, @2); }
 522 | rhs "{...}"
 523     { grammar_current_rule_action_append ($2, @2); }
 524 | rhs "%prec" symbol
 525     { grammar_current_rule_prec_set ($3, @3); }
 526 | rhs "%dprec" INT
 527     { grammar_current_rule_dprec_set ($3, @3); }
 528 | rhs "%merge" TYPE
 529     { grammar_current_rule_merge_set ($3, @3); }
 530 ;
 531
 532
 533 /*----------------------------*
 534  | variable and content.opt.  |
 535  *---------------------------*/
 536
 537 variable:
 538   ID
 539   | STRING { $$ = uniqstr_new ($1); } /* deprecated and not M4-friendly */
 540   ;
 541
 542 /* Some content or empty by default. */
 543 content.opt:
 544   /* Nothing. */
 545     {
 546       $$ = "";
 547     }
 548 | STRING
 549 ;
 550
 551
 552 /*-------------*
 553  | braceless.  |
 554  *-------------*/
 555
 556 braceless:
 557   "{...}"
 558     {
 559       code_props plain_code;
 560       $1[strlen ($1) - 1] = '\n';
 561       code_props_plain_init (&plain_code, $1+1, @1);
 562       code_props_translate_code (&plain_code);
 563       gram_scanner_last_string_free ();
 564       $$ = plain_code.code;
 565     }
 566 ;
 567
 568
 569 /*---------------*
 570  | Identifiers.  |
 571  *---------------*/
 572
 573 /* Identifiers are returned as uniqstr values by the scanner.
 574    Depending on their use, we may need to make them genuine symbols.  */
 575
 576 id:
 577   ID
 578     { $$ = symbol_from_uniqstr ($1, @1); }
 579 | CHAR
 580     {
 581       $$ = symbol_get (char_name ($1), @1);
 582       symbol_class_set ($$, token_sym, @1, false);
 583       symbol_user_token_number_set ($$, $1, @1);
 584     }
 585 ;
 586
 587 id_colon:
 588   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 589 ;
 590
 591
 592 symbol:
 593   id
 594 | string_as_id
 595 ;
 596
 597 /* A string used as an ID: quote it.  */
 598 string_as_id:
 599   STRING
 600     {
 601       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 602       symbol_class_set ($$, token_sym, @1, false);
 603     }
 604 ;
 605
 606 epilogue.opt:
 607   /* Nothing.  */
 608 | "%%" EPILOGUE
 609     {
 610       code_props plain_code;
 611       code_props_plain_init (&plain_code, $2, @2);
 612       code_props_translate_code (&plain_code);
 613       gram_scanner_last_string_free ();
 614       muscle_code_grow ("epilogue", plain_code.code, @2);
 615       code_scanner_last_string_free ();
 616     }
 617 ;
 618
 619 %%
 620
 621
 622 /* Return the location of the left-hand side of a rule whose
 623    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 624    the right-hand side, and return an empty location equal to the end
 625    boundary of RHS[0] if the right-hand side is empty.  */
 626
 627 static YYLTYPE
 628 lloc_default (YYLTYPE const *rhs, int n)
 629 {
 630   int i;
 631   YYLTYPE loc;
 632
 633   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 634      The bug is fixed in 7.4.2m, but play it safe for now.  */
 635   loc.start = rhs[n].end;
 636   loc.end = rhs[n].end;
 637
 638   /* Ignore empty nonterminals the start of the the right-hand side.
 639      Do not bother to ignore them at the end of the right-hand side,
 640      since empty nonterminals have the same end as their predecessors.  */
 641   for (i = 1; i <= n; i++)
 642     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 643       {
 644         loc.start = rhs[i].start;
 645         break;
 646       }
 647
 648   return loc;
 649 }
 650
 651
 652 /* Add a lex-param or a parse-param (depending on TYPE) with
 653    declaration DECL and location LOC.  */
 654
 655 static void
 656 add_param (char const *type, char *decl, location loc)
 657 {
 658   static char const alphanum[26 + 26 + 1 + 10] =
 659     "abcdefghijklmnopqrstuvwxyz"
 660     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 661     "_"
 662     "0123456789";
 663   char const *name_start = NULL;
 664   char *p;
 665
 666   /* Stop on last actual character.  */
 667   for (p = decl; p[1]; p++)
 668     if ((p == decl
 669          || ! memchr (alphanum, p[-1], sizeof alphanum))
 670         && memchr (alphanum, p[0], sizeof alphanum - 10))
 671       name_start = p;
 672
 673   /* Strip the surrounding '{' and '}', and any blanks just inside
 674      the braces.  */
 675   while (*--p == ' ' || *p == '\t')
 676     continue;
 677   p[1] = '\0';
 678   while (*++decl == ' ' || *decl == '\t')
 679     continue;
 680
 681   if (! name_start)
 682     complain_at (loc, _("missing identifier in parameter declaration"));
 683   else
 684     {
 685       char *name;
 686       size_t name_len;
 687
 688       for (name_len = 1;
 689            memchr (alphanum, name_start[name_len], sizeof alphanum);
 690            name_len++)
 691         continue;
 692
 693       name = xmalloc (name_len + 1);
 694       memcpy (name, name_start, name_len);
 695       name[name_len] = '\0';
 696       muscle_pair_list_grow (type, decl, name);
 697       free (name);
 698     }
 699
 700   gram_scanner_last_string_free ();
 701 }
 702
 703
 704 static void
 705 version_check (location const *loc, char const *version)
 706 {
 707   if (strverscmp (version, PACKAGE_VERSION) > 0)
 708     {
 709       complain_at (*loc, "require bison %s, but have %s",
 710                    version, PACKAGE_VERSION);
 711       exit (63);
 712     }
 713 }
 714
 715 static void
 716 gram_error (location const *loc, char const *msg)
 717 {
 718   complain_at (*loc, "%s", msg);
 719 }
 720
 721 char const *
 722 token_name (int type)
 723 {
 724   return yytname[YYTRANSLATE (type)];
 725 }
 726
 727 static char const *
 728 char_name (char c)
 729 {
 730   if (c == '\'')
 731     return "'\\''";
 732   else
 733     {
 734       char buf[4];
 735       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 736       return quotearg_style (escape_quoting_style, buf);
 737     }
 738 }