tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 ## ------------- ##
  24 ## Basic tests.  ##
  25 ## ------------- ##
  26
  27 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  28 # ------------------------------------------
  29 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  30 # taken in "slurp" mode, i.e., one can match end-of-lines.
  31 m4_define([AT_MATCHES_CHECK],
  32 [AT_CHECK([perl -0777 -ne '
  33 my $count = 0;
  34 s{$2}{ ++$count; "" }gem;
  35 printf "$count\n";' $1], [0], [$3
  36 ])])
  37
  38
  39 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  40 # ------------------------------------------------
  41 # Don't interfere with caller's files.
  42 m4_divert_text([PREPARE_TESTS],
  43 [at_save_special_files ()
  44 {
  45   for at_save_file in stderr experr expout
  46   do
  47     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  48   done
  49 }
  50
  51 at_restore_special_files ()
  52 {
  53   for at_save_file in stderr experr expout
  54   do
  55     test ! -f at-bison-check-$at_save_file.bak ||
  56       mv at-bison-check-$at_save_file.bak $at_save_file
  57   done
  58 }
  59 ])
  60
  61 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  62 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  63
  64
  65
  66 ## ------------------------------- ##
  67 ## Macros decoding Bison options.  ##
  68 ## ------------------------------- ##
  69
  70 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  71 # ----------------------------------------------------------------
  72 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  73 m4_define([AT_LOC_PUSHDEF],
  74 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  75 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  76 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  77 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  78
  79 # AT_LOC_POPDEF
  80 # -------------
  81 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  82 m4_define([AT_LOC_POPDEF],
  83 [m4_popdef([AT_LOC_FIRST_LINE])
  84 m4_popdef([AT_LOC_FIRST_COLUMN])
  85 m4_popdef([AT_LOC_LAST_LINE])
  86 m4_popdef([AT_LOC_LAST_COLUMN])])
  87
  88
  89
  90 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  91 # -----------------------------------------
  92 m4_define([AT_BISON_OPTION_PUSHDEFS],
  93 [m4_divert_text([KILL],
  94                 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])])
  95
  96
  97 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  98 # --------------------------------------------------
  99 # This macro works around the impossibility to define macros
 100 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 101 # This sucks hard, GNU M4 should really provide M5-like $$1.
 102 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 103 [m4_if([$1$2], $[1]$[2], [],
 104        [m4_fatal([$0: Invalid arguments: $@])])dnl
 105 m4_pushdef([AT_DEFINES_IF],
 106 [m4_bmatch([$3], [%defines], [$1], [$2])])
 107 m4_pushdef([AT_SKEL_CC_IF],
 108 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 109 m4_pushdef([AT_SKEL_JAVA_IF],
 110 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 111 m4_pushdef([AT_LANG],
 112 [AT_SKEL_JAVA_IF([java],
 113                  [AT_SKEL_CC_IF([c++],
 114                                 [c])])])
 115 m4_pushdef([AT_GLR_IF],
 116 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 117 m4_pushdef([AT_LALR1_CC_IF],
 118 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 119 m4_pushdef([AT_GLR_CC_IF],
 120 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 121 # Using yacc.c?
 122 m4_pushdef([AT_YACC_IF],
 123 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 124 m4_pushdef([AT_LEXPARAM_IF],
 125 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 126 m4_pushdef([AT_LOCATION_IF],
 127 [m4_bmatch([$3], [%locations], [$1], [$2])])
 128 m4_pushdef([AT_LOCATION_TYPE_IF],
 129 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
 130 m4_pushdef([AT_PARAM_IF],
 131 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 132 m4_pushdef([AT_PURE_IF],
 133 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 134            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 135            [$2])])
 136 m4_pushdef([AT_PURE_AND_LOC_IF],
 137 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 138 m4_pushdef([AT_GLR_OR_PARAM_IF],
 139 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 140 m4_pushdef([AT_NAME_PREFIX],
 141 [m4_bmatch([$3], [\(%define api\.prefix\|%name-prefix\) ".*"],
 142            [m4_bregexp([$3], [\(%define api\.prefix\|%name-prefix\) "\([^""]*\)"], [\2])],
 143            [yy])])
 144 m4_pushdef([AT_TOKEN_PREFIX],
 145 [m4_bmatch([$3], [%define api.tokens.prefix ".*"],
 146            [m4_bregexp([$3], [%define api.tokens.prefix "\(.*\)"], [\1])])])
 147 m4_pushdef([AT_API_prefix],
 148 [m4_bmatch([$3], [%define api\.prefix ".*"],
 149            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 150            [yy])])
 151 m4_pushdef([AT_API_PREFIX],
 152 [m4_toupper(AT_API_prefix)])
 153 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 154 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 155 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 156                     [$2])])
 157 # yyerror always sees the locations (when activated), except if
 158 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 159 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 160 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 161                                         [$1])],
 162                             [$1])],
 163                 [$2])])
 164
 165 # The interface is pure: either because %define api.pure, or because we
 166 # are using the C++ parsers.
 167 m4_pushdef([AT_PURE_LEX_IF],
 168 [AT_PURE_IF([$1],
 169             [AT_SKEL_CC_IF([$1], [$2])])])
 170
 171 m4_pushdef([AT_YYSTYPE],
 172 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 173                [AT_API_PREFIX[STYPE]])])
 174 m4_pushdef([AT_YYLTYPE],
 175 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 176                [AT_API_PREFIX[LTYPE]])])
 177
 178
 179 AT_PURE_LEX_IF(
 180 [m4_pushdef([AT_LOC], [(*llocp)])
 181  m4_pushdef([AT_VAL], [(*lvalp)])
 182  m4_pushdef([AT_YYLEX_FORMALS],
 183             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 184  m4_pushdef([AT_YYLEX_ARGS],
 185             [lvalp[]AT_LOCATION_IF([, llocp])])
 186  m4_pushdef([AT_USE_LEX_ARGS],
 187             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 188  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 189             [AT_YYLEX_FORMALS, ])
 190  m4_pushdef([AT_YYLEX_PRE_ARGS],
 191             [AT_YYLEX_ARGS, ])
 192 ],
 193 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 194  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 195  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 196  m4_pushdef([AT_YYLEX_ARGS],        [])
 197  m4_pushdef([AT_USE_LEX_ARGS],    [])
 198  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 199  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 200 ])
 201
 202 # Handle the different types of location components.
 203
 204 AT_SKEL_CC_IF(
 205   [AT_LOCATION_TYPE_IF(
 206     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 207     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 208   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 209
 210
 211 AT_GLR_IF([AT_KEYWORDS([glr])])
 212 ])# _AT_BISON_OPTION_PUSHDEFS
 213
 214
 215 # AT_BISON_OPTION_POPDEFS
 216 # -----------------------
 217 m4_define([AT_BISON_OPTION_POPDEFS],
 218 [m4_divert_text([KILL],
 219 [m4_popdef([AT_YYLEX_PRE_ARGS])
 220 m4_popdef([AT_YYLEX_PRE_FORMALS])
 221 m4_popdef([AT_USE_LEX_ARGS])
 222 m4_popdef([AT_YYLEX_ARGS])
 223 m4_popdef([AT_YYLEX_FORMALS])
 224 m4_popdef([AT_YYLTYPE])
 225 m4_popdef([AT_YYSTYPE])
 226 m4_popdef([AT_VAL])
 227 m4_popdef([AT_LOC])
 228 m4_popdef([AT_PURE_LEX_IF])
 229 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 230 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 231 m4_popdef([AT_API_PREFIX])
 232 m4_popdef([AT_API_prefix])
 233 m4_popdef([AT_NAME_PREFIX])
 234 m4_popdef([AT_GLR_OR_PARAM_IF])
 235 m4_popdef([AT_PURE_AND_LOC_IF])
 236 m4_popdef([AT_LOCATION_TYPE_IF])
 237 m4_popdef([AT_LOCATION_IF])
 238 m4_popdef([AT_PARAM_IF])
 239 m4_popdef([AT_LEXPARAM_IF])
 240 m4_popdef([AT_YACC_IF])
 241 m4_popdef([AT_GLR_IF])
 242 m4_popdef([AT_SKEL_CC_IF])
 243 m4_popdef([AT_LANG])
 244 m4_popdef([AT_SKEL_JAVA_IF])
 245 m4_popdef([AT_GLR_CC_IF])
 246 m4_popdef([AT_LALR1_CC_IF])
 247 m4_popdef([AT_DEFINES_IF])
 248 AT_LOC_POPDEF])dnl
 249 ])# AT_BISON_OPTION_POPDEFS
 250
 251
 252
 253 ## -------------------------- ##
 254 ## Generating Grammar Files.  ##
 255 ## -------------------------- ##
 256
 257 # AT_DATA_SOURCE_PROLOGUE
 258 # ------------------------
 259 # The prologue that should be included in any source code that is
 260 # meant to be compiled.
 261 m4_define([AT_DATA_SOURCE_PROLOGUE],
 262 [[#include <config.h>
 263 /* We don't need perfect functions for these tests. */
 264 #undef malloc
 265 #undef memcmp
 266 #undef realloc
 267 ]])
 268
 269 # AT_DATA_GRAMMAR_PROLOGUE
 270 # ------------------------
 271 # The prologue that should be included in any grammar which parser is
 272 # meant to be compiled.
 273 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 274 [[%code top {
 275 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 276 [}
 277 ]])
 278
 279 # AT_DATA_SOURCE(NAME, CONTENT)
 280 # -----------------------------
 281 # Generate the file NAME, which CONTENT is preceded by
 282 # AT_DATA_SOURCE_PROLOGUE.
 283 m4_define([AT_DATA_SOURCE],
 284 [AT_DATA([$1],
 285 [AT_DATA_SOURCE_PROLOGUE
 286 $2])
 287 ])
 288
 289 # AT_DATA_GRAMMAR(NAME, CONTENT)
 290 # ------------------------------
 291 # Generate the file NAME, which CONTENT is preceded by
 292 # AT_DATA_GRAMMAR_PROLOGUE.
 293 m4_define([AT_DATA_GRAMMAR],
 294 [AT_DATA([$1],
 295 [AT_DATA_GRAMMAR_PROLOGUE
 296 $2])
 297 ])
 298
 299 # AT_YYLEX_PROTOTYPE
 300 # AT_YYLEX_DECLARE_EXTERN
 301 # AT_YYLEX_DECLARE
 302 # AT_YYLEX_DEFINE([INPUT], [ACTION])
 303 # ----------------------------------
 304 # INPUT can be empty, or in double quotes, or a list (in braces).
 305 # ACTION may compute yylval for instance, using "res" as token type,
 306 # and "toknum" as the number of calls to yylex (starting at 0).
 307 m4_define([AT_YYLEX_PROTOTYPE],
 308 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 309 ])
 310
 311 m4_define([AT_YYLEX_DECLARE_EXTERN],
 312 [AT_YYLEX_PROTOTYPE;dnl
 313 ])
 314
 315 m4_define([AT_YYLEX_DECLARE],
 316 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 317 ])
 318
 319 m4_define([AT_YYLEX_DEFINE],
 320 [[#include <assert.h>
 321 static
 322 ]AT_YYLEX_PROTOTYPE[
 323 {
 324   ]m4_bmatch([$1], [^\(".*"\)?$],
 325              [[static char const input[] = ]m4_default([$1], [""])],
 326              [[static int const input[] = ]$1])[;
 327   static size_t toknum = 0;
 328   int res;
 329   ]AT_USE_LEX_ARGS[;
 330   assert (toknum < sizeof input);
 331   res = input[toknum++];
 332   ]$2[;]AT_LOCATION_IF([[
 333   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 334   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 335   return res;
 336 }]dnl
 337 ])
 338
 339 # AT_YYERROR_PROTOTYPE
 340 # AT_YYERROR_DECLARE_EXTERN
 341 # AT_YYERROR_DECLARE
 342 # AT_YYERROR_DEFINE
 343 # -------------------------
 344 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 345 m4_define([AT_YYERROR_FORMALS],
 346 [m4_case(AT_LANG,
 347 [c], [AT_YYERROR_ARG_LOC_IF([YYLTYPE *llocp, ])[const char *msg]])[]dnl
 348 ])
 349
 350 m4_define([AT_YYERROR_PROTOTYPE],
 351 [m4_case(AT_LANG,
 352 [c], [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])[]dnl
 353 ])
 354
 355 m4_define([AT_YYERROR_DECLARE_EXTERN],
 356 [m4_case(AT_LANG,
 357 [c], [AT_YYERROR_PROTOTYPE;])[]dnl
 358 ])
 359
 360 m4_define([AT_YYERROR_DECLARE],
 361 [m4_case(AT_LANG,
 362 [c], [static AT_YYERROR_DECLARE_EXTERN])[]dnl
 363 ])
 364
 365 m4_define([AT_YYERROR_DEFINE],
 366 [m4_case(AT_LANG,
 367 [c], [[#include <stdio.h>
 368 /* A C error reporting function.  */
 369 static
 370 ]AT_YYERROR_PROTOTYPE[
 371 {
 372 ]AT_YYERROR_SEES_LOC_IF([[
 373   fprintf (stderr, "%d.%d",
 374            ]AT_LOC_FIRST_LINE[, ]AT_LOC_FIRST_COLUMN[);
 375   if (]AT_LOC_FIRST_LINE[ != ]AT_LOC_LAST_LINE[)
 376     fprintf (stderr, "-%d.%d",
 377              ]AT_LOC_LAST_LINE[,  ]AT_LOC_LAST_COLUMN[ - 1);
 378   else if (]AT_LOC_FIRST_COLUMN[ != ]AT_LOC_LAST_COLUMN[ - 1)
 379     fprintf (stderr, "-%d",
 380              ]AT_LOC_LAST_COLUMN[ - 1);
 381   fprintf (stderr, ": ");]])[
 382   fprintf (stderr, "%s\n", msg);
 383 }]],
 384 [c++], [[/* A C++ error reporting function.  */
 385 void
 386 ]AT_NAME_PREFIX[::parser::error (]AT_LOCATION_IF([[const location_type& l, ]])[const std::string& m)
 387 {  std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 388 }]],
 389 [java], [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 390 {
 391     if (l == null)
 392       System.err.println (s);
 393     else
 394       System.err.println (l + ": " + s);
 395   }
 396 ]], [[
 397   public void yyerror (String s)
 398   {
 399     System.err.println (s);
 400 }]])])dnl
 401 ])
 402
 403
 404 ## --------------- ##
 405 ## Running Bison.  ##
 406 ## --------------- ##
 407
 408 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 409 # -------------------------------------------------
 410 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 411 # shell constructs (such as redirection or pipes) that would prevent
 412 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 413 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 414 #
 415 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 416 # Bison in the test suite.  For now it ensures that:
 417 #
 418 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 419 #      a non-zero exit status since Bison doesn't always try to free all memory
 420 #      in that case.
 421 #
 422 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 423 #      --graph and --report=all output for every working grammar.
 424 #
 425 #   3. If stderr contains a warning, -Werror and --warnings=error
 426 #      convert the warning to an error.
 427 #
 428 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 429 m4_define([AT_BISON_CHECK],
 430 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 431        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 432 AT_BISON_CHECK_NO_XML($@)])
 433
 434 m4_define([AT_BISON_WERROR_MSG],
 435           [[bison: warnings being treated as errors]])
 436
 437 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 438 # --------------------------------------------------------
 439 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 440 # when a tortured grammar's XML is known to be too large for xsltproc to
 441 # handle.
 442 m4_define([AT_BISON_CHECK_NO_XML],
 443 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 444                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 445 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 446       m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0], [[
 447         # Defining POSIXLY_CORRECT causes bison to complain if options
 448         # are added after the grammar file name, so skip these checks
 449         # in that case.
 450         if test -z "${POSIXLY_CORRECT+set}"; then
 451           ]AT_SAVE_SPECIAL_FILES[
 452
 453           # To avoid expanding it repeatedly, store specified stdout.
 454           ]AT_DATA([expout], [$3])[
 455
 456           # Run with -Werror.
 457           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Werror]],
 458                     [[1]], [expout], [stderr])[
 459
 460           # Build expected stderr up to and including the "warnings being
 461           # treated as errors" message.
 462           ]AT_DATA([[at-bison-check-warnings]], [$4])[
 463           at_bison_check_first=`sed -n \
 464             '/: warning: /{=;q;}' at-bison-check-warnings`
 465           : ${at_bison_check_first:=1}
 466           at_bison_check_first_tmp=`sed -n \
 467             '/conflicts: [0-9].*reduce$/{=;q;}' at-bison-check-warnings`
 468           : ${at_bison_check_first_tmp:=1}
 469           if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 470             at_bison_check_first=$at_bison_check_first_tmp
 471           fi
 472           if test $at_bison_check_first -gt 1; then
 473             sed -n "1,`expr $at_bison_check_first - 1`"p \
 474               at-bison-check-warnings > experr
 475           fi
 476           echo ']AT_BISON_WERROR_MSG[' >> experr
 477
 478           # Finish building expected stderr and check.  Unlike warnings,
 479           # complaints cause bison to exit early.  Thus, with -Werror, bison
 480           # does not necessarily report all warnings that it does without
 481           # -Werror, but it at least reports one.
 482           at_bison_check_last=`sed -n '$=' stderr`
 483           : ${at_bison_check_last:=1}
 484           at_bison_check_last=`expr $at_bison_check_last - 1`
 485           sed -n "$at_bison_check_first,$at_bison_check_last"p \
 486             at-bison-check-warnings >> experr
 487           ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 488                       stderr 1>&2]], [[0]], [[]], [experr])[
 489
 490           # Now check --warnings=error.
 491           cp stderr experr
 492           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=error]],
 493                     [[1]], [expout], [experr])[
 494
 495           # Now check -Wnone and --warnings=none by making sure that
 496           # -Werror doesn't change the exit status when -Wnone or
 497           # --warnings=none is specified.
 498           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Wnone -Werror]],
 499                     [[0]], [expout])[
 500           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=none \
 501                     -Werror]], [[0]], [expout])[
 502
 503           ]AT_RESTORE_SPECIAL_FILES[
 504         fi
 505       ]])
 506 ])
 507
 508 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 509 # -----------------------------------------------------
 510 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 511 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 512 # have a non-zero exit status.
 513 m4_define([AT_BISON_CHECK_XML],
 514 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 515   AT_SAVE_SPECIAL_FILES
 516   [mkdir xml-tests]
 517   m4_pushdef([AT_BISON_ARGS],
 518              [m4_bpatsubsts([[$1]],
 519                             [--report(-file)?=[^][ ]*], [],
 520                             [--graph=[^][ ]*], [],
 521                             [--xml=[^][ ]*], [])])dnl
 522   # Don't combine these Bison invocations since we want to be sure that
 523   # --report=all isn't required to get the full XML file.
 524   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 525              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 526            [[0]], [ignore], [ignore])
 527   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 528            [[0]], [ignore], [ignore])
 529   m4_popdef([AT_BISON_ARGS])dnl
 530   [cp xml-tests/test.output expout]
 531   AT_CHECK([[$XSLTPROC \
 532              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 533              xml-tests/test.xml]], [[0]], [expout])
 534   [cp xml-tests/test.dot expout]
 535   AT_CHECK([[$XSLTPROC \
 536              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 537              xml-tests/test.xml]], [[0]], [expout])
 538   [rm -rf xml-tests expout]
 539   AT_RESTORE_SPECIAL_FILES
 540 [fi]])
 541
 542 # AT_QUELL_VALGRIND
 543 # -----------------
 544 # Put this before a Bison invocation to keep Valgrind from complaining about
 545 # reachable memory.
 546 #
 547 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 548 # The triple quoting below will cause test cases to fail if you do.  If you do
 549 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 550 # will then fail to shell-escape its contents when attempting to print them.
 551 # The testsuite verbose output, at least, will be incorrect, but nothing may
 552 # fail to make sure you notice.
 553 m4_define([AT_QUELL_VALGRIND],
 554 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 555
 556 ## ------------------------ ##
 557 ## Compiling C, C++ Files.  ##
 558 ## ------------------------ ##
 559
 560
 561 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 562 # ----------------------------------------
 563 # Compile SOURCES into OUTPUT.
 564 #
 565 # If OUTPUT does not contain '.', assume that we are linking too,
 566 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 567 # with trailing .o removed, and ".c" appended.
 568 m4_define([AT_COMPILE],
 569 [AT_CHECK(m4_join([ ],
 570                   [$CC $CFLAGS $CPPFLAGS],
 571                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 572                   [-o $1],
 573                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 574                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 575            0, [ignore], [ignore])])
 576
 577 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 578 # ---------------------------------------------
 579 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 580 # ignore the test.
 581 #
 582 # If OUTPUT does not contain '.', assume that we are linking too,
 583 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 584 # with trailing .o removed, and ".cc" appended.
 585 m4_define([AT_COMPILE_CXX],
 586 [AT_KEYWORDS(c++)
 587 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 588 AT_CHECK(m4_join([ ],
 589                  [$CXX $CXXFLAGS $CPPFLAGS],
 590                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 591                  [-o $1],
 592                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 593                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 594          0, [ignore], [ignore])])
 595
 596 # AT_JAVA_COMPILE(SOURCES)
 597 # ------------------------
 598 # Compile SOURCES into Java class files.  Skip the test if java or javac
 599 # is not installed.
 600 m4_define([AT_JAVA_COMPILE],
 601 [AT_KEYWORDS(java)
 602 AT_SKIP_IF([[test -z "$CONF_JAVA$CONF_JAVAC"]])
 603 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 604          [[0]], [ignore], [ignore])])
 605
 606 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 607 # --------------------------------------------
 608 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 609 #
 610 # If OUTPUT does not contain '.', assume that we are linking too,
 611 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 612 # with trailing .o removed, and ".c"/".cc" appended.
 613 m4_define([AT_LANG_COMPILE],
 614 [m4_case(AT_LANG,
 615 [c],    [AT_COMPILE([$1], [$2])],
 616 [c++],  [AT_COMPILE_CXX([$1], [$2])],
 617 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 618         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 619 ])
 620
 621 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 622 # -------------------------------------------
 623 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 624 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 625 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 626 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 627 # AT_SKEL_JAVA_IF.
 628 m4_define([AT_FULL_COMPILE],
 629 [m4_case(AT_LANG,
 630 [java],
 631   [AT_BISON_CHECK([-o $1.java $1.y])
 632    AT_LANG_COMPILE([$1],
 633                     m4_join([ ],
 634                             [$1.java],
 635                             m4_ifval($2, [[$1-$2.java]]),
 636                            m4_ifval($3, [[$1-$3.java]])))],
 637 [c++],
 638   [AT_BISON_CHECK([-o $1.cc $1.y])
 639    AT_LANG_COMPILE([$1],
 640                      m4_join([ ],
 641                              [$1.cc],
 642                              m4_ifval($2, [[$1-$2.cc]]),
 643                            m4_ifval($3, [[$1-$3.cc]])))],
 644 [c],
 645   [AT_BISON_CHECK([-o $1.c $1.y])
 646    AT_LANG_COMPILE([$1],
 647                   m4_join([ ],
 648                           [$1.c],
 649                           m4_ifval($2, [[$1-$2.c]]),
 650                            m4_ifval($3, [[$1-$3.c]])))])
 651 ])
 652
 653
 654 ## ---------------------------- ##
 655 ## Running a generated parser.  ##
 656 ## ---------------------------- ##
 657
 658
 659 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 660 # ------------------------------------------------------------
 661 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 662 #
 663 # Get rid of spurious messages when compiled with --coverage:
 664 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 665 m4_define([AT_PARSER_CHECK],
 666 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 667 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 668          [0], [], [$4])
 669 ])
 670
 671
 672 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 673 # -----------------------------------------------------------------
 674 m4_define([AT_JAVA_PARSER_CHECK],
 675 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 676
 677
 678 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 679 #                          DECLS, GRAMMAR, INPUT,
 680 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 681 #                          [OTHER-CHECKS],
 682 #                          [PARSER-EXIT-VALUE],
 683 #                          [PARSER-STDOUT], [PARSER-STDERR])
 684 # -------------------------------------------------------------
 685 # Using TITLE as the test group title, check the generated parser tables
 686 # and parser for a specified grammar file under a condition labeled by
 687 # COND-VALUE.
 688 #
 689 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 690 # recognized attribute is described below where it is relevant.
 691 #
 692 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 693 # the grammar file.  Insert basic yyerror, yylex, and main function
 694 # definitions as well.  Hardcode yylex to return the (possibly empty)
 695 # comma-delimited series of tokens in INPUT followed by token 0.
 696 #
 697 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 698 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 699 # On the bison command-line, specify `--report=all --defines'.  Check
 700 # that Bison exits with value 0, has no stdout, and has stderr
 701 # BISON-STDERR.
 702 #
 703 # If TEST-SPEC contains the attribute `last-state', check that the value
 704 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 705 # the grammar; in other words, check the number of states (minus one).
 706 # Otherwise, check that everything in the `.output' file starting with
 707 # the definition of state 0 is the same as the entire value of
 708 # TABLES-OR-LAST-STATE.
 709 #
 710 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 711 # `.output' file, which is named `input.output', and/or grammar file,
 712 # which is named `input.y'.
 713 #
 714 # Finally, compile the generated parser and then run it using
 715 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 716 # PARSER-STDERR as the 2nd-4th arguments.
 717 #
 718 # As a precondition, you must properly double-quote all arguments that
 719 # are to be interpreted as strings.
 720 #
 721 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 722 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 723 # first argument.  This is useful, for example, when wrapping multiple
 724 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 725 # condition, in another macro.
 726 #
 727 # For example:
 728 #
 729 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 730 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 731 #   # ---------------------------------------------------------------------
 732 #   m4_define([AT_TEST_SYNTAX_ERROR],
 733 #   [
 734 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 735 #                              [[last-state]],
 736 #                              [[%error-verbose ]$2], [$3], [$4],
 737 #                              [[]], [$5], [], [$6], [$7], [$8])
 738 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 739 #                              [[last-state]],
 740 #                              [$2], [$3], [$4],
 741 #                              [[]], [$5], [], [$6], [$7], [$8])
 742 #   ])
 743 #
 744 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 745 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 746 #                        [[3]],
 747 #                        [[1]], [[]],
 748 #                        [AT_COND_CASE([[no verbose]],
 749 #                                      [[syntax error
 750 #   ]],
 751 #                                      [[syntax error, unexpected 'b', expecting $end
 752 #   ]])])
 753 m4_define([AT_TEST_TABLES_AND_PARSE],
 754 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 755
 756 AT_SETUP([$1])
 757 AT_BISON_OPTION_PUSHDEFS([$4])
 758 AT_DATA_GRAMMAR([[input.y]],
 759 [[%code {
 760   #include <stdio.h>
 761   ]AT_YYERROR_DECLARE[
 762   ]AT_YYLEX_DECLARE[
 763 }
 764
 765 ]$4[
 766
 767 %%
 768
 769 ]$5[
 770
 771 %%
 772 ]AT_YYERROR_DEFINE[
 773 static int
 774 yylex (void)
 775 {
 776   static int const input[] = {
 777     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 778   };
 779   static int const *inputp = input;
 780   return *inputp++;
 781 }
 782
 783 int
 784 main (void)
 785 {
 786   return yyparse ();
 787 }
 788 ]])
 789
 790 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 791 # expanding macros, so it corrupts some special characters in the
 792 # macros.  To avoid this, expand now and pass it the result with proper
 793 # string quotation.  Assume args 7 through 12 expand to properly quoted
 794 # strings.
 795
 796 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 797       [AT_BISON_CHECK],
 798       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 799                                [0], [], m4_dquote($7))
 800
 801 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 802       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 803                 m4_dquote($8))],
 804       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 805                 m4_dquote($8)[[
 806 ]])])
 807
 808 $9
 809
 810 # Canonical LR generates very large tables, resulting in very long
 811 # files with #line directives that may overflow what the standards
 812 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 813 # will issue an error.
 814 #
 815 # There is no "" around `wc` since some indent the result.
 816 m4_bmatch([$4], [%define lr.type canonical-lr],
 817 [if test 32767 -lt `wc -l < input.c`; then
 818   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 819   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 820 fi])
 821 AT_COMPILE([[input]])
 822
 823 AT_PARSER_CHECK([[./input]],
 824                 m4_ifval([$10], [m4_dquote($10)]),
 825                 m4_ifval([$11], [m4_dquote($11)]),
 826                 m4_ifval([$12], [m4_dquote($12)]))
 827
 828 AT_BISON_OPTION_POPDEFS
 829 AT_CLEANUP
 830
 831 m4_popdef([AT_COND_CASE])])
 832
 833
 834
 835 ## ----------------------- ##
 836 ## Launch the test suite.  ##
 837 ## ----------------------- ##
 838
 839 AT_INIT
 840
 841 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 842 # options are processed, so we don't know the value of CXX and
 843 # CXXFLAGS yet.
 844 #
 845 # Note that it also means that command line values for CXX and
 846 # CXXFLAGS will not be propagated to CC and CFLAGS.
 847 AT_ARG_OPTION([compile-c-with-cxx],
 848               [compile C parsers with the C++ compiler])
 849
 850 AT_COLOR_TESTS
 851
 852 AT_TESTED([bison])