tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2011 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # We want a recent Autotest.
  21 m4_version_prereq([2.58])
  22
  23
  24 ## ------------- ##
  25 ## Basic tests.  ##
  26 ## ------------- ##
  27
  28 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  29 # ------------------------------------------
  30 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  31 # taken in "slurp" mode, i.e., one can match end-of-lines.
  32 m4_define([AT_MATCHES_CHECK],
  33 [AT_CHECK([perl -0777 -ne '
  34 my $count = 0;
  35 s{$2}{ ++$count; "" }gem;
  36 printf "$count\n";' $1], [0], [$3
  37 ])])
  38
  39
  40 ## ------------------------------- ##
  41 ## Macros decoding Bison options.  ##
  42 ## ------------------------------- ##
  43
  44 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  45 # ----------------------------------------------------------------
  46 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  47 m4_define([AT_LOC_PUSHDEF],
  48 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  49 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  50 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  51 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  52
  53 # AT_LOC_POPDEF
  54 # -------------
  55 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  56 m4_define([AT_LOC_POPDEF],
  57 [m4_popdef([AT_LOC_FIRST_LINE])
  58 m4_popdef([AT_LOC_FIRST_COLUMN])
  59 m4_popdef([AT_LOC_LAST_LINE])
  60 m4_popdef([AT_LOC_LAST_COLUMN])])
  61
  62
  63
  64 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  65 # -----------------------------------------
  66 m4_define([AT_BISON_OPTION_PUSHDEFS],
  67 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  68
  69
  70 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  71 # --------------------------------------------------
  72 # This macro works around the impossibility to define macros
  73 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  74 # This sucks hard, GNU M4 should really provide M5 like $$1.
  75 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  76 [m4_if([$1$2], $[1]$[2], [],
  77        [m4_fatal([$0: Invalid arguments: $@])])dnl
  78 m4_pushdef([AT_DEFINES_IF],
  79 [m4_bmatch([$3], [%defines], [$1], [$2])])
  80 m4_pushdef([AT_SKEL_CC_IF],
  81 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  82 m4_pushdef([AT_SKEL_JAVA_IF],
  83 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
  84 m4_pushdef([AT_GLR_IF],
  85 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  86 m4_pushdef([AT_LALR1_CC_IF],
  87 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  88 m4_pushdef([AT_GLR_CC_IF],
  89 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  90 # Using yacc.c?
  91 m4_pushdef([AT_YACC_IF],
  92 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  93 m4_pushdef([AT_LEXPARAM_IF],
  94 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  95 m4_pushdef([AT_LOCATION_IF],
  96 [m4_bmatch([$3], [%locations], [$1], [$2])])
  97 m4_pushdef([AT_LOCATION_TYPE_IF],
  98 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
  99 m4_pushdef([AT_PARAM_IF],
 100 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 101 m4_pushdef([AT_PURE_IF],
 102 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 103            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 104            [$2])])
 105 m4_pushdef([AT_PURE_AND_LOC_IF],
 106 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 107 m4_pushdef([AT_GLR_OR_PARAM_IF],
 108 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 109 m4_pushdef([AT_NAME_PREFIX],
 110 [m4_bmatch([$3], [%name-prefix ".*"],
 111            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
 112            [yy])])
 113 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 114 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 115 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 116                     [$2])])
 117 # yyerror always sees the locations (when activated), except if
 118 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 119 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 120 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 121                                         [$1])],
 122                             [$1])],
 123                 [$2])])
 124
 125 # The interface is pure: either because %define api.pure, or because we
 126 # are using the C++ parsers.
 127 m4_pushdef([AT_PURE_LEX_IF],
 128 [AT_PURE_IF([$1],
 129             [AT_SKEL_CC_IF([$1], [$2])])])
 130
 131 AT_PURE_LEX_IF(
 132 [m4_pushdef([AT_LOC], [(*llocp)])
 133  m4_pushdef([AT_VAL], [(*lvalp)])
 134  m4_pushdef([AT_LEX_FORMALS],
 135             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 136  m4_pushdef([AT_LEX_ARGS],
 137             [lvalp[]AT_LOCATION_IF([, llocp])])
 138  m4_pushdef([AT_USE_LEX_ARGS],
 139             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 140  m4_pushdef([AT_LEX_PRE_FORMALS],
 141             [AT_LEX_FORMALS, ])
 142  m4_pushdef([AT_LEX_PRE_ARGS],
 143             [AT_LEX_ARGS, ])
 144 ],
 145 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 146  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 147  m4_pushdef([AT_LEX_FORMALS],     [void])
 148  m4_pushdef([AT_LEX_ARGS],        [])
 149  m4_pushdef([AT_USE_LEX_ARGS],    [])
 150  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 151  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 152 ])
 153
 154 # Handle the different types of location components.
 155
 156 AT_SKEL_CC_IF(
 157   [AT_LOCATION_TYPE_IF(
 158     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 159     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 160   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 161
 162 ])# _AT_BISON_OPTION_PUSHDEFS
 163
 164
 165 # AT_BISON_OPTION_POPDEFS
 166 # -----------------------
 167 m4_define([AT_BISON_OPTION_POPDEFS],
 168 [m4_popdef([AT_LEX_PRE_ARGS])
 169 m4_popdef([AT_LEX_PRE_FORMALS])
 170 m4_popdef([AT_USE_LEX_ARGS])
 171 m4_popdef([AT_LEX_ARGS])
 172 m4_popdef([AT_LEX_FORMALS])
 173 m4_popdef([AT_VAL])
 174 m4_popdef([AT_LOC])
 175 m4_popdef([AT_PURE_LEX_IF])
 176 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 177 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 178 m4_popdef([AT_NAME_PREFIX])
 179 m4_popdef([AT_GLR_OR_PARAM_IF])
 180 m4_popdef([AT_PURE_AND_LOC_IF])
 181 m4_popdef([AT_LOCATION_TYPE_IF])
 182 m4_popdef([AT_LOCATION_IF])
 183 m4_popdef([AT_PARAM_IF])
 184 m4_popdef([AT_LEXPARAM_IF])
 185 m4_popdef([AT_YACC_IF])
 186 m4_popdef([AT_GLR_IF])
 187 m4_popdef([AT_SKEL_CC_IF])
 188 m4_popdef([AT_SKEL_JAVA_IF])
 189 m4_popdef([AT_GLR_CC_IF])
 190 m4_popdef([AT_LALR1_CC_IF])
 191 m4_popdef([AT_DEFINES_IF])
 192 AT_LOC_POPDEF
 193 ])# AT_BISON_OPTION_POPDEFS
 194
 195
 196
 197 ## -------------------------- ##
 198 ## Generating Grammar Files.  ##
 199 ## -------------------------- ##
 200
 201 # AT_DATA_SOURCE_PROLOGUE
 202 # ------------------------
 203 # The prologue that should be included in any source code that is
 204 # meant to be compiled.
 205 m4_define([AT_DATA_SOURCE_PROLOGUE],
 206 [[#include <config.h>
 207 /* We don't need perfect functions for these tests. */
 208 #undef malloc
 209 #undef memcmp
 210 #undef realloc
 211 ]])
 212
 213 # AT_DATA_GRAMMAR_PROLOGUE
 214 # ------------------------
 215 # The prologue that should be included in any grammar which parser is
 216 # meant to be compiled.
 217 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 218 [[%code top {
 219 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 220 [}
 221 ]])
 222
 223 # AT_DATA_SOURCE(NAME, CONTENT)
 224 # -----------------------------
 225 # Generate the file NAME, which CONTENT is preceded by
 226 # AT_DATA_SOURCE_PROLOGUE.
 227 m4_define([AT_DATA_SOURCE],
 228 [AT_DATA([$1],
 229 [AT_DATA_SOURCE_PROLOGUE
 230 $2])
 231 ])
 232
 233 # AT_DATA_GRAMMAR(NAME, CONTENT)
 234 # ------------------------------
 235 # Generate the file NAME, which CONTENT is preceded by
 236 # AT_DATA_GRAMMAR_PROLOGUE.
 237 m4_define([AT_DATA_GRAMMAR],
 238 [AT_DATA([$1],
 239 [AT_DATA_GRAMMAR_PROLOGUE
 240 $2])
 241 ])
 242
 243 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 244 # -------------------------------------------------
 245 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 246 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 247 #
 248 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 249 # Bison in the test suite.  For now it ensures that:
 250 #
 251 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 252 #      a non-zero exit status since Bison doesn't always try to free all memory
 253 #      in that case.
 254 #
 255 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 256 #      --graph and --report=all output for every working grammar.
 257 #
 258 #   3. If stderr contains a warning, -Werror and --warnings=error
 259 #      convert the warning to an error.
 260 m4_define([AT_BISON_CHECK],
 261 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 262        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 263 AT_BISON_CHECK_NO_XML($@)])
 264
 265 m4_define([AT_BISON_WERROR_MSG],
 266           [[bison: warnings being treated as errors]])
 267
 268 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 269 # --------------------------------------------------------
 270 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 271 # when a tortured grammar's XML is known to be too large for xsltproc to
 272 # handle.
 273 m4_define([AT_BISON_CHECK_NO_XML],
 274 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 275                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 276 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 277       [m4_if(m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0],
 278              [[# Don't interfere with caller's files.
 279               if test -f stderr; then
 280                 mv stderr at-bison-check-stderr.bak
 281               fi
 282               if test -f experr; then
 283                 mv experr at-bison-check-experr.bak
 284               fi
 285
 286               # Run with -Werror.
 287               ]AT_CHECK(AT_QUELL_VALGRIND[[ bison -Werror ]$1],
 288                         [[1]], [$3], [stderr])[
 289
 290               # Build expected stderr up to and including the "warnings
 291               # being treated as errors" message.
 292               ]AT_DATA([[at-bison-check-warnings]], [$4])[
 293               at_bison_check_first="` \
 294                 sed -n '/: warning: /=' at-bison-check-warnings \
 295                 | sed -n 1p \
 296               `"
 297               if test $at_bison_check_first -gt 1; then
 298                 sed -n "1,`expr $at_bison_check_first - 1`"p \
 299                   at-bison-check-warnings > experr
 300               fi
 301               echo ']AT_BISON_WERROR_MSG[' >> experr
 302
 303               # Finish building expected stderr and check.  Unlike
 304               # warnings, complaints cause bison to exit early.  Thus,
 305               # with -Werror, bison does not necessarily report all
 306               # warnings that it does without -Werror, but it at least
 307               # reports one.
 308               at_bison_check_last="`sed -n '$=' stderr`"
 309               if test x"$at_bison_check_last" = x; then
 310                 at_bison_check_last=1
 311               fi
 312               at_bison_check_last="`expr $at_bison_check_last - 1`"
 313               sed -n "$at_bison_check_first,$at_bison_check_last"p \
 314                 at-bison-check-warnings >> experr
 315               ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 316                           stderr 1>&2]], [[0]], [[]], [experr])[
 317
 318               # Now check --warnings=error.
 319               cp stderr experr
 320               ]AT_CHECK(AT_QUELL_VALGRIND[[ bison --warnings=error ]$1],
 321                         [[1]], [$3], [experr])[
 322
 323               # Restore caller's files.
 324               if test -f at-bison-check-experr.bak; then
 325                 mv at-bison-check-experr.bak experr
 326               fi
 327               if test -f at-bison-check-stderr.bak; then
 328                 mv at-bison-check-stderr.bak stderr
 329               fi
 330              ]])
 331       ])
 332 ])
 333
 334 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 335 # -----------------------------------------------------
 336 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 337 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 338 # have a non-zero exit status.
 339 m4_define([AT_BISON_CHECK_XML],
 340 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 341   mkdir xml-tests]
 342   m4_pushdef([AT_BISON_ARGS],
 343              [m4_bpatsubsts([[$1]],
 344                             [--report(-file)?=[^][ ]*], [],
 345                             [--graph=[^][ ]*], [],
 346                             [--xml=[^][ ]*], [])])dnl
 347   # Don't combine these Bison invocations since we want to be sure that
 348   # --report=all isn't required to get the full XML file.
 349   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 350              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 351            [[0]], [ignore], [ignore])
 352   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 353            [[0]], [ignore], [ignore])
 354   m4_popdef([AT_BISON_ARGS])dnl
 355   [cp xml-tests/test.output expout]
 356   AT_CHECK([[$XSLTPROC \
 357              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 358              xml-tests/test.xml]], [[0]], [expout])
 359   [cp xml-tests/test.dot expout]
 360   AT_CHECK([[$XSLTPROC \
 361              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 362              xml-tests/test.xml]], [[0]], [expout])
 363   [rm -rf xml-tests expout
 364 fi]])
 365
 366 # AT_QUELL_VALGRIND
 367 # -----------------
 368 # Put this before a Bison invocation to keep Valgrind from complaining about
 369 # reachable memory.
 370 #
 371 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 372 # The triple quoting below will cause test cases to fail if you do.  If you do
 373 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 374 # will then fail to shell-escape its contents when attempting to print them.
 375 # The testsuite verbose output, at least, will be incorrect, but nothing may
 376 # fail to make sure you notice.
 377 m4_define([AT_QUELL_VALGRIND],
 378 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 379
 380 ## ------------------------ ##
 381 ## Compiling C, C++ Files.  ##
 382 ## ------------------------ ##
 383
 384
 385 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 386 # ----------------------------------------
 387 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 388 # assume that we are linking too; this is a hack.
 389 m4_define([AT_COMPILE],
 390 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 391            0, [ignore], [ignore])])
 392
 393 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 394 # --------------------------------------------
 395 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 396 # assume that we are linking too; this is a hack.
 397 # If the C++ compiler does not work, ignore the test.
 398 m4_define([AT_COMPILE_CXX],
 399 [AT_KEYWORDS(c++)
 400 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 401 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 402          0, [ignore], [ignore])])
 403
 404 # AT_JAVA_COMPILE(SOURCES)
 405 # ------------------------
 406 # Compile SOURCES into Java class files.  Skip the test if java or javac
 407 # is not installed.
 408 m4_define([AT_JAVA_COMPILE],
 409 [AT_KEYWORDS(java)
 410 AT_CHECK([[test -n "$CONF_JAVA" || exit 77
 411            test -n "$CONF_JAVAC" || exit 77]])
 412 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 413          [[0]], [ignore], [ignore])])
 414
 415 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 416 # --------------------------------
 417 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 418 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 419 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 420 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 421 # AT_SKEL_JAVA_IF.
 422 m4_define([AT_FULL_COMPILE], [
 423   AT_SKEL_JAVA_IF([
 424     AT_BISON_CHECK([[-o ]$1[.java ]$1[.y]])
 425     AT_JAVA_COMPILE([$1[.java]]m4_ifval($2,
 426                                         [[$1[.java ]$1[-]$2[.java]]]))
 427   ], [
 428     AT_SKEL_CC_IF([
 429       AT_BISON_CHECK([[-o ]$1[.cc ]$1[.y]])
 430       AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1[.cc ]$1[-]$2[.cc]]]))
 431     ], [
 432       AT_BISON_CHECK([[-o ]$1[.c ]$1[.y]])
 433       AT_COMPILE([$1]m4_ifval($2, [, [$1[.c ]$1[-]$2[.c]]]))
 434     ])
 435   ])
 436 ])
 437
 438
 439 ## ---------------------------- ##
 440 ## Running a generated parser.  ##
 441 ## ---------------------------- ##
 442
 443 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 444 # ------------------------------------------------------------
 445 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 446 m4_define([AT_PARSER_CHECK],
 447 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 448
 449 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 450 # -----------------------------------------------------------------
 451 m4_define([AT_JAVA_PARSER_CHECK],
 452 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 453
 454 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 455 #                          DECLS, GRAMMAR, INPUT,
 456 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 457 #                          [OTHER-CHECKS],
 458 #                          [PARSER-EXIT-VALUE],
 459 #                          [PARSER-STDOUT], [PARSER-STDERR])
 460 # -------------------------------------------------------------
 461 # Using TITLE as the test group title, check the generated parser tables
 462 # and parser for a specified grammar file under a condition labeled by
 463 # COND-VALUE.
 464 #
 465 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 466 # recognized attribute is described below where it is relevant.
 467 #
 468 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 469 # the grammar file.  Insert basic yyerror, yylex, and main function
 470 # definitions as well.  Hardcode yylex to return the (possibly empty)
 471 # comma-delimited series of tokens in INPUT followed by token 0.
 472 #
 473 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 474 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 475 # On the bison command-line, specify `--report=all --defines'.  Check
 476 # that Bison exits with value 0, has no stdout, and has stderr
 477 # BISON-STDERR.
 478 #
 479 # If TEST-SPEC contains the attribute `last-state', check that the value
 480 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 481 # the grammar; in other words, check the number of states (minus one).
 482 # Otherwise, check that everything in the `.output' file starting with
 483 # the definition of state 0 is the same as the entire value of
 484 # TABLES-OR-LAST-STATE.
 485 #
 486 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 487 # `.output' file, which is named `input.output', and/or grammar file,
 488 # which is named `input.y'.
 489 #
 490 # Finally, compile the generated parser and then run it using
 491 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 492 # PARSER-STDERR as the 2nd-4th arguments.
 493 #
 494 # As a precondition, you must properly double-quote all arguments that
 495 # are to be interpreted as strings.
 496 #
 497 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 498 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 499 # first argument.  This is useful, for example, when wrapping multiple
 500 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 501 # condition, in another macro.
 502 #
 503 # For example:
 504 #
 505 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 506 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 507 #   # ---------------------------------------------------------------------
 508 #   m4_define([AT_TEST_SYNTAX_ERROR],
 509 #   [
 510 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 511 #                              [[last-state]],
 512 #                              [[%error-verbose ]$2], [$3], [$4],
 513 #                              [[]], [$5], [], [$6], [$7], [$8])
 514 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 515 #                              [[last-state]],
 516 #                              [$2], [$3], [$4],
 517 #                              [[]], [$5], [], [$6], [$7], [$8])
 518 #   ])
 519 #
 520 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 521 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 522 #                        [[3]],
 523 #                        [[1]], [[]],
 524 #                        [AT_COND_CASE([[no verbose]],
 525 #                                      [[syntax error
 526 #   ]],
 527 #                                      [[syntax error, unexpected 'b', expecting $end
 528 #   ]])])
 529 m4_define([AT_TEST_TABLES_AND_PARSE],
 530 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 531
 532 AT_SETUP([$1])
 533
 534 AT_DATA_GRAMMAR([[input.y]],
 535 [[%code {
 536   #include <stdio.h>
 537   static void yyerror (char const *msg);
 538   static int yylex (void);
 539 }
 540
 541 ]$4[
 542
 543 %%
 544
 545 ]$5[
 546
 547 %%
 548
 549 static void
 550 yyerror (char const *msg)
 551 {
 552   fprintf (stderr, "%s\n", msg);
 553 }
 554
 555 static int
 556 yylex (void)
 557 {
 558   static int const input[] = {
 559     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 560   };
 561   static int const *inputp = input;
 562   return *inputp++;
 563 }
 564
 565 int
 566 main (void)
 567 {
 568   return yyparse ();
 569 }
 570 ]])
 571
 572 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 573 # expanding macros, so it corrupts some special characters in the
 574 # macros.  To avoid this, expand now and pass it the result with proper
 575 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 576 # strings.
 577
 578 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 579       [AT_BISON_CHECK],
 580       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 581                                [0], [], m4_dquote($7))
 582
 583 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 584       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 585                 m4_dquote($8))],
 586       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 587                 m4_dquote($8)[[
 588 ]])])
 589
 590 $9
 591
 592 AT_COMPILE([[input]])
 593
 594 AT_PARSER_CHECK([[./input]],
 595                 m4_ifval([$10], [m4_dquote($10)]),
 596                 m4_ifval([$11], [m4_dquote($11)]),
 597                 m4_ifval([$12], [m4_dquote($12)]))
 598
 599 AT_CLEANUP
 600
 601 m4_popdef([AT_COND_CASE])])
 602
 603
 604
 605 ## ----------------------- ##
 606 ## Launch the test suite.  ##
 607 ## ----------------------- ##
 608
 609 AT_INIT
 610
 611 AT_TESTED([bison])