tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # We want a recent Autotest.
  21 m4_version_prereq([2.58])
  22
  23
  24 ## ------------- ##
  25 ## Basic tests.  ##
  26 ## ------------- ##
  27
  28 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  29 # ------------------------------------------
  30 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  31 # taken in "slurp" mode, i.e., one can match end-of-lines.
  32 m4_define([AT_MATCHES_CHECK],
  33 [AT_CHECK([perl -0777 -ne '
  34 my $count = 0;
  35 s{$2}{ ++$count; "" }gem;
  36 printf "$count\n";' $1], [0], [$3
  37 ])])
  38
  39
  40 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  41 # ------------------------------------------------
  42 # Don't interfere with caller's files.
  43 m4_divert_text([PREPARE_TESTS],
  44 [at_save_special_files ()
  45 {
  46   for at_save_file in stderr experr expout
  47   do
  48     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  49   done
  50 }
  51
  52 at_restore_special_files ()
  53 {
  54   for at_save_file in stderr experr expout
  55   do
  56     test ! -f at-bison-check-$at_save_file.bak ||
  57       mv at-bison-check-$at_save_file.bak $at_save_file
  58   done
  59 }
  60 ])
  61
  62 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  63 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  64
  65
  66
  67 ## ------------------------------- ##
  68 ## Macros decoding Bison options.  ##
  69 ## ------------------------------- ##
  70
  71 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  72 # ----------------------------------------------------------------
  73 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  74 m4_define([AT_LOC_PUSHDEF],
  75 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  76 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  77 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  78 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  79
  80 # AT_LOC_POPDEF
  81 # -------------
  82 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  83 m4_define([AT_LOC_POPDEF],
  84 [m4_popdef([AT_LOC_FIRST_LINE])
  85 m4_popdef([AT_LOC_FIRST_COLUMN])
  86 m4_popdef([AT_LOC_LAST_LINE])
  87 m4_popdef([AT_LOC_LAST_COLUMN])])
  88
  89
  90
  91 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  92 # -----------------------------------------
  93 m4_define([AT_BISON_OPTION_PUSHDEFS],
  94 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  95
  96
  97 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  98 # --------------------------------------------------
  99 # This macro works around the impossibility to define macros
 100 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 101 # This sucks hard, GNU M4 should really provide M5-like $$1.
 102 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 103 [m4_if([$1$2], $[1]$[2], [],
 104        [m4_fatal([$0: Invalid arguments: $@])])dnl
 105 m4_pushdef([AT_DEFINES_IF],
 106 [m4_bmatch([$3], [%defines], [$1], [$2])])
 107 m4_pushdef([AT_SKEL_CC_IF],
 108 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 109 m4_pushdef([AT_SKEL_JAVA_IF],
 110 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 111 m4_pushdef([AT_GLR_IF],
 112 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
 113 m4_pushdef([AT_LALR1_CC_IF],
 114 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 115 m4_pushdef([AT_GLR_CC_IF],
 116 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 117 # Using yacc.c?
 118 m4_pushdef([AT_YACC_IF],
 119 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 120 m4_pushdef([AT_LEXPARAM_IF],
 121 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 122 m4_pushdef([AT_LOCATION_IF],
 123 [m4_bmatch([$3], [%locations], [$1], [$2])])
 124 m4_pushdef([AT_LOCATION_TYPE_IF],
 125 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
 126 m4_pushdef([AT_PARAM_IF],
 127 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 128 m4_pushdef([AT_PURE_IF],
 129 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 130            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 131            [$2])])
 132 m4_pushdef([AT_PURE_AND_LOC_IF],
 133 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 134 m4_pushdef([AT_GLR_OR_PARAM_IF],
 135 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 136 m4_pushdef([AT_NAME_PREFIX],
 137 [m4_bmatch([$3], [%name-prefix ".*"],
 138            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
 139            [yy])])
 140 m4_pushdef([AT_TOKEN_PREFIX],
 141 [m4_bmatch([$3], [%define api.tokens.prefix ".*"],
 142            [m4_bregexp([$3], [%define api.tokens.prefix "\(.*\)"], [\1])])])
 143 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 144 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 145 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 146                     [$2])])
 147 # yyerror always sees the locations (when activated), except if
 148 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 149 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 150 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 151                                         [$1])],
 152                             [$1])],
 153                 [$2])])
 154
 155 # The interface is pure: either because %define api.pure, or because we
 156 # are using the C++ parsers.
 157 m4_pushdef([AT_PURE_LEX_IF],
 158 [AT_PURE_IF([$1],
 159             [AT_SKEL_CC_IF([$1], [$2])])])
 160
 161 AT_PURE_LEX_IF(
 162 [m4_pushdef([AT_LOC], [(*llocp)])
 163  m4_pushdef([AT_VAL], [(*lvalp)])
 164  m4_pushdef([AT_LEX_FORMALS],
 165             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 166  m4_pushdef([AT_LEX_ARGS],
 167             [lvalp[]AT_LOCATION_IF([, llocp])])
 168  m4_pushdef([AT_USE_LEX_ARGS],
 169             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 170  m4_pushdef([AT_LEX_PRE_FORMALS],
 171             [AT_LEX_FORMALS, ])
 172  m4_pushdef([AT_LEX_PRE_ARGS],
 173             [AT_LEX_ARGS, ])
 174 ],
 175 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 176  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 177  m4_pushdef([AT_LEX_FORMALS],     [void])
 178  m4_pushdef([AT_LEX_ARGS],        [])
 179  m4_pushdef([AT_USE_LEX_ARGS],    [])
 180  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 181  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 182 ])
 183
 184 # Handle the different types of location components.
 185
 186 AT_SKEL_CC_IF(
 187   [AT_LOCATION_TYPE_IF(
 188     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 189     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 190   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 191
 192
 193 AT_GLR_IF([AT_KEYWORDS([glr])])
 194 ])# _AT_BISON_OPTION_PUSHDEFS
 195
 196
 197 # AT_BISON_OPTION_POPDEFS
 198 # -----------------------
 199 m4_define([AT_BISON_OPTION_POPDEFS],
 200 [m4_popdef([AT_LEX_PRE_ARGS])
 201 m4_popdef([AT_LEX_PRE_FORMALS])
 202 m4_popdef([AT_USE_LEX_ARGS])
 203 m4_popdef([AT_LEX_ARGS])
 204 m4_popdef([AT_LEX_FORMALS])
 205 m4_popdef([AT_VAL])
 206 m4_popdef([AT_LOC])
 207 m4_popdef([AT_PURE_LEX_IF])
 208 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 209 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 210 m4_popdef([AT_NAME_PREFIX])
 211 m4_popdef([AT_GLR_OR_PARAM_IF])
 212 m4_popdef([AT_PURE_AND_LOC_IF])
 213 m4_popdef([AT_LOCATION_TYPE_IF])
 214 m4_popdef([AT_LOCATION_IF])
 215 m4_popdef([AT_PARAM_IF])
 216 m4_popdef([AT_LEXPARAM_IF])
 217 m4_popdef([AT_YACC_IF])
 218 m4_popdef([AT_GLR_IF])
 219 m4_popdef([AT_SKEL_CC_IF])
 220 m4_popdef([AT_SKEL_JAVA_IF])
 221 m4_popdef([AT_GLR_CC_IF])
 222 m4_popdef([AT_LALR1_CC_IF])
 223 m4_popdef([AT_DEFINES_IF])
 224 AT_LOC_POPDEF
 225 ])# AT_BISON_OPTION_POPDEFS
 226
 227
 228
 229 ## -------------------------- ##
 230 ## Generating Grammar Files.  ##
 231 ## -------------------------- ##
 232
 233 # AT_DATA_SOURCE_PROLOGUE
 234 # ------------------------
 235 # The prologue that should be included in any source code that is
 236 # meant to be compiled.
 237 m4_define([AT_DATA_SOURCE_PROLOGUE],
 238 [[#include <config.h>
 239 /* We don't need perfect functions for these tests. */
 240 #undef malloc
 241 #undef memcmp
 242 #undef realloc
 243 ]])
 244
 245 # AT_DATA_GRAMMAR_PROLOGUE
 246 # ------------------------
 247 # The prologue that should be included in any grammar which parser is
 248 # meant to be compiled.
 249 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 250 [[%code top {
 251 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 252 [}
 253 ]])
 254
 255 # AT_DATA_SOURCE(NAME, CONTENT)
 256 # -----------------------------
 257 # Generate the file NAME, which CONTENT is preceded by
 258 # AT_DATA_SOURCE_PROLOGUE.
 259 m4_define([AT_DATA_SOURCE],
 260 [AT_DATA([$1],
 261 [AT_DATA_SOURCE_PROLOGUE
 262 $2])
 263 ])
 264
 265 # AT_DATA_GRAMMAR(NAME, CONTENT)
 266 # ------------------------------
 267 # Generate the file NAME, which CONTENT is preceded by
 268 # AT_DATA_GRAMMAR_PROLOGUE.
 269 m4_define([AT_DATA_GRAMMAR],
 270 [AT_DATA([$1],
 271 [AT_DATA_GRAMMAR_PROLOGUE
 272 $2])
 273 ])
 274
 275 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 276 # -------------------------------------------------
 277 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 278 # shell constructs (such as redirection or pipes) that would prevent
 279 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 280 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 281 #
 282 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 283 # Bison in the test suite.  For now it ensures that:
 284 #
 285 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 286 #      a non-zero exit status since Bison doesn't always try to free all memory
 287 #      in that case.
 288 #
 289 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 290 #      --graph and --report=all output for every working grammar.
 291 #
 292 #   3. If stderr contains a warning, -Werror and --warnings=error
 293 #      convert the warning to an error.
 294 #
 295 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 296 m4_define([AT_BISON_CHECK],
 297 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 298        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 299 AT_BISON_CHECK_NO_XML($@)])
 300
 301 m4_define([AT_BISON_WERROR_MSG],
 302           [[bison: warnings being treated as errors]])
 303
 304 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 305 # --------------------------------------------------------
 306 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 307 # when a tortured grammar's XML is known to be too large for xsltproc to
 308 # handle.
 309 m4_define([AT_BISON_CHECK_NO_XML],
 310 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 311                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 312 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 313       m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0], [[
 314         # Defining POSIXLY_CORRECT causes bison to complain if options
 315         # are added after the grammar file name, so skip these checks
 316         # in that case.
 317         if test -z "${POSIXLY_CORRECT+set}"; then
 318           ]AT_SAVE_SPECIAL_FILES[
 319
 320           # To avoid expanding it repeatedly, store specified stdout.
 321           ]AT_DATA([expout], [$3])[
 322
 323           # Run with -Werror.
 324           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Werror]],
 325                     [[1]], [expout], [stderr])[
 326
 327           # Build expected stderr up to and including the "warnings being
 328           # treated as errors" message.
 329           ]AT_DATA([[at-bison-check-warnings]], [$4])[
 330           at_bison_check_first=`sed -n \
 331             '/: warning: /{=;q;}' at-bison-check-warnings`
 332           : ${at_bison_check_first:=1}
 333           at_bison_check_first_tmp=`sed -n \
 334             '/conflicts: [0-9].*reduce$/{=;q;}' at-bison-check-warnings`
 335           : ${at_bison_check_first_tmp:=1}
 336           if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 337             at_bison_check_first=$at_bison_check_first_tmp
 338           fi
 339           if test $at_bison_check_first -gt 1; then
 340             sed -n "1,`expr $at_bison_check_first - 1`"p \
 341               at-bison-check-warnings > experr
 342           fi
 343           echo ']AT_BISON_WERROR_MSG[' >> experr
 344
 345           # Finish building expected stderr and check.  Unlike warnings,
 346           # complaints cause bison to exit early.  Thus, with -Werror, bison
 347           # does not necessarily report all warnings that it does without
 348           # -Werror, but it at least reports one.
 349           at_bison_check_last=`sed -n '$=' stderr`
 350           : ${at_bison_check_last:=1}
 351           at_bison_check_last=`expr $at_bison_check_last - 1`
 352           sed -n "$at_bison_check_first,$at_bison_check_last"p \
 353             at-bison-check-warnings >> experr
 354           ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 355                       stderr 1>&2]], [[0]], [[]], [experr])[
 356
 357           # Now check --warnings=error.
 358           cp stderr experr
 359           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=error]],
 360                     [[1]], [expout], [experr])[
 361
 362           # Now check -Wnone and --warnings=none by making sure that
 363           # -Werror doesn't change the exit status when -Wnone or
 364           # --warnings=none is specified.
 365           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Wnone -Werror]],
 366                     [[0]], [expout])[
 367           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=none \
 368                     -Werror]], [[0]], [expout])[
 369
 370           ]AT_RESTORE_SPECIAL_FILES[
 371         fi
 372       ]])
 373 ])
 374
 375 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 376 # -----------------------------------------------------
 377 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 378 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 379 # have a non-zero exit status.
 380 m4_define([AT_BISON_CHECK_XML],
 381 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 382   AT_SAVE_SPECIAL_FILES
 383   [mkdir xml-tests]
 384   m4_pushdef([AT_BISON_ARGS],
 385              [m4_bpatsubsts([[$1]],
 386                             [--report(-file)?=[^][ ]*], [],
 387                             [--graph=[^][ ]*], [],
 388                             [--xml=[^][ ]*], [])])dnl
 389   # Don't combine these Bison invocations since we want to be sure that
 390   # --report=all isn't required to get the full XML file.
 391   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 392              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 393            [[0]], [ignore], [ignore])
 394   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 395            [[0]], [ignore], [ignore])
 396   m4_popdef([AT_BISON_ARGS])dnl
 397   [cp xml-tests/test.output expout]
 398   AT_CHECK([[$XSLTPROC \
 399              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 400              xml-tests/test.xml]], [[0]], [expout])
 401   [cp xml-tests/test.dot expout]
 402   AT_CHECK([[$XSLTPROC \
 403              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 404              xml-tests/test.xml]], [[0]], [expout])
 405   [rm -rf xml-tests expout]
 406   AT_RESTORE_SPECIAL_FILES
 407 [fi]])
 408
 409 # AT_QUELL_VALGRIND
 410 # -----------------
 411 # Put this before a Bison invocation to keep Valgrind from complaining about
 412 # reachable memory.
 413 #
 414 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 415 # The triple quoting below will cause test cases to fail if you do.  If you do
 416 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 417 # will then fail to shell-escape its contents when attempting to print them.
 418 # The testsuite verbose output, at least, will be incorrect, but nothing may
 419 # fail to make sure you notice.
 420 m4_define([AT_QUELL_VALGRIND],
 421 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 422
 423 ## ------------------------ ##
 424 ## Compiling C, C++ Files.  ##
 425 ## ------------------------ ##
 426
 427
 428 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 429 # ----------------------------------------
 430 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 431 # assume that we are linking too; this is a hack.
 432 m4_define([AT_COMPILE],
 433 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 434            0, [ignore], [ignore])])
 435
 436 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 437 # --------------------------------------------
 438 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 439 # assume that we are linking too; this is a hack.
 440 # If the C++ compiler does not work, ignore the test.
 441 m4_define([AT_COMPILE_CXX],
 442 [AT_KEYWORDS(c++)
 443 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 444 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 445          0, [ignore], [ignore])])
 446
 447 # AT_JAVA_COMPILE(SOURCES)
 448 # ------------------------
 449 # Compile SOURCES into Java class files.  Skip the test if java or javac
 450 # is not installed.
 451 m4_define([AT_JAVA_COMPILE],
 452 [AT_KEYWORDS(java)
 453 AT_CHECK([[test -n "$CONF_JAVA" || exit 77
 454            test -n "$CONF_JAVAC" || exit 77]])
 455 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 456          [[0]], [ignore], [ignore])])
 457
 458 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 459 # --------------------------------
 460 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 461 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 462 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 463 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 464 # AT_SKEL_JAVA_IF.
 465 m4_define([AT_FULL_COMPILE], [
 466   AT_SKEL_JAVA_IF([
 467     AT_BISON_CHECK([[-o ]$1[.java ]$1[.y]])
 468     AT_JAVA_COMPILE([$1[.java]]m4_ifval($2,
 469                                         [[$1[.java ]$1[-]$2[.java]]]))
 470   ], [
 471     AT_SKEL_CC_IF([
 472       AT_BISON_CHECK([[-o ]$1[.cc ]$1[.y]])
 473       AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1[.cc ]$1[-]$2[.cc]]]))
 474     ], [
 475       AT_BISON_CHECK([[-o ]$1[.c ]$1[.y]])
 476       AT_COMPILE([$1]m4_ifval($2, [, [$1[.c ]$1[-]$2[.c]]]))
 477     ])
 478   ])
 479 ])
 480
 481
 482 ## ---------------------------- ##
 483 ## Running a generated parser.  ##
 484 ## ---------------------------- ##
 485
 486
 487 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 488 # ------------------------------------------------------------
 489 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 490 #
 491 # Get rid of spurious messages when compiled with --coverage:
 492 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 493 m4_define([AT_PARSER_CHECK],
 494 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 495 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 496          [0], [], [$4])
 497 ])
 498
 499
 500 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 501 # -----------------------------------------------------------------
 502 m4_define([AT_JAVA_PARSER_CHECK],
 503 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 504
 505
 506 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 507 #                          DECLS, GRAMMAR, INPUT,
 508 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 509 #                          [OTHER-CHECKS],
 510 #                          [PARSER-EXIT-VALUE],
 511 #                          [PARSER-STDOUT], [PARSER-STDERR])
 512 # -------------------------------------------------------------
 513 # Using TITLE as the test group title, check the generated parser tables
 514 # and parser for a specified grammar file under a condition labeled by
 515 # COND-VALUE.
 516 #
 517 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 518 # recognized attribute is described below where it is relevant.
 519 #
 520 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 521 # the grammar file.  Insert basic yyerror, yylex, and main function
 522 # definitions as well.  Hardcode yylex to return the (possibly empty)
 523 # comma-delimited series of tokens in INPUT followed by token 0.
 524 #
 525 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 526 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 527 # On the bison command-line, specify `--report=all --defines'.  Check
 528 # that Bison exits with value 0, has no stdout, and has stderr
 529 # BISON-STDERR.
 530 #
 531 # If TEST-SPEC contains the attribute `last-state', check that the value
 532 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 533 # the grammar; in other words, check the number of states (minus one).
 534 # Otherwise, check that everything in the `.output' file starting with
 535 # the definition of state 0 is the same as the entire value of
 536 # TABLES-OR-LAST-STATE.
 537 #
 538 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 539 # `.output' file, which is named `input.output', and/or grammar file,
 540 # which is named `input.y'.
 541 #
 542 # Finally, compile the generated parser and then run it using
 543 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 544 # PARSER-STDERR as the 2nd-4th arguments.
 545 #
 546 # As a precondition, you must properly double-quote all arguments that
 547 # are to be interpreted as strings.
 548 #
 549 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 550 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 551 # first argument.  This is useful, for example, when wrapping multiple
 552 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 553 # condition, in another macro.
 554 #
 555 # For example:
 556 #
 557 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 558 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 559 #   # ---------------------------------------------------------------------
 560 #   m4_define([AT_TEST_SYNTAX_ERROR],
 561 #   [
 562 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 563 #                              [[last-state]],
 564 #                              [[%error-verbose ]$2], [$3], [$4],
 565 #                              [[]], [$5], [], [$6], [$7], [$8])
 566 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 567 #                              [[last-state]],
 568 #                              [$2], [$3], [$4],
 569 #                              [[]], [$5], [], [$6], [$7], [$8])
 570 #   ])
 571 #
 572 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 573 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 574 #                        [[3]],
 575 #                        [[1]], [[]],
 576 #                        [AT_COND_CASE([[no verbose]],
 577 #                                      [[syntax error
 578 #   ]],
 579 #                                      [[syntax error, unexpected 'b', expecting $end
 580 #   ]])])
 581 m4_define([AT_TEST_TABLES_AND_PARSE],
 582 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 583
 584 AT_SETUP([$1])
 585
 586 AT_DATA_GRAMMAR([[input.y]],
 587 [[%code {
 588   #include <stdio.h>
 589   static void yyerror (char const *msg);
 590   static int yylex (void);
 591 }
 592
 593 ]$4[
 594
 595 %%
 596
 597 ]$5[
 598
 599 %%
 600
 601 static void
 602 yyerror (char const *msg)
 603 {
 604   fprintf (stderr, "%s\n", msg);
 605 }
 606
 607 static int
 608 yylex (void)
 609 {
 610   static int const input[] = {
 611     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 612   };
 613   static int const *inputp = input;
 614   return *inputp++;
 615 }
 616
 617 int
 618 main (void)
 619 {
 620   return yyparse ();
 621 }
 622 ]])
 623
 624 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 625 # expanding macros, so it corrupts some special characters in the
 626 # macros.  To avoid this, expand now and pass it the result with proper
 627 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 628 # strings.
 629
 630 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 631       [AT_BISON_CHECK],
 632       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 633                                [0], [], m4_dquote($7))
 634
 635 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 636       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 637                 m4_dquote($8))],
 638       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 639                 m4_dquote($8)[[
 640 ]])])
 641
 642 $9
 643
 644 # Canonical LR generates very large tables, resulting in very long
 645 # files with #line directives that may overflow what the standards
 646 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 647 # will issue an error.
 648 #
 649 # There is no "" around `wc` since some indent the result.
 650 m4_bmatch([$4], [%define lr.type canonical-lr],
 651 [if test 32767 -lt `wc -l < input.c`; then
 652   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 653   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 654 fi])
 655 AT_COMPILE([[input]])
 656
 657 AT_PARSER_CHECK([[./input]],
 658                 m4_ifval([$10], [m4_dquote($10)]),
 659                 m4_ifval([$11], [m4_dquote($11)]),
 660                 m4_ifval([$12], [m4_dquote($12)]))
 661
 662 AT_CLEANUP
 663
 664 m4_popdef([AT_COND_CASE])])
 665
 666
 667
 668 ## ----------------------- ##
 669 ## Launch the test suite.  ##
 670 ## ----------------------- ##
 671
 672 AT_INIT
 673
 674 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 675 # options are processed, so we don't know the value of CXX and
 676 # CXXFLAGS yet.
 677 #
 678 # Note that it also means that command line values for CXX and
 679 # CXXFLAGS will not be propagated to CC and CFLAGS.
 680 AT_ARG_OPTION([compile-c-with-cxx],
 681               [compile C parsers with the C++ compiler])
 682
 683 AT_COLOR_TESTS
 684
 685 AT_TESTED([bison])