src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002-2012 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software: you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation, either version 3 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  19
  20 #include <config.h>
  21 #include "system.h"
  22
  23 #include "complain.h"
  24 #include "conflicts.h"
  25 #include "files.h"
  26 #include "getargs.h"
  27 #include "gram.h"
  28 #include "muscle-tab.h"
  29 #include "named-ref.h"
  30 #include "quotearg.h"
  31 #include "reader.h"
  32 #include "symlist.h"
  33 #include "symtab.h"
  34 #include "scan-gram.h"
  35 #include "scan-code.h"
  36 #include "xmemdup0.h"
  37
  38 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  39 static YYLTYPE lloc_default (YYLTYPE const *, int);
  40
  41 #define YY_LOCATION_PRINT(File, Loc) \
  42           location_print (File, Loc)
  43
  44 static void version_check (location const *loc, char const *version);
  45
  46 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  47    FIXME: depends on the undocumented availability of YYLLOC.  */
  48 #undef  yyerror
  49 #define yyerror(Msg) \
  50         gram_error (&yylloc, Msg)
  51 static void gram_error (location const *, char const *);
  52
  53 static char const *char_name (char);
  54 %}
  55
  56 %code
  57 {
  58   static int current_prec = 0;
  59   static location current_lhs_location;
  60   static named_ref *current_lhs_named_ref;
  61   static symbol *current_lhs_symbol;
  62   static symbol_class current_class = unknown_sym;
  63   static uniqstr current_type = NULL;
  64
  65   /** Set the new current left-hand side symbol, possibly common
  66    * to several right-hand side parts of rule.
  67    */
  68   static
  69   void
  70   current_lhs(symbol *sym, location loc, named_ref *ref)
  71   {
  72     current_lhs_symbol = sym;
  73     current_lhs_location = loc;
  74     /* In order to simplify memory management, named references for lhs
  75        are always assigned by deep copy into the current symbol_list
  76        node.  This is because a single named-ref in the grammar may
  77        result in several uses when the user factors lhs between several
  78        rules using "|".  Therefore free the parser's original copy.  */
  79     free (current_lhs_named_ref);
  80     current_lhs_named_ref = ref;
  81   }
  82
  83   #define YYTYPE_INT16 int_fast16_t
  84   #define YYTYPE_INT8 int_fast8_t
  85   #define YYTYPE_UINT16 uint_fast16_t
  86   #define YYTYPE_UINT8 uint_fast8_t
  87 }
  88
  89 %debug
  90 %verbose
  91 %defines
  92 %locations
  93 %pure-parser
  94 %define parse.error "verbose"
  95 %define parse.lac full
  96 %name-prefix="gram_"
  97 %expect 0
  98
  99 %initial-action
 100 {
 101   /* Bison's grammar can initial empty locations, hence a default
 102      location is needed. */
 103   boundary_set (&@$.start, current_file, 1, 1);
 104   boundary_set (&@$.end, current_file, 1, 1);
 105 }
 106
 107 %union
 108 {
 109   assoc assoc;
 110   char *code;
 111   char const *chars;
 112   int integer;
 113   named_ref *named_ref;
 114   symbol *symbol;
 115   symbol_list *list;
 116   uniqstr uniqstr;
 117   unsigned char character;
 118 };
 119
 120 /* Define the tokens together with their human representation.  */
 121 %token GRAM_EOF 0 "end of file"
 122 %token STRING     "string"
 123 %token INT        "integer"
 124
 125 %token PERCENT_TOKEN       "%token"
 126 %token PERCENT_NTERM       "%nterm"
 127
 128 %token PERCENT_TYPE        "%type"
 129 %token PERCENT_DESTRUCTOR  "%destructor"
 130 %token PERCENT_PRINTER     "%printer"
 131
 132 %token PERCENT_LEFT        "%left"
 133 %token PERCENT_RIGHT       "%right"
 134 %token PERCENT_NONASSOC    "%nonassoc"
 135 %token PERCENT_PRECEDENCE  "%precedence"
 136
 137 %token PERCENT_PREC          "%prec"
 138 %token PERCENT_DPREC         "%dprec"
 139 %token PERCENT_MERGE         "%merge"
 140
 141 /*----------------------.
 142 | Global Declarations.  |
 143 `----------------------*/
 144
 145 %token
 146   PERCENT_CODE            "%code"
 147   PERCENT_DEFAULT_PREC    "%default-prec"
 148   PERCENT_DEFINE          "%define"
 149   PERCENT_DEFINES         "%defines"
 150   PERCENT_ERROR_VERBOSE   "%error-verbose"
 151   PERCENT_EXPECT          "%expect"
 152   PERCENT_EXPECT_RR       "%expect-rr"
 153   PERCENT_FLAG            "%<flag>"
 154   PERCENT_FILE_PREFIX     "%file-prefix"
 155   PERCENT_GLR_PARSER      "%glr-parser"
 156   PERCENT_INITIAL_ACTION  "%initial-action"
 157   PERCENT_LANGUAGE        "%language"
 158   PERCENT_NAME_PREFIX     "%name-prefix"
 159   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 160   PERCENT_NO_LINES        "%no-lines"
 161   PERCENT_NONDETERMINISTIC_PARSER
 162                           "%nondeterministic-parser"
 163   PERCENT_OUTPUT          "%output"
 164   PERCENT_REQUIRE         "%require"
 165   PERCENT_SKELETON        "%skeleton"
 166   PERCENT_START           "%start"
 167   PERCENT_TOKEN_TABLE     "%token-table"
 168   PERCENT_VERBOSE         "%verbose"
 169   PERCENT_YACC            "%yacc"
 170 ;
 171
 172 %token BRACED_CODE     "{...}"
 173 %token BRACED_PREDICATE "%?{...}"
 174 %token BRACKETED_ID    "[identifier]"
 175 %token CHAR            "char"
 176 %token EPILOGUE        "epilogue"
 177 %token EQUAL           "="
 178 %token ID              "identifier"
 179 %token ID_COLON        "identifier:"
 180 %token PERCENT_PERCENT "%%"
 181 %token PIPE            "|"
 182 %token PROLOGUE        "%{...%}"
 183 %token SEMICOLON       ";"
 184 %token TAG             "<tag>"
 185 %token TAG_ANY         "<*>"
 186 %token TAG_NONE        "<>"
 187
 188 %type <character> CHAR
 189 %printer { fputs (char_name ($$), yyo); } CHAR
 190
 191 /* braceless is not to be used for rule or symbol actions, as it
 192    calls code_props_plain_init.  */
 193 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 194 %type <code> "{...}" "%?{...}"
 195 %printer { fputs (quotearg_style (c_quoting_style, $$), yyo); }
 196          STRING
 197 %printer { fprintf (yyo, "{\n%s\n}", $$); }
 198          braceless content.opt "{...}" "%{...%}" EPILOGUE
 199
 200 %type <uniqstr> BRACKETED_ID ID ID_COLON PERCENT_FLAG TAG tag variable
 201 %printer { fputs ($$, yyo); } <uniqstr>
 202 %printer { fprintf (yyo, "[%s]", $$); } BRACKETED_ID
 203 %printer { fprintf (yyo, "%s:", $$); } ID_COLON
 204 %printer { fprintf (yyo, "%%%s", $$); } PERCENT_FLAG
 205 %printer { fprintf (yyo, "<%s>", $$); } TAG tag
 206
 207 %type <integer> INT
 208 %printer { fprintf (yyo, "%d", $$); } <integer>
 209
 210 %type <symbol> id id_colon string_as_id symbol symbol.prec
 211 %printer { fprintf (yyo, "%s", $$->tag); } <symbol>
 212 %printer { fprintf (yyo, "%s:", $$->tag); } id_colon
 213
 214 %type <assoc> precedence_declarator
 215 %type <list>  symbols.1 symbols.prec generic_symlist generic_symlist_item
 216 %type <named_ref> named_ref.opt
 217
 218 /*---------.
 219 | %param.  |
 220 `---------*/
 221 %code requires
 222 {
 223 # ifndef PARAM_TYPE
 224 #  define PARAM_TYPE
 225   typedef enum
 226   {
 227     param_none   = 0,
 228     param_lex    = 1 << 0,
 229     param_parse  = 1 << 1,
 230     param_both   = param_lex | param_parse
 231   } param_type;
 232 # endif
 233 };
 234 %code
 235 {
 236   /** Add a lex-param and/or a parse-param.
 237    *
 238    * \param type  where to push this formal argument.
 239    * \param decl  the formal argument.  Destroyed.
 240    * \param loc   the location in the source.
 241    */
 242   static void add_param (param_type type, char *decl, location loc);
 243   static param_type current_param = param_none;
 244 };
 245 %union
 246 {
 247   param_type param;
 248 }
 249 %token <param> PERCENT_PARAM "%param";
 250 %printer
 251 {
 252   switch ($$)
 253     {
 254 #define CASE(In, Out)                                           \
 255       case param_ ## In: fputs ("%" #Out, stderr); break
 256       CASE(lex,   lex-param);
 257       CASE(parse, parse-param);
 258       CASE(both,  param);
 259 #undef CASE
 260       case param_none: aver (false); break;
 261     }
 262 } <param>;
 263
 264
 265                      /*==========\
 266                      | Grammar.  |
 267                      \==========*/
 268 %%
 269
 270 input:
 271   prologue_declarations "%%" grammar epilogue.opt
 272 ;
 273
 274
 275         /*------------------------------------.
 276         | Declarations: before the first %%.  |
 277         `------------------------------------*/
 278
 279 prologue_declarations:
 280   /* Nothing */
 281 | prologue_declarations prologue_declaration
 282 ;
 283
 284 prologue_declaration:
 285   grammar_declaration
 286 | "%{...%}"
 287     {
 288       code_props plain_code;
 289       code_props_plain_init (&plain_code, $1, @1);
 290       code_props_translate_code (&plain_code);
 291       gram_scanner_last_string_free ();
 292       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 293                         plain_code.code, @1);
 294       code_scanner_last_string_free ();
 295     }
 296 | "%<flag>"
 297     {
 298       muscle_percent_define_ensure ($1, @1, true);
 299     }
 300 | "%define" variable content.opt
 301     {
 302       muscle_percent_define_insert ($2, @2, $3,
 303                                     MUSCLE_PERCENT_DEFINE_GRAMMAR_FILE);
 304     }
 305 | "%defines"                       { defines_flag = true; }
 306 | "%defines" STRING
 307     {
 308       defines_flag = true;
 309       spec_defines_file = xstrdup ($2);
 310     }
 311 | "%error-verbose"
 312     {
 313       muscle_percent_define_insert ("parse.error", @1, "verbose",
 314                                     MUSCLE_PERCENT_DEFINE_GRAMMAR_FILE);
 315     }
 316 | "%expect" INT                    { expected_sr_conflicts = $2; }
 317 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 318 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 319 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 320 | "%glr-parser"
 321     {
 322       nondeterministic_parser = true;
 323       glr_parser = true;
 324     }
 325 | "%initial-action" "{...}"
 326     {
 327       code_props action;
 328       code_props_symbol_action_init (&action, $2, @2);
 329       code_props_translate_code (&action);
 330       gram_scanner_last_string_free ();
 331       muscle_code_grow ("initial_action", action.code, @2);
 332       code_scanner_last_string_free ();
 333     }
 334 | "%language" STRING            { language_argmatch ($2, grammar_prio, @1); }
 335 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 336 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 337 | "%no-lines"                   { no_lines_flag = true; }
 338 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 339 | "%output" STRING              { spec_outfile = $2; }
 340 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 341 | "%param" { current_param = $1; } params { current_param = param_none; }
 342 | "%require" STRING             { version_check (&@2, $2); }
 343 | "%skeleton" STRING
 344     {
 345       char const *skeleton_user = $2;
 346       if (strchr (skeleton_user, '/'))
 347         {
 348           size_t dir_length = strlen (current_file);
 349           char *skeleton_build;
 350           while (dir_length && current_file[dir_length - 1] != '/')
 351             --dir_length;
 352           while (dir_length && current_file[dir_length - 1] == '/')
 353             --dir_length;
 354           skeleton_build =
 355             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 356           if (dir_length > 0)
 357             {
 358               memcpy (skeleton_build, current_file, dir_length);
 359               skeleton_build[dir_length++] = '/';
 360             }
 361           strcpy (skeleton_build + dir_length, skeleton_user);
 362           skeleton_user = uniqstr_new (skeleton_build);
 363           free (skeleton_build);
 364         }
 365       skeleton_arg (skeleton_user, grammar_prio, @1);
 366     }
 367 | "%token-table"                { token_table_flag = true; }
 368 | "%verbose"                    { report_flag |= report_states; }
 369 | "%yacc"                       { yacc_flag = true; }
 370 | /*FIXME: Err?  What is this horror doing here? */ ";"
 371 ;
 372
 373 params:
 374    params "{...}"  { add_param (current_param, $2, @2); }
 375 | "{...}"          { add_param (current_param, $1, @1); }
 376 ;
 377
 378
 379 /*----------------------.
 380 | grammar_declaration.  |
 381 `----------------------*/
 382
 383 grammar_declaration:
 384   precedence_declaration
 385 | symbol_declaration
 386 | "%start" symbol
 387     {
 388       grammar_start_symbol_set ($2, @2);
 389     }
 390 | code_props_type "{...}" generic_symlist
 391     {
 392       code_props code;
 393       code_props_symbol_action_init (&code, $2, @2);
 394       code_props_translate_code (&code);
 395       {
 396         symbol_list *list;
 397         for (list = $3; list; list = list->next)
 398           symbol_list_code_props_set (list, $1, &code);
 399         symbol_list_free ($3);
 400       }
 401     }
 402 | "%default-prec"
 403     {
 404       default_prec = true;
 405     }
 406 | "%no-default-prec"
 407     {
 408       default_prec = false;
 409     }
 410 | "%code" braceless
 411     {
 412       /* Do not invoke muscle_percent_code_grow here since it invokes
 413          muscle_user_name_list_grow.  */
 414       muscle_code_grow ("percent_code()", $2, @2);
 415       code_scanner_last_string_free ();
 416     }
 417 | "%code" ID braceless
 418     {
 419       muscle_percent_code_grow ($2, @2, $3, @3);
 420       code_scanner_last_string_free ();
 421     }
 422 ;
 423
 424 %type <code_type> code_props_type;
 425 %union {code_props_type code_type;};
 426 %printer { fprintf (yyo, "%s", code_props_type_string ($$)); } <code_type>;
 427 code_props_type:
 428   "%destructor"  { $$ = destructor; }
 429 | "%printer"     { $$ = printer; }
 430 ;
 431
 432 /*---------.
 433 | %union.  |
 434 `---------*/
 435
 436 %token PERCENT_UNION "%union";
 437
 438 union_name:
 439   /* Nothing. */ {}
 440 | ID             { muscle_code_grow ("union_name", $1, @1); }
 441 ;
 442
 443 grammar_declaration:
 444   "%union" union_name braceless
 445     {
 446       union_seen = true;
 447       muscle_code_grow ("stype", $3, @3);
 448       code_scanner_last_string_free ();
 449     }
 450 ;
 451
 452
 453
 454
 455 symbol_declaration:
 456   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 457     {
 458       current_class = unknown_sym;
 459       current_type = NULL;
 460     }
 461 | "%token" { current_class = token_sym; } symbol_defs.1
 462     {
 463       current_class = unknown_sym;
 464       current_type = NULL;
 465     }
 466 | "%type" TAG symbols.1
 467     {
 468       symbol_list *list;
 469       tag_seen = true;
 470       for (list = $3; list; list = list->next)
 471         symbol_type_set (list->content.sym, $2, @2);
 472       symbol_list_free ($3);
 473     }
 474 ;
 475
 476 precedence_declaration:
 477   precedence_declarator tag.opt symbols.prec
 478     {
 479       symbol_list *list;
 480       ++current_prec;
 481       for (list = $3; list; list = list->next)
 482         {
 483           symbol_type_set (list->content.sym, current_type, @2);
 484           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 485         }
 486       symbol_list_free ($3);
 487       current_type = NULL;
 488     }
 489 ;
 490
 491 precedence_declarator:
 492   "%left"       { $$ = left_assoc; }
 493 | "%right"      { $$ = right_assoc; }
 494 | "%nonassoc"   { $$ = non_assoc; }
 495 | "%precedence" { $$ = precedence_assoc; }
 496 ;
 497
 498 tag.opt:
 499   /* Nothing. */ { current_type = NULL; }
 500 | TAG            { current_type = $1; tag_seen = true; }
 501 ;
 502
 503 /* Just like symbols.1 but accept INT for the sake of POSIX.  */
 504 symbols.prec:
 505   symbol.prec
 506     { $$ = symbol_list_sym_new ($1, @1); }
 507 | symbols.prec symbol.prec
 508     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 509 ;
 510
 511 symbol.prec:
 512   symbol     { $$ = $1; }
 513 | symbol INT { $$ = $1; symbol_user_token_number_set ($1, $2, @2); }
 514 ;
 515
 516 /* One or more symbols to be %typed. */
 517 symbols.1:
 518   symbol
 519     { $$ = symbol_list_sym_new ($1, @1); }
 520 | symbols.1 symbol
 521     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 522 ;
 523
 524 generic_symlist:
 525   generic_symlist_item { $$ = $1; }
 526 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 527 ;
 528
 529 generic_symlist_item:
 530   symbol    { $$ = symbol_list_sym_new ($1, @1); }
 531 | tag       { $$ = symbol_list_type_new ($1, @1); }
 532 ;
 533
 534 tag:
 535   TAG
 536 | "<*>" { $$ = uniqstr_new ("*"); }
 537 | "<>"  { $$ = uniqstr_new (""); }
 538 ;
 539
 540 /* One token definition.  */
 541 symbol_def:
 542   TAG
 543      {
 544        current_type = $1;
 545        tag_seen = true;
 546      }
 547 | id
 548      {
 549        symbol_class_set ($1, current_class, @1, true);
 550        symbol_type_set ($1, current_type, @1);
 551      }
 552 | id INT
 553     {
 554       symbol_class_set ($1, current_class, @1, true);
 555       symbol_type_set ($1, current_type, @1);
 556       symbol_user_token_number_set ($1, $2, @2);
 557     }
 558 | id string_as_id
 559     {
 560       symbol_class_set ($1, current_class, @1, true);
 561       symbol_type_set ($1, current_type, @1);
 562       symbol_make_alias ($1, $2, @$);
 563     }
 564 | id INT string_as_id
 565     {
 566       symbol_class_set ($1, current_class, @1, true);
 567       symbol_type_set ($1, current_type, @1);
 568       symbol_user_token_number_set ($1, $2, @2);
 569       symbol_make_alias ($1, $3, @$);
 570     }
 571 ;
 572
 573 /* One or more symbol definitions. */
 574 symbol_defs.1:
 575   symbol_def
 576 | symbol_defs.1 symbol_def
 577 ;
 578
 579
 580         /*------------------------------------------.
 581         | The grammar section: between the two %%.  |
 582         `------------------------------------------*/
 583
 584 grammar:
 585   rules_or_grammar_declaration
 586 | grammar rules_or_grammar_declaration
 587 ;
 588
 589 /* As a Bison extension, one can use the grammar declarations in the
 590    body of the grammar.  */
 591 rules_or_grammar_declaration:
 592   rules
 593 | grammar_declaration ";"
 594 | error ";"
 595     {
 596       yyerrok;
 597     }
 598 ;
 599
 600 rules:
 601   id_colon named_ref.opt { current_lhs ($1, @1, $2); } rhses.1
 602   {
 603     /* Free the current lhs. */
 604     current_lhs (0, @1, 0);
 605   }
 606 ;
 607
 608 rhses.1:
 609   rhs                { grammar_current_rule_end (@1); }
 610 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 611 | rhses.1 ";"
 612 ;
 613
 614 rhs:
 615   /* Nothing.  */
 616     { grammar_current_rule_begin (current_lhs_symbol, current_lhs_location,
 617                                   current_lhs_named_ref); }
 618 | rhs symbol named_ref.opt
 619     { grammar_current_rule_symbol_append ($2, @2, $3); }
 620 | rhs "{...}" named_ref.opt
 621     { grammar_current_rule_action_append ($2, @2, $3, false); }
 622 | rhs "%?{...}"
 623     { grammar_current_rule_action_append ($2, @2, NULL, true); }
 624 | rhs "%prec" symbol
 625     { grammar_current_rule_prec_set ($3, @3); }
 626 | rhs "%dprec" INT
 627     { grammar_current_rule_dprec_set ($3, @3); }
 628 | rhs "%merge" TAG
 629     { grammar_current_rule_merge_set ($3, @3); }
 630 ;
 631
 632 named_ref.opt:
 633   /* Nothing. */ { $$ = 0; }
 634 |
 635   BRACKETED_ID   { $$ = named_ref_new($1, @1); }
 636 ;
 637
 638 /*---------------------------.
 639 | variable and content.opt.  |
 640 `---------------------------*/
 641
 642 /* The STRING form of variable is deprecated and is not M4-friendly.
 643    For example, M4 fails for `%define "[" "value"'.  */
 644 variable:
 645   ID
 646 | STRING { $$ = uniqstr_new ($1); }
 647 ;
 648
 649 /* Some content or empty by default. */
 650 content.opt:
 651   /* Nothing. */   { $$ = ""; }
 652 | ID { $$ = $1; }
 653 | STRING
 654 ;
 655
 656
 657 /*------------.
 658 | braceless.  |
 659 `------------*/
 660
 661 braceless:
 662   "{...}"
 663     {
 664       code_props plain_code;
 665       $1[strlen ($1) - 1] = '\n';
 666       code_props_plain_init (&plain_code, $1+1, @1);
 667       code_props_translate_code (&plain_code);
 668       gram_scanner_last_string_free ();
 669       $$ = plain_code.code;
 670     }
 671 ;
 672
 673
 674 /*--------------.
 675 | Identifiers.  |
 676 `--------------*/
 677
 678 /* Identifiers are returned as uniqstr values by the scanner.
 679    Depending on their use, we may need to make them genuine symbols.  */
 680
 681 id:
 682   ID
 683     { $$ = symbol_from_uniqstr ($1, @1); }
 684 | CHAR
 685     {
 686       $$ = symbol_get (char_name ($1), @1);
 687       symbol_class_set ($$, token_sym, @1, false);
 688       symbol_user_token_number_set ($$, $1, @1);
 689     }
 690 ;
 691
 692 id_colon:
 693   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 694 ;
 695
 696
 697 symbol:
 698   id
 699 | string_as_id
 700 ;
 701
 702 /* A string used as an ID: quote it.  */
 703 string_as_id:
 704   STRING
 705     {
 706       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 707       symbol_class_set ($$, token_sym, @1, false);
 708     }
 709 ;
 710
 711 epilogue.opt:
 712   /* Nothing.  */
 713 | "%%" EPILOGUE
 714     {
 715       code_props plain_code;
 716       code_props_plain_init (&plain_code, $2, @2);
 717       code_props_translate_code (&plain_code);
 718       gram_scanner_last_string_free ();
 719       muscle_code_grow ("epilogue", plain_code.code, @2);
 720       code_scanner_last_string_free ();
 721     }
 722 ;
 723
 724 %%
 725
 726
 727 /* Return the location of the left-hand side of a rule whose
 728    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 729    the right-hand side, and return an empty location equal to the end
 730    boundary of RHS[0] if the right-hand side is empty.  */
 731
 732 static YYLTYPE
 733 lloc_default (YYLTYPE const *rhs, int n)
 734 {
 735   int i;
 736   YYLTYPE loc;
 737
 738   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 739      The bug is fixed in 7.4.2m, but play it safe for now.  */
 740   loc.start = rhs[n].end;
 741   loc.end = rhs[n].end;
 742
 743   /* Ignore empty nonterminals the start of the right-hand side.
 744      Do not bother to ignore them at the end of the right-hand side,
 745      since empty nonterminals have the same end as their predecessors.  */
 746   for (i = 1; i <= n; i++)
 747     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 748       {
 749         loc.start = rhs[i].start;
 750         break;
 751       }
 752
 753   return loc;
 754 }
 755
 756
 757 static void
 758 add_param (param_type type, char *decl, location loc)
 759 {
 760   static char const alphanum[26 + 26 + 1 + 10] =
 761     "abcdefghijklmnopqrstuvwxyz"
 762     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 763     "_"
 764     "0123456789";
 765
 766   char const *name_start = NULL;
 767   {
 768     char *p;
 769     /* Stop on last actual character.  */
 770     for (p = decl; p[1]; p++)
 771       if ((p == decl
 772            || ! memchr (alphanum, p[-1], sizeof alphanum))
 773           && memchr (alphanum, p[0], sizeof alphanum - 10))
 774         name_start = p;
 775
 776     /* Strip the surrounding '{' and '}', and any blanks just inside
 777        the braces.  */
 778     --p;
 779     while (isspace ((unsigned char) *p))
 780       --p;
 781     p[1] = '\0';
 782     ++decl;
 783     while (isspace ((unsigned char) *decl))
 784       ++decl;
 785   }
 786
 787   if (! name_start)
 788     complain_at (loc, complaint,
 789                  _("missing identifier in parameter declaration"));
 790   else
 791     {
 792       char *name = xmemdup0 (name_start, strspn (name_start, alphanum));
 793       if (type & param_lex)
 794         muscle_pair_list_grow ("lex_param", decl, name);
 795       if (type & param_parse)
 796         muscle_pair_list_grow ("parse_param", decl, name);
 797       free (name);
 798     }
 799
 800   gram_scanner_last_string_free ();
 801 }
 802
 803
 804 static void
 805 version_check (location const *loc, char const *version)
 806 {
 807   if (strverscmp (version, PACKAGE_VERSION) > 0)
 808     {
 809       complain_at (*loc, complaint, "require bison %s, but have %s",
 810                    version, PACKAGE_VERSION);
 811       exit (EX_MISMATCH);
 812     }
 813 }
 814
 815 static void
 816 gram_error (location const *loc, char const *msg)
 817 {
 818   complain_at (*loc, complaint, "%s", msg);
 819 }
 820
 821 char const *
 822 token_name (int type)
 823 {
 824   return yytname[YYTRANSLATE (type)];
 825 }
 826
 827 static char const *
 828 char_name (char c)
 829 {
 830   if (c == '\'')
 831     return "'\\''";
 832   else
 833     {
 834       char buf[4];
 835       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 836       return quotearg_style (escape_quoting_style, buf);
 837     }
 838 }