src/scan-gram.l

   1 /* Bison Grammar Scanner                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2009 Free Software
   4    Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 %option debug nodefault noinput nounput noyywrap never-interactive
  22 %option prefix="gram_" outfile="lex.yy.c"
  23
  24 %{
  25 /* Work around a bug in flex 2.5.31.  See Debian bug 333231
  26    <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
  27 #undef gram_wrap
  28 #define gram_wrap() 1
  29
  30 #define FLEX_PREFIX(Id) gram_ ## Id
  31 #include "flex-scanner.h"
  32
  33 #include "complain.h"
  34 #include "files.h"
  35 #include "gram.h"
  36 #include "quotearg.h"
  37 #include "reader.h"
  38 #include "uniqstr.h"
  39
  40 #include <ctype.h>
  41 #include <mbswidth.h>
  42 #include <quote.h>
  43
  44 #include "scan-gram.h"
  45
  46 #define YY_DECL GRAM_LEX_DECL
  47
  48 #define YY_USER_INIT                                    \
  49    code_start = scanner_cursor = loc->start;            \
  50
  51 /* Location of scanner cursor.  */
  52 static boundary scanner_cursor;
  53
  54 #define YY_USER_ACTION  location_compute (loc, &scanner_cursor, yytext, yyleng);
  55
  56 static size_t no_cr_read (FILE *, char *, size_t);
  57 #define YY_INPUT(buf, result, size) ((result) = no_cr_read (yyin, buf, size))
  58
  59 /* A string representing the most recently saved token.  */
  60 static char *last_string;
  61
  62 void
  63 gram_scanner_last_string_free (void)
  64 {
  65   STRING_FREE;
  66 }
  67
  68 static void handle_syncline (char *, location);
  69 static unsigned long int scan_integer (char const *p, int base, location loc);
  70 static int convert_ucn_to_byte (char const *hex_text);
  71 static void unexpected_eof (boundary, char const *);
  72 static void unexpected_newline (boundary, char const *);
  73
  74 %}
  75  /* A C-like comment in directives/rules. */
  76 %x SC_YACC_COMMENT
  77  /* Strings and characters in directives/rules. */
  78 %x SC_ESCAPED_STRING SC_ESCAPED_CHARACTER
  79  /* A identifier was just read in directives/rules.  Special state
  80     to capture the sequence `identifier :'. */
  81 %x SC_AFTER_IDENTIFIER
  82
  83  /* Three types of user code:
  84     - prologue (code between `%{' `%}' in the first section, before %%);
  85     - actions, printers, union, etc, (between braced in the middle section);
  86     - epilogue (everything after the second %%). */
  87 %x SC_PROLOGUE SC_BRACED_CODE SC_EPILOGUE
  88  /* C and C++ comments in code. */
  89 %x SC_COMMENT SC_LINE_COMMENT
  90  /* Strings and characters in code. */
  91 %x SC_STRING SC_CHARACTER
  92
  93 letter    [.abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ_]
  94 id        {letter}({letter}|[0-9])*
  95 directive %{letter}({letter}|[0-9]|-)*
  96 int       [0-9]+
  97
  98 /* POSIX says that a tag must be both an id and a C union member, but
  99    historically almost any character is allowed in a tag.  We disallow
 100    NUL and newline, as this simplifies our implementation.  */
 101 tag      [^\0\n>]+
 102
 103 /* Zero or more instances of backslash-newline.  Following GCC, allow
 104    white space between the backslash and the newline.  */
 105 splice   (\\[ \f\t\v]*\n)*
 106
 107 %%
 108 %{
 109   /* Nesting level of the current code in braces.  */
 110   int braces_level IF_LINT (= 0);
 111
 112   /* Parent context state, when applicable.  */
 113   int context_state IF_LINT (= 0);
 114
 115   /* Location of most recent identifier, when applicable.  */
 116   location id_loc IF_LINT (= empty_location);
 117
 118   /* Where containing code started, when applicable.  Its initial
 119      value is relevant only when yylex is invoked in the SC_EPILOGUE
 120      start condition.  */
 121   boundary code_start = scanner_cursor;
 122
 123   /* Where containing comment or string or character literal started,
 124      when applicable.  */
 125   boundary token_start IF_LINT (= scanner_cursor);
 126 %}
 127
 128
 129   /*-----------------------.
 130   | Scanning white space.  |
 131   `-----------------------*/
 132
 133 <INITIAL,SC_AFTER_IDENTIFIER>
 134 {
 135   /* Comments and white space.  */
 136   ","          warn_at (*loc, _("stray `,' treated as white space"));
 137   [ \f\n\t\v]  |
 138   "//".*       ;
 139   "/*" {
 140     token_start = loc->start;
 141     context_state = YY_START;
 142     BEGIN SC_YACC_COMMENT;
 143   }
 144
 145   /* #line directives are not documented, and may be withdrawn or
 146      modified in future versions of Bison.  */
 147   ^"#line "{int}" \"".*"\"\n" {
 148     handle_syncline (yytext + sizeof "#line " - 1, *loc);
 149   }
 150 }
 151
 152
 153   /*----------------------------.
 154   | Scanning Bison directives.  |
 155   `----------------------------*/
 156 <INITIAL>
 157 {
 158   "%binary"                         return PERCENT_NONASSOC;
 159   "%code"                           return PERCENT_CODE;
 160   "%debug"                          return PERCENT_DEBUG;
 161   "%default"[-_]"prec"              return PERCENT_DEFAULT_PREC;
 162   "%define"                         return PERCENT_DEFINE;
 163   "%defines"                        return PERCENT_DEFINES;
 164   "%destructor"                     return PERCENT_DESTRUCTOR;
 165   "%dprec"                          return PERCENT_DPREC;
 166   "%error"[-_]"verbose"             return PERCENT_ERROR_VERBOSE;
 167   "%expect"                         return PERCENT_EXPECT;
 168   "%expect"[-_]"rr"                 return PERCENT_EXPECT_RR;
 169   "%file-prefix"                    return PERCENT_FILE_PREFIX;
 170   "%fixed"[-_]"output"[-_]"files"   return PERCENT_YACC;
 171   "%initial-action"                 return PERCENT_INITIAL_ACTION;
 172   "%glr-parser"                     return PERCENT_GLR_PARSER;
 173   "%language"                       return PERCENT_LANGUAGE;
 174   "%left"                           return PERCENT_LEFT;
 175   "%lex-param"                      return PERCENT_LEX_PARAM;
 176   "%locations"                      return PERCENT_LOCATIONS;
 177   "%merge"                          return PERCENT_MERGE;
 178   "%name"[-_]"prefix"               return PERCENT_NAME_PREFIX;
 179   "%no"[-_]"default"[-_]"prec"      return PERCENT_NO_DEFAULT_PREC;
 180   "%no"[-_]"lines"                  return PERCENT_NO_LINES;
 181   "%nonassoc"                       return PERCENT_NONASSOC;
 182   "%nondeterministic-parser"        return PERCENT_NONDETERMINISTIC_PARSER;
 183   "%nterm"                          return PERCENT_NTERM;
 184   "%output"                         return PERCENT_OUTPUT;
 185   "%parse-param"                    return PERCENT_PARSE_PARAM;
 186   "%prec"                           return PERCENT_PREC;
 187   "%printer"                        return PERCENT_PRINTER;
 188   "%pure"[-_]"parser"               return PERCENT_PURE_PARSER;
 189   "%require"                        return PERCENT_REQUIRE;
 190   "%right"                          return PERCENT_RIGHT;
 191   "%skeleton"                       return PERCENT_SKELETON;
 192   "%start"                          return PERCENT_START;
 193   "%term"                           return PERCENT_TOKEN;
 194   "%token"                          return PERCENT_TOKEN;
 195   "%token"[-_]"table"               return PERCENT_TOKEN_TABLE;
 196   "%type"                           return PERCENT_TYPE;
 197   "%union"                          return PERCENT_UNION;
 198   "%verbose"                        return PERCENT_VERBOSE;
 199   "%yacc"                           return PERCENT_YACC;
 200
 201   {directive} {
 202     complain_at (*loc, _("invalid directive: %s"), quote (yytext));
 203   }
 204
 205   "="                     return EQUAL;
 206   "|"                     return PIPE;
 207   ";"                     return SEMICOLON;
 208   "<*>"                   return TYPE_TAG_ANY;
 209   "<>"                    return TYPE_TAG_NONE;
 210
 211   {id} {
 212     val->uniqstr = uniqstr_new (yytext);
 213     id_loc = *loc;
 214     BEGIN SC_AFTER_IDENTIFIER;
 215   }
 216
 217   {int} {
 218     val->integer = scan_integer (yytext, 10, *loc);
 219     return INT;
 220   }
 221   0[xX][0-9abcdefABCDEF]+ {
 222     val->integer = scan_integer (yytext, 16, *loc);
 223     return INT;
 224   }
 225
 226   /* Characters.  We don't check there is only one.  */
 227   "'"         STRING_GROW; token_start = loc->start; BEGIN SC_ESCAPED_CHARACTER;
 228
 229   /* Strings. */
 230   "\""        token_start = loc->start; BEGIN SC_ESCAPED_STRING;
 231
 232   /* Prologue. */
 233   "%{"        code_start = loc->start; BEGIN SC_PROLOGUE;
 234
 235   /* Code in between braces.  */
 236   "{" {
 237     STRING_GROW;
 238     braces_level = 0;
 239     code_start = loc->start;
 240     BEGIN SC_BRACED_CODE;
 241   }
 242
 243   /* A type. */
 244   "<"{tag}">" {
 245     obstack_grow (&obstack_for_string, yytext + 1, yyleng - 2);
 246     STRING_FINISH;
 247     val->uniqstr = uniqstr_new (last_string);
 248     STRING_FREE;
 249     return TYPE;
 250   }
 251
 252   "%%" {
 253     static int percent_percent_count;
 254     if (++percent_percent_count == 2)
 255       BEGIN SC_EPILOGUE;
 256     return PERCENT_PERCENT;
 257   }
 258
 259   . {
 260     complain_at (*loc, _("invalid character: %s"), quote (yytext));
 261   }
 262
 263   <<EOF>> {
 264     loc->start = loc->end = scanner_cursor;
 265     yyterminate ();
 266   }
 267 }
 268
 269
 270   /*-----------------------------------------------------------------.
 271   | Scanning after an identifier, checking whether a colon is next.  |
 272   `-----------------------------------------------------------------*/
 273
 274 <SC_AFTER_IDENTIFIER>
 275 {
 276   ":" {
 277     *loc = id_loc;
 278     BEGIN INITIAL;
 279     return ID_COLON;
 280   }
 281   . {
 282     scanner_cursor.column -= mbsnwidth (yytext, yyleng, 0);
 283     yyless (0);
 284     *loc = id_loc;
 285     BEGIN INITIAL;
 286     return ID;
 287   }
 288   <<EOF>> {
 289     *loc = id_loc;
 290     BEGIN INITIAL;
 291     return ID;
 292   }
 293 }
 294
 295
 296   /*---------------------------------------------------------------.
 297   | Scanning a Yacc comment.  The initial `/ *' is already eaten.  |
 298   `---------------------------------------------------------------*/
 299
 300 <SC_YACC_COMMENT>
 301 {
 302   "*/"     BEGIN context_state;
 303   .|\n     ;
 304   <<EOF>>  unexpected_eof (token_start, "*/"); BEGIN context_state;
 305 }
 306
 307
 308   /*------------------------------------------------------------.
 309   | Scanning a C comment.  The initial `/ *' is already eaten.  |
 310   `------------------------------------------------------------*/
 311
 312 <SC_COMMENT>
 313 {
 314   "*"{splice}"/"  STRING_GROW; BEGIN context_state;
 315   <<EOF>>         unexpected_eof (token_start, "*/"); BEGIN context_state;
 316 }
 317
 318
 319   /*--------------------------------------------------------------.
 320   | Scanning a line comment.  The initial `//' is already eaten.  |
 321   `--------------------------------------------------------------*/
 322
 323 <SC_LINE_COMMENT>
 324 {
 325   "\n"           STRING_GROW; BEGIN context_state;
 326   {splice}       STRING_GROW;
 327   <<EOF>>        BEGIN context_state;
 328 }
 329
 330
 331   /*------------------------------------------------.
 332   | Scanning a Bison string, including its escapes. |
 333   | The initial quote is already eaten.             |
 334   `------------------------------------------------*/
 335
 336 <SC_ESCAPED_STRING>
 337 {
 338   "\""|"\n" {
 339     if (yytext[0] == '\n')
 340       unexpected_newline (token_start, "\"");
 341     STRING_FINISH;
 342     loc->start = token_start;
 343     val->chars = last_string;
 344     BEGIN INITIAL;
 345     return STRING;
 346   }
 347   <<EOF>> {
 348     unexpected_eof (token_start, "\"");
 349     STRING_FINISH;
 350     loc->start = token_start;
 351     val->chars = last_string;
 352     BEGIN INITIAL;
 353     return STRING;
 354   }
 355 }
 356
 357   /*----------------------------------------------------------.
 358   | Scanning a Bison character literal, decoding its escapes. |
 359   | The initial quote is already eaten.                       |
 360   `----------------------------------------------------------*/
 361
 362 <SC_ESCAPED_CHARACTER>
 363 {
 364   "'"|"\n" {
 365     if (yytext[0] == '\n')
 366       unexpected_newline (token_start, "'");
 367     STRING_GROW;
 368     STRING_FINISH;
 369     loc->start = token_start;
 370     val->character = last_string[1];
 371     STRING_FREE;
 372     BEGIN INITIAL;
 373     return CHAR;
 374   }
 375   <<EOF>> {
 376     unexpected_eof (token_start, "'");
 377     STRING_FINISH;
 378     loc->start = token_start;
 379     if (strlen(last_string) > 1)
 380       val->character = last_string[1];
 381     else
 382       val->character = last_string[0];
 383     STRING_FREE;
 384     BEGIN INITIAL;
 385     return CHAR;
 386   }
 387 }
 388
 389 <SC_ESCAPED_CHARACTER,SC_ESCAPED_STRING>
 390 {
 391   \0        complain_at (*loc, _("invalid null character"));
 392 }
 393
 394
 395   /*----------------------------.
 396   | Decode escaped characters.  |
 397   `----------------------------*/
 398
 399 <SC_ESCAPED_STRING,SC_ESCAPED_CHARACTER>
 400 {
 401   \\[0-7]{1,3} {
 402     unsigned long int c = strtoul (yytext + 1, NULL, 8);
 403     if (!c || UCHAR_MAX < c)
 404       complain_at (*loc, _("invalid number after \\-escape: %s"),
 405                    yytext+1);
 406     else
 407       obstack_1grow (&obstack_for_string, c);
 408   }
 409
 410   \\x[0-9abcdefABCDEF]+ {
 411     verify (UCHAR_MAX < ULONG_MAX);
 412     unsigned long int c = strtoul (yytext + 2, NULL, 16);
 413     if (!c || UCHAR_MAX < c)
 414       complain_at (*loc, _("invalid number after \\-escape: %s"),
 415                    yytext+1);
 416     else
 417       obstack_1grow (&obstack_for_string, c);
 418   }
 419
 420   \\a   obstack_1grow (&obstack_for_string, '\a');
 421   \\b   obstack_1grow (&obstack_for_string, '\b');
 422   \\f   obstack_1grow (&obstack_for_string, '\f');
 423   \\n   obstack_1grow (&obstack_for_string, '\n');
 424   \\r   obstack_1grow (&obstack_for_string, '\r');
 425   \\t   obstack_1grow (&obstack_for_string, '\t');
 426   \\v   obstack_1grow (&obstack_for_string, '\v');
 427
 428   /* \\[\"\'?\\] would be shorter, but it confuses xgettext.  */
 429   \\("\""|"'"|"?"|"\\")  obstack_1grow (&obstack_for_string, yytext[1]);
 430
 431   \\(u|U[0-9abcdefABCDEF]{4})[0-9abcdefABCDEF]{4} {
 432     int c = convert_ucn_to_byte (yytext);
 433     if (c <= 0)
 434       complain_at (*loc, _("invalid number after \\-escape: %s"),
 435                    yytext+1);
 436     else
 437       obstack_1grow (&obstack_for_string, c);
 438   }
 439   \\(.|\n)      {
 440     char const *p = yytext + 1;
 441     /* Quote only if escaping won't make the character visible.  */
 442     if (isspace ((unsigned char) *p) && isprint ((unsigned char) *p))
 443       p = quote (p);
 444     else
 445       p = quotearg_style_mem (escape_quoting_style, p, 1);
 446     complain_at (*loc, _("invalid character after \\-escape: %s"), p);
 447   }
 448 }
 449
 450   /*--------------------------------------------.
 451   | Scanning user-code characters and strings.  |
 452   `--------------------------------------------*/
 453
 454 <SC_CHARACTER,SC_STRING>
 455 {
 456   {splice}|\\{splice}[^\n\[\]]  STRING_GROW;
 457 }
 458
 459 <SC_CHARACTER>
 460 {
 461   "'"           STRING_GROW; BEGIN context_state;
 462   \n            unexpected_newline (token_start, "'"); BEGIN context_state;
 463   <<EOF>>       unexpected_eof (token_start, "'"); BEGIN context_state;
 464 }
 465
 466 <SC_STRING>
 467 {
 468   "\""          STRING_GROW; BEGIN context_state;
 469   \n            unexpected_newline (token_start, "\""); BEGIN context_state;
 470   <<EOF>>       unexpected_eof (token_start, "\""); BEGIN context_state;
 471 }
 472
 473
 474   /*---------------------------------------------------.
 475   | Strings, comments etc. can be found in user code.  |
 476   `---------------------------------------------------*/
 477
 478 <SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE>
 479 {
 480   "'" {
 481     STRING_GROW;
 482     context_state = YY_START;
 483     token_start = loc->start;
 484     BEGIN SC_CHARACTER;
 485   }
 486   "\"" {
 487     STRING_GROW;
 488     context_state = YY_START;
 489     token_start = loc->start;
 490     BEGIN SC_STRING;
 491   }
 492   "/"{splice}"*" {
 493     STRING_GROW;
 494     context_state = YY_START;
 495     token_start = loc->start;
 496     BEGIN SC_COMMENT;
 497   }
 498   "/"{splice}"/" {
 499     STRING_GROW;
 500     context_state = YY_START;
 501     BEGIN SC_LINE_COMMENT;
 502   }
 503 }
 504
 505
 506
 507   /*-----------------------------------------------------------.
 508   | Scanning some code in braces (actions). The initial "{" is |
 509   | already eaten.                                             |
 510   `-----------------------------------------------------------*/
 511
 512 <SC_BRACED_CODE>
 513 {
 514   "{"|"<"{splice}"%"  STRING_GROW; braces_level++;
 515   "%"{splice}">"      STRING_GROW; braces_level--;
 516   "}" {
 517     obstack_1grow (&obstack_for_string, '}');
 518
 519     --braces_level;
 520     if (braces_level < 0)
 521       {
 522         STRING_FINISH;
 523         loc->start = code_start;
 524         val->code = last_string;
 525         BEGIN INITIAL;
 526         return BRACED_CODE;
 527       }
 528   }
 529
 530   /* Tokenize `<<%' correctly (as `<<' `%') rather than incorrrectly
 531      (as `<' `<%').  */
 532   "<"{splice}"<"  STRING_GROW;
 533
 534   <<EOF>> {
 535     unexpected_eof (code_start, "}");
 536     STRING_FINISH;
 537     loc->start = code_start;
 538     val->code = last_string;
 539     BEGIN INITIAL;
 540     return BRACED_CODE;
 541   }
 542 }
 543
 544
 545   /*--------------------------------------------------------------.
 546   | Scanning some prologue: from "%{" (already scanned) to "%}".  |
 547   `--------------------------------------------------------------*/
 548
 549 <SC_PROLOGUE>
 550 {
 551   "%}" {
 552     STRING_FINISH;
 553     loc->start = code_start;
 554     val->chars = last_string;
 555     BEGIN INITIAL;
 556     return PROLOGUE;
 557   }
 558
 559   <<EOF>> {
 560     unexpected_eof (code_start, "%}");
 561     STRING_FINISH;
 562     loc->start = code_start;
 563     val->chars = last_string;
 564     BEGIN INITIAL;
 565     return PROLOGUE;
 566   }
 567 }
 568
 569
 570   /*---------------------------------------------------------------.
 571   | Scanning the epilogue (everything after the second "%%", which |
 572   | has already been eaten).                                       |
 573   `---------------------------------------------------------------*/
 574
 575 <SC_EPILOGUE>
 576 {
 577   <<EOF>> {
 578     STRING_FINISH;
 579     loc->start = code_start;
 580     val->chars = last_string;
 581     BEGIN INITIAL;
 582     return EPILOGUE;
 583   }
 584 }
 585
 586
 587   /*-----------------------------------------------------.
 588   | By default, grow the string obstack with the input.  |
 589   `-----------------------------------------------------*/
 590
 591 <SC_COMMENT,SC_LINE_COMMENT,SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE,SC_STRING,SC_CHARACTER,SC_ESCAPED_STRING,SC_ESCAPED_CHARACTER>.      |
 592 <SC_COMMENT,SC_LINE_COMMENT,SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE>\n   STRING_GROW;
 593
 594 %%
 595
 596 /* Read bytes from FP into buffer BUF of size SIZE.  Return the
 597    number of bytes read.  Remove '\r' from input, treating \r\n
 598    and isolated \r as \n.  */
 599
 600 static size_t
 601 no_cr_read (FILE *fp, char *buf, size_t size)
 602 {
 603   size_t bytes_read = fread (buf, 1, size, fp);
 604   if (bytes_read)
 605     {
 606       char *w = memchr (buf, '\r', bytes_read);
 607       if (w)
 608         {
 609           char const *r = ++w;
 610           char const *lim = buf + bytes_read;
 611
 612           for (;;)
 613             {
 614               /* Found an '\r'.  Treat it like '\n', but ignore any
 615                  '\n' that immediately follows.  */
 616               w[-1] = '\n';
 617               if (r == lim)
 618                 {
 619                   int ch = getc (fp);
 620                   if (ch != '\n' && ungetc (ch, fp) != ch)
 621                     break;
 622                 }
 623               else if (*r == '\n')
 624                 r++;
 625
 626               /* Copy until the next '\r'.  */
 627               do
 628                 {
 629                   if (r == lim)
 630                     return w - buf;
 631                 }
 632               while ((*w++ = *r++) != '\r');
 633             }
 634
 635           return w - buf;
 636         }
 637     }
 638
 639   return bytes_read;
 640 }
 641
 642
 643
 644 /*------------------------------------------------------.
 645 | Scan NUMBER for a base-BASE integer at location LOC.  |
 646 `------------------------------------------------------*/
 647
 648 static unsigned long int
 649 scan_integer (char const *number, int base, location loc)
 650 {
 651   verify (INT_MAX < ULONG_MAX);
 652   unsigned long int num = strtoul (number, NULL, base);
 653
 654   if (INT_MAX < num)
 655     {
 656       complain_at (loc, _("integer out of range: %s"), quote (number));
 657       num = INT_MAX;
 658     }
 659
 660   return num;
 661 }
 662
 663
 664 /*------------------------------------------------------------------.
 665 | Convert universal character name UCN to a single-byte character,  |
 666 | and return that character.  Return -1 if UCN does not correspond  |
 667 | to a single-byte character.                                       |
 668 `------------------------------------------------------------------*/
 669
 670 static int
 671 convert_ucn_to_byte (char const *ucn)
 672 {
 673   verify (UCHAR_MAX <= INT_MAX);
 674   unsigned long int code = strtoul (ucn + 2, NULL, 16);
 675
 676   /* FIXME: Currently we assume Unicode-compatible unibyte characters
 677      on ASCII hosts (i.e., Latin-1 on hosts with 8-bit bytes).  On
 678      non-ASCII hosts we support only the portable C character set.
 679      These limitations should be removed once we add support for
 680      multibyte characters.  */
 681
 682   if (UCHAR_MAX < code)
 683     return -1;
 684
 685 #if ! ('$' == 0x24 && '@' == 0x40 && '`' == 0x60 && '~' == 0x7e)
 686   {
 687     /* A non-ASCII host.  Use CODE to index into a table of the C
 688        basic execution character set, which is guaranteed to exist on
 689        all Standard C platforms.  This table also includes '$', '@',
 690        and '`', which are not in the basic execution character set but
 691        which are unibyte characters on all the platforms that we know
 692        about.  */
 693     static signed char const table[] =
 694       {
 695         '\0',   -1,   -1,   -1,   -1,   -1,   -1, '\a',
 696         '\b', '\t', '\n', '\v', '\f', '\r',   -1,   -1,
 697           -1,   -1,   -1,   -1,   -1,   -1,   -1,   -1,
 698           -1,   -1,   -1,   -1,   -1,   -1,   -1,   -1,
 699          ' ',  '!',  '"',  '#',  '$',  '%',  '&', '\'',
 700          '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
 701          '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
 702          '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
 703          '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
 704          'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
 705          'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
 706          'X',  'Y',  'Z',  '[', '\\',  ']',  '^',  '_',
 707          '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
 708          'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
 709          'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
 710          'x',  'y',  'z',  '{',  '|',  '}',  '~'
 711       };
 712
 713     code = code < sizeof table ? table[code] : -1;
 714   }
 715 #endif
 716
 717   return code;
 718 }
 719
 720
 721 /*----------------------------------------------------------------.
 722 | Handle `#line INT "FILE"'.  ARGS has already skipped `#line '.  |
 723 `----------------------------------------------------------------*/
 724
 725 static void
 726 handle_syncline (char *args, location loc)
 727 {
 728   char *after_num;
 729   unsigned long int lineno = strtoul (args, &after_num, 10);
 730   char *file = strchr (after_num, '"') + 1;
 731   *strchr (file, '"') = '\0';
 732   if (INT_MAX <= lineno)
 733     {
 734       warn_at (loc, _("line number overflow"));
 735       lineno = INT_MAX;
 736     }
 737   current_file = uniqstr_new (file);
 738   boundary_set (&scanner_cursor, current_file, lineno, 1);
 739 }
 740
 741
 742 /*----------------------------------------------------------------.
 743 | For a token or comment starting at START, report message MSGID, |
 744 | which should say that an end marker was found before            |
 745 | the expected TOKEN_END.                                         |
 746 `----------------------------------------------------------------*/
 747
 748 static void
 749 unexpected_end (boundary start, char const *msgid, char const *token_end)
 750 {
 751   location loc;
 752   loc.start = start;
 753   loc.end = scanner_cursor;
 754   complain_at (loc, _(msgid), token_end);
 755 }
 756
 757
 758 /*------------------------------------------------------------------------.
 759 | Report an unexpected EOF in a token or comment starting at START.       |
 760 | An end of file was encountered and the expected TOKEN_END was missing.  |
 761 `------------------------------------------------------------------------*/
 762
 763 static void
 764 unexpected_eof (boundary start, char const *token_end)
 765 {
 766   unexpected_end (start, N_("missing `%s' at end of file"), token_end);
 767 }
 768
 769
 770 /*----------------------------------------.
 771 | Likewise, but for unexpected newlines.  |
 772 `----------------------------------------*/
 773
 774 static void
 775 unexpected_newline (boundary start, char const *token_end)
 776 {
 777   unexpected_end (start, N_("missing `%s' at end of line"), token_end);
 778 }
 779
 780
 781 /*-------------------------.
 782 | Initialize the scanner.  |
 783 `-------------------------*/
 784
 785 void
 786 gram_scanner_initialize (void)
 787 {
 788   obstack_init (&obstack_for_string);
 789 }
 790
 791
 792 /*-----------------------------------------------.
 793 | Free all the memory allocated to the scanner.  |
 794 `-----------------------------------------------*/
 795
 796 void
 797 gram_scanner_free (void)
 798 {
 799   obstack_free (&obstack_for_string, 0);
 800   /* Reclaim Flex's buffers.  */
 801   yylex_destroy ();
 802 }