src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002-2012 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software: you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation, either version 3 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  19
  20 #include <config.h>
  21 #include "system.h"
  22
  23 #include "c-ctype.h"
  24 #include "complain.h"
  25 #include "conflicts.h"
  26 #include "files.h"
  27 #include "getargs.h"
  28 #include "gram.h"
  29 #include "muscle-tab.h"
  30 #include "named-ref.h"
  31 #include "quotearg.h"
  32 #include "reader.h"
  33 #include "symlist.h"
  34 #include "symtab.h"
  35 #include "scan-gram.h"
  36 #include "scan-code.h"
  37 #include "xmemdup0.h"
  38
  39 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  40 static YYLTYPE lloc_default (YYLTYPE const *, int);
  41
  42 #define YY_LOCATION_PRINT(File, Loc) \
  43           location_print (File, Loc)
  44
  45 static void version_check (location const *loc, char const *version);
  46
  47 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  48    FIXME: depends on the undocumented availability of YYLLOC.  */
  49 #undef  yyerror
  50 #define yyerror(Msg) \
  51         gram_error (&yylloc, Msg)
  52 static void gram_error (location const *, char const *);
  53
  54 static char const *char_name (char);
  55 %}
  56
  57 %code
  58 {
  59   static int current_prec = 0;
  60   static location current_lhs_location;
  61   static named_ref *current_lhs_named_ref;
  62   static symbol *current_lhs_symbol;
  63   static symbol_class current_class = unknown_sym;
  64   static uniqstr current_type = NULL;
  65
  66   /** Set the new current left-hand side symbol, possibly common
  67    * to several right-hand side parts of rule.
  68    */
  69   static
  70   void
  71   current_lhs(symbol *sym, location loc, named_ref *ref)
  72   {
  73     current_lhs_symbol = sym;
  74     current_lhs_location = loc;
  75     /* In order to simplify memory management, named references for lhs
  76        are always assigned by deep copy into the current symbol_list
  77        node.  This is because a single named-ref in the grammar may
  78        result in several uses when the user factors lhs between several
  79        rules using "|".  Therefore free the parser's original copy.  */
  80     free (current_lhs_named_ref);
  81     current_lhs_named_ref = ref;
  82   }
  83
  84   #define YYTYPE_INT16 int_fast16_t
  85   #define YYTYPE_INT8 int_fast8_t
  86   #define YYTYPE_UINT16 uint_fast16_t
  87   #define YYTYPE_UINT8 uint_fast8_t
  88 }
  89
  90 %verbose
  91 %defines
  92 %define locations
  93 %define api.pure
  94 %define parse.error verbose
  95 %define parse.lac full
  96 %define parse.trace
  97 %name-prefix "gram_"
  98 %expect 0
  99
 100 %initial-action
 101 {
 102   /* Bison's grammar can initial empty locations, hence a default
 103      location is needed. */
 104   boundary_set (&@$.start, current_file, 1, 1);
 105   boundary_set (&@$.end, current_file, 1, 1);
 106 }
 107
 108 %union
 109 {
 110   assoc assoc;
 111   char *code;
 112   char const *chars;
 113   int integer;
 114   named_ref *named_ref;
 115   symbol *symbol;
 116   symbol_list *list;
 117   uniqstr uniqstr;
 118   unsigned char character;
 119 };
 120
 121 /* Define the tokens together with their human representation.  */
 122 %token GRAM_EOF 0 "end of file"
 123 %token STRING     "string"
 124 %token INT        "integer"
 125
 126 %token PERCENT_TOKEN       "%token"
 127 %token PERCENT_NTERM       "%nterm"
 128
 129 %token PERCENT_TYPE        "%type"
 130 %token PERCENT_DESTRUCTOR  "%destructor"
 131 %token PERCENT_PRINTER     "%printer"
 132
 133 %token PERCENT_LEFT        "%left"
 134 %token PERCENT_RIGHT       "%right"
 135 %token PERCENT_NONASSOC    "%nonassoc"
 136 %token PERCENT_PRECEDENCE  "%precedence"
 137
 138 %token PERCENT_PREC          "%prec"
 139 %token PERCENT_DPREC         "%dprec"
 140 %token PERCENT_MERGE         "%merge"
 141
 142 /*----------------------.
 143 | Global Declarations.  |
 144 `----------------------*/
 145
 146 %token
 147   PERCENT_CODE            "%code"
 148   PERCENT_DEFAULT_PREC    "%default-prec"
 149   PERCENT_DEFINE          "%define"
 150   PERCENT_DEFINES         "%defines"
 151   PERCENT_ERROR_VERBOSE   "%error-verbose"
 152   PERCENT_EXPECT          "%expect"
 153   PERCENT_EXPECT_RR       "%expect-rr"
 154   PERCENT_FLAG            "%<flag>"
 155   PERCENT_FILE_PREFIX     "%file-prefix"
 156   PERCENT_GLR_PARSER      "%glr-parser"
 157   PERCENT_INITIAL_ACTION  "%initial-action"
 158   PERCENT_LANGUAGE        "%language"
 159   PERCENT_NAME_PREFIX     "%name-prefix"
 160   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 161   PERCENT_NO_LINES        "%no-lines"
 162   PERCENT_NONDETERMINISTIC_PARSER
 163                           "%nondeterministic-parser"
 164   PERCENT_OUTPUT          "%output"
 165   PERCENT_REQUIRE         "%require"
 166   PERCENT_SKELETON        "%skeleton"
 167   PERCENT_START           "%start"
 168   PERCENT_TOKEN_TABLE     "%token-table"
 169   PERCENT_VERBOSE         "%verbose"
 170   PERCENT_YACC            "%yacc"
 171 ;
 172
 173 %token BRACED_CODE     "{...}"
 174 %token BRACED_PREDICATE "%?{...}"
 175 %token BRACKETED_ID    "[identifier]"
 176 %token CHAR            "char"
 177 %token EPILOGUE        "epilogue"
 178 %token EQUAL           "="
 179 %token ID              "identifier"
 180 %token ID_COLON        "identifier:"
 181 %token PERCENT_PERCENT "%%"
 182 %token PIPE            "|"
 183 %token PROLOGUE        "%{...%}"
 184 %token SEMICOLON       ";"
 185 %token TAG             "<tag>"
 186 %token TAG_ANY         "<*>"
 187 %token TAG_NONE        "<>"
 188
 189 %type <character> CHAR
 190 %printer { fputs (char_name ($$), yyo); } CHAR
 191
 192 /* braceless is not to be used for rule or symbol actions, as it
 193    calls code_props_plain_init.  */
 194 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 195 %type <code> "{...}" "%?{...}"
 196 %printer { fputs (quotearg_style (c_quoting_style, $$), yyo); }
 197          STRING
 198 %printer { fprintf (yyo, "{\n%s\n}", $$); }
 199          braceless content.opt "{...}" "%{...%}" EPILOGUE
 200
 201 %type <uniqstr> BRACKETED_ID ID ID_COLON PERCENT_FLAG TAG tag variable
 202 %printer { fputs ($$, yyo); } <uniqstr>
 203 %printer { fprintf (yyo, "[%s]", $$); } BRACKETED_ID
 204 %printer { fprintf (yyo, "%s:", $$); } ID_COLON
 205 %printer { fprintf (yyo, "%%%s", $$); } PERCENT_FLAG
 206 %printer { fprintf (yyo, "<%s>", $$); } TAG tag
 207
 208 %type <integer> INT
 209 %printer { fprintf (yyo, "%d", $$); } <integer>
 210
 211 %type <symbol> id id_colon string_as_id symbol symbol.prec
 212 %printer { fprintf (yyo, "%s", $$->tag); } <symbol>
 213 %printer { fprintf (yyo, "%s:", $$->tag); } id_colon
 214
 215 %type <assoc> precedence_declarator
 216 %type <list>  symbols.1 symbols.prec generic_symlist generic_symlist_item
 217 %type <named_ref> named_ref.opt
 218
 219 /*---------.
 220 | %param.  |
 221 `---------*/
 222 %code requires
 223 {
 224 # ifndef PARAM_TYPE
 225 #  define PARAM_TYPE
 226   typedef enum
 227   {
 228     param_none   = 0,
 229     param_lex    = 1 << 0,
 230     param_parse  = 1 << 1,
 231     param_both   = param_lex | param_parse
 232   } param_type;
 233 # endif
 234 };
 235 %code
 236 {
 237   /** Add a lex-param and/or a parse-param.
 238    *
 239    * \param type  where to push this formal argument.
 240    * \param decl  the formal argument.  Destroyed.
 241    * \param loc   the location in the source.
 242    */
 243   static void add_param (param_type type, char *decl, location loc);
 244   static param_type current_param = param_none;
 245 };
 246 %union
 247 {
 248   param_type param;
 249 }
 250 %token <param> PERCENT_PARAM "%param";
 251 %printer
 252 {
 253   switch ($$)
 254     {
 255 #define CASE(In, Out)                                           \
 256       case param_ ## In: fputs ("%" #Out, stderr); break
 257       CASE(lex,   lex-param);
 258       CASE(parse, parse-param);
 259       CASE(both,  param);
 260 #undef CASE
 261       case param_none: aver (false); break;
 262     }
 263 } <param>;
 264
 265
 266                      /*==========\
 267                      | Grammar.  |
 268                      \==========*/
 269 %%
 270
 271 input:
 272   prologue_declarations "%%" grammar epilogue.opt
 273 ;
 274
 275
 276         /*------------------------------------.
 277         | Declarations: before the first %%.  |
 278         `------------------------------------*/
 279
 280 prologue_declarations:
 281   /* Nothing */
 282 | prologue_declarations prologue_declaration
 283 ;
 284
 285 prologue_declaration:
 286   grammar_declaration
 287 | "%{...%}"
 288     {
 289       code_props plain_code;
 290       code_props_plain_init (&plain_code, $1, @1);
 291       code_props_translate_code (&plain_code);
 292       gram_scanner_last_string_free ();
 293       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 294                         plain_code.code, @1);
 295       code_scanner_last_string_free ();
 296     }
 297 | "%<flag>"
 298     {
 299       muscle_percent_define_ensure ($1, @1, true);
 300     }
 301 | "%define" variable content.opt
 302     {
 303       muscle_percent_define_insert ($2, @2, $3,
 304                                     MUSCLE_PERCENT_DEFINE_GRAMMAR_FILE);
 305     }
 306 | "%defines"                       { defines_flag = true; }
 307 | "%defines" STRING
 308     {
 309       defines_flag = true;
 310       spec_defines_file = xstrdup ($2);
 311     }
 312 | "%error-verbose"
 313     {
 314       muscle_percent_define_insert ("parse.error", @1, "verbose",
 315                                     MUSCLE_PERCENT_DEFINE_GRAMMAR_FILE);
 316     }
 317 | "%expect" INT                    { expected_sr_conflicts = $2; }
 318 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 319 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 320 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 321 | "%glr-parser"
 322     {
 323       nondeterministic_parser = true;
 324       glr_parser = true;
 325     }
 326 | "%initial-action" "{...}"
 327     {
 328       code_props action;
 329       code_props_symbol_action_init (&action, $2, @2);
 330       code_props_translate_code (&action);
 331       gram_scanner_last_string_free ();
 332       muscle_code_grow ("initial_action", action.code, @2);
 333       code_scanner_last_string_free ();
 334     }
 335 | "%language" STRING            { language_argmatch ($2, grammar_prio, @1); }
 336 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 337 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 338 | "%no-lines"                   { no_lines_flag = true; }
 339 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 340 | "%output" STRING              { spec_outfile = $2; }
 341 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 342 | "%param" { current_param = $1; } params { current_param = param_none; }
 343 | "%require" STRING             { version_check (&@2, $2); }
 344 | "%skeleton" STRING
 345     {
 346       char const *skeleton_user = $2;
 347       if (strchr (skeleton_user, '/'))
 348         {
 349           size_t dir_length = strlen (current_file);
 350           char *skeleton_build;
 351           while (dir_length && current_file[dir_length - 1] != '/')
 352             --dir_length;
 353           while (dir_length && current_file[dir_length - 1] == '/')
 354             --dir_length;
 355           skeleton_build =
 356             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 357           if (dir_length > 0)
 358             {
 359               memcpy (skeleton_build, current_file, dir_length);
 360               skeleton_build[dir_length++] = '/';
 361             }
 362           strcpy (skeleton_build + dir_length, skeleton_user);
 363           skeleton_user = uniqstr_new (skeleton_build);
 364           free (skeleton_build);
 365         }
 366       skeleton_arg (skeleton_user, grammar_prio, @1);
 367     }
 368 | "%token-table"                { token_table_flag = true; }
 369 | "%verbose"                    { report_flag |= report_states; }
 370 | "%yacc"                       { yacc_flag = true; }
 371 | /*FIXME: Err?  What is this horror doing here? */ ";"
 372 ;
 373
 374 params:
 375    params "{...}"  { add_param (current_param, $2, @2); }
 376 | "{...}"          { add_param (current_param, $1, @1); }
 377 ;
 378
 379
 380 /*----------------------.
 381 | grammar_declaration.  |
 382 `----------------------*/
 383
 384 grammar_declaration:
 385   precedence_declaration
 386 | symbol_declaration
 387 | "%start" symbol
 388     {
 389       grammar_start_symbol_set ($2, @2);
 390     }
 391 | code_props_type "{...}" generic_symlist
 392     {
 393       code_props code;
 394       code_props_symbol_action_init (&code, $2, @2);
 395       code_props_translate_code (&code);
 396       {
 397         symbol_list *list;
 398         for (list = $3; list; list = list->next)
 399           symbol_list_code_props_set (list, $1, &code);
 400         symbol_list_free ($3);
 401       }
 402     }
 403 | "%default-prec"
 404     {
 405       default_prec = true;
 406     }
 407 | "%no-default-prec"
 408     {
 409       default_prec = false;
 410     }
 411 | "%code" braceless
 412     {
 413       /* Do not invoke muscle_percent_code_grow here since it invokes
 414          muscle_user_name_list_grow.  */
 415       muscle_code_grow ("percent_code()", $2, @2);
 416       code_scanner_last_string_free ();
 417     }
 418 | "%code" ID braceless
 419     {
 420       muscle_percent_code_grow ($2, @2, $3, @3);
 421       code_scanner_last_string_free ();
 422     }
 423 ;
 424
 425 %type <code_type> code_props_type;
 426 %union {code_props_type code_type;};
 427 %printer { fprintf (yyo, "%s", code_props_type_string ($$)); } <code_type>;
 428 code_props_type:
 429   "%destructor"  { $$ = destructor; }
 430 | "%printer"     { $$ = printer; }
 431 ;
 432
 433 /*---------.
 434 | %union.  |
 435 `---------*/
 436
 437 %token PERCENT_UNION "%union";
 438
 439 union_name:
 440   /* Nothing. */ {}
 441 | ID             { muscle_code_grow ("union_name", $1, @1); }
 442 ;
 443
 444 grammar_declaration:
 445   "%union" union_name braceless
 446     {
 447       union_seen = true;
 448       muscle_code_grow ("stype", $3, @3);
 449       code_scanner_last_string_free ();
 450     }
 451 ;
 452
 453
 454
 455
 456 symbol_declaration:
 457   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 458     {
 459       current_class = unknown_sym;
 460       current_type = NULL;
 461     }
 462 | "%token" { current_class = token_sym; } symbol_defs.1
 463     {
 464       current_class = unknown_sym;
 465       current_type = NULL;
 466     }
 467 | "%type" TAG symbols.1
 468     {
 469       symbol_list *list;
 470       tag_seen = true;
 471       for (list = $3; list; list = list->next)
 472         symbol_type_set (list->content.sym, $2, @2);
 473       symbol_list_free ($3);
 474     }
 475 ;
 476
 477 precedence_declaration:
 478   precedence_declarator tag.opt symbols.prec
 479     {
 480       symbol_list *list;
 481       ++current_prec;
 482       for (list = $3; list; list = list->next)
 483         {
 484           symbol_type_set (list->content.sym, current_type, @2);
 485           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 486         }
 487       symbol_list_free ($3);
 488       current_type = NULL;
 489     }
 490 ;
 491
 492 precedence_declarator:
 493   "%left"       { $$ = left_assoc; }
 494 | "%right"      { $$ = right_assoc; }
 495 | "%nonassoc"   { $$ = non_assoc; }
 496 | "%precedence" { $$ = precedence_assoc; }
 497 ;
 498
 499 tag.opt:
 500   /* Nothing. */ { current_type = NULL; }
 501 | TAG            { current_type = $1; tag_seen = true; }
 502 ;
 503
 504 /* Just like symbols.1 but accept INT for the sake of POSIX.  */
 505 symbols.prec:
 506   symbol.prec
 507     { $$ = symbol_list_sym_new ($1, @1); }
 508 | symbols.prec symbol.prec
 509     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 510 ;
 511
 512 symbol.prec:
 513   symbol     { $$ = $1; }
 514 | symbol INT { $$ = $1; symbol_user_token_number_set ($1, $2, @2); }
 515 ;
 516
 517 /* One or more symbols to be %typed. */
 518 symbols.1:
 519   symbol
 520     { $$ = symbol_list_sym_new ($1, @1); }
 521 | symbols.1 symbol
 522     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 523 ;
 524
 525 generic_symlist:
 526   generic_symlist_item { $$ = $1; }
 527 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 528 ;
 529
 530 generic_symlist_item:
 531   symbol    { $$ = symbol_list_sym_new ($1, @1); }
 532 | tag       { $$ = symbol_list_type_new ($1, @1); }
 533 ;
 534
 535 tag:
 536   TAG
 537 | "<*>" { $$ = uniqstr_new ("*"); }
 538 | "<>"  { $$ = uniqstr_new (""); }
 539 ;
 540
 541 /* One token definition.  */
 542 symbol_def:
 543   TAG
 544      {
 545        current_type = $1;
 546        tag_seen = true;
 547      }
 548 | id
 549      {
 550        symbol_class_set ($1, current_class, @1, true);
 551        symbol_type_set ($1, current_type, @1);
 552      }
 553 | id INT
 554     {
 555       symbol_class_set ($1, current_class, @1, true);
 556       symbol_type_set ($1, current_type, @1);
 557       symbol_user_token_number_set ($1, $2, @2);
 558     }
 559 | id string_as_id
 560     {
 561       symbol_class_set ($1, current_class, @1, true);
 562       symbol_type_set ($1, current_type, @1);
 563       symbol_make_alias ($1, $2, @$);
 564     }
 565 | id INT string_as_id
 566     {
 567       symbol_class_set ($1, current_class, @1, true);
 568       symbol_type_set ($1, current_type, @1);
 569       symbol_user_token_number_set ($1, $2, @2);
 570       symbol_make_alias ($1, $3, @$);
 571     }
 572 ;
 573
 574 /* One or more symbol definitions. */
 575 symbol_defs.1:
 576   symbol_def
 577 | symbol_defs.1 symbol_def
 578 ;
 579
 580
 581         /*------------------------------------------.
 582         | The grammar section: between the two %%.  |
 583         `------------------------------------------*/
 584
 585 grammar:
 586   rules_or_grammar_declaration
 587 | grammar rules_or_grammar_declaration
 588 ;
 589
 590 /* As a Bison extension, one can use the grammar declarations in the
 591    body of the grammar.  */
 592 rules_or_grammar_declaration:
 593   rules
 594 | grammar_declaration ";"
 595 | error ";"
 596     {
 597       yyerrok;
 598     }
 599 ;
 600
 601 rules:
 602   id_colon named_ref.opt { current_lhs ($1, @1, $2); } rhses.1
 603   {
 604     /* Free the current lhs. */
 605     current_lhs (0, @1, 0);
 606   }
 607 ;
 608
 609 rhses.1:
 610   rhs                { grammar_current_rule_end (@1); }
 611 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 612 | rhses.1 ";"
 613 ;
 614
 615 rhs:
 616   /* Nothing.  */
 617     { grammar_current_rule_begin (current_lhs_symbol, current_lhs_location,
 618                                   current_lhs_named_ref); }
 619 | rhs symbol named_ref.opt
 620     { grammar_current_rule_symbol_append ($2, @2, $3); }
 621 | rhs "{...}" named_ref.opt
 622     { grammar_current_rule_action_append ($2, @2, $3, false); }
 623 | rhs "%?{...}"
 624     { grammar_current_rule_action_append ($2, @2, NULL, true); }
 625 | rhs "%prec" symbol
 626     { grammar_current_rule_prec_set ($3, @3); }
 627 | rhs "%dprec" INT
 628     { grammar_current_rule_dprec_set ($3, @3); }
 629 | rhs "%merge" TAG
 630     { grammar_current_rule_merge_set ($3, @3); }
 631 ;
 632
 633 named_ref.opt:
 634   /* Nothing. */ { $$ = 0; }
 635 |
 636   BRACKETED_ID   { $$ = named_ref_new($1, @1); }
 637 ;
 638
 639 /*---------------------------.
 640 | variable and content.opt.  |
 641 `---------------------------*/
 642
 643 /* The STRING form of variable is deprecated and is not M4-friendly.
 644    For example, M4 fails for `%define "[" "value"'.  */
 645 variable:
 646   ID
 647 | STRING { $$ = uniqstr_new ($1); }
 648 ;
 649
 650 /* Some content or empty by default. */
 651 content.opt:
 652   /* Nothing. */   { $$ = ""; }
 653 | ID { $$ = $1; }
 654 | STRING
 655 ;
 656
 657
 658 /*------------.
 659 | braceless.  |
 660 `------------*/
 661
 662 braceless:
 663   "{...}"
 664     {
 665       code_props plain_code;
 666       $1[strlen ($1) - 1] = '\n';
 667       code_props_plain_init (&plain_code, $1+1, @1);
 668       code_props_translate_code (&plain_code);
 669       gram_scanner_last_string_free ();
 670       $$ = plain_code.code;
 671     }
 672 ;
 673
 674
 675 /*--------------.
 676 | Identifiers.  |
 677 `--------------*/
 678
 679 /* Identifiers are returned as uniqstr values by the scanner.
 680    Depending on their use, we may need to make them genuine symbols.  */
 681
 682 id:
 683   ID
 684     { $$ = symbol_from_uniqstr ($1, @1); }
 685 | CHAR
 686     {
 687       $$ = symbol_get (char_name ($1), @1);
 688       symbol_class_set ($$, token_sym, @1, false);
 689       symbol_user_token_number_set ($$, $1, @1);
 690     }
 691 ;
 692
 693 id_colon:
 694   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 695 ;
 696
 697
 698 symbol:
 699   id
 700 | string_as_id
 701 ;
 702
 703 /* A string used as an ID: quote it.  */
 704 string_as_id:
 705   STRING
 706     {
 707       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 708       symbol_class_set ($$, token_sym, @1, false);
 709     }
 710 ;
 711
 712 epilogue.opt:
 713   /* Nothing.  */
 714 | "%%" EPILOGUE
 715     {
 716       code_props plain_code;
 717       code_props_plain_init (&plain_code, $2, @2);
 718       code_props_translate_code (&plain_code);
 719       gram_scanner_last_string_free ();
 720       muscle_code_grow ("epilogue", plain_code.code, @2);
 721       code_scanner_last_string_free ();
 722     }
 723 ;
 724
 725 %%
 726
 727
 728 /* Return the location of the left-hand side of a rule whose
 729    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 730    the right-hand side, and return an empty location equal to the end
 731    boundary of RHS[0] if the right-hand side is empty.  */
 732
 733 static YYLTYPE
 734 lloc_default (YYLTYPE const *rhs, int n)
 735 {
 736   int i;
 737   YYLTYPE loc;
 738
 739   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 740      The bug is fixed in 7.4.2m, but play it safe for now.  */
 741   loc.start = rhs[n].end;
 742   loc.end = rhs[n].end;
 743
 744   /* Ignore empty nonterminals the start of the right-hand side.
 745      Do not bother to ignore them at the end of the right-hand side,
 746      since empty nonterminals have the same end as their predecessors.  */
 747   for (i = 1; i <= n; i++)
 748     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 749       {
 750         loc.start = rhs[i].start;
 751         break;
 752       }
 753
 754   return loc;
 755 }
 756
 757
 758 static void
 759 add_param (param_type type, char *decl, location loc)
 760 {
 761   static char const alphanum[26 + 26 + 1 + 10] =
 762     "abcdefghijklmnopqrstuvwxyz"
 763     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 764     "_"
 765     "0123456789";
 766
 767   char const *name_start = NULL;
 768   {
 769     char *p;
 770     /* Stop on last actual character.  */
 771     for (p = decl; p[1]; p++)
 772       if ((p == decl
 773            || ! memchr (alphanum, p[-1], sizeof alphanum))
 774           && memchr (alphanum, p[0], sizeof alphanum - 10))
 775         name_start = p;
 776
 777     /* Strip the surrounding '{' and '}', and any blanks just inside
 778        the braces.  */
 779     --p;
 780   while (c_isspace ((unsigned char) *p))
 781       --p;
 782     p[1] = '\0';
 783     ++decl;
 784   while (c_isspace ((unsigned char) *decl))
 785       ++decl;
 786   }
 787
 788   if (! name_start)
 789     complain (&loc, complaint, _("missing identifier in parameter declaration"));
 790   else
 791     {
 792       char *name = xmemdup0 (name_start, strspn (name_start, alphanum));
 793       if (type & param_lex)
 794         muscle_pair_list_grow ("lex_param", decl, name);
 795       if (type & param_parse)
 796         muscle_pair_list_grow ("parse_param", decl, name);
 797       free (name);
 798     }
 799
 800   gram_scanner_last_string_free ();
 801 }
 802
 803
 804 static void
 805 version_check (location const *loc, char const *version)
 806 {
 807   if (strverscmp (version, PACKAGE_VERSION) > 0)
 808     {
 809       complain (loc, complaint, "require bison %s, but have %s",
 810                 version, PACKAGE_VERSION);
 811       exit (EX_MISMATCH);
 812     }
 813 }
 814
 815 static void
 816 gram_error (location const *loc, char const *msg)
 817 {
 818   complain (loc, complaint, "%s", msg);
 819 }
 820
 821 char const *
 822 token_name (int type)
 823 {
 824   return yytname[YYTRANSLATE (type)];
 825 }
 826
 827 static char const *
 828 char_name (char c)
 829 {
 830   if (c == '\'')
 831     return "'\\''";
 832   else
 833     {
 834       char buf[4];
 835       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 836       return quotearg_style (escape_quoting_style, buf);
 837     }
 838 }