tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4 # Copyright (C) 2003-2010 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 # We want a recent Autotest.
  20 m4_version_prereq([2.58])
  21
  22
  23 ## ------------- ##
  24 ## Basic tests.  ##
  25 ## ------------- ##
  26
  27 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  28 # ------------------------------------------
  29 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  30 # taken in "slurp" mode, i.e., one can match end-of-lines.
  31 m4_define([AT_MATCHES_CHECK],
  32 [AT_CHECK([perl -0777 -ne '
  33 my $count = 0;
  34 s{$2}{ ++$count; "" }gem;
  35 printf "$count\n";' $1], [0], [$3
  36 ])])
  37
  38
  39 ## ------------------------------- ##
  40 ## Macros decoding Bison options.  ##
  41 ## ------------------------------- ##
  42
  43
  44 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  45 # -----------------------------------------
  46 m4_define([AT_BISON_OPTION_PUSHDEFS],
  47 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  48
  49
  50 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  51 # --------------------------------------------------
  52 # This macro works around the impossibility to define macros
  53 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  54 # This sucks hard, GNU M4 should really provide M5 like $$1.
  55 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  56 [m4_if([$1$2], $[1]$[2], [],
  57        [m4_fatal([$0: Invalid arguments: $@])])dnl
  58 m4_pushdef([AT_DEFINES_IF],
  59 [m4_bmatch([$3], [%defines], [$1], [$2])])
  60 m4_pushdef([AT_SKEL_CC_IF],
  61 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  62 m4_pushdef([AT_GLR_IF],
  63 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  64 m4_pushdef([AT_LALR1_CC_IF],
  65 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  66 m4_pushdef([AT_GLR_CC_IF],
  67 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  68 # Using yacc.c?
  69 m4_pushdef([AT_YACC_IF],
  70 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  71 m4_pushdef([AT_LEXPARAM_IF],
  72 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  73 m4_pushdef([AT_LOCATION_IF],
  74 [m4_bmatch([$3], [%locations], [$1], [$2])])
  75 m4_pushdef([AT_LOCATION_TYPE_IF],
  76 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
  77 m4_pushdef([AT_PARAM_IF],
  78 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  79 m4_pushdef([AT_PURE_IF],
  80 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
  81            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
  82            [$2])])
  83 m4_pushdef([AT_PURE_AND_LOC_IF],
  84 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
  85 m4_pushdef([AT_GLR_OR_PARAM_IF],
  86 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
  87 m4_pushdef([AT_NAME_PREFIX],
  88 [m4_bmatch([$3], [%name-prefix ".*"],
  89            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
  90            [yy])])
  91 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
  92 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
  93 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
  94                     [$2])])
  95 # yyerror always sees the locations (when activated), except if
  96 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
  97 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
  98 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
  99                                         [$1])],
 100                             [$1])],
 101                 [$2])])
 102
 103 # The interface is pure: either because %define api.pure, or because we
 104 # are using the C++ parsers.
 105 m4_pushdef([AT_PURE_LEX_IF],
 106 [AT_PURE_IF([$1],
 107             [AT_SKEL_CC_IF([$1], [$2])])])
 108
 109 AT_PURE_LEX_IF(
 110 [m4_pushdef([AT_LOC], [(*llocp)])
 111  m4_pushdef([AT_VAL], [(*lvalp)])
 112  m4_pushdef([AT_LEX_FORMALS],
 113             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 114  m4_pushdef([AT_LEX_ARGS],
 115             [lvalp[]AT_LOCATION_IF([, llocp])])
 116  m4_pushdef([AT_USE_LEX_ARGS],
 117             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 118  m4_pushdef([AT_LEX_PRE_FORMALS],
 119             [AT_LEX_FORMALS, ])
 120  m4_pushdef([AT_LEX_PRE_ARGS],
 121             [AT_LEX_ARGS, ])
 122 ],
 123 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 124  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 125  m4_pushdef([AT_LEX_FORMALS],     [void])
 126  m4_pushdef([AT_LEX_ARGS],        [])
 127  m4_pushdef([AT_USE_LEX_ARGS],    [])
 128  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 129  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 130 ])
 131 ])# _AT_BISON_OPTION_PUSHDEFS
 132
 133
 134 # AT_BISON_OPTION_POPDEFS
 135 # -----------------------
 136 m4_define([AT_BISON_OPTION_POPDEFS],
 137 [m4_popdef([AT_LEX_PRE_ARGS])
 138 m4_popdef([AT_LEX_PRE_FORMALS])
 139 m4_popdef([AT_USE_LEX_ARGS])
 140 m4_popdef([AT_LEX_ARGS])
 141 m4_popdef([AT_LEX_FORMALS])
 142 m4_popdef([AT_VAL])
 143 m4_popdef([AT_LOC])
 144 m4_popdef([AT_PURE_LEX_IF])
 145 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 146 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 147 m4_popdef([AT_NAME_PREFIX])
 148 m4_popdef([AT_GLR_OR_PARAM_IF])
 149 m4_popdef([AT_PURE_AND_LOC_IF])
 150 m4_popdef([AT_LOCATION_TYPE_IF])
 151 m4_popdef([AT_LOCATION_IF])
 152 m4_popdef([AT_PARAM_IF])
 153 m4_popdef([AT_LEXPARAM_IF])
 154 m4_popdef([AT_YACC_IF])
 155 m4_popdef([AT_GLR_IF])
 156 m4_popdef([AT_SKEL_CC_IF])
 157 m4_popdef([AT_GLR_CC_IF])
 158 m4_popdef([AT_LALR1_CC_IF])
 159 m4_popdef([AT_DEFINES_IF])
 160 ])# AT_BISON_OPTION_POPDEFS
 161
 162
 163
 164 ## -------------------------- ##
 165 ## Generating Grammar Files.  ##
 166 ## -------------------------- ##
 167
 168 # AT_DATA_SOURCE_PROLOGUE
 169 # ------------------------
 170 # The prologue that should be included in any source code that is
 171 # meant to be compiled.
 172 m4_define([AT_DATA_SOURCE_PROLOGUE],
 173 [[#include <config.h>
 174 /* We don't need perfect functions for these tests. */
 175 #undef malloc
 176 #undef memcmp
 177 #undef realloc
 178 ]])
 179
 180 # AT_DATA_GRAMMAR_PROLOGUE
 181 # ------------------------
 182 # The prologue that should be included in any grammar which parser is
 183 # meant to be compiled.
 184 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 185 [[%code top {
 186 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 187 [}
 188 ]])
 189
 190 # AT_DATA_SOURCE(NAME, CONTENT)
 191 # -----------------------------
 192 # Generate the file NAME, which CONTENT is preceded by
 193 # AT_DATA_SOURCE_PROLOGUE.
 194 m4_define([AT_DATA_SOURCE],
 195 [AT_DATA([$1],
 196 [AT_DATA_SOURCE_PROLOGUE
 197 $2])
 198 ])
 199
 200 # AT_DATA_GRAMMAR(NAME, CONTENT)
 201 # ------------------------------
 202 # Generate the file NAME, which CONTENT is preceded by
 203 # AT_DATA_GRAMMAR_PROLOGUE.
 204 m4_define([AT_DATA_GRAMMAR],
 205 [AT_DATA([$1],
 206 [AT_DATA_GRAMMAR_PROLOGUE
 207 $2])
 208 ])
 209
 210 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 211 # -------------------------------------------------
 212 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 213 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 214 #
 215 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 216 # Bison in the test suite.  For now it ensures that:
 217 #
 218 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 219 #      a non-zero exit status since Bison doesn't always try to free all memory
 220 #      in that case.
 221 #
 222 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 223 #      --graph and --report=all output for every working grammar.
 224 m4_define([AT_BISON_CHECK],
 225 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 226        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 227 AT_BISON_CHECK_NO_XML($@)])
 228
 229 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 230 # --------------------------------------------------------
 231 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 232 # when a tortured grammar's XML is known to be too large for xsltproc to
 233 # handle.
 234 m4_define([AT_BISON_CHECK_NO_XML],
 235 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 236                 [AT_QUELL_VALGRIND ])[[bison ]]$@)])
 237
 238 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 239 # -----------------------------------------------------
 240 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 241 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 242 # have a non-zero exit status.
 243 m4_define([AT_BISON_CHECK_XML],
 244 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 245   mkdir xml-tests]
 246   m4_pushdef([AT_BISON_ARGS],
 247              [m4_bpatsubsts([[$1]],
 248                             [--report(-file)?=[^][ ]*], [],
 249                             [--graph=[^][ ]*], [],
 250                             [--xml=[^][ ]*], [])])dnl
 251   # Don't combine these Bison invocations since we want to be sure that
 252   # --report=all isn't required to get the full XML file.
 253   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 254              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 255            [[0]], [ignore], [ignore])
 256   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 257            [[0]], [ignore], [ignore])
 258   m4_popdef([AT_BISON_ARGS])dnl
 259   [cp xml-tests/test.output expout]
 260   AT_CHECK([[$XSLTPROC \
 261              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 262              xml-tests/test.xml]], [[0]], [expout])
 263   [cp xml-tests/test.dot expout]
 264   AT_CHECK([[$XSLTPROC \
 265              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 266              xml-tests/test.xml]], [[0]], [expout])
 267   [rm -rf xml-tests expout
 268 fi]])
 269
 270 # AT_QUELL_VALGRIND
 271 # -----------------
 272 # Put this before a Bison invocation to keep Valgrind from complaining about
 273 # reachable memory.
 274 #
 275 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 276 # The triple quoting below will cause test cases to fail if you do.  If you do
 277 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 278 # will then fail to shell-escape its contents when attempting to print them.
 279 # The testsuite verbose output, at least, will be incorrect, but nothing may
 280 # fail to make sure you notice.
 281 m4_define([AT_QUELL_VALGRIND],
 282 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 283
 284 ## ------------------------ ##
 285 ## Compiling C, C++ Files.  ##
 286 ## ------------------------ ##
 287
 288
 289 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 290 # ----------------------------------------
 291 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 292 # assume that we are linking too; this is a hack.
 293 m4_define([AT_COMPILE],
 294 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 295            0, [ignore], [ignore])])
 296
 297 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 298 # --------------------------------------------
 299 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 300 # assume that we are linking too; this is a hack.
 301 # If the C++ compiler does not work, ignore the test.
 302 m4_define([AT_COMPILE_CXX],
 303 [AT_KEYWORDS(c++)
 304 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 305 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 306          0, [ignore], [ignore])])
 307
 308
 309 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 310 # --------------------------------
 311 # Compile OUTPUT.y to OUTPUT.c or OUTPUT.cc, and compile it to OUTPUT.
 312 # If OTHER is specified, compile OUTPUT-OTHER.c or OUTPUT-OTHER.cc to OUTPUT
 313 # along with it.
 314 # Relies on AT_SKEL_CC_IF.
 315 m4_define([AT_FULL_COMPILE],
 316 [AT_SKEL_CC_IF(
 317   [AT_BISON_CHECK([-o $1.cc $1.y])
 318    AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1.cc $1-$2.cc]]))],
 319   [AT_BISON_CHECK([-o $1.c $1.y])
 320    AT_COMPILE([$1]m4_ifval($2, [, [$1.c $1-$2.c]]))])
 321 ])
 322
 323
 324 ## ---------------------------- ##
 325 ## Running a generated parser.  ##
 326 ## ---------------------------- ##
 327
 328 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 329 # ------------------------------------------------------------
 330 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 331 m4_define([AT_PARSER_CHECK],
 332 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 333
 334 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 335 #                          DECLS, GRAMMAR, INPUT,
 336 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 337 #                          [OTHER-CHECKS],
 338 #                          [PARSER-EXIT-VALUE],
 339 #                          [PARSER-STDOUT], [PARSER-STDERR])
 340 # -------------------------------------------------------------
 341 # Using TITLE as the test group title, check the generated parser tables
 342 # and parser for a specified grammar file under a condition labeled by
 343 # COND-VALUE.
 344 #
 345 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 346 # recognized attribute is described below where it is relevant.
 347 #
 348 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 349 # the grammar file.  Insert basic yyerror, yylex, and main function
 350 # definitions as well.  Hardcode yylex to return the (possibly empty)
 351 # comma-delimited series of tokens in INPUT followed by token 0.
 352 #
 353 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 354 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 355 # On the bison command-line, specify `--report=all --defines'.  Check
 356 # that Bison exits with value 0, has no stdout, and has stderr
 357 # BISON-STDERR.
 358 #
 359 # If TEST-SPEC contains the attribute `last-state', check that the value
 360 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 361 # the grammar; in other words, check the number of states (minus one).
 362 # Otherwise, check that everything in the `.output' file starting with
 363 # the definition of state 0 is the same as the entire value of
 364 # TABLES-OR-LAST-STATE.
 365 #
 366 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 367 # `.output' file, which is named `input.output', and/or grammar file,
 368 # which is named `input.y'.
 369 #
 370 # Finally, compile the generated parser and then run it using
 371 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 372 # PARSER-STDERR as the 2nd-4th arguments.
 373 #
 374 # As a precondition, you must properly double-quote all arguments that
 375 # are to be interpreted as strings.
 376 #
 377 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 378 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 379 # first argument.  This is useful, for example, when wrapping multiple
 380 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 381 # condition, in another macro.
 382 #
 383 # For example:
 384 #
 385 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 386 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 387 #   # ---------------------------------------------------------------------
 388 #   m4_define([AT_TEST_SYNTAX_ERROR],
 389 #   [
 390 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 391 #                              [[last-state]],
 392 #                              [[%error-verbose ]$2], [$3], [$4],
 393 #                              [[]], [$5], [], [$6], [$7], [$8])
 394 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 395 #                              [[last-state]],
 396 #                              [$2], [$3], [$4],
 397 #                              [[]], [$5], [], [$6], [$7], [$8])
 398 #   ])
 399 #
 400 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 401 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 402 #                        [[3]],
 403 #                        [[1]], [[]],
 404 #                        [AT_COND_CASE([[no verbose]],
 405 #                                      [[syntax error
 406 #   ]],
 407 #                                      [[syntax error, unexpected 'b', expecting $end
 408 #   ]])])
 409 m4_define([AT_TEST_TABLES_AND_PARSE],
 410 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 411
 412 AT_SETUP([$1])
 413
 414 AT_DATA_GRAMMAR([[input.y]],
 415 [[%code {
 416   #include <stdio.h>
 417   static void yyerror (char const *msg);
 418   static int yylex (void);
 419 }
 420
 421 ]$4[
 422
 423 %%
 424
 425 ]$5[
 426
 427 %%
 428
 429 static void
 430 yyerror (char const *msg)
 431 {
 432   fprintf (stderr, "%s\n", msg);
 433 }
 434
 435 static int
 436 yylex (void)
 437 {
 438   static int const input[] = {
 439     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 440   };
 441   static int const *inputp = input;
 442   return *inputp++;
 443 }
 444
 445 int
 446 main (void)
 447 {
 448   return yyparse ();
 449 }
 450 ]])
 451
 452 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 453 # expanding macros, so it corrupts some special characters in the
 454 # macros.  To avoid this, expand now and pass it the result with proper
 455 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 456 # strings.
 457
 458 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 459       [AT_BISON_CHECK],
 460       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 461                                [0], [], m4_dquote($7))
 462
 463 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 464       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 465                 m4_dquote($8))],
 466       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 467                 m4_dquote($8)[[
 468 ]])])
 469
 470 $9
 471
 472 AT_COMPILE([[input]])
 473
 474 AT_PARSER_CHECK([[./input]],
 475                 m4_ifval([$10], [m4_dquote($10)]),
 476                 m4_ifval([$11], [m4_dquote($11)]),
 477                 m4_ifval([$12], [m4_dquote($12)]))
 478
 479 AT_CLEANUP
 480
 481 m4_popdef([AT_COND_CASE])])
 482
 483
 484
 485 ## ----------------------- ##
 486 ## Launch the test suite.  ##
 487 ## ----------------------- ##
 488
 489 AT_INIT
 490
 491 AT_TESTED([bison])