src/scan-skel.l

   1                                                              /* -*- C -*- */
   2 /* Scan Bison Skeletons.
   3    Copyright (C) 2001  Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    Bison is free software; you can redistribute it and/or modify it
   8    under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2, or (at your option)
  10    any later version.
  11
  12    Bison is distributed in the hope that it will be useful, but
  13    WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with Bison; see the file COPYING.  If not, write to the Free
  19    Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20    02111-1307, USA.  */
  21
  22 %option debug nodefault noyywrap nounput
  23 %option prefix="skel_" outfile="lex.yy.c"
  24
  25 /* If we enable
  26
  27    %option yylineno
  28
  29    Then we have warning: `yy_flex_realloc' defined but not used.
  30    Seems like a Flex bug to me: Why the heck yylineno would trigger
  31    the REJECT exception???  */
  32
  33 %{
  34 #include "system.h"
  35 #include "skeleton.h"
  36 #include "parse-skel.h"
  37 %}
  38
  39 %{
  40 /* Each time we match a string, move the end cursor to its end. */
  41 #define YY_USER_ACTION  yylloc->last_column += yyleng;
  42 %}
  43 %%
  44 %{
  45   /* At each yylex invocation, mark the current position as the
  46      start of the next token.  */
  47   LOCATION_STEP (*yylloc);
  48 %}
  49
  50 "%%{line}"          { return LINE; }
  51 "%%{skeleton-line}" { return SLINE; }
  52
  53 "%%{yacc}"    { return YACC; }
  54 "%%{section}" { return SECTION; }
  55
  56 "%%{guards}"   { return GUARDS; }
  57 "%%{actions}"  { return ACTIONS; }
  58 "%%{tokendef}" { return TOKENS; }
  59
  60   /* Muscle.  */
  61 "%%{"[a-zA-Z][0-9a-zA-Z_-]+"}" {
  62   yylval->string = xstrndup (yytext + 3, yyleng - 4);
  63   return MUSCLE;
  64 }
  65
  66   /* String.  */
  67 "%%\"".*"\"" {
  68   yylval->string = xstrndup (yytext + 3, yyleng - 4);
  69   return STRING;
  70 }
  71
  72   /* End of line.  */
  73 "\n" {
  74   LOCATION_LINES (*yylloc, yyleng);
  75   return '\n';
  76 }
  77
  78   /* White spaces.  */
  79 [\t ]+ {
  80   yylval->string = yytext;
  81   return BLANKS;
  82 }
  83
  84   /* Plain Characters.  */
  85 [^%\n]+ {
  86   yylval->string = yytext;
  87   return RAW;
  88 }
  89
  90   /* Plain Character.  */
  91 . {
  92   yylval->character = *yytext;
  93   return CHARACTER;
  94 }
  95
  96 %%