tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4 # Copyright (C) 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301, USA.
  20
  21 # We want a recent Autotest.
  22 m4_version_prereq([2.58])
  23
  24
  25 ## ------------------------------- ##
  26 ## Macros decoding Bison options.  ##
  27 ## ------------------------------- ##
  28
  29
  30 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  31 # -----------------------------------------
  32 m4_define([AT_BISON_OPTION_PUSHDEFS],
  33 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  34
  35
  36 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  37 # --------------------------------------------------
  38 # This macro works around the impossibility to define macros
  39 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  40 # This sucks hard, GNU M4 should really provide M5 like $$1.
  41 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  42 [m4_if([$1$2], $[1]$[2], [],
  43        [m4_fatal([$0: Invalid arguments: $@])])dnl
  44 m4_pushdef([AT_LALR1_CC_IF],
  45 [m4_bmatch([$3], ["lalr1.cc"], [$1], [$2])])
  46 m4_pushdef([AT_GLR_CC_IF],
  47 [m4_bmatch([$3], ["glr.cc"], [$1], [$2])])
  48 m4_pushdef([AT_SKEL_CC_IF],
  49 [m4_bmatch([$3], ["\(glr\|lalr1\).cc"], [$1], [$2])])
  50 m4_pushdef([AT_GLR_IF],
  51 [m4_bmatch([$3], [%glr-parser], [$1], [$2])])
  52 # Using yacc.c?
  53 m4_pushdef([AT_YACC_IF],
  54 [m4_bmatch([$3], [%glr-parser\|%skeleton], [$2], [$1])])
  55 m4_pushdef([AT_PARAM_IF],
  56 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  57 m4_pushdef([AT_LOCATION_IF],
  58 [m4_bmatch([$3], [%locations], [$1], [$2])])
  59 m4_pushdef([AT_PURE_IF],
  60 [m4_bmatch([$3], [%pure-parser], [$1], [$2])])
  61 m4_pushdef([AT_PUSH_IF],
  62 [m4_bmatch([$3], [%push-parser], [$1], [$2])])
  63 m4_pushdef([AT_PURE_OR_PUSH_IF],
  64 [m4_bmatch([$3], [%pure-parser\|%push-parser], [$1], [$2])])
  65 m4_pushdef([AT_PURE_AND_LOC_IF],
  66 [m4_bmatch([$3], [%locations.*%pure-parser\|%pure-parser.*%locations],
  67            [$1], [$2])])
  68 m4_pushdef([AT_GLR_OR_PARAM_IF],
  69 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
  70 m4_pushdef([AT_NAME_PREFIX],
  71 [m4_bmatch([$3], [%name-prefix ".*"],
  72            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
  73            [yy])])
  74 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
  75 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
  76 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
  77                     [$2])])
  78 # yyerror always sees the locations (when activated), except if
  79 # push or (yacc & pure & !param).
  80 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
  81 [AT_PUSH_IF([$2],[AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
  82                                         [$1])],
  83                             [$1])],
  84                 [$2])])])
  85
  86 # The interface is pure: either because %pure-parser, or because we
  87 # are using the C++ parsers.
  88 m4_pushdef([AT_PURE_LEX_IF],
  89 [AT_PURE_OR_PUSH_IF([$1],
  90             [AT_SKEL_CC_IF([$1], [$2])])])
  91
  92 AT_PURE_LEX_IF(
  93 [m4_pushdef([AT_LOC], [(*llocp)])
  94  m4_pushdef([AT_VAL], [(*lvalp)])
  95  m4_pushdef([AT_LEX_FORMALS],
  96             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
  97  m4_pushdef([AT_LEX_ARGS],
  98             [lvalp[]AT_LOCATION_IF([, llocp])])
  99  m4_pushdef([AT_USE_LEX_ARGS],
 100             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 101  m4_pushdef([AT_LEX_PRE_FORMALS],
 102             [AT_LEX_FORMALS, ])
 103  m4_pushdef([AT_LEX_PRE_ARGS],
 104             [AT_LEX_ARGS, ])
 105 ],
 106 [m4_pushdef([AT_LOC], [(yylloc)])
 107  m4_pushdef([AT_VAL], [(yylval)])
 108  m4_pushdef([AT_LEX_FORMALS],     [void])
 109  m4_pushdef([AT_LEX_ARGS],        [])
 110  m4_pushdef([AT_USE_LEX_ARGS],    [])
 111  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 112  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 113 ])
 114 ])# _AT_BISON_OPTION_PUSHDEFS
 115
 116
 117 # AT_BISON_OPTION_POPDEFS
 118 # -----------------------
 119 m4_define([AT_BISON_OPTION_POPDEFS],
 120 [m4_popdef([AT_LEX_PRE_ARGS])
 121 m4_popdef([AT_LEX_PRE_FORMALS])
 122 m4_popdef([AT_USE_LEX_ARGS])
 123 m4_popdef([AT_LEX_ARGS])
 124 m4_popdef([AT_LEX_FORMALS])
 125 m4_popdef([AT_VAL])
 126 m4_popdef([AT_LOC])
 127 m4_popdef([AT_PURE_LEX_IF])
 128 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 129 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 130 m4_popdef([AT_NAME_PREFIX])
 131 m4_popdef([AT_GLR_OR_PARAM_IF])
 132 m4_popdef([AT_PURE_AND_LOC_IF])
 133 m4_popdef([AT_LOCATION_IF])
 134 m4_popdef([AT_PARAM_IF])
 135 m4_popdef([AT_YACC_IF])
 136 m4_popdef([AT_GLR_IF])
 137 m4_popdef([AT_SKEL_CC_IF])
 138 m4_popdef([AT_GLR_CC_IF])
 139 m4_popdef([AT_LALR1_CC_IF])
 140 ])# AT_BISON_OPTION_POPDEFS
 141
 142
 143
 144 ## -------------------------- ##
 145 ## Generating Grammar Files.  ##
 146 ## -------------------------- ##
 147
 148
 149 # AT_DATA_GRAMMAR_PROLOGUE
 150 # ------------------------
 151 # The prologue that should be included in any grammar which parser is
 152 # meant to be compiled.
 153 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 154 [[%{
 155 #include <config.h>
 156 /* We don't need perfect functions for these tests. */
 157 #undef malloc
 158 #undef memcmp
 159 #undef realloc
 160 %}]
 161 ])
 162
 163
 164 # AT_DATA_GRAMMAR(NAME, CONTENT)
 165 # ------------------------------
 166 # Generate the file NAME, which CONTENT is preceded by
 167 # AT_DATA_GRAMMAR_PROLOGUE.
 168 m4_define([AT_DATA_GRAMMAR],
 169 [AT_DATA([$1],
 170 [AT_DATA_GRAMMAR_PROLOGUE
 171 $2])
 172 ])
 173
 174
 175 ## ------------------------ ##
 176 ## Compiling C, C++ Files.  ##
 177 ## ------------------------ ##
 178
 179
 180 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 181 # ----------------------------------------
 182 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 183 # assume that we are linking too; this is a hack.
 184 m4_define([AT_COMPILE],
 185 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 186            0, [ignore], [ignore])])
 187
 188 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 189 # --------------------------------------------
 190 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 191 # assume that we are linking too; this is a hack.
 192 # If the C++ compiler does not work, ignore the test.
 193 m4_define([AT_COMPILE_CXX],
 194 [AT_KEYWORDS(c++)
 195 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 196 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 197          0, [ignore], [ignore])])
 198
 199
 200
 201 ## ---------------------------- ##
 202 ## Running a generated parser.  ##
 203 ## ---------------------------- ##
 204
 205 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR)
 206 # -----------------------------------------------------
 207 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 208 m4_define([AT_PARSER_CHECK],
 209 [AT_CHECK([$PREPARSER $1], [$2], [$3], [$4])])
 210
 211
 212
 213
 214 ## ----------------------- ##
 215 ## Launch the test suite.  ##
 216 ## ----------------------- ##
 217
 218 AT_INIT
 219
 220 AT_TESTED([bison])