tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4 # Copyright (C) 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 # We want a recent Autotest.
  20 m4_version_prereq([2.58])
  21
  22
  23 ## ------------------------------- ##
  24 ## Macros decoding Bison options.  ##
  25 ## ------------------------------- ##
  26
  27
  28 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  29 # -----------------------------------------
  30 m4_define([AT_BISON_OPTION_PUSHDEFS],
  31 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  32
  33
  34 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  35 # --------------------------------------------------
  36 # This macro works around the impossibility to define macros
  37 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  38 # This sucks hard, GNU M4 should really provide M5 like $$1.
  39 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  40 [m4_if([$1$2], $[1]$[2], [],
  41        [m4_fatal([$0: Invalid arguments: $@])])dnl
  42 m4_pushdef([AT_DEFINES_IF],
  43 [m4_bmatch([$3], [%defines], [$1], [$2])])
  44 m4_pushdef([AT_SKEL_CC_IF],
  45 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  46 m4_pushdef([AT_GLR_IF],
  47 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  48 m4_pushdef([AT_LALR1_CC_IF],
  49 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  50 m4_pushdef([AT_GLR_CC_IF],
  51 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  52 # Using yacc.c?
  53 m4_pushdef([AT_YACC_IF],
  54 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  55 m4_pushdef([AT_LEXPARAM_IF],
  56 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  57 m4_pushdef([AT_PARAM_IF],
  58 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  59 m4_pushdef([AT_LOCATION_IF],
  60 [m4_bmatch([$3], [%locations], [$1], [$2])])
  61 m4_pushdef([AT_PURE_IF],
  62 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
  63            [m4_bmatch([$3], [%define  *api\.pure *"false"], [$2], [$1])],
  64            [$2])])
  65 m4_pushdef([AT_PURE_AND_LOC_IF],
  66 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
  67 m4_pushdef([AT_GLR_OR_PARAM_IF],
  68 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
  69 m4_pushdef([AT_NAME_PREFIX],
  70 [m4_bmatch([$3], [%name-prefix ".*"],
  71            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
  72            [yy])])
  73 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
  74 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
  75 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
  76                     [$2])])
  77 # yyerror always sees the locations (when activated), except if
  78 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
  79 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
  80 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
  81                                         [$1])],
  82                             [$1])],
  83                 [$2])])
  84
  85 # The interface is pure: either because %define api.pure, or because we
  86 # are using the C++ parsers.
  87 m4_pushdef([AT_PURE_LEX_IF],
  88 [AT_PURE_IF([$1],
  89             [AT_SKEL_CC_IF([$1], [$2])])])
  90
  91 AT_PURE_LEX_IF(
  92 [m4_pushdef([AT_LOC], [(*llocp)])
  93  m4_pushdef([AT_VAL], [(*lvalp)])
  94  m4_pushdef([AT_LEX_FORMALS],
  95             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
  96  m4_pushdef([AT_LEX_ARGS],
  97             [lvalp[]AT_LOCATION_IF([, llocp])])
  98  m4_pushdef([AT_USE_LEX_ARGS],
  99             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 100  m4_pushdef([AT_LEX_PRE_FORMALS],
 101             [AT_LEX_FORMALS, ])
 102  m4_pushdef([AT_LEX_PRE_ARGS],
 103             [AT_LEX_ARGS, ])
 104 ],
 105 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 106  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 107  m4_pushdef([AT_LEX_FORMALS],     [void])
 108  m4_pushdef([AT_LEX_ARGS],        [])
 109  m4_pushdef([AT_USE_LEX_ARGS],    [])
 110  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 111  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 112 ])
 113 AT_GLR_IF([AT_KEYWORDS([glr])])
 114 ])# _AT_BISON_OPTION_PUSHDEFS
 115
 116
 117 # AT_BISON_OPTION_POPDEFS
 118 # -----------------------
 119 m4_define([AT_BISON_OPTION_POPDEFS],
 120 [m4_popdef([AT_LEX_PRE_ARGS])
 121 m4_popdef([AT_LEX_PRE_FORMALS])
 122 m4_popdef([AT_USE_LEX_ARGS])
 123 m4_popdef([AT_LEX_ARGS])
 124 m4_popdef([AT_LEX_FORMALS])
 125 m4_popdef([AT_VAL])
 126 m4_popdef([AT_LOC])
 127 m4_popdef([AT_PURE_LEX_IF])
 128 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 129 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 130 m4_popdef([AT_NAME_PREFIX])
 131 m4_popdef([AT_GLR_OR_PARAM_IF])
 132 m4_popdef([AT_PURE_AND_LOC_IF])
 133 m4_popdef([AT_LOCATION_IF])
 134 m4_popdef([AT_PARAM_IF])
 135 m4_popdef([AT_LEXPARAM_IF])
 136 m4_popdef([AT_YACC_IF])
 137 m4_popdef([AT_GLR_IF])
 138 m4_popdef([AT_SKEL_CC_IF])
 139 m4_popdef([AT_GLR_CC_IF])
 140 m4_popdef([AT_LALR1_CC_IF])
 141 m4_popdef([AT_DEFINES_IF])
 142 ])# AT_BISON_OPTION_POPDEFS
 143
 144
 145
 146 ## -------------------------- ##
 147 ## Generating Grammar Files.  ##
 148 ## -------------------------- ##
 149
 150 # AT_DATA_SOURCE_PROLOGUE
 151 # ------------------------
 152 # The prologue that should be included in any source code that is
 153 # meant to be compiled.
 154 m4_define([AT_DATA_SOURCE_PROLOGUE],
 155 [[#include <config.h>
 156 /* We don't need perfect functions for these tests. */
 157 #undef malloc
 158 #undef memcmp
 159 #undef realloc
 160 ]])
 161
 162 # AT_DATA_GRAMMAR_PROLOGUE
 163 # ------------------------
 164 # The prologue that should be included in any grammar which parser is
 165 # meant to be compiled.
 166 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 167 [[%code top {
 168 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 169 [}
 170 ]])
 171
 172 # AT_DATA_SOURCE(NAME, CONTENT)
 173 # -----------------------------
 174 # Generate the file NAME, which CONTENT is preceded by
 175 # AT_DATA_SOURCE_PROLOGUE.
 176 m4_define([AT_DATA_SOURCE],
 177 [AT_DATA([$1],
 178 [AT_DATA_SOURCE_PROLOGUE
 179 $2])
 180 ])
 181
 182 # AT_DATA_GRAMMAR(NAME, CONTENT)
 183 # ------------------------------
 184 # Generate the file NAME, which CONTENT is preceded by
 185 # AT_DATA_GRAMMAR_PROLOGUE.
 186 m4_define([AT_DATA_GRAMMAR],
 187 [AT_DATA([$1],
 188 [AT_DATA_GRAMMAR_PROLOGUE
 189 $2])
 190 ])
 191
 192 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 193 # -------------------------------------------------
 194 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 195 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 196 #
 197 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 198 # Bison in the test suite.  For now it ensures that:
 199 #
 200 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 201 #      a non-zero exit status since Bison doesn't always try to free all memory
 202 #      in that case.
 203 #
 204 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 205 #      --graph and --report=all output for every working grammar.
 206 m4_define([AT_BISON_CHECK],
 207 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 208        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 209 AT_BISON_CHECK_NO_XML($@)])
 210
 211 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 212 # --------------------------------------------------------
 213 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 214 # when a tortured grammar's XML is known to be too large for xsltproc to
 215 # handle.
 216 m4_define([AT_BISON_CHECK_NO_XML],
 217 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 218                 [AT_QUELL_VALGRIND ])[[bison ]]$@)])
 219
 220 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 221 # -----------------------------------------------------
 222 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 223 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 224 # have a non-zero exit status.
 225 m4_define([AT_BISON_CHECK_XML],
 226 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 227   mkdir xml-tests]
 228   m4_pushdef([AT_BISON_ARGS],
 229              [m4_bpatsubsts([[$1]],
 230                             [--report(-file)?=[^][ ]*], [],
 231                             [--graph=[^][ ]*], [],
 232                             [--xml=[^][ ]*], [])])dnl
 233   # Don't combine these Bison invocations since we want to be sure that
 234   # --report=all isn't required to get the full XML file.
 235   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 236              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 237            [[0]], [ignore], [ignore])
 238   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 239            [[0]], [ignore], [ignore])
 240   m4_popdef([AT_BISON_ARGS])dnl
 241   [cp xml-tests/test.output expout]
 242   AT_CHECK([[$XSLTPROC \
 243              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 244              xml-tests/test.xml]], [[0]], [expout])
 245   [cp xml-tests/test.dot expout]
 246   AT_CHECK([[$XSLTPROC \
 247              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 248              xml-tests/test.xml]], [[0]], [expout])
 249   [rm -rf xml-tests expout
 250 fi]])
 251
 252 # AT_QUELL_VALGRIND
 253 # -----------------
 254 # Put this before a Bison invocation to keep Valgrind from complaining about
 255 # reachable memory.
 256 #
 257 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 258 # The triple quoting below will cause test cases to fail if you do.  If you do
 259 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 260 # will then fail to shell-escape its contents when attempting to print them.
 261 # The testsuite verbose output, at least, will be incorrect, but nothing may
 262 # fail to make sure you notice.
 263 m4_define([AT_QUELL_VALGRIND],
 264 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 265
 266 ## ------------------------ ##
 267 ## Compiling C, C++ Files.  ##
 268 ## ------------------------ ##
 269
 270
 271 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 272 # ----------------------------------------
 273 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 274 # assume that we are linking too; this is a hack.
 275 m4_define([AT_COMPILE],
 276 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 277            0, [ignore], [ignore])])
 278
 279 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 280 # --------------------------------------------
 281 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 282 # assume that we are linking too; this is a hack.
 283 # If the C++ compiler does not work, ignore the test.
 284 m4_define([AT_COMPILE_CXX],
 285 [AT_KEYWORDS(c++)
 286 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 287 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 288          0, [ignore], [ignore])])
 289
 290
 291 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 292 # --------------------------------
 293 # Compile OUTPUT.y to OUTPUT.c or OUTPUT.cc, and compile it to OUTPUT.
 294 # If OTHER is specified, compile OUTPUT-OTHER.c or OUTPUT-OTHER.cc to OUTPUT
 295 # along with it.
 296 # Relies on AT_SKEL_CC_IF.
 297 m4_define([AT_FULL_COMPILE],
 298 [AT_SKEL_CC_IF(
 299   [AT_BISON_CHECK([-o $1.cc $1.y])
 300    AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1.cc $1-$2.cc]]))],
 301   [AT_BISON_CHECK([-o $1.c $1.y])
 302    AT_COMPILE([$1]m4_ifval($2, [, [$1.c $1-$2.c]]))])
 303 ])
 304
 305
 306 ## ---------------------------- ##
 307 ## Running a generated parser.  ##
 308 ## ---------------------------- ##
 309
 310 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 311 # ------------------------------------------------------------
 312 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 313 m4_define([AT_PARSER_CHECK],
 314 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 315
 316
 317
 318
 319 ## ----------------------- ##
 320 ## Launch the test suite.  ##
 321 ## ----------------------- ##
 322
 323 AT_INIT
 324
 325 AT_TESTED([bison])