src/scan-gram.l

   1 /* Bison Grammar Scanner                             -*- C -*-
   2    Copyright (C) 2002 Free Software Foundation, Inc.
   3
   4    This file is part of Bison, the GNU Compiler Compiler.
   5
   6    This program is free software; you can redistribute it and/or modify
   7    it under the terms of the GNU General Public License as published by
   8    the Free Software Foundation; either version 2 of the License, or
   9    (at your option) any later version.
  10
  11    This program is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14    GNU General Public License for more details.
  15
  16    You should have received a copy of the GNU General Public License
  17    along with this program; if not, write to the Free Software
  18    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307  USA
  20 */
  21
  22 %option debug nodefault noyywrap never-interactive
  23 %option prefix="gram_" outfile="lex.yy.c"
  24
  25 %{
  26 #include "system.h"
  27 #include "mbswidth.h"
  28 #include "complain.h"
  29 #include "quote.h"
  30 #include "getargs.h"
  31 #include "gram.h"
  32 #include "reader.h"
  33
  34 /* Each time we match a string, move the end cursor to its end. */
  35 #define YY_USER_INIT                            \
  36 do {                                            \
  37   LOCATION_RESET (*yylloc);                     \
  38   yylloc->file = infile;                        \
  39    /* This is only to avoid GCC warnings. */    \
  40   if (yycontrol) {;};                           \
  41 } while (0)
  42
  43 #define YY_USER_ACTION  extend_location (yylloc, yytext, yyleng);
  44 #define YY_STEP         LOCATION_STEP (*yylloc)
  45
  46 #define YY_INPUT(buf, result, size) ((result) = no_cr_read (yyin, buf, size))
  47
  48
  49 /* Read bytes from FP into buffer BUF of size SIZE.  Return the
  50    number of bytes read.  Remove '\r' from input, treating \r\n
  51    and isolated \r as \n.  */
  52
  53 static size_t
  54 no_cr_read (FILE *fp, char *buf, size_t size)
  55 {
  56   size_t s = fread (buf, 1, size, fp);
  57   if (s)
  58     {
  59       char *w = memchr (buf, '\r', s);
  60       if (w)
  61         {
  62           char const *r = ++w;
  63           char const *lim = buf + s;
  64
  65           for (;;)
  66             {
  67               /* Found an '\r'.  Treat it like '\n', but ignore any
  68                  '\n' that immediately follows.  */
  69               w[-1] = '\n';
  70               if (r == lim)
  71                 {
  72                   int ch = getc (fp);
  73                   if (ch != '\n' && ungetc (ch, fp) != ch)
  74                     break;
  75                 }
  76               else if (*r == '\n')
  77                 r++;
  78
  79               /* Copy until the next '\r'.  */
  80               do
  81                 {
  82                   if (r == lim)
  83                     return w - buf;
  84                 }
  85               while ((*w++ = *r++) != '\r');
  86             }
  87
  88           return w - buf;
  89         }
  90     }
  91
  92   return s;
  93 }
  94
  95
  96 /* Extend *LOC to account for token TOKEN of size SIZE.  */
  97
  98 static void
  99 extend_location (location_t *loc, char const *token, int size)
 100 {
 101   int line = loc->last_line;
 102   int column = loc->last_column;
 103   char const *p0 = token;
 104   char const *p = token;
 105   char const *lim = token + size;
 106
 107   for (p = token; p < lim; p++)
 108     switch (*p)
 109       {
 110       case '\r':
 111         /* \r shouldn't survive no_cr_read.  */
 112         abort ();
 113
 114       case '\n':
 115         line++;
 116         column = 1;
 117         p0 = p + 1;
 118         break;
 119
 120       case '\t':
 121         column += mbsnwidth (p0, p - p0, 0);
 122         column += 8 - ((column - 1) & 7);
 123         p0 = p + 1;
 124         break;
 125       }
 126
 127   loc->last_line = line;
 128   loc->last_column = column + mbsnwidth (p0, p - p0, 0);
 129 }
 130
 131
 132
 133 /* STRING_OBSTACK -- Used to store all the characters that we need to
 134    keep (to construct ID, STRINGS etc.).  Use the following macros to
 135    use it.
 136
 137    Use YY_OBS_GROW to append what has just been matched, and
 138    YY_OBS_FINISH to end the string (it puts the ending 0).
 139    YY_OBS_FINISH also stores this string in LAST_STRING, which can be
 140    used, and which is used by YY_OBS_FREE to free the last string.  */
 141
 142 static struct obstack string_obstack;
 143
 144 #define YY_OBS_GROW   \
 145   obstack_grow (&string_obstack, yytext, yyleng)
 146
 147 #define YY_OBS_FINISH                                   \
 148   do {                                                  \
 149     obstack_1grow (&string_obstack, '\0');              \
 150     last_string = obstack_finish (&string_obstack);     \
 151   } while (0)
 152
 153 #define YY_OBS_FREE \
 154   obstack_free (&string_obstack, last_string)
 155
 156
 157 /* Within well-formed rules, RULE_LENGTH is the number of values in
 158    the current rule so far, which says where to find `$0' with respect
 159    to the top of the stack.  It is not the same as the rule->length in
 160    the case of mid rule actions.
 161
 162    Outside of well-formed rules, RULE_LENGTH has an undefined value.  */
 163 static int rule_length;
 164
 165 static void handle_dollar (braced_code_t code_kind,
 166                            char *cp, location_t location);
 167 static void handle_at (braced_code_t code_kind,
 168                        char *cp, location_t location);
 169 static void handle_syncline (char *args, location_t *location);
 170 static int convert_ucn_to_byte (char const *hex_text);
 171 static void unexpected_end_of_file (location_t *, char const *);
 172
 173 %}
 174 %x SC_COMMENT SC_LINE_COMMENT SC_YACC_COMMENT
 175 %x SC_STRING SC_CHARACTER
 176 %x SC_ESCAPED_STRING SC_ESCAPED_CHARACTER
 177 %x SC_BRACED_CODE SC_PROLOGUE SC_EPILOGUE
 178
 179 letter    [.abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ_]
 180 id        {letter}({letter}|[0-9])*
 181 directive %{letter}({letter}|[0-9]|-)*
 182 int       [0-9]+
 183
 184 /* POSIX says that a tag must be both an id and a C union member, but
 185    historically almost any character is allowed in a tag.  We disallow
 186    NUL and newline, as this simplifies our implementation.  */
 187 tag      [^\0\n>]+
 188
 189 /* Zero or more instances of backslash-newline.  Following GCC, allow
 190    white space between the backslash and the newline.  */
 191 splice   (\\[ \f\t\v]*\n)*
 192
 193 %%
 194 %{
 195   /* Nesting level of the current code in braces.  */
 196   int braces_level IF_LINT (= 0);
 197
 198   /* Scanner context when scanning C code.  */
 199   int c_context IF_LINT (= 0);
 200
 201   /* A string representing the most recently saved token.  */
 202   char *last_string;
 203
 204   /* At each yylex invocation, mark the current position as the
 205      start of the next token.  */
 206   YY_STEP;
 207 %}
 208
 209
 210   /*----------------------------.
 211   | Scanning Bison directives.  |
 212   `----------------------------*/
 213 <INITIAL>
 214 {
 215   "%binary"               return PERCENT_NONASSOC;
 216   "%debug"                return PERCENT_DEBUG;
 217   "%define"               return PERCENT_DEFINE;
 218   "%defines"              return PERCENT_DEFINES;
 219   "%destructor"           return PERCENT_DESTRUCTOR;
 220   "%dprec"                return PERCENT_DPREC;
 221   "%error"[-_]"verbose"   return PERCENT_ERROR_VERBOSE;
 222   "%expect"               return PERCENT_EXPECT;
 223   "%file-prefix"          return PERCENT_FILE_PREFIX;
 224   "%fixed"[-_]"output"[-_]"files"   return PERCENT_YACC;
 225   "%glr-parser"           return PERCENT_GLR_PARSER;
 226   "%left"                 return PERCENT_LEFT;
 227   "%locations"            return PERCENT_LOCATIONS;
 228   "%merge"                return PERCENT_MERGE;
 229   "%name"[-_]"prefix"     return PERCENT_NAME_PREFIX;
 230   "%no"[-_]"lines"        return PERCENT_NO_LINES;
 231   "%nonassoc"             return PERCENT_NONASSOC;
 232   "%nterm"                return PERCENT_NTERM;
 233   "%output"               return PERCENT_OUTPUT;
 234   "%parse-param"          return PERCENT_PARSE_PARAM;
 235   "%prec"                 rule_length--; return PERCENT_PREC;
 236   "%printer"              return PERCENT_PRINTER;
 237   "%pure"[-_]"parser"     return PERCENT_PURE_PARSER;
 238   "%right"                return PERCENT_RIGHT;
 239   "%lex-param"            return PERCENT_LEX_PARAM;
 240   "%skeleton"             return PERCENT_SKELETON;
 241   "%start"                return PERCENT_START;
 242   "%term"                 return PERCENT_TOKEN;
 243   "%token"                return PERCENT_TOKEN;
 244   "%token"[-_]"table"     return PERCENT_TOKEN_TABLE;
 245   "%type"                 return PERCENT_TYPE;
 246   "%union"                return PERCENT_UNION;
 247   "%verbose"              return PERCENT_VERBOSE;
 248   "%yacc"                 return PERCENT_YACC;
 249
 250   {directive}             {
 251     complain_at (*yylloc, _("invalid directive: %s"), quote (yytext));
 252     YY_STEP;
 253   }
 254
 255   ^"#line "{int}" \""[^\"]*"\"\n"   handle_syncline (yytext + strlen ("#line "), yylloc); YY_STEP;
 256
 257   "="                     return EQUAL;
 258   ":"                     rule_length = 0; return COLON;
 259   "|"                     rule_length = 0; return PIPE;
 260   ","                     return COMMA;
 261   ";"                     return SEMICOLON;
 262
 263   [ \f\n\t\v]  YY_STEP;
 264
 265   {id}        {
 266     yylval->symbol = symbol_get (yytext, *yylloc);
 267     rule_length++;
 268     return ID;
 269   }
 270
 271   {int} {
 272     unsigned long num;
 273     errno = 0;
 274     num = strtoul (yytext, 0, 10);
 275     if (INT_MAX < num || errno)
 276       {
 277         complain_at (*yylloc, _("integer out of range: %s"), quote (yytext));
 278         num = INT_MAX;
 279       }
 280     yylval->integer = num;
 281     return INT;
 282   }
 283
 284   /* Characters.  We don't check there is only one.  */
 285   "'"         YY_OBS_GROW; BEGIN SC_ESCAPED_CHARACTER;
 286
 287   /* Strings. */
 288   "\""        YY_OBS_GROW; BEGIN SC_ESCAPED_STRING;
 289
 290   /* Comments. */
 291   "/*"        BEGIN SC_YACC_COMMENT;
 292   "//".*      YY_STEP;
 293
 294   /* Prologue. */
 295   "%{"        BEGIN SC_PROLOGUE;
 296
 297   /* Code in between braces.  */
 298   "{"         YY_OBS_GROW; braces_level = 0; BEGIN SC_BRACED_CODE;
 299
 300   /* A type. */
 301   "<"{tag}">" {
 302     obstack_grow (&string_obstack, yytext + 1, yyleng - 2);
 303     YY_OBS_FINISH;
 304     yylval->string = last_string;
 305     return TYPE;
 306   }
 307
 308   "%%" {
 309     static int percent_percent_count;
 310     if (++percent_percent_count == 2)
 311       BEGIN SC_EPILOGUE;
 312     return PERCENT_PERCENT;
 313   }
 314
 315   . {
 316     complain_at (*yylloc, _("invalid character: %s"), quote (yytext));
 317     YY_STEP;
 318   }
 319 }
 320
 321
 322   /*---------------------------------------------------------------.
 323   | Scanning a Yacc comment.  The initial `/ *' is already eaten.  |
 324   `---------------------------------------------------------------*/
 325
 326 <SC_YACC_COMMENT>
 327 {
 328   "*/" {
 329     YY_STEP;
 330     BEGIN INITIAL;
 331   }
 332
 333   .|\n     ;
 334   <<EOF>>  unexpected_end_of_file (yylloc, "*/");
 335 }
 336
 337
 338   /*------------------------------------------------------------.
 339   | Scanning a C comment.  The initial `/ *' is already eaten.  |
 340   `------------------------------------------------------------*/
 341
 342 <SC_COMMENT>
 343 {
 344   "*"{splice}"/"  YY_OBS_GROW; BEGIN c_context;
 345   <<EOF>>         unexpected_end_of_file (yylloc, "*/");
 346 }
 347
 348
 349   /*--------------------------------------------------------------.
 350   | Scanning a line comment.  The initial `//' is already eaten.  |
 351   `--------------------------------------------------------------*/
 352
 353 <SC_LINE_COMMENT>
 354 {
 355   "\n"           YY_OBS_GROW; BEGIN c_context;
 356   {splice}       YY_OBS_GROW;
 357   <<EOF>>        BEGIN c_context;
 358 }
 359
 360
 361   /*----------------------------------------------------------------.
 362   | Scanning a C string, including its escapes.  The initial `"' is |
 363   | already eaten.                                                  |
 364   `----------------------------------------------------------------*/
 365
 366 <SC_ESCAPED_STRING>
 367 {
 368   "\"" {
 369     YY_OBS_GROW;
 370     YY_OBS_FINISH;
 371     yylval->string = last_string;
 372     rule_length++;
 373     BEGIN INITIAL;
 374     return STRING;
 375   }
 376
 377   .|\n      YY_OBS_GROW;
 378   <<EOF>>   unexpected_end_of_file (yylloc, "\"");
 379 }
 380
 381   /*---------------------------------------------------------------.
 382   | Scanning a C character, decoding its escapes.  The initial "'" |
 383   | is already eaten.                                              |
 384   `---------------------------------------------------------------*/
 385
 386 <SC_ESCAPED_CHARACTER>
 387 {
 388   "'" {
 389     YY_OBS_GROW;
 390     YY_OBS_FINISH;
 391     yylval->symbol = symbol_get (last_string, *yylloc);
 392     symbol_class_set (yylval->symbol, token_sym, *yylloc);
 393     symbol_user_token_number_set (yylval->symbol,
 394                                   (unsigned char) last_string[1], *yylloc);
 395     YY_OBS_FREE;
 396     rule_length++;
 397     BEGIN INITIAL;
 398     return ID;
 399   }
 400
 401   .|\n      YY_OBS_GROW;
 402   <<EOF>>   unexpected_end_of_file (yylloc, "'");
 403 }
 404
 405
 406   /*----------------------------.
 407   | Decode escaped characters.  |
 408   `----------------------------*/
 409
 410 <SC_ESCAPED_STRING,SC_ESCAPED_CHARACTER>
 411 {
 412   \\[0-7]{1,3} {
 413     unsigned long c = strtoul (yytext + 1, 0, 8);
 414     if (UCHAR_MAX < c)
 415       {
 416         complain_at (*yylloc, _("invalid escape sequence: %s"),
 417                      quote (yytext));
 418         YY_STEP;
 419       }
 420     else
 421       obstack_1grow (&string_obstack, c);
 422   }
 423
 424   \\x[0-9a-fA-F]+ {
 425     unsigned long c;
 426     errno = 0;
 427     c = strtoul (yytext + 2, 0, 16);
 428     if (UCHAR_MAX < c || errno)
 429       {
 430         complain_at (*yylloc, _("invalid escape sequence: %s"),
 431                      quote (yytext));
 432         YY_STEP;
 433       }
 434     else
 435       obstack_1grow (&string_obstack, c);
 436   }
 437
 438   \\a   obstack_1grow (&string_obstack, '\a');
 439   \\b   obstack_1grow (&string_obstack, '\b');
 440   \\f   obstack_1grow (&string_obstack, '\f');
 441   \\n   obstack_1grow (&string_obstack, '\n');
 442   \\r   obstack_1grow (&string_obstack, '\r');
 443   \\t   obstack_1grow (&string_obstack, '\t');
 444   \\v   obstack_1grow (&string_obstack, '\v');
 445   \\[\"\'?\\]  obstack_1grow (&string_obstack, yytext[1]);
 446   \\(u|U[0-9a-fA-F]{4})[0-9a-fA-F]{4} {
 447     int c = convert_ucn_to_byte (yytext);
 448     if (c < 0)
 449       {
 450         complain_at (*yylloc, _("invalid escape sequence: %s"),
 451                      quote (yytext));
 452         YY_STEP;
 453       }
 454     else
 455       obstack_1grow (&string_obstack, c);
 456   }
 457   \\(.|\n)      {
 458     complain_at (*yylloc, _("unrecognized escape sequence: %s"),
 459                  quote (yytext));
 460     YY_OBS_GROW;
 461   }
 462 }
 463
 464
 465   /*----------------------------------------------------------.
 466   | Scanning a C character without decoding its escapes.  The |
 467   | initial "'" is already eaten.                             |
 468   `----------------------------------------------------------*/
 469
 470 <SC_CHARACTER>
 471 {
 472   "'"               YY_OBS_GROW; BEGIN c_context;
 473   \\{splice}[\'\\]  YY_OBS_GROW;
 474   <<EOF>>           unexpected_end_of_file (yylloc, "'");
 475 }
 476
 477
 478   /*----------------------------------------------------------------.
 479   | Scanning a C string, without decoding its escapes.  The initial |
 480   | `"' is already eaten.                                           |
 481   `----------------------------------------------------------------*/
 482
 483 <SC_STRING>
 484 {
 485   "\""              YY_OBS_GROW; BEGIN c_context;
 486   \\{splice}[\"\\]  YY_OBS_GROW;
 487   <<EOF>>           unexpected_end_of_file (yylloc, "\"");
 488 }
 489
 490
 491   /*---------------------------------------------------.
 492   | Strings, comments etc. can be found in user code.  |
 493   `---------------------------------------------------*/
 494
 495 <SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE>
 496 {
 497   "'"             YY_OBS_GROW; c_context = YY_START; BEGIN SC_CHARACTER;
 498   "\""            YY_OBS_GROW; c_context = YY_START; BEGIN SC_STRING;
 499   "/"{splice}"*"  YY_OBS_GROW; c_context = YY_START; BEGIN SC_COMMENT;
 500   "/"{splice}"/"  YY_OBS_GROW; c_context = YY_START; BEGIN SC_LINE_COMMENT;
 501 }
 502
 503
 504   /*---------------------------------------------------------------.
 505   | Scanning some code in braces (%union and actions). The initial |
 506   | "{" is already eaten.                                          |
 507   `---------------------------------------------------------------*/
 508
 509 <SC_BRACED_CODE>
 510 {
 511   "{"|"<"{splice}"%"  YY_OBS_GROW; braces_level++;
 512   "%"{splice}">"      YY_OBS_GROW; braces_level--;
 513   "}" {
 514     YY_OBS_GROW;
 515     braces_level--;
 516     if (braces_level < 0)
 517       {
 518         YY_OBS_FINISH;
 519         yylval->string = last_string;
 520         rule_length++;
 521         BEGIN INITIAL;
 522         return BRACED_CODE;
 523       }
 524   }
 525
 526   /* Tokenize `<<%' correctly (as `<<' `%') rather than incorrrectly
 527      (as `<' `<%').  */
 528   "<"{splice}"<"  YY_OBS_GROW;
 529
 530   "$"("<"{tag}">")?(-?[0-9]+|"$") { handle_dollar (current_braced_code,
 531                                                    yytext, *yylloc); }
 532   "@"(-?[0-9]+|"$")               { handle_at (current_braced_code,
 533                                                yytext, *yylloc); }
 534
 535   <<EOF>>  unexpected_end_of_file (yylloc, "}");
 536 }
 537
 538
 539   /*--------------------------------------------------------------.
 540   | Scanning some prologue: from "%{" (already scanned) to "%}".  |
 541   `--------------------------------------------------------------*/
 542
 543 <SC_PROLOGUE>
 544 {
 545   "%}" {
 546     YY_OBS_FINISH;
 547     yylval->string = last_string;
 548     BEGIN INITIAL;
 549     return PROLOGUE;
 550   }
 551
 552   <<EOF>>  unexpected_end_of_file (yylloc, "%}");
 553 }
 554
 555
 556   /*---------------------------------------------------------------.
 557   | Scanning the epilogue (everything after the second "%%", which |
 558   | has already been eaten).                                       |
 559   `---------------------------------------------------------------*/
 560
 561 <SC_EPILOGUE>
 562 {
 563   <<EOF>> {
 564     YY_OBS_FINISH;
 565     yylval->string = last_string;
 566     BEGIN INITIAL;
 567     return EPILOGUE;
 568   }
 569 }
 570
 571
 572   /*----------------------------------------------------------------.
 573   | By default, grow the string obstack with the input, escaping M4 |
 574   | quoting characters.                                             |
 575   `----------------------------------------------------------------*/
 576
 577 <SC_COMMENT,SC_LINE_COMMENT,SC_STRING,SC_CHARACTER,SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE>
 578 {
 579   \$    obstack_sgrow (&string_obstack, "$][");
 580   \@    obstack_sgrow (&string_obstack, "@@");
 581   \[    obstack_sgrow (&string_obstack, "@{");
 582   \]    obstack_sgrow (&string_obstack, "@}");
 583   .|\n  YY_OBS_GROW;
 584 }
 585
 586
 587 %%
 588
 589 /*------------------------------------------------------------------.
 590 | TEXT is pointing to a wannabee semantic value (i.e., a `$').      |
 591 |                                                                   |
 592 | Possible inputs: $[<TYPENAME>]($|integer)                         |
 593 |                                                                   |
 594 | Output to the STRING_OBSTACK a reference to this semantic value.  |
 595 `------------------------------------------------------------------*/
 596
 597 static inline void
 598 handle_action_dollar (char *text, location_t location)
 599 {
 600   const char *type_name = NULL;
 601   char *cp = text + 1;
 602
 603   /* Get the type name if explicit. */
 604   if (*cp == '<')
 605     {
 606       type_name = ++cp;
 607       while (*cp != '>')
 608         ++cp;
 609       *cp = '\0';
 610       ++cp;
 611     }
 612
 613   if (*cp == '$')
 614     {
 615       if (!type_name)
 616         type_name = symbol_list_n_type_name_get (current_rule, location, 0);
 617       if (!type_name && typed)
 618         complain_at (location, _("$$ of `%s' has no declared type"),
 619                      current_rule->sym->tag);
 620       if (!type_name)
 621         type_name = "";
 622       obstack_fgrow1 (&string_obstack,
 623                       "]b4_lhs_value([%s])[", type_name);
 624     }
 625   else
 626     {
 627       long num;
 628       errno = 0;
 629       num = strtol (cp, 0, 10);
 630
 631       if (INT_MIN <= num && num <= rule_length && ! errno)
 632         {
 633           int n = num;
 634           if (!type_name && n > 0)
 635             type_name = symbol_list_n_type_name_get (current_rule, location,
 636                                                      n);
 637           if (!type_name && typed)
 638             complain_at (location, _("$%d of `%s' has no declared type"),
 639                       n, current_rule->sym->tag);
 640           if (!type_name)
 641             type_name = "";
 642           obstack_fgrow3 (&string_obstack,
 643                           "]b4_rhs_value([%d], [%d], [%s])[",
 644                           rule_length, n, type_name);
 645         }
 646       else
 647         complain_at (location, _("integer out of range: %s"), quote (text));
 648     }
 649 }
 650
 651
 652 /*---------------------------------------------------------------.
 653 | TEXT is expected to be $$ in some code associated to a symbol: |
 654 | destructor or printer.                                         |
 655 `---------------------------------------------------------------*/
 656
 657 static inline void
 658 handle_symbol_code_dollar (char *text, location_t location)
 659 {
 660   char *cp = text + 1;
 661   if (*cp == '$')
 662     obstack_sgrow (&string_obstack, "]b4_dollar_dollar[");
 663   else
 664     complain_at (location, _("invalid value: %s"), quote (text));
 665 }
 666
 667
 668 /*-----------------------------------------------------------------.
 669 | Dispatch onto handle_action_dollar, or handle_destructor_dollar, |
 670 | depending upon CODE_KIND.                                        |
 671 `-----------------------------------------------------------------*/
 672
 673 static void
 674 handle_dollar (braced_code_t braced_code_kind,
 675                char *text, location_t location)
 676 {
 677   switch (braced_code_kind)
 678     {
 679     case action_braced_code:
 680       handle_action_dollar (text, location);
 681       break;
 682
 683     case destructor_braced_code:
 684     case printer_braced_code:
 685       handle_symbol_code_dollar (text, location);
 686       break;
 687     }
 688 }
 689
 690
 691 /*------------------------------------------------------.
 692 | TEXT is a location token (i.e., a `@...').  Output to |
 693 | STRING_OBSTACK a reference to this location.          |
 694 `------------------------------------------------------*/
 695
 696 static inline void
 697 handle_action_at (char *text, location_t location)
 698 {
 699   char *cp = text + 1;
 700   locations_flag = 1;
 701
 702   if (*cp == '$')
 703     {
 704       obstack_sgrow (&string_obstack, "]b4_lhs_location[");
 705     }
 706   else
 707     {
 708       long num;
 709       errno = 0;
 710       num = strtol (cp, 0, 10);
 711
 712       if (INT_MIN <= num && num <= rule_length && ! errno)
 713         {
 714           int n = num;
 715           obstack_fgrow2 (&string_obstack, "]b4_rhs_location([%d], [%d])[",
 716                           rule_length, n);
 717         }
 718       else
 719         complain_at (location, _("integer out of range: %s"), quote (text));
 720     }
 721 }
 722
 723
 724 /*---------------------------------------------------------------.
 725 | TEXT is expected to be @$ in some code associated to a symbol: |
 726 | destructor or printer.                                         |
 727 `---------------------------------------------------------------*/
 728
 729 static inline void
 730 handle_symbol_code_at (char *text, location_t location)
 731 {
 732   char *cp = text + 1;
 733   if (*cp == '$')
 734     obstack_sgrow (&string_obstack, "]b4_at_dollar[");
 735   else
 736     complain_at (location, _("invalid value: %s"), quote (text));
 737 }
 738
 739
 740 /*-------------------------------------------------------------------.
 741 | Dispatch onto handle_action_at, or handle_destructor_at, depending |
 742 | upon CODE_KIND.                                                    |
 743 `-------------------------------------------------------------------*/
 744
 745 static void
 746 handle_at (braced_code_t braced_code_kind,
 747            char *text, location_t location)
 748 {
 749   switch (braced_code_kind)
 750     {
 751     case action_braced_code:
 752       handle_action_at (text, location);
 753       break;
 754
 755     case destructor_braced_code:
 756     case printer_braced_code:
 757       handle_symbol_code_at (text, location);
 758       break;
 759     }
 760 }
 761
 762
 763 /*------------------------------------------------------------------.
 764 | Convert universal character name UCN to a single-byte character,  |
 765 | and return that character.  Return -1 if UCN does not correspond  |
 766 | to a single-byte character.                                       |
 767 `------------------------------------------------------------------*/
 768
 769 static int
 770 convert_ucn_to_byte (char const *ucn)
 771 {
 772   unsigned long code = strtoul (ucn + 2, 0, 16);
 773
 774   /* FIXME: Currently we assume Unicode-compatible unibyte characters
 775      on ASCII hosts (i.e., Latin-1 on hosts with 8-bit bytes).  On
 776      non-ASCII hosts we support only the portable C character set.
 777      These limitations should be removed once we add support for
 778      multibyte characters.  */
 779
 780   if (UCHAR_MAX < code)
 781     return -1;
 782
 783 #if ! ('$' == 0x24 && '@' == 0x40 && '`' == 0x60 && '~' == 0x7e)
 784   {
 785     /* A non-ASCII host.  Use CODE to index into a table of the C
 786        basic execution character set, which is guaranteed to exist on
 787        all Standard C platforms.  This table also includes '$', '@',
 788        and '`', which are not in the basic execution character set but
 789        which are unibyte characters on all the platforms that we know
 790        about.  */
 791     static signed char const table[] =
 792       {
 793         '\0',   -1,   -1,   -1,   -1,   -1,   -1, '\a',
 794         '\b', '\t', '\n', '\v', '\f', '\r',   -1,   -1,
 795           -1,   -1,   -1,   -1,   -1,   -1,   -1,   -1,
 796           -1,   -1,   -1,   -1,   -1,   -1,   -1,   -1,
 797          ' ',  '!',  '"',  '#',  '$',  '%',  '&', '\'',
 798          '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
 799          '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
 800          '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
 801          '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
 802          'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
 803          'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
 804          'X',  'Y',  'Z',  '[', '\\',  ']',  '^',  '_',
 805          '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
 806          'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
 807          'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
 808          'x',  'y',  'z',  '{',  '|',  '}',  '~'
 809       };
 810
 811     code = code < sizeof table ? table[code] : -1;
 812   }
 813 #endif
 814
 815   return code;
 816 }
 817
 818
 819 /*----------------------------------------------------------------.
 820 | Handle `#line INT "FILE"'.  ARGS has already skipped `#line '.  |
 821 `----------------------------------------------------------------*/
 822
 823 static void
 824 handle_syncline (char *args, location_t *location)
 825 {
 826   int lineno = strtol (args, &args, 10);
 827   const char *file = NULL;
 828   file = strchr (args, '"') + 1;
 829   *strchr (file, '"') = 0;
 830   /* FIXME: Leaking...  Can't free, as some locations are still
 831      pointing to the old file name.  */
 832   infile = xstrdup (file);
 833   location->file = infile;
 834   location->last_line = lineno;
 835 }
 836
 837
 838 /*-------------------------------------------------------------.
 839 | Report an unexpected end of file at LOC.  An end of file was |
 840 | encountered and the expected TOKEN_END was missing.  After   |
 841 | reporting the problem, pretend that TOKEN_END was found.     |
 842 `-------------------------------------------------------------*/
 843
 844 static void
 845 unexpected_end_of_file (location_t *loc, char const *token_end)
 846 {
 847   size_t i = strlen (token_end);
 848
 849   complain_at (*loc, _("missing `%s' at end of file"), token_end);
 850
 851   /* Adjust location's last column so that any later message does not
 852      mention the characters just inserted.  */
 853   loc->last_column -= i;
 854
 855   while (i != 0)
 856     unput (token_end[--i]);
 857 }
 858
 859
 860 /*-------------------------.
 861 | Initialize the scanner.  |
 862 `-------------------------*/
 863
 864 void
 865 scanner_initialize (void)
 866 {
 867   obstack_init (&string_obstack);
 868 }
 869
 870
 871 /*-----------------------------------------------.
 872 | Free all the memory allocated to the scanner.  |
 873 `-----------------------------------------------*/
 874
 875 void
 876 scanner_free (void)
 877 {
 878   obstack_free (&string_obstack, 0);
 879   /* Reclaim Flex's buffers.  */
 880   yy_delete_buffer (YY_CURRENT_BUFFER);
 881 }