src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software
   4    Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 #include <config.h>
  22 #include "system.h"
  23
  24 #include "complain.h"
  25 #include "conflicts.h"
  26 #include "files.h"
  27 #include "getargs.h"
  28 #include "gram.h"
  29 #include "muscle-tab.h"
  30 #include "quotearg.h"
  31 #include "reader.h"
  32 #include "symlist.h"
  33 #include "named-ref.h"
  34 #include "scan-gram.h"
  35 #include "scan-code.h"
  36
  37 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  38 static YYLTYPE lloc_default (YYLTYPE const *, int);
  39
  40 #define YY_LOCATION_PRINT(File, Loc) \
  41           location_print (File, Loc)
  42
  43 static void version_check (location const *loc, char const *version);
  44
  45 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  46    FIXME: depends on the undocumented availability of YYLLOC.  */
  47 #undef  yyerror
  48 #define yyerror(Msg) \
  49         gram_error (&yylloc, Msg)
  50 static void gram_error (location const *, char const *);
  51
  52 static char const *char_name (char);
  53
  54 /** Add a lex-param or a parse-param.
  55  *
  56  * \param type  \a lex_param or \a parse_param
  57  * \param decl  the formal argument
  58  * \param loc   the location in the source.
  59  */
  60 static void add_param (char const *type, char *decl, location loc);
  61
  62
  63 static symbol_class current_class = unknown_sym;
  64 static uniqstr current_type = NULL;
  65 static symbol *current_lhs;
  66 static location current_lhs_location;
  67 static named_ref *current_lhs_named_ref;
  68 static int current_prec = 0;
  69
  70 #define YYTYPE_INT16 int_fast16_t
  71 #define YYTYPE_INT8 int_fast8_t
  72 #define YYTYPE_UINT16 uint_fast16_t
  73 #define YYTYPE_UINT8 uint_fast8_t
  74 %}
  75
  76 %debug
  77 %verbose
  78 %defines
  79 %locations
  80 %pure-parser
  81 %error-verbose
  82 %name-prefix="gram_"
  83 %expect 0
  84
  85 %initial-action
  86 {
  87   /* Bison's grammar can initial empty locations, hence a default
  88      location is needed. */
  89   boundary_set (&@$.start, current_file, 1, 1);
  90   boundary_set (&@$.end, current_file, 1, 1);
  91 }
  92
  93 %union
  94 {
  95   symbol *symbol;
  96   symbol_list *list;
  97   int integer;
  98   char const *chars;
  99   char *code;
 100   assoc assoc;
 101   uniqstr uniqstr;
 102   unsigned char character;
 103   named_ref *named_ref;
 104 };
 105
 106 /* Define the tokens together with their human representation.  */
 107 %token GRAM_EOF 0 "end of file"
 108 %token STRING     "string"
 109 %token INT        "integer"
 110
 111 %token PERCENT_TOKEN       "%token"
 112 %token PERCENT_NTERM       "%nterm"
 113
 114 %token PERCENT_TYPE        "%type"
 115 %token PERCENT_DESTRUCTOR  "%destructor"
 116 %token PERCENT_PRINTER     "%printer"
 117
 118 %token PERCENT_LEFT        "%left"
 119 %token PERCENT_RIGHT       "%right"
 120 %token PERCENT_NONASSOC    "%nonassoc"
 121 %token PERCENT_PRECEDENCE  "%precedence"
 122
 123 %token PERCENT_PREC          "%prec"
 124 %token PERCENT_DPREC         "%dprec"
 125 %token PERCENT_MERGE         "%merge"
 126
 127
 128 /*----------------------.
 129 | Global Declarations.  |
 130 `----------------------*/
 131
 132 %token
 133   PERCENT_CODE            "%code"
 134   PERCENT_DEFAULT_PREC    "%default-prec"
 135   PERCENT_DEFINE          "%define"
 136   PERCENT_DEFINES         "%defines"
 137   PERCENT_EXPECT          "%expect"
 138   PERCENT_EXPECT_RR       "%expect-rr"
 139   PERCENT_FLAG            "%<flag>"
 140   PERCENT_FILE_PREFIX     "%file-prefix"
 141   PERCENT_GLR_PARSER      "%glr-parser"
 142   PERCENT_INITIAL_ACTION  "%initial-action"
 143   PERCENT_LANGUAGE        "%language"
 144   PERCENT_LEX_PARAM       "%lex-param"
 145   PERCENT_NAME_PREFIX     "%name-prefix"
 146   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 147   PERCENT_NO_LINES        "%no-lines"
 148   PERCENT_NONDETERMINISTIC_PARSER
 149                           "%nondeterministic-parser"
 150   PERCENT_OUTPUT          "%output"
 151   PERCENT_PARSE_PARAM     "%parse-param"
 152   PERCENT_REQUIRE         "%require"
 153   PERCENT_SKELETON        "%skeleton"
 154   PERCENT_START           "%start"
 155   PERCENT_TOKEN_TABLE     "%token-table"
 156   PERCENT_VERBOSE         "%verbose"
 157   PERCENT_YACC            "%yacc"
 158 ;
 159
 160 %token BRACED_CODE     "{...}"
 161 %token CHAR            "char"
 162 %token EPILOGUE        "epilogue"
 163 %token EQUAL           "="
 164 %token ID              "identifier"
 165 %token ID_COLON        "identifier:"
 166 %token PERCENT_PERCENT "%%"
 167 %token PIPE            "|"
 168 %token PROLOGUE        "%{...%}"
 169 %token SEMICOLON       ";"
 170 %token TAG             "<tag>"
 171 %token TAG_ANY         "<*>"
 172 %token TAG_NONE        "<>"
 173 %token BRACKETED_ID    "[id]"
 174
 175 %type <character> CHAR
 176 %printer { fputs (char_name ($$), stderr); } CHAR
 177
 178 /* braceless is not to be used for rule or symbol actions, as it
 179    calls code_props_plain_init.  */
 180 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 181 %type <code> "{...}"
 182 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 183          STRING
 184 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 185          braceless content.opt "{...}" "%{...%}" EPILOGUE
 186
 187 %type <uniqstr> TAG ID ID_COLON BRACKETED_ID PERCENT_FLAG variable
 188 %type <named_ref> named_ref.opt
 189 %printer { fputs ($$, stderr); } ID variable
 190 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 191 %printer { fprintf (stderr, "%%%s", $$); } PERCENT_FLAG
 192 %printer { fprintf (stderr, "<%s>", $$); } TAG
 193
 194 %type <integer> INT
 195 %printer { fprintf (stderr, "%d", $$); } INT
 196
 197 %type <symbol> id id_colon symbol symbol.prec string_as_id
 198 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 199 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 200
 201 %type <assoc> precedence_declarator
 202 %type <list>  symbols.1 symbols.prec generic_symlist generic_symlist_item
 203 %%
 204
 205 input:
 206   prologue_declarations "%%" grammar epilogue.opt
 207 ;
 208
 209
 210         /*------------------------------------.
 211         | Declarations: before the first %%.  |
 212         `------------------------------------*/
 213
 214 prologue_declarations:
 215   /* Nothing */
 216 | prologue_declarations prologue_declaration
 217 ;
 218
 219 prologue_declaration:
 220   grammar_declaration
 221 | "%{...%}"
 222     {
 223       code_props plain_code;
 224       code_props_plain_init (&plain_code, $1, @1);
 225       code_props_translate_code (&plain_code);
 226       gram_scanner_last_string_free ();
 227       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 228                         plain_code.code, @1);
 229       code_scanner_last_string_free ();
 230     }
 231 | "%<flag>"
 232     {
 233       muscle_percent_define_ensure ($1, @1, true);
 234     }
 235 | "%define" variable content.opt
 236     {
 237       muscle_percent_define_insert ($2, @2, $3,
 238                                     MUSCLE_PERCENT_DEFINE_GRAMMAR_FILE);
 239     }
 240 | "%defines"                       { defines_flag = true; }
 241 | "%defines" STRING
 242     {
 243       defines_flag = true;
 244       spec_defines_file = xstrdup ($2);
 245     }
 246 | "%expect" INT                    { expected_sr_conflicts = $2; }
 247 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 248 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 249 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 250 | "%glr-parser"
 251     {
 252       nondeterministic_parser = true;
 253       glr_parser = true;
 254     }
 255 | "%initial-action" "{...}"
 256     {
 257       code_props action;
 258       code_props_symbol_action_init (&action, $2, @2);
 259       code_props_translate_code (&action);
 260       gram_scanner_last_string_free ();
 261       muscle_code_grow ("initial_action", action.code, @2);
 262       code_scanner_last_string_free ();
 263     }
 264 | "%language" STRING            { language_argmatch ($2, grammar_prio, @1); }
 265 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 266 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 267 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 268 | "%no-lines"                   { no_lines_flag = true; }
 269 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 270 | "%output" STRING              { spec_outfile = $2; }
 271 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 272 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 273 | "%require" STRING             { version_check (&@2, $2); }
 274 | "%skeleton" STRING
 275     {
 276       char const *skeleton_user = $2;
 277       if (strchr (skeleton_user, '/'))
 278         {
 279           size_t dir_length = strlen (current_file);
 280           char *skeleton_build;
 281           while (dir_length && current_file[dir_length - 1] != '/')
 282             --dir_length;
 283           while (dir_length && current_file[dir_length - 1] == '/')
 284             --dir_length;
 285           skeleton_build =
 286             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 287           if (dir_length > 0)
 288             {
 289               strncpy (skeleton_build, current_file, dir_length);
 290               skeleton_build[dir_length++] = '/';
 291             }
 292           strcpy (skeleton_build + dir_length, skeleton_user);
 293           skeleton_user = uniqstr_new (skeleton_build);
 294           free (skeleton_build);
 295         }
 296       skeleton_arg (skeleton_user, grammar_prio, @1);
 297     }
 298 | "%token-table"                { token_table_flag = true; }
 299 | "%verbose"                    { report_flag |= report_states; }
 300 | "%yacc"                       { yacc_flag = true; }
 301 | /*FIXME: Err?  What is this horror doing here? */ ";"
 302 ;
 303
 304 grammar_declaration:
 305   precedence_declaration
 306 | symbol_declaration
 307 | "%start" symbol
 308     {
 309       grammar_start_symbol_set ($2, @2);
 310     }
 311 | "%destructor" "{...}" generic_symlist
 312     {
 313       symbol_list *list;
 314       for (list = $3; list; list = list->next)
 315         symbol_list_destructor_set (list, $2, @2);
 316       symbol_list_free ($3);
 317     }
 318 | "%printer" "{...}" generic_symlist
 319     {
 320       symbol_list *list;
 321       for (list = $3; list; list = list->next)
 322         symbol_list_printer_set (list, $2, @2);
 323       symbol_list_free ($3);
 324     }
 325 | "%default-prec"
 326     {
 327       default_prec = true;
 328     }
 329 | "%no-default-prec"
 330     {
 331       default_prec = false;
 332     }
 333 | "%code" braceless
 334     {
 335       /* Do not invoke muscle_percent_code_grow here since it invokes
 336          muscle_user_name_list_grow.  */
 337       muscle_code_grow ("percent_code()", $2, @2);
 338       code_scanner_last_string_free ();
 339     }
 340 | "%code" ID braceless
 341     {
 342       muscle_percent_code_grow ($2, @2, $3, @3);
 343       code_scanner_last_string_free ();
 344     }
 345 ;
 346
 347
 348 /*---------.
 349 | %union.  |
 350 `---------*/
 351
 352 %token PERCENT_UNION "%union";
 353
 354 union_name:
 355   /* Nothing. */ {}
 356 | ID             { muscle_code_grow ("union_name", $1, @1); }
 357 ;
 358
 359 grammar_declaration:
 360   "%union" union_name braceless
 361     {
 362       union_seen = true;
 363       muscle_code_grow ("stype", $3, @3);
 364       code_scanner_last_string_free ();
 365     }
 366 ;
 367
 368
 369
 370
 371 symbol_declaration:
 372   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 373     {
 374       current_class = unknown_sym;
 375       current_type = NULL;
 376     }
 377 | "%token" { current_class = token_sym; } symbol_defs.1
 378     {
 379       current_class = unknown_sym;
 380       current_type = NULL;
 381     }
 382 | "%type" TAG symbols.1
 383     {
 384       symbol_list *list;
 385       tag_seen = true;
 386       for (list = $3; list; list = list->next)
 387         symbol_type_set (list->content.sym, $2, @2);
 388       symbol_list_free ($3);
 389     }
 390 ;
 391
 392 precedence_declaration:
 393   precedence_declarator tag.opt symbols.prec
 394     {
 395       symbol_list *list;
 396       ++current_prec;
 397       for (list = $3; list; list = list->next)
 398         {
 399           symbol_type_set (list->content.sym, current_type, @2);
 400           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 401         }
 402       symbol_list_free ($3);
 403       current_type = NULL;
 404     }
 405 ;
 406
 407 precedence_declarator:
 408   "%left"       { $$ = left_assoc; }
 409 | "%right"      { $$ = right_assoc; }
 410 | "%nonassoc"   { $$ = non_assoc; }
 411 | "%precedence" { $$ = precedence_assoc; }
 412 ;
 413
 414 tag.opt:
 415   /* Nothing. */ { current_type = NULL; }
 416 | TAG            { current_type = $1; tag_seen = true; }
 417 ;
 418
 419 /* Just like symbols.1 but accept INT for the sake of POSIX.  */
 420 symbols.prec:
 421   symbol.prec
 422     { $$ = symbol_list_sym_new ($1, @1); }
 423 | symbols.prec symbol.prec
 424     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 425 ;
 426
 427 symbol.prec:
 428     symbol { $$ = $1; }
 429   | symbol INT { $$ = $1; symbol_user_token_number_set ($1, $2, @2); }
 430   ;
 431
 432 /* One or more symbols to be %typed. */
 433 symbols.1:
 434   symbol
 435     { $$ = symbol_list_sym_new ($1, @1); }
 436 | symbols.1 symbol
 437     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 438 ;
 439
 440 generic_symlist:
 441   generic_symlist_item { $$ = $1; }
 442 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 443 ;
 444
 445 generic_symlist_item:
 446   symbol    { $$ = symbol_list_sym_new ($1, @1); }
 447 | TAG       { $$ = symbol_list_type_new ($1, @1); }
 448 | "<*>"     { $$ = symbol_list_default_tagged_new (@1); }
 449 | "<>"      { $$ = symbol_list_default_tagless_new (@1); }
 450 ;
 451
 452 /* One token definition.  */
 453 symbol_def:
 454   TAG
 455      {
 456        current_type = $1;
 457        tag_seen = true;
 458      }
 459 | id
 460      {
 461        symbol_class_set ($1, current_class, @1, true);
 462        symbol_type_set ($1, current_type, @1);
 463      }
 464 | id INT
 465     {
 466       symbol_class_set ($1, current_class, @1, true);
 467       symbol_type_set ($1, current_type, @1);
 468       symbol_user_token_number_set ($1, $2, @2);
 469     }
 470 | id string_as_id
 471     {
 472       symbol_class_set ($1, current_class, @1, true);
 473       symbol_type_set ($1, current_type, @1);
 474       symbol_make_alias ($1, $2, @$);
 475     }
 476 | id INT string_as_id
 477     {
 478       symbol_class_set ($1, current_class, @1, true);
 479       symbol_type_set ($1, current_type, @1);
 480       symbol_user_token_number_set ($1, $2, @2);
 481       symbol_make_alias ($1, $3, @$);
 482     }
 483 ;
 484
 485 /* One or more symbol definitions. */
 486 symbol_defs.1:
 487   symbol_def
 488 | symbol_defs.1 symbol_def
 489 ;
 490
 491
 492         /*------------------------------------------.
 493         | The grammar section: between the two %%.  |
 494         `------------------------------------------*/
 495
 496 grammar:
 497   rules_or_grammar_declaration
 498 | grammar rules_or_grammar_declaration
 499 ;
 500
 501 /* As a Bison extension, one can use the grammar declarations in the
 502    body of the grammar.  */
 503 rules_or_grammar_declaration:
 504   rules
 505 | grammar_declaration ";"
 506 | error ";"
 507     {
 508       yyerrok;
 509     }
 510 ;
 511
 512 rules:
 513   id_colon named_ref.opt { current_lhs = $1; current_lhs_location = @1;
 514     current_lhs_named_ref = $2; } rhses.1
 515 ;
 516
 517 rhses.1:
 518   rhs                { grammar_current_rule_end (@1); }
 519 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 520 | rhses.1 ";"
 521 ;
 522
 523 rhs:
 524   /* Nothing.  */
 525     { grammar_current_rule_begin (current_lhs, current_lhs_location,
 526                                   current_lhs_named_ref); }
 527 | rhs symbol named_ref.opt
 528     { grammar_current_rule_symbol_append ($2, @2, $3); }
 529 | rhs "{...}" named_ref.opt
 530     { grammar_current_rule_action_append ($2, @2, $3); }
 531 | rhs "%prec" symbol
 532     { grammar_current_rule_prec_set ($3, @3); }
 533 | rhs "%dprec" INT
 534     { grammar_current_rule_dprec_set ($3, @3); }
 535 | rhs "%merge" TAG
 536     { grammar_current_rule_merge_set ($3, @3); }
 537 ;
 538
 539 named_ref.opt:
 540   /* Nothing.  */
 541     { $$ = 0; }
 542 |
 543   BRACKETED_ID
 544     { $$ = named_ref_new($1, @1); }
 545 ;
 546
 547
 548 /*---------------------------.
 549 | variable and content.opt.  |
 550 `---------------------------*/
 551
 552 /* The STRING form of variable is deprecated and is not M4-friendly.
 553    For example, M4 fails for `%define "[" "value"'.  */
 554 variable:
 555   ID
 556 | STRING { $$ = uniqstr_new ($1); }
 557 ;
 558
 559 /* Some content or empty by default. */
 560 content.opt:
 561   /* Nothing. */   { $$ = ""; }
 562 | STRING
 563 ;
 564
 565
 566 /*------------.
 567 | braceless.  |
 568 `------------*/
 569
 570 braceless:
 571   "{...}"
 572     {
 573       code_props plain_code;
 574       $1[strlen ($1) - 1] = '\n';
 575       code_props_plain_init (&plain_code, $1+1, @1);
 576       code_props_translate_code (&plain_code);
 577       gram_scanner_last_string_free ();
 578       $$ = plain_code.code;
 579     }
 580 ;
 581
 582
 583 /*--------------.
 584 | Identifiers.  |
 585 `--------------*/
 586
 587 /* Identifiers are returned as uniqstr values by the scanner.
 588    Depending on their use, we may need to make them genuine symbols.  */
 589
 590 id:
 591   ID
 592     { $$ = symbol_from_uniqstr ($1, @1); }
 593 | CHAR
 594     {
 595       $$ = symbol_get (char_name ($1), @1);
 596       symbol_class_set ($$, token_sym, @1, false);
 597       symbol_user_token_number_set ($$, $1, @1);
 598     }
 599 ;
 600
 601 id_colon:
 602   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 603 ;
 604
 605
 606 symbol:
 607   id
 608 | string_as_id
 609 ;
 610
 611 /* A string used as an ID: quote it.  */
 612 string_as_id:
 613   STRING
 614     {
 615       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 616       symbol_class_set ($$, token_sym, @1, false);
 617     }
 618 ;
 619
 620 epilogue.opt:
 621   /* Nothing.  */
 622 | "%%" EPILOGUE
 623     {
 624       code_props plain_code;
 625       code_props_plain_init (&plain_code, $2, @2);
 626       code_props_translate_code (&plain_code);
 627       gram_scanner_last_string_free ();
 628       muscle_code_grow ("epilogue", plain_code.code, @2);
 629       code_scanner_last_string_free ();
 630     }
 631 ;
 632
 633 %%
 634
 635
 636 /* Return the location of the left-hand side of a rule whose
 637    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 638    the right-hand side, and return an empty location equal to the end
 639    boundary of RHS[0] if the right-hand side is empty.  */
 640
 641 static YYLTYPE
 642 lloc_default (YYLTYPE const *rhs, int n)
 643 {
 644   int i;
 645   YYLTYPE loc;
 646
 647   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 648      The bug is fixed in 7.4.2m, but play it safe for now.  */
 649   loc.start = rhs[n].end;
 650   loc.end = rhs[n].end;
 651
 652   /* Ignore empty nonterminals the start of the the right-hand side.
 653      Do not bother to ignore them at the end of the right-hand side,
 654      since empty nonterminals have the same end as their predecessors.  */
 655   for (i = 1; i <= n; i++)
 656     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 657       {
 658         loc.start = rhs[i].start;
 659         break;
 660       }
 661
 662   return loc;
 663 }
 664
 665
 666 /* Add a lex-param or a parse-param (depending on TYPE) with
 667    declaration DECL and location LOC.  */
 668
 669 static void
 670 add_param (char const *type, char *decl, location loc)
 671 {
 672   static char const alphanum[26 + 26 + 1 + 10] =
 673     "abcdefghijklmnopqrstuvwxyz"
 674     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 675     "_"
 676     "0123456789";
 677   char const *name_start = NULL;
 678   char *p;
 679
 680   /* Stop on last actual character.  */
 681   for (p = decl; p[1]; p++)
 682     if ((p == decl
 683          || ! memchr (alphanum, p[-1], sizeof alphanum))
 684         && memchr (alphanum, p[0], sizeof alphanum - 10))
 685       name_start = p;
 686
 687   /* Strip the surrounding '{' and '}', and any blanks just inside
 688      the braces.  */
 689   while (*--p == ' ' || *p == '\t')
 690     continue;
 691   p[1] = '\0';
 692   while (*++decl == ' ' || *decl == '\t')
 693     continue;
 694
 695   if (! name_start)
 696     complain_at (loc, _("missing identifier in parameter declaration"));
 697   else
 698     {
 699       char *name;
 700       size_t name_len;
 701
 702       for (name_len = 1;
 703            memchr (alphanum, name_start[name_len], sizeof alphanum);
 704            name_len++)
 705         continue;
 706
 707       name = xmalloc (name_len + 1);
 708       memcpy (name, name_start, name_len);
 709       name[name_len] = '\0';
 710       muscle_pair_list_grow (type, decl, name);
 711       free (name);
 712     }
 713
 714   gram_scanner_last_string_free ();
 715 }
 716
 717
 718 static void
 719 version_check (location const *loc, char const *version)
 720 {
 721   if (strverscmp (version, PACKAGE_VERSION) > 0)
 722     {
 723       complain_at (*loc, "require bison %s, but have %s",
 724                    version, PACKAGE_VERSION);
 725       exit (63);
 726     }
 727 }
 728
 729 static void
 730 gram_error (location const *loc, char const *msg)
 731 {
 732   complain_at (*loc, "%s", msg);
 733 }
 734
 735 char const *
 736 token_name (int type)
 737 {
 738   return yytname[YYTRANSLATE (type)];
 739 }
 740
 741 static char const *
 742 char_name (char c)
 743 {
 744   if (c == '\'')
 745     return "'\\''";
 746   else
 747     {
 748       char buf[4];
 749       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 750       return quotearg_style (escape_quoting_style, buf);
 751     }
 752 }