data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4
   5 # Copyright (C) 2002, 2004-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 ## ---------------- ##
  22 ## Identification.  ##
  23 ## ---------------- ##
  24
  25 # b4_copyright(TITLE, YEARS)
  26 # --------------------------
  27 m4_define([b4_copyright],
  28 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  29
  30 b4_comment([$1
  31
  32 m4_text_wrap([Copyright (C) $2 Free Software Foundation, Inc.], [   ])
  33
  34 This program is free software: you can redistribute it and/or modify
  35 it under the terms of the GNU General Public License as published by
  36 the Free Software Foundation, either version 3 of the License, or
  37 (at your option) any later version.
  38
  39 This program is distributed in the hope that it will be useful,
  40 but WITHOUT ANY WARRANTY; without even the implied warranty of
  41 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  42 GNU General Public License for more details.
  43
  44 You should have received a copy of the GNU General Public License
  45 along with this program.  If not, see <http://www.gnu.org/licenses/>.])
  46
  47 b4_comment([As a special exception, you may create a larger work that contains
  48 part or all of the Bison parser skeleton and distribute that work
  49 under terms of your choice, so long as that work isn't itself a
  50 parser generator using the skeleton or a modified version thereof
  51 as a parser skeleton.  Alternatively, if you modify or redistribute
  52 the parser skeleton itself, you may (at your option) remove this
  53 special exception, which will cause the skeleton and the resulting
  54 Bison output files to be licensed under the GNU General Public
  55 License without this special exception.
  56
  57 This special exception was added by the Free Software Foundation in
  58 version 2.2 of Bison.])])
  59
  60
  61 ## ---------------- ##
  62 ## Error handling.  ##
  63 ## ---------------- ##
  64
  65 # The following error handling macros print error directives that should not
  66 # become arguments of other macro invocations since they would likely then be
  67 # mangled.  Thus, they print to stdout directly.
  68
  69 # b4_cat(TEXT)
  70 # ------------
  71 # Write TEXT to stdout.  Precede the final newline with an @ so that it's
  72 # escaped.  For example:
  73 #
  74 #   b4_cat([[@complain(invalid input@)]])
  75 m4_define([b4_cat],
  76 [m4_syscmd([cat <<'_m4eof'
  77 ]m4_bpatsubst(m4_dquote($1), [_m4eof], [_m4@`eof])[@
  78 _m4eof
  79 ])dnl
  80 m4_if(m4_sysval, [0], [], [m4_fatal([$0: cannot write to stdout])])])
  81
  82 # b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
  83 # -------------------------------------------
  84 # Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to stdout.
  85 #
  86 # For example:
  87 #
  88 #   b4_error([[warn]], [[invalid value for '%s': %s]], [[foo]], [[3]])
  89 m4_define([b4_error],
  90 [b4_cat([[@]$1[(]$2[]]dnl
  91 [m4_if([$#], [2], [],
  92        [m4_foreach([b4_arg],
  93                    m4_dquote(m4_shift(m4_shift($@))),
  94                    [[@,]b4_arg])])[@)]])])
  95
  96 # b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
  97 # ----------------------------------------------------------
  98 # Write @KIND_at(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
  99 #
 100 # For example:
 101 #
 102 #   b4_error_at([[complain]], [[input.y:2.3]], [[input.y:5.4]],
 103 #               [[invalid %s]], [[foo]])
 104 m4_define([b4_error_at],
 105 [b4_cat([[@]$1[_at(]$2[@,]$3[@,]$4[]]dnl
 106 [m4_if([$#], [4], [],
 107        [m4_foreach([b4_arg],
 108                    m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
 109                    [[@,]b4_arg])])[@)]])])
 110
 111 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
 112 # ------------------------------------
 113 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 114 #
 115 # For example:
 116 #
 117 #   b4_warn([[invalid value for '%s': %s]], [[foo]], [[3]])
 118 #
 119 # As a simple test suite, this:
 120 #
 121 #   m4_divert(-1)
 122 #   m4_define([asdf], [ASDF])
 123 #   m4_define([fsa], [FSA])
 124 #   m4_define([fdsa], [FDSA])
 125 #   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
 126 #   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
 127 #   b4_warn()
 128 #   b4_warn(1)
 129 #   b4_warn(1, 2)
 130 #
 131 # Should produce this without newlines:
 132 #
 133 #   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
 134 #   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
 135 #   @warn(@)
 136 #   @warn(1@)
 137 #   @warn(1@,2@)
 138 m4_define([b4_warn],
 139 [b4_error([[warn]], $@)])
 140
 141 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 142 # ---------------------------------------------------
 143 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 144 #
 145 # For example:
 146 #
 147 #   b4_warn_at([[input.y:2.3]], [[input.y:5.4]], [[invalid %s]], [[foo]])
 148 m4_define([b4_warn_at],
 149 [b4_error_at([[warn]], $@)])
 150
 151 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 152 # ----------------------------------------
 153 # Write @complain(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 154 #
 155 # See b4_warn example.
 156 m4_define([b4_complain],
 157 [b4_error([[complain]], $@)])
 158
 159 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 160 # -------------------------------------------------------
 161 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 162 #
 163 # See b4_warn_at example.
 164 m4_define([b4_complain_at],
 165 [b4_error_at([[complain]], $@)])
 166
 167 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 168 # -------------------------------------
 169 # Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 170 #
 171 # See b4_warn example.
 172 m4_define([b4_fatal],
 173 [b4_error([[fatal]], $@)dnl
 174 m4_exit(1)])
 175
 176 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 177 # ----------------------------------------------------
 178 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 179 #
 180 # See b4_warn_at example.
 181 m4_define([b4_fatal_at],
 182 [b4_error_at([[fatal]], $@)dnl
 183 m4_exit(1)])
 184
 185
 186 ## ------------ ##
 187 ## Data Types.  ##
 188 ## ------------ ##
 189
 190 # b4_ints_in(INT1, INT2, LOW, HIGH)
 191 # ---------------------------------
 192 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 193 m4_define([b4_ints_in],
 194 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 195
 196
 197
 198 ## ------------------ ##
 199 ## Decoding options.  ##
 200 ## ------------------ ##
 201
 202 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 203 # -----------------------------------
 204 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 205 m4_define([b4_flag_if],
 206 [m4_case(b4_$1_flag,
 207          [0], [$3],
 208          [1], [$2],
 209          [m4_fatal([invalid $1 value: ]$1)])])
 210
 211
 212 # b4_define_flag_if(FLAG)
 213 # -----------------------
 214 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 215 # value of the Boolean FLAG.
 216 m4_define([b4_define_flag_if],
 217 [_b4_define_flag_if($[1], $[2], [$1])])
 218
 219 # _b4_define_flag_if($1, $2, FLAG)
 220 # --------------------------------
 221 # Work around the impossibility to define macros inside macros,
 222 # because issuing `[$1]' is not possible in M4.  GNU M4 should provide
 223 # $$1 a la M5/TeX.
 224 m4_define([_b4_define_flag_if],
 225 [m4_if([$1$2], $[1]$[2], [],
 226        [m4_fatal([$0: Invalid arguments: $@])])dnl
 227 m4_define([b4_$3_if],
 228           [b4_flag_if([$3], [$1], [$2])])])
 229
 230
 231 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 232 # -----------------------------
 233 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 234 b4_define_flag_if([defines])            # Whether headers are requested.
 235 b4_define_flag_if([error_verbose])      # Whether error are verbose.
 236 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 237 b4_define_flag_if([locations])          # Whether locations are tracked.
 238 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 239 b4_define_flag_if([token_table])        # Whether yytoken_table is demanded.
 240 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 241
 242 # yytoken_table is needed to support verbose errors.
 243 b4_error_verbose_if([m4_define([b4_token_table_flag], [1])])
 244
 245
 246
 247 ## ----------- ##
 248 ## Synclines.  ##
 249 ## ----------- ##
 250
 251 # b4_basename(NAME)
 252 # -----------------
 253 # Similar to POSIX basename; the differences don't matter here.
 254 # Beware that NAME is not evaluated.
 255 m4_define([b4_basename],
 256 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 257
 258
 259 # b4_syncline(LINE, FILE)
 260 # -----------------------
 261 m4_define([b4_syncline],
 262 [b4_flag_if([synclines], [
 263 b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 264 b4_sync_start([$1], [$2])])])
 265
 266 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 267 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 268
 269 # b4_user_code(USER-CODE)
 270 # -----------------------
 271 # Emit code from the user, ending it with synclines.
 272 m4_define([b4_user_code],
 273 [$1
 274 b4_syncline([@oline@], [@ofile@])])
 275
 276
 277 # b4_define_user_code(MACRO)
 278 # --------------------------
 279 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 280 m4_define([b4_define_user_code],
 281 [m4_define([b4_user_$1],
 282 [b4_user_code([b4_$1])])])
 283
 284
 285 # b4_user_actions
 286 # b4_user_initial_action
 287 # b4_user_post_prologue
 288 # b4_user_pre_prologue
 289 # b4_user_stype
 290 # ----------------------
 291 # Macros that issue user code, ending with synclines.
 292 b4_define_user_code([actions])
 293 b4_define_user_code([initial_action])
 294 b4_define_user_code([post_prologue])
 295 b4_define_user_code([pre_prologue])
 296 b4_define_user_code([stype])
 297
 298
 299 # b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
 300 # -----------------------------------------------------
 301 # Complain if any name of type WHAT is used by the user (as recorded in
 302 # USER-LIST) but is not used by Bison (as recorded by macros in the
 303 # namespace BISON-NAMESPACE).
 304 #
 305 # USER-LIST must expand to a list specifying all user occurrences of all names
 306 # of type WHAT.   Each item in the list must be a triplet specifying one
 307 # occurrence: name, start boundary, and end boundary.  Empty string names are
 308 # fine.  An empty list is fine.
 309 #
 310 # For example, to define b4_foo_user_names to be used for USER-LIST with three
 311 # name occurrences and with correct quoting:
 312 #
 313 #   m4_define([b4_foo_user_names],
 314 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 315 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 316 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 317 #
 318 # The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
 319 # is used by Bison (in the front-end or in the skeleton).  Empty string names
 320 # are fine, but it would be ugly for Bison to actually use one.
 321 #
 322 # For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
 323 # the names bar and baz are used by Bison:
 324 #
 325 #   m4_define([b4_foo_bison_names(bar)])
 326 #   m4_define([b4_foo_bison_names(baz)])
 327 #
 328 # To invoke b4_check_user_names with TYPE foo, with USER-LIST
 329 # b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
 330 # quoting:
 331 #
 332 #   b4_check_user_names([[foo]], [b4_foo_user_names],
 333 #                       [[b4_foo_bison_names]])
 334 m4_define([b4_check_user_names],
 335 [m4_foreach([b4_occurrence], $2,
 336 [m4_pushdef([b4_occurrence], b4_occurrence)dnl
 337 m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
 338 m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
 339 m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
 340 m4_ifndef($3[(]m4_quote(b4_user_name)[)],
 341           [b4_complain_at([b4_start], [b4_end],
 342                           [[%s '%s' is not used]],
 343                           [$1], [b4_user_name])])[]dnl
 344 m4_popdef([b4_occurrence])dnl
 345 m4_popdef([b4_user_name])dnl
 346 m4_popdef([b4_start])dnl
 347 m4_popdef([b4_end])dnl
 348 ])])
 349
 350
 351
 352
 353 ## --------------------- ##
 354 ## b4_percent_define_*.  ##
 355 ## --------------------- ##
 356
 357
 358 # b4_percent_define_use(VARIABLE)
 359 # -------------------------------
 360 # Declare that VARIABLE was used.
 361 m4_define([b4_percent_define_use],
 362 [m4_define([b4_percent_define_bison_variables(]$1[)])dnl
 363 ])
 364
 365 # b4_percent_define_get(VARIABLE, [DEFAULT])
 366 # ------------------------------------------
 367 # Mimic muscle_percent_define_get in ../src/muscle-tab.h.  That is, if
 368 # the %define variable VARIABLE is defined, emit its value.  Contrary
 369 # to its C counterpart, return DEFAULT otherwise.  Also, record
 370 # Bison's usage of VARIABLE by defining
 371 # b4_percent_define_bison_variables(VARIABLE).
 372 #
 373 # For example:
 374 #
 375 #   b4_percent_define_get([[foo]])
 376 m4_define([b4_percent_define_get],
 377 [b4_percent_define_use([$1])dnl
 378 m4_ifdef([b4_percent_define(]$1[)],
 379          [m4_indir([b4_percent_define(]$1[)])],
 380          [$2])])
 381
 382
 383 # b4_percent_define_get_loc(VARIABLE)
 384 # -----------------------------------
 385 # Mimic muscle_percent_define_get_loc in ../src/muscle-tab.h exactly.  That is,
 386 # if the %define variable VARIABLE is undefined, complain fatally since that's
 387 # a Bison or skeleton error.  Otherwise, return its definition location in a
 388 # form approriate for the first two arguments of b4_warn_at, b4_complain_at, or
 389 # b4_fatal_at.  Don't record this as a Bison usage of VARIABLE as there's no
 390 # reason to suspect that the user-supplied value has yet influenced the output.
 391 #
 392 # For example:
 393 #
 394 #   b4_complain_at(b4_percent_define_get_loc([[foo]]), [[invalid foo]])
 395 m4_define([b4_percent_define_get_loc],
 396 [m4_ifdef([b4_percent_define_loc(]$1[)],
 397           [m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
 398 b4_loc[]dnl
 399 m4_popdef([b4_loc])],
 400           [b4_fatal([[b4_percent_define_get_loc: undefined %%define variable '%s']], [$1])])])
 401
 402 # b4_percent_define_get_syncline(VARIABLE)
 403 # ----------------------------------------
 404 # Mimic muscle_percent_define_get_syncline in ../src/muscle-tab.h exactly.
 405 # That is, if the %define variable VARIABLE is undefined, complain fatally
 406 # since that's a Bison or skeleton error.  Otherwise, return its definition
 407 # location as a b4_syncline invocation.  Don't record this as a Bison usage of
 408 # VARIABLE as there's no reason to suspect that the user-supplied value has yet
 409 # influenced the output.
 410 #
 411 # For example:
 412 #
 413 #   b4_percent_define_get_syncline([[foo]])
 414 m4_define([b4_percent_define_get_syncline],
 415 [m4_ifdef([b4_percent_define_syncline(]$1[)],
 416           [m4_indir([b4_percent_define_syncline(]$1[)])],
 417           [b4_fatal([[b4_percent_define_get_syncline: undefined %%define variable '%s']], [$1])])])
 418
 419 # b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
 420 # ------------------------------------------------------
 421 # Mimic muscle_percent_define_ifdef in ../src/muscle-tab.h exactly.  That is,
 422 # if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
 423 # IF-FALSE.  Also, record Bison's usage of VARIABLE by defining
 424 # b4_percent_define_bison_variables(VARIABLE).
 425 #
 426 # For example:
 427 #
 428 #   b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
 429 m4_define([b4_percent_define_ifdef],
 430 [m4_ifdef([b4_percent_define(]$1[)],
 431           [m4_define([b4_percent_define_bison_variables(]$1[)])$2],
 432           [$3])])
 433
 434 # b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
 435 # --------------------------------------------------------
 436 # Mimic muscle_percent_define_flag_if in ../src/muscle-tab.h exactly.  That is,
 437 # if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
 438 # If it is defined to "false", expand IF-FALSE.  Complain if it is undefined
 439 # (a Bison or skeleton error since the default value should have been set
 440 # already) or defined to any other value (possibly a user error).  Also, record
 441 # Bison's usage of VARIABLE by defining
 442 # b4_percent_define_bison_variables(VARIABLE).
 443 #
 444 # For example:
 445 #
 446 #   b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
 447 m4_define([b4_percent_define_flag_if],
 448 [b4_percent_define_ifdef([$1],
 449   [m4_case(b4_percent_define_get([$1]),
 450            [], [$2], [true], [$2], [false], [$3],
 451            [m4_expand_once([b4_complain_at(b4_percent_define_get_loc([$1]),
 452                                            [[invalid value for %%define Boolean variable '%s']],
 453                                            [$1])],
 454                            [[b4_percent_define_flag_if($1)]])])],
 455   [b4_fatal([[b4_percent_define_flag_if: undefined %%define variable '%s']], [$1])])])
 456
 457 # b4_percent_define_default(VARIABLE, DEFAULT)
 458 # --------------------------------------------
 459 # Mimic muscle_percent_define_default in ../src/muscle-tab.h exactly.  That is,
 460 # if the %define variable VARIABLE is undefined, set its value to DEFAULT.
 461 # Don't record this as a Bison usage of VARIABLE as there's no reason to
 462 # suspect that the value has yet influenced the output.
 463 #
 464 # For example:
 465 #
 466 #   b4_percent_define_default([[foo]], [[default value]])
 467 m4_define([b4_percent_define_default],
 468 [m4_ifndef([b4_percent_define(]$1[)],
 469            [m4_define([b4_percent_define(]$1[)], [$2])dnl
 470             m4_define([b4_percent_define_loc(]$1[)],
 471                       [[[[<skeleton default value>:-1.-1]],
 472                         [[<skeleton default value>:-1.-1]]]])dnl
 473             m4_define([b4_percent_define_syncline(]$1[)], [[]])])])
 474
 475 # b4_percent_define_check_values(VALUES)
 476 # --------------------------------------
 477 # Mimic muscle_percent_define_check_values in ../src/muscle-tab.h exactly
 478 # except that the VALUES structure is more appropriate for M4.  That is, VALUES
 479 # is a list of sublists of strings.  For each sublist, the first string is the
 480 # name of a %define variable, and all remaining strings in that sublist are the
 481 # valid values for that variable.  Complain if such a variable is undefined (a
 482 # Bison error since the default value should have been set already) or defined
 483 # to any other value (possibly a user error).  Don't record this as a Bison
 484 # usage of the variable as there's no reason to suspect that the value has yet
 485 # influenced the output.
 486 #
 487 # For example:
 488 #
 489 #   b4_percent_define_check_values([[[[foo]], [[foo-value1]], [[foo-value2]]]],
 490 #                                  [[[[bar]], [[bar-value1]]]])
 491 m4_define([b4_percent_define_check_values],
 492 [m4_foreach([b4_sublist], m4_quote($@),
 493             [_b4_percent_define_check_values(b4_sublist)])])
 494
 495 m4_define([_b4_percent_define_check_values],
 496 [m4_ifdef([b4_percent_define(]$1[)],
 497   [m4_pushdef([b4_good_value], [0])dnl
 498    m4_if($#, 1, [],
 499          [m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 500                      [m4_if(m4_indir([b4_percent_define(]$1[)]), b4_value,
 501                             [m4_define([b4_good_value], [1])])])])dnl
 502    m4_if(b4_good_value, [0],
 503          [b4_complain_at(b4_percent_define_get_loc([$1]),
 504                          [[invalid value for %%define variable '%s': '%s']],
 505                          [$1],
 506                          m4_dquote(m4_indir([b4_percent_define(]$1[)])))
 507           m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 508                      [b4_complain_at(b4_percent_define_get_loc([$1]),
 509                                      [[accepted value: '%s']],
 510                                      m4_dquote(b4_value))])])dnl
 511    m4_popdef([b4_good_value])],
 512   [b4_fatal([[b4_percent_define_check_values: undefined %%define variable '%s']], [$1])])])
 513
 514 # b4_percent_code_get([QUALIFIER])
 515 # --------------------------------
 516 # If any %code blocks for QUALIFIER are defined, emit them beginning with a
 517 # comment and ending with synclines and a newline.  If QUALIFIER is not
 518 # specified or empty, do this for the unqualified %code blocks.  Also, record
 519 # Bison's usage of QUALIFIER (if specified) by defining
 520 # b4_percent_code_bison_qualifiers(QUALIFIER).
 521 #
 522 # For example, to emit any unqualified %code blocks followed by any %code
 523 # blocks for the qualifier foo:
 524 #
 525 #   b4_percent_code_get
 526 #   b4_percent_code_get([[foo]])
 527 m4_define([b4_percent_code_get],
 528 [m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
 529 m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
 530 m4_ifdef(b4_macro_name,
 531 [b4_comment([m4_if([$#], [0], [[Unqualified %code]],
 532                    [["%code ]$1["]])[ blocks.]])
 533 b4_user_code([m4_indir(b4_macro_name)])
 534 ])dnl
 535 m4_popdef([b4_macro_name])])
 536
 537 # b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
 538 # -----------------------------------------------------
 539 # If any %code blocks for QUALIFIER (or unqualified %code blocks if
 540 # QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
 541 # Also, record Bison's usage of QUALIFIER (if specified) by defining
 542 # b4_percent_code_bison_qualifiers(QUALIFIER).
 543 m4_define([b4_percent_code_ifdef],
 544 [m4_ifdef([b4_percent_code(]$1[)],
 545           [m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
 546           [$3])])
 547
 548
 549 ## ----------------------------------------------------------- ##
 550 ## After processing the skeletons, check that all the user's   ##
 551 ## %define variables and %code qualifiers were used by Bison.  ##
 552 ## ----------------------------------------------------------- ##
 553
 554 m4_define([b4_check_user_names_wrap],
 555 [m4_ifdef([b4_percent_]$1[_user_]$2[s],
 556           [b4_check_user_names([[%]$1 $2],
 557                                [b4_percent_]$1[_user_]$2[s],
 558                                [[b4_percent_]$1[_bison_]$2[s]])])])
 559
 560 m4_wrap_lifo([
 561 b4_check_user_names_wrap([[define]], [[variable]])
 562 b4_check_user_names_wrap([[code]], [[qualifier]])
 563 ])
 564
 565
 566 ## ---------------- ##
 567 ## Default values.  ##
 568 ## ---------------- ##
 569
 570 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 571 m4_define_default([b4_pre_prologue], [])
 572 m4_define_default([b4_post_prologue], [])
 573 m4_define_default([b4_epilogue], [])
 574 m4_define_default([b4_parse_param], [])
 575
 576 # The initial column and line.
 577 m4_define_default([b4_location_initial_column], [1])
 578 m4_define_default([b4_location_initial_line],   [1])
 579
 580 # Sanity checks.
 581 b4_percent_define_ifdef([api.prefix],
 582 [m4_ifdef([b4_prefix],
 583 [b4_complain_at(b4_percent_define_get_loc([api.prefix]),
 584                 [['%s' and '%s' cannot be used together]],
 585                 [%name-prefix],
 586                 [%define api.prefix])])])