data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4
   5 # Copyright (C) 2002, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free
   6 # Software Foundation, Inc.
   7
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21
  22 ## ---------------- ##
  23 ## Identification.  ##
  24 ## ---------------- ##
  25
  26 # b4_copyright(TITLE, [YEARS])
  27 # ----------------------------
  28 # If YEARS are not defined, use b4_copyright_years.
  29 m4_define([b4_copyright],
  30 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  31
  32 b4_comment([$1
  33
  34 ]m4_dquote(m4_text_wrap([Copyright (C)
  35 ]m4_ifval([$2], [[$2]], [m4_defn([b4_copyright_years])])[
  36 Free Software Foundation, Inc.]))[
  37
  38 This program is free software: you can redistribute it and/or modify
  39 it under the terms of the GNU General Public License as published by
  40 the Free Software Foundation, either version 3 of the License, or
  41 (at your option) any later version.
  42
  43 This program is distributed in the hope that it will be useful,
  44 but WITHOUT ANY WARRANTY; without even the implied warranty of
  45 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  46 GNU General Public License for more details.
  47
  48 You should have received a copy of the GNU General Public License
  49 along with this program.  If not, see <http://www.gnu.org/licenses/>.])
  50
  51 b4_comment([As a special exception, you may create a larger work that contains
  52 part or all of the Bison parser skeleton and distribute that work
  53 under terms of your choice, so long as that work isn't itself a
  54 parser generator using the skeleton or a modified version thereof
  55 as a parser skeleton.  Alternatively, if you modify or redistribute
  56 the parser skeleton itself, you may (at your option) remove this
  57 special exception, which will cause the skeleton and the resulting
  58 Bison output files to be licensed under the GNU General Public
  59 License without this special exception.
  60
  61 This special exception was added by the Free Software Foundation in
  62 version 2.2 of Bison.])])
  63
  64
  65 ## ---------------- ##
  66 ## Error handling.  ##
  67 ## ---------------- ##
  68
  69 # The following error handling macros print error directives that should not
  70 # become arguments of other macro invocations since they would likely then be
  71 # mangled.  Thus, they print to stdout directly.
  72
  73 # b4_cat(TEXT)
  74 # ------------
  75 # Write TEXT to stdout.  Precede the final newline with an @ so that it's
  76 # escaped.  For example:
  77 #
  78 #   b4_cat([[@complain(invalid input@)]])
  79 m4_define([b4_cat],
  80 [m4_syscmd([cat <<'_m4eof'
  81 ]m4_bpatsubst(m4_dquote($1), [_m4eof], [_m4@`eof])[@
  82 _m4eof
  83 ])dnl
  84 m4_if(m4_sysval, [0], [], [m4_fatal([$0: cannot write to stdout])])])
  85
  86 # b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
  87 # -------------------------------------------
  88 # Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to stdout.
  89 #
  90 # For example:
  91 #
  92 #   b4_error([[warn]], [[invalid value for `%s': %s]], [[foo]], [[3]])
  93 m4_define([b4_error],
  94 [b4_cat([[@]$1[(]$2[]]dnl
  95 [m4_if([$#], [2], [],
  96        [m4_foreach([b4_arg],
  97                    m4_dquote(m4_shift(m4_shift($@))),
  98                    [[@,]b4_arg])])[@)]])])
  99
 100 # b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
 101 # ----------------------------------------------------------
 102 # Write @KIND_at(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 103 #
 104 # For example:
 105 #
 106 #   b4_error_at([[complain]], [[input.y:2.3]], [[input.y:5.4]],
 107 #               [[invalid %s]], [[foo]])
 108 m4_define([b4_error_at],
 109 [b4_cat([[@]$1[_at(]$2[@,]$3[@,]$4[]]dnl
 110 [m4_if([$#], [4], [],
 111        [m4_foreach([b4_arg],
 112                    m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
 113                    [[@,]b4_arg])])[@)]])])
 114
 115 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
 116 # ------------------------------------
 117 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 118 #
 119 # For example:
 120 #
 121 #   b4_warn([[invalid value for `%s': %s]], [[foo]], [[3]])
 122 #
 123 # As a simple test suite, this:
 124 #
 125 #   m4_divert(-1)
 126 #   m4_define([asdf], [ASDF])
 127 #   m4_define([fsa], [FSA])
 128 #   m4_define([fdsa], [FDSA])
 129 #   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
 130 #   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
 131 #   b4_warn()
 132 #   b4_warn(1)
 133 #   b4_warn(1, 2)
 134 #
 135 # Should produce this without newlines:
 136 #
 137 #   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
 138 #   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
 139 #   @warn(@)
 140 #   @warn(1@)
 141 #   @warn(1@,2@)
 142 m4_define([b4_warn],
 143 [b4_error([[warn]], $@)])
 144
 145 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 146 # ---------------------------------------------------
 147 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 148 #
 149 # For example:
 150 #
 151 #   b4_warn_at([[input.y:2.3]], [[input.y:5.4]], [[invalid %s]], [[foo]])
 152 m4_define([b4_warn_at],
 153 [b4_error_at([[warn]], $@)])
 154
 155 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 156 # ----------------------------------------
 157 # Write @complain(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 158 #
 159 # See b4_warn example.
 160 m4_define([b4_complain],
 161 [b4_error([[complain]], $@)])
 162
 163 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 164 # -------------------------------------------------------
 165 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 166 #
 167 # See b4_warn_at example.
 168 m4_define([b4_complain_at],
 169 [b4_error_at([[complain]], $@)])
 170
 171 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 172 # -------------------------------------
 173 # Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 174 #
 175 # See b4_warn example.
 176 m4_define([b4_fatal],
 177 [b4_error([[fatal]], $@)dnl
 178 m4_exit(1)])
 179
 180 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 181 # ----------------------------------------------------
 182 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 183 #
 184 # See b4_warn_at example.
 185 m4_define([b4_fatal_at],
 186 [b4_error_at([[fatal]], $@)dnl
 187 m4_exit(1)])
 188
 189
 190 ## ---------------- ##
 191 ## Default values.  ##
 192 ## ---------------- ##
 193
 194 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 195 m4_define_default([b4_pre_prologue], [])
 196 m4_define_default([b4_post_prologue], [])
 197 m4_define_default([b4_epilogue], [])
 198 m4_define_default([b4_parse_param], [])
 199
 200 # The initial column and line.
 201 m4_define_default([b4_location_initial_column], [1])
 202 m4_define_default([b4_location_initial_line],   [1])
 203
 204
 205 ## ------------ ##
 206 ## Data Types.  ##
 207 ## ------------ ##
 208
 209 # b4_ints_in(INT1, INT2, LOW, HIGH)
 210 # ---------------------------------
 211 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 212 m4_define([b4_ints_in],
 213 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 214
 215
 216 # b4_subtract(LHS, RHS)
 217 # ---------------------
 218 # Evaluate LHS - RHS if they are integer literals, otherwise expand
 219 # to (LHS) - (RHS).
 220 m4_define([b4_subtract],
 221 [m4_bmatch([$1$2], [^[0123456789]*$],
 222            [m4_eval([$1 - $2])],
 223            [($1) - ($2)])])
 224
 225 # b4_args(ARG1, ...)
 226 # _b4_args(ARG1, ...)
 227 # -------------------
 228 # Join with comma, skipping empty arguments.
 229 # b4_args calls itself recursively until it sees the first non-empty
 230 # argument, then calls _b4_args which prepends each non-empty argument
 231 # with a comma.
 232 m4_define([b4_args],
 233 [m4_if([$#$1],
 234        [1], [],
 235        [m4_ifval([$1],
 236                  [$1[]_$0(m4_shift($@))],
 237                  [$0(m4_shift($@))])])])
 238
 239 # _b4_args(ARGS1, ...)
 240 # --------------------
 241 m4_define([_b4_args],
 242 [m4_if([$#$1],
 243        [1], [],
 244        [m4_ifval([$1], [, $1])[]$0(m4_shift($@))])])
 245
 246
 247
 248
 249 # b4_integral_parser_tables_map(MACRO)
 250 # -------------------------------------
 251 # Map MACRO on all the integral tables.  MACRO is expected to have
 252 # the signature MACRO(TABLE-NAME, CONTENT, COMMENT).
 253 m4_define([b4_integral_parser_tables_map],
 254 [$1([pact], [b4_pact],
 255     [[YYPACT[STATE-NUM] -- Index in YYTABLE of the portion describing
 256 STATE-NUM.]])
 257
 258 $1([defact], [b4_defact],
 259    [[YYDEFACT[S] -- default reduction number in state S.  Performed when
 260 YYTABLE does not specify something else to do.  Zero means the default
 261 is an error.]])
 262
 263 $1([pgoto], [b4_pgoto], [[YYPGOTO[NTERM-NUM].]])
 264
 265 $1([defgoto], [b4_defgoto], [[YYDEFGOTO[NTERM-NUM].]])
 266
 267 $1([table], [b4_table],
 268    [[YYTABLE[YYPACT[STATE-NUM]].  What to do in state STATE-NUM.  If
 269 positive, shift that token.  If negative, reduce the rule which
 270 number is the opposite.  If YYTABLE_NINF, syntax error.]])
 271
 272 $1([check], [b4_check])
 273
 274 $1([stos], [b4_stos],
 275    [[STOS_[STATE-NUM] -- The (internal number of the) accessing
 276 symbol of state STATE-NUM.]])
 277
 278 $1([r1], [b4_r1],
 279    [[YYR1[YYN] -- Symbol number of symbol that rule YYN derives.]])
 280
 281 $1([r2], [b4_r2],
 282    [[YYR2[YYN] -- Number of symbols composing right hand side of rule YYN.]])
 283 ])
 284
 285
 286 # b4_parser_tables_declare
 287 # b4_parser_tables_define
 288 # ------------------------
 289 # Define/declare the (deterministic) parser tables.
 290 m4_define([b4_parser_tables_declare],
 291 [b4_integral_parser_tables_map([b4_integral_parser_table_declare])])
 292
 293 m4_define([b4_parser_tables_define],
 294 [b4_integral_parser_tables_map([b4_integral_parser_table_define])])
 295
 296
 297
 298 ## ------------------ ##
 299 ## Decoding options.  ##
 300 ## ------------------ ##
 301
 302 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 303 # -----------------------------------
 304 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 305 m4_define([b4_flag_if],
 306 [m4_case(b4_$1_flag,
 307          [0], [$3],
 308          [1], [$2],
 309          [m4_fatal([invalid $1 value: ]$1)])])
 310
 311
 312 # b4_define_flag_if(FLAG)
 313 # -----------------------
 314 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 315 # value of the Boolean FLAG.
 316 m4_define([b4_define_flag_if],
 317 [_b4_define_flag_if($[1], $[2], [$1])])
 318
 319 # _b4_define_flag_if($1, $2, FLAG)
 320 # --------------------------------
 321 # This macro works around the impossibility to define macros
 322 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 323 # This sucks hard, GNU M4 should really provide M5 like $$1.
 324 m4_define([_b4_define_flag_if],
 325 [m4_if([$1$2], $[1]$[2], [],
 326        [m4_fatal([$0: Invalid arguments: $@])])dnl
 327 m4_define([b4_$3_if],
 328           [b4_flag_if([$3], [$1], [$2])])])
 329
 330
 331 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 332 # -----------------------------
 333 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 334 b4_define_flag_if([defines])            # Whether headers are requested.
 335 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 336 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 337 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 338
 339
 340 ## --------- ##
 341 ## Symbols.  ##
 342 ## --------- ##
 343
 344 # b4_symbol_(NUM, FIELD)
 345 # ----------------------
 346 # Recover a FIELD about symbol #NUM.  Thanks to m4_indir, fails if
 347 # undefined.
 348 m4_define([b4_symbol_],
 349 [m4_indir([b4_symbol($1, $2)])])
 350
 351
 352 # b4_symbol(NUM, FIELD)
 353 # ---------------------
 354 # Recover a FIELD about symbol #NUM.  Thanks to m4_indir, fails if
 355 # undefined.  If FIELD = id, prepend the prefix.
 356 m4_define([b4_symbol],
 357 [m4_case([$2],
 358          [id],    [m4_do([b4_percent_define_get([api.tokens.prefix])],
 359                          [b4_symbol_([$1], [id])])],
 360          [b4_symbol_($@)])])
 361
 362
 363 # b4_symbol_if(NUM, FIELD, IF-TRUE, IF-FALSE)
 364 # -------------------------------------------
 365 # If FIELD about symbol #NUM is 1 expand IF-TRUE, if is 0, expand IF-FALSE.
 366 # Otherwise an error.
 367 m4_define([b4_symbol_if],
 368 [m4_case(b4_symbol([$1], [$2]),
 369          [1], [$3],
 370          [0], [$4],
 371          [m4_fatal([$0: field $2 of $1 is not a Boolean:] b4_symbol([$1], [$2]))])])
 372
 373
 374 # b4_symbol_action_location(SYMBOL-NUM, KIND)
 375 # -------------------------------------------
 376 # Report the location of the KIND action as FILE:LINE.
 377 m4_define([b4_symbol_action_location],
 378 [b4_symbol([$1], [$2_file]):b4_syncline([b4_symbol([$1], [$2_line])])])
 379
 380
 381 # b4_symbol_action(SYMBOL-NUM, KIND)
 382 # ----------------------------------
 383 # Run the action KIND (destructor or printer) for SYMBOL-NUM.
 384 # Same as in C, but using references instead of pointers.
 385 m4_define([b4_symbol_action],
 386 [b4_symbol_if([$1], [has_$2],
 387 [m4_pushdef([b4_dollar_dollar],
 388     [b4_symbol_value([(*yyvaluep)],
 389                      b4_symbol_if([$1], [has_type],
 390                                   [b4_symbol([$1], [type])]))])dnl
 391 m4_pushdef([b4_at_dollar], [(*yylocationp)])dnl
 392       b4_symbol_case_([$1])
 393 b4_syncline([b4_symbol([$1], [$2_line])], ["b4_symbol([$1], [$2_file])"])
 394         b4_symbol([$1], [$2])
 395 b4_syncline([@oline@], [@ofile@])
 396         break;
 397
 398 m4_popdef([b4_at_dollar])dnl
 399 m4_popdef([b4_dollar_dollar])dnl
 400 ])])
 401
 402
 403 # b4_symbol_destructor(SYMBOL-NUM)
 404 # b4_symbol_printer(SYMBOL-NUM)
 405 # --------------------------------
 406 m4_define([b4_symbol_destructor], [b4_symbol_action([$1], [destructor])])
 407 m4_define([b4_symbol_printer],    [b4_symbol_action([$1], [printer])])
 408
 409
 410 # b4_symbol_case_(SYMBOL-NUM)
 411 # ---------------------------
 412 # Issue a "case NUM" for SYMBOL-NUM.
 413 m4_define([b4_symbol_case_],
 414 [      case b4_symbol([$1], [number]): // b4_symbol([$1], [tag])
 415 ])
 416
 417
 418 # b4_symbol_foreach(MACRO)
 419 # ------------------------
 420 # Invoke MACRO(SYMBOL-NUM) for each SYMBOL-NUM.
 421 m4_define([b4_symbol_foreach],
 422           [m4_map([$1], m4_defn([b4_symbol_numbers]))])
 423
 424
 425 ## ------- ##
 426 ## Types.  ##
 427 ## ------- ##
 428
 429 # b4_type_action_(NUMS)
 430 # ---------------------
 431 # Run actions for the symbol NUMS that all have the same type-name.
 432 # Skip NUMS that have no type-name.
 433 m4_define([b4_type_action_],
 434 [b4_symbol_if([$1], [has_type],
 435 [m4_map([b4_symbol_case_], [$@])[]dnl
 436         b4_dollar_dollar([b4_symbol([$1], [number])],
 437                          [b4_symbol([$1], [tag])],
 438                          [b4_symbol([$1], [type])]);
 439         break;
 440
 441 ])])
 442
 443 # b4_type_foreach(MACRO)
 444 # ----------------------
 445 # Invoke MACRO(SYMBOL-NUMS) for each set of SYMBOL-NUMS for each type set.
 446 m4_define([b4_type_foreach],
 447           [m4_map([$1], m4_defn([b4_type_names]))])
 448
 449
 450
 451 ## ----------- ##
 452 ## Synclines.  ##
 453 ## ----------- ##
 454
 455 # b4_basename(NAME)
 456 # -----------------
 457 # Similar to POSIX basename; the differences don't matter here.
 458 # Beware that NAME is not evaluated.
 459 m4_define([b4_basename],
 460 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 461
 462
 463 # b4_syncline(LINE, FILE)
 464 # -----------------------
 465 m4_define([b4_syncline],
 466 [b4_flag_if([synclines],
 467 [b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 468 b4_sync_start([$1], [$2])])])
 469
 470 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 471 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 472
 473 # b4_user_code(USER-CODE)
 474 # -----------------------
 475 # Emit code from the user, ending it with synclines.
 476 m4_define([b4_user_code],
 477 [$1
 478 b4_syncline([@oline@], [@ofile@])])
 479
 480
 481 # b4_define_user_code(MACRO)
 482 # --------------------------
 483 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 484 m4_define([b4_define_user_code],
 485 [m4_define([b4_user_$1],
 486 [b4_user_code([b4_$1])])])
 487
 488
 489 # b4_user_actions
 490 # b4_user_initial_action
 491 # b4_user_post_prologue
 492 # b4_user_pre_prologue
 493 # b4_user_stype
 494 # ----------------------
 495 # Macros that issue user code, ending with synclines.
 496 b4_define_user_code([actions])
 497 b4_define_user_code([initial_action])
 498 b4_define_user_code([post_prologue])
 499 b4_define_user_code([pre_prologue])
 500 b4_define_user_code([stype])
 501
 502
 503 # b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
 504 # -----------------------------------------------------
 505 # Complain if any name of type WHAT is used by the user (as recorded in
 506 # USER-LIST) but is not used by Bison (as recorded by macros in the
 507 # namespace BISON-NAMESPACE).
 508 #
 509 # USER-LIST must expand to a list specifying all user occurrences of all names
 510 # of type WHAT.   Each item in the list must be a triplet specifying one
 511 # occurrence: name, start boundary, and end boundary.  Empty string names are
 512 # fine.  An empty list is fine.
 513 #
 514 # For example, to define b4_foo_user_names to be used for USER-LIST with three
 515 # name occurrences and with correct quoting:
 516 #
 517 #   m4_define([b4_foo_user_names],
 518 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 519 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 520 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 521 #
 522 # The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
 523 # is used by Bison (in the front-end or in the skeleton).  Empty string names
 524 # are fine, but it would be ugly for Bison to actually use one.
 525 #
 526 # For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
 527 # the names bar and baz are used by Bison:
 528 #
 529 #   m4_define([b4_foo_bison_names(bar)])
 530 #   m4_define([b4_foo_bison_names(baz)])
 531 #
 532 # To invoke b4_check_user_names with TYPE foo, with USER-LIST
 533 # b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
 534 # quoting:
 535 #
 536 #   b4_check_user_names([[foo]], [b4_foo_user_names],
 537 #                       [[b4_foo_bison_names]])
 538 m4_define([b4_check_user_names],
 539 [m4_foreach([b4_occurrence], $2,
 540 [m4_pushdef([b4_occurrence], b4_occurrence)dnl
 541 m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
 542 m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
 543 m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
 544 m4_ifndef($3[(]m4_quote(b4_user_name)[)],
 545           [b4_complain_at([b4_start], [b4_end],
 546                           [[%s `%s' is not used]],
 547                           [$1], [b4_user_name])])[]dnl
 548 m4_popdef([b4_occurrence])dnl
 549 m4_popdef([b4_user_name])dnl
 550 m4_popdef([b4_start])dnl
 551 m4_popdef([b4_end])dnl
 552 ])])
 553
 554
 555
 556 ## --------------------- ##
 557 ## b4_percent_define_*.  ##
 558 ## --------------------- ##
 559
 560
 561 # b4_percent_define_use(VARIABLE)
 562 # -------------------------------
 563 # Declare that VARIABLE was used.
 564 m4_define([b4_percent_define_use],
 565 [m4_define([b4_percent_define_bison_variables(]$1[)])dnl
 566 ])
 567
 568 # b4_percent_define_get(VARIABLE, [DEFAULT])
 569 # ------------------------------------------
 570 # Mimic muscle_percent_define_get in ../src/muscle-tab.h.  That is, if
 571 # the %define variable VARIABLE is defined, emit its value.  Contrary
 572 # to its C counterpart, return DEFAULT otherwise.  Also, record
 573 # Bison's usage of VARIABLE by defining
 574 # b4_percent_define_bison_variables(VARIABLE).
 575 #
 576 # For example:
 577 #
 578 #   b4_percent_define_get([[foo]])
 579 m4_define([b4_percent_define_get],
 580 [b4_percent_define_use([$1])dnl
 581 m4_ifdef([b4_percent_define(]$1[)],
 582          [m4_indir([b4_percent_define(]$1[)])],
 583          [$2])])
 584
 585 # b4_percent_define_get_loc(VARIABLE)
 586 # -----------------------------------
 587 # Mimic muscle_percent_define_get_loc in ../src/muscle-tab.h exactly.  That is,
 588 # if the %define variable VARIABLE is undefined, complain fatally since that's
 589 # a Bison or skeleton error.  Otherwise, return its definition location in a
 590 # form approriate for the first two arguments of b4_warn_at, b4_complain_at, or
 591 # b4_fatal_at.  Don't record this as a Bison usage of VARIABLE as there's no
 592 # reason to suspect that the user-supplied value has yet influenced the output.
 593 #
 594 # For example:
 595 #
 596 #   b4_complain_at(b4_percent_define_get_loc([[foo]]), [[invalid foo]])
 597 m4_define([b4_percent_define_get_loc],
 598 [m4_ifdef([b4_percent_define_loc(]$1[)],
 599           [m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
 600 b4_loc[]dnl
 601 m4_popdef([b4_loc])],
 602           [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_get_loc]], [$1])])])
 603
 604 # b4_percent_define_get_syncline(VARIABLE)
 605 # ----------------------------------------
 606 # Mimic muscle_percent_define_get_syncline in ../src/muscle-tab.h exactly.
 607 # That is, if the %define variable VARIABLE is undefined, complain fatally
 608 # since that's a Bison or skeleton error.  Otherwise, return its definition
 609 # location as a b4_syncline invocation.  Don't record this as a Bison usage of
 610 # VARIABLE as there's no reason to suspect that the user-supplied value has yet
 611 # influenced the output.
 612 #
 613 # For example:
 614 #
 615 #   b4_percent_define_get_syncline([[foo]])
 616 m4_define([b4_percent_define_get_syncline],
 617 [m4_ifdef([b4_percent_define_syncline(]$1[)],
 618           [m4_indir([b4_percent_define_syncline(]$1[)])],
 619           [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_get_syncline]], [$1])])])
 620
 621 # b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
 622 # ------------------------------------------------------
 623 # Mimic muscle_percent_define_ifdef in ../src/muscle-tab.h exactly.  That is,
 624 # if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
 625 # IF-FALSE.  Also, record Bison's usage of VARIABLE by defining
 626 # b4_percent_define_bison_variables(VARIABLE).
 627 #
 628 # For example:
 629 #
 630 #   b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
 631 m4_define([b4_percent_define_ifdef],
 632 [m4_ifdef([b4_percent_define(]$1[)],
 633           [b4_percent_define_use([$1])$2],
 634           [$3])])
 635
 636
 637 ## --------- ##
 638 ## Options.  ##
 639 ## --------- ##
 640
 641
 642 # b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
 643 # --------------------------------------------------------
 644 # Mimic muscle_percent_define_flag_if in ../src/muscle-tab.h exactly.  That is,
 645 # if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
 646 # If it is defined to "false", expand IF-FALSE.  Complain if it is undefined
 647 # (a Bison or skeleton error since the default value should have been set
 648 # already) or defined to any other value (possibly a user error).  Also, record
 649 # Bison's usage of VARIABLE by defining
 650 # b4_percent_define_bison_variables(VARIABLE).
 651 #
 652 # For example:
 653 #
 654 #   b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
 655 m4_define([b4_percent_define_flag_if],
 656 [b4_percent_define_ifdef([$1],
 657   [m4_case(b4_percent_define_get([$1]),
 658            [], [$2], [true], [$2], [false], [$3],
 659            [m4_expand_once([b4_complain_at(b4_percent_define_get_loc([$1]),
 660                                            [[invalid value for %%define Boolean variable `%s']],
 661                                            [$1])],
 662                            [[b4_percent_define_flag_if($1)]])])],
 663   [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_flag_if]], [$1])])])
 664
 665
 666 # b4_percent_define_default(VARIABLE, DEFAULT)
 667 # --------------------------------------------
 668 # Mimic muscle_percent_define_default in ../src/muscle-tab.h exactly.  That is,
 669 # if the %define variable VARIABLE is undefined, set its value to DEFAULT.
 670 # Don't record this as a Bison usage of VARIABLE as there's no reason to
 671 # suspect that the value has yet influenced the output.
 672 #
 673 # For example:
 674 #
 675 #   b4_percent_define_default([[foo]], [[default value]])
 676 m4_define([b4_percent_define_default],
 677 [m4_ifndef([b4_percent_define(]$1[)],
 678            [m4_define([b4_percent_define(]$1[)], [$2])dnl
 679             m4_define([b4_percent_define_loc(]$1[)],
 680                       [[[[<skeleton default value>:-1.-1]],
 681                         [[<skeleton default value>:-1.-1]]]])dnl
 682             m4_define([b4_percent_define_syncline(]$1[)], [[]])])])
 683
 684
 685 # b4_percent_define_if_define(VARIABLE)
 686 # -------------------------------------
 687 # Define b4_VARIABLE_if that executes its $1 or $2 depending whether
 688 # VARIABLE was %defined.  The characters `.' and `-' in VARIABLE are mapped
 689 # to `_'.
 690 m4_define([b4_percent_define_if_define_],
 691 [m4_define(m4_bpatsubst([b4_$1_if], [[-.]], [_]),
 692            [b4_percent_define_flag_if([$1], [$2], [$3])])])
 693 m4_define([b4_percent_define_if_define],
 694 [b4_percent_define_default([[$1]], [[false]])
 695 b4_percent_define_if_define_([$1], $[1], $[2])])
 696
 697
 698 # b4_percent_define_check_values(VALUES)
 699 # --------------------------------------
 700 # Mimic muscle_percent_define_check_values in ../src/muscle-tab.h exactly
 701 # except that the VALUES structure is more appropriate for M4.  That is, VALUES
 702 # is a list of sublists of strings.  For each sublist, the first string is the
 703 # name of a %define variable, and all remaining strings in that sublist are the
 704 # valid values for that variable.  Complain if such a variable is undefined (a
 705 # Bison error since the default value should have been set already) or defined
 706 # to any other value (possibly a user error).  Don't record this as a Bison
 707 # usage of the variable as there's no reason to suspect that the value has yet
 708 # influenced the output.
 709 #
 710 # For example:
 711 #
 712 #   b4_percent_define_check_values([[[[foo]], [[foo-value1]], [[foo-value2]]]],
 713 #                                  [[[[bar]], [[bar-value1]]]])
 714 m4_define([b4_percent_define_check_values],
 715 [m4_foreach([b4_sublist], m4_quote($@),
 716             [_b4_percent_define_check_values(b4_sublist)])])
 717
 718 m4_define([_b4_percent_define_check_values],
 719 [m4_ifdef([b4_percent_define(]$1[)],
 720   [m4_pushdef([b4_good_value], [0])dnl
 721    m4_if($#, 1, [],
 722          [m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 723                      [m4_if(m4_indir([b4_percent_define(]$1[)]), b4_value,
 724                             [m4_define([b4_good_value], [1])])])])dnl
 725    m4_if(b4_good_value, [0],
 726          [b4_complain_at(b4_percent_define_get_loc([$1]),
 727                          [[invalid value for %%define variable `%s': `%s']],
 728                          [$1],
 729                          m4_dquote(m4_indir([b4_percent_define(]$1[)])))
 730           m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 731                      [b4_complain_at(b4_percent_define_get_loc([$1]),
 732                                      [[accepted value: `%s']],
 733                                      m4_dquote(b4_value))])])dnl
 734    m4_popdef([b4_good_value])],
 735   [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_check_values]], [$1])])])
 736
 737 # b4_percent_code_get([QUALIFIER])
 738 # --------------------------------
 739 # If any %code blocks for QUALIFIER are defined, emit them beginning with a
 740 # comment and ending with synclines and a newline.  If QUALIFIER is not
 741 # specified or empty, do this for the unqualified %code blocks.  Also, record
 742 # Bison's usage of QUALIFIER (if specified) by defining
 743 # b4_percent_code_bison_qualifiers(QUALIFIER).
 744 #
 745 # For example, to emit any unqualified %code blocks followed by any %code
 746 # blocks for the qualifier foo:
 747 #
 748 #   b4_percent_code_get
 749 #   b4_percent_code_get([[foo]])
 750 m4_define([b4_percent_code_get],
 751 [m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
 752 m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
 753 m4_ifdef(b4_macro_name,
 754 [b4_comment([m4_if([$#], [0], [[Unqualified %code]],
 755                    [["%code ]$1["]])[ blocks.]])
 756 b4_user_code([m4_indir(b4_macro_name)])
 757 ])dnl
 758 m4_popdef([b4_macro_name])])
 759
 760 # b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
 761 # -----------------------------------------------------
 762 # If any %code blocks for QUALIFIER (or unqualified %code blocks if
 763 # QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
 764 # Also, record Bison's usage of QUALIFIER (if specified) by defining
 765 # b4_percent_code_bison_qualifiers(QUALIFIER).
 766 m4_define([b4_percent_code_ifdef],
 767 [m4_ifdef([b4_percent_code(]$1[)],
 768           [m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
 769           [$3])])
 770
 771
 772 ## ------------------ ##
 773 ## Common variables.  ##
 774 ## ------------------ ##
 775
 776 # Default values for %define.
 777 # ---------------------------
 778 # If the api.tokens.prefix, it is empty.
 779 m4_percent_define_default([[api.tokens.prefix]], [[]])
 780
 781 # b4_parse_assert_if([IF-ASSERTIONS-ARE-USED], [IF-NOT])
 782 # b4_parse_trace_if([IF-DEBUG-TRACES-ARE-ENABLED], [IF-NOT])
 783 # b4_lex_symbol_if([IF-YYLEX-RETURNS-A-COMPLETE-SYMBOL], [IF-NOT])
 784 # b4_variant_if([IF-VARIANT-ARE-USED], [IF-NOT])
 785 # ----------------------------------------------
 786 b4_percent_define_if_define([lex_symbol])
 787 b4_percent_define_if_define([locations])     # Whether locations are tracked.
 788 b4_percent_define_if_define([parse.assert])
 789 b4_percent_define_if_define([parse.trace])
 790 b4_percent_define_if_define([variant])
 791
 792
 793 # b4_error_verbose_if([IF-ERRORS-ARE-VERBOSE], [IF-NOT])
 794 # ------------------------------------------------------
 795 # Map %define parse.error "(simple|verbose)" to b4_error_verbose_if and
 796 # b4_error_verbose_flag.
 797 b4_percent_define_default([[parse.error]], [[simple]])
 798 b4_percent_define_check_values([[[[parse.error]],
 799                                  [[simple]], [[verbose]]]])
 800 m4_define([b4_error_verbose_flag],
 801           [m4_case(b4_percent_define_get([[parse.error]]),
 802                    [simple],  [[0]],
 803                    [verbose], [[1]])])
 804 b4_define_flag_if([error_verbose])
 805
 806
 807 ## ----------------------------------------------------------- ##
 808 ## After processing the skeletons, check that all the user's   ##
 809 ## %define variables and %code qualifiers were used by Bison.  ##
 810 ## ----------------------------------------------------------- ##
 811
 812 m4_define([b4_check_user_names_wrap],
 813 [m4_ifdef([b4_percent_]$1[_user_]$2[s],
 814           [b4_check_user_names([[%]$1 $2],
 815                                [b4_percent_]$1[_user_]$2[s],
 816                                [[b4_percent_]$1[_bison_]$2[s]])])])
 817
 818 m4_wrap_lifo([
 819 b4_check_user_names_wrap([[define]], [[variable]])
 820 b4_check_user_names_wrap([[code]], [[qualifier]])
 821 ])