src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation,
   4    Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 #include <config.h>
  22 #include "system.h"
  23
  24 #include <strverscmp.h>
  25
  26 #include "complain.h"
  27 #include "conflicts.h"
  28 #include "files.h"
  29 #include "getargs.h"
  30 #include "gram.h"
  31 #include "muscle_tab.h"
  32 #include "quotearg.h"
  33 #include "reader.h"
  34 #include "symlist.h"
  35 #include "scan-gram.h"
  36 #include "scan-code.h"
  37
  38 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  39 static YYLTYPE lloc_default (YYLTYPE const *, int);
  40
  41 #define YY_LOCATION_PRINT(File, Loc) \
  42           location_print (File, Loc)
  43
  44 static void version_check (location const *loc, char const *version);
  45
  46 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  47    FIXME: depends on the undocumented availability of YYLLOC.  */
  48 #undef  yyerror
  49 #define yyerror(Msg) \
  50         gram_error (&yylloc, Msg)
  51 static void gram_error (location const *, char const *);
  52
  53 static char const *char_name (char);
  54
  55 /** Add a lex-param or a parse-param.
  56  *
  57  * \param type  \a lex_param or \a parse_param
  58  * \param decl  the formal argument
  59  * \param loc   the location in the source.
  60  */
  61 static void add_param (char const *type, char *decl, location loc);
  62
  63
  64 static symbol_class current_class = unknown_sym;
  65 static uniqstr current_type = NULL;
  66 static symbol *current_lhs;
  67 static location current_lhs_location;
  68 static int current_prec = 0;
  69
  70 #define YYTYPE_INT16 int_fast16_t
  71 #define YYTYPE_INT8 int_fast8_t
  72 #define YYTYPE_UINT16 uint_fast16_t
  73 #define YYTYPE_UINT8 uint_fast8_t
  74 %}
  75
  76 %debug
  77 %verbose
  78 %defines
  79 %locations
  80 %pure-parser
  81 %error-verbose
  82 %name-prefix="gram_"
  83 %expect 0
  84
  85 %initial-action
  86 {
  87   /* Bison's grammar can initial empty locations, hence a default
  88      location is needed. */
  89   boundary_set (&@$.start, current_file, 1, 1);
  90   boundary_set (&@$.end, current_file, 1, 1);
  91 }
  92
  93 %union
  94 {
  95   symbol *symbol;
  96   symbol_list *list;
  97   int integer;
  98   char const *chars;
  99   char *code;
 100   assoc assoc;
 101   uniqstr uniqstr;
 102   unsigned char character;
 103 };
 104
 105 /* Define the tokens together with their human representation.  */
 106 %token GRAM_EOF 0 "end of file"
 107 %token STRING     "string"
 108 %token INT        "integer"
 109
 110 %token PERCENT_TOKEN       "%token"
 111 %token PERCENT_NTERM       "%nterm"
 112
 113 %token PERCENT_TYPE        "%type"
 114 %token PERCENT_DESTRUCTOR  "%destructor"
 115 %token PERCENT_PRINTER     "%printer"
 116
 117 %token PERCENT_LEFT        "%left"
 118 %token PERCENT_RIGHT       "%right"
 119 %token PERCENT_NONASSOC    "%nonassoc"
 120
 121 %token PERCENT_PREC          "%prec"
 122 %token PERCENT_DPREC         "%dprec"
 123 %token PERCENT_MERGE         "%merge"
 124
 125
 126 /*----------------------.
 127 | Global Declarations.  |
 128 `----------------------*/
 129
 130 %token
 131   PERCENT_CODE            "%code"
 132   PERCENT_DEBUG           "%debug"
 133   PERCENT_DEFAULT_PREC    "%default-prec"
 134   PERCENT_DEFINE          "%define"
 135   PERCENT_DEFINES         "%defines"
 136   PERCENT_ERROR_VERBOSE   "%error-verbose"
 137   PERCENT_EXPECT          "%expect"
 138   PERCENT_EXPECT_RR       "%expect-rr"
 139   PERCENT_FILE_PREFIX     "%file-prefix"
 140   PERCENT_GLR_PARSER      "%glr-parser"
 141   PERCENT_INITIAL_ACTION  "%initial-action"
 142   PERCENT_LANGUAGE        "%language"
 143   PERCENT_LEX_PARAM       "%lex-param"
 144   PERCENT_LOCATIONS       "%locations"
 145   PERCENT_NAME_PREFIX     "%name-prefix"
 146   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 147   PERCENT_NO_LINES        "%no-lines"
 148   PERCENT_NONDETERMINISTIC_PARSER
 149                           "%nondeterministic-parser"
 150   PERCENT_OUTPUT          "%output"
 151   PERCENT_PARSE_PARAM     "%parse-param"
 152   PERCENT_PURE_PARSER     "%pure-parser"
 153   PERCENT_REQUIRE         "%require"
 154   PERCENT_SKELETON        "%skeleton"
 155   PERCENT_START           "%start"
 156   PERCENT_TOKEN_TABLE     "%token-table"
 157   PERCENT_VERBOSE         "%verbose"
 158   PERCENT_YACC            "%yacc"
 159 ;
 160
 161 %token BRACED_CODE     "{...}"
 162 %token CHAR            "char"
 163 %token EPILOGUE        "epilogue"
 164 %token EQUAL           "="
 165 %token ID              "identifier"
 166 %token ID_COLON        "identifier:"
 167 %token PERCENT_PERCENT "%%"
 168 %token PIPE            "|"
 169 %token PROLOGUE        "%{...%}"
 170 %token SEMICOLON       ";"
 171 %token TYPE            "type"
 172 %token TYPE_TAG_ANY    "<*>"
 173 %token TYPE_TAG_NONE   "<>"
 174
 175 %type <character> CHAR
 176 %printer { fputs (char_name ($$), stderr); } CHAR
 177
 178 /* braceless is not to be used for rule or symbol actions, as it
 179    calls code_props_plain_init.  */
 180 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 181 %type <code> "{...}"
 182 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 183          STRING
 184 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 185          braceless content.opt "{...}" "%{...%}" EPILOGUE
 186
 187 %type <uniqstr> TYPE ID ID_COLON variable
 188 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 189 %printer { fputs ($$, stderr); } ID variable
 190 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 191
 192 %type <integer> INT
 193 %printer { fprintf (stderr, "%d", $$); } INT
 194
 195 %type <symbol> id id_colon symbol string_as_id
 196 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 197 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 198
 199 %type <assoc> precedence_declarator
 200 %type <list>  symbols.1 generic_symlist generic_symlist_item
 201 %%
 202
 203 input:
 204   prologue_declarations "%%" grammar epilogue.opt
 205 ;
 206
 207
 208         /*------------------------------------.
 209         | Declarations: before the first %%.  |
 210         `------------------------------------*/
 211
 212 prologue_declarations:
 213   /* Nothing */
 214 | prologue_declarations prologue_declaration
 215 ;
 216
 217 prologue_declaration:
 218   grammar_declaration
 219 | "%{...%}"
 220     {
 221       code_props plain_code;
 222       code_props_plain_init (&plain_code, $1, @1);
 223       code_props_translate_code (&plain_code);
 224       gram_scanner_last_string_free ();
 225       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 226                         plain_code.code, @1);
 227       code_scanner_last_string_free ();
 228     }
 229 | "%debug"                         { debug_flag = true; }
 230 | "%define" variable content.opt
 231     {
 232       muscle_percent_define_insert ($2, @2, $3);
 233     }
 234 | "%defines"                       { defines_flag = true; }
 235 | "%defines" STRING
 236     {
 237       defines_flag = true;
 238       spec_defines_file = xstrdup ($2);
 239     }
 240 | "%error-verbose"                 { error_verbose = true; }
 241 | "%expect" INT                    { expected_sr_conflicts = $2; }
 242 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 243 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 244 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 245 | "%glr-parser"
 246     {
 247       nondeterministic_parser = true;
 248       glr_parser = true;
 249     }
 250 | "%initial-action" "{...}"
 251     {
 252       code_props action;
 253       code_props_symbol_action_init (&action, $2, @2);
 254       code_props_translate_code (&action);
 255       gram_scanner_last_string_free ();
 256       muscle_code_grow ("initial_action", action.code, @2);
 257       code_scanner_last_string_free ();
 258     }
 259 | "%language" STRING            { language_argmatch ($2, 1, &@1); }
 260 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 261 | "%locations"                  { locations_flag = true; }
 262 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 263 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 264 | "%no-lines"                   { no_lines_flag = true; }
 265 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 266 | "%output" STRING              { spec_outfile = $2; }
 267 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 268 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 269 | "%pure-parser"                { pure_parser = true; }
 270 | "%require" STRING             { version_check (&@2, $2); }
 271 | "%skeleton" STRING
 272     {
 273       char const *skeleton_user = $2;
 274       if (strchr (skeleton_user, '/'))
 275         {
 276           size_t dir_length = strlen (current_file);
 277           char *skeleton_build;
 278           while (dir_length && current_file[dir_length - 1] != '/')
 279             --dir_length;
 280           while (dir_length && current_file[dir_length - 1] == '/')
 281             --dir_length;
 282           skeleton_build =
 283             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 284           if (dir_length > 0)
 285             {
 286               strncpy (skeleton_build, current_file, dir_length);
 287               skeleton_build[dir_length++] = '/';
 288             }
 289           strcpy (skeleton_build + dir_length, skeleton_user);
 290           skeleton_user = uniqstr_new (skeleton_build);
 291           free (skeleton_build);
 292         }
 293       skeleton_arg (skeleton_user, 1, &@1);
 294     }
 295 | "%token-table"                { token_table_flag = true; }
 296 | "%verbose"                    { report_flag = report_states; }
 297 | "%yacc"                       { yacc_flag = true; }
 298 | /*FIXME: Err?  What is this horror doing here? */ ";"
 299 ;
 300
 301 grammar_declaration:
 302   precedence_declaration
 303 | symbol_declaration
 304 | "%start" symbol
 305     {
 306       grammar_start_symbol_set ($2, @2);
 307     }
 308 | "%destructor" "{...}" generic_symlist
 309     {
 310       symbol_list *list;
 311       for (list = $3; list; list = list->next)
 312         symbol_list_destructor_set (list, $2, @2);
 313       symbol_list_free ($3);
 314     }
 315 | "%printer" "{...}" generic_symlist
 316     {
 317       symbol_list *list;
 318       for (list = $3; list; list = list->next)
 319         symbol_list_printer_set (list, $2, @2);
 320       symbol_list_free ($3);
 321     }
 322 | "%default-prec"
 323     {
 324       default_prec = true;
 325     }
 326 | "%no-default-prec"
 327     {
 328       default_prec = false;
 329     }
 330 | "%code" braceless
 331     {
 332       /* Do not invoke muscle_percent_code_grow here since it invokes
 333          muscle_user_name_list_grow.  */
 334       muscle_code_grow ("percent_code()", $2, @2);
 335       code_scanner_last_string_free ();
 336     }
 337 | "%code" ID braceless
 338     {
 339       muscle_percent_code_grow ($2, @2, $3, @3);
 340       code_scanner_last_string_free ();
 341     }
 342 ;
 343
 344
 345 /*----------*
 346  | %union.  |
 347  *----------*/
 348
 349 %token PERCENT_UNION "%union";
 350
 351 union_name:
 352   /* Nothing. */ {}
 353 | ID             { muscle_code_grow ("union_name", $1, @1); }
 354 ;
 355
 356 grammar_declaration:
 357   "%union" union_name braceless
 358     {
 359       union_seen = true;
 360       muscle_code_grow ("stype", $3, @3);
 361       code_scanner_last_string_free ();
 362     }
 363 ;
 364
 365
 366
 367
 368 symbol_declaration:
 369   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 370     {
 371       current_class = unknown_sym;
 372       current_type = NULL;
 373     }
 374 | "%token" { current_class = token_sym; } symbol_defs.1
 375     {
 376       current_class = unknown_sym;
 377       current_type = NULL;
 378     }
 379 | "%type" TYPE symbols.1
 380     {
 381       symbol_list *list;
 382       tag_seen = true;
 383       for (list = $3; list; list = list->next)
 384         symbol_type_set (list->content.sym, $2, @2);
 385       symbol_list_free ($3);
 386     }
 387 ;
 388
 389 precedence_declaration:
 390   precedence_declarator type.opt symbols.1
 391     {
 392       symbol_list *list;
 393       ++current_prec;
 394       for (list = $3; list; list = list->next)
 395         {
 396           symbol_type_set (list->content.sym, current_type, @2);
 397           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 398         }
 399       symbol_list_free ($3);
 400       current_type = NULL;
 401     }
 402 ;
 403
 404 precedence_declarator:
 405   "%left"     { $$ = left_assoc; }
 406 | "%right"    { $$ = right_assoc; }
 407 | "%nonassoc" { $$ = non_assoc; }
 408 ;
 409
 410 type.opt:
 411   /* Nothing. */ { current_type = NULL; }
 412 | TYPE           { current_type = $1; tag_seen = true; }
 413 ;
 414
 415 /* One or more symbols to be %typed. */
 416 symbols.1:
 417   symbol
 418     { $$ = symbol_list_sym_new ($1, @1); }
 419 | symbols.1 symbol
 420     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 421 ;
 422
 423 generic_symlist:
 424   generic_symlist_item { $$ = $1; }
 425 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 426 ;
 427
 428 generic_symlist_item:
 429   symbol            { $$ = symbol_list_sym_new ($1, @1); }
 430 | TYPE              { $$ = symbol_list_type_new ($1, @1); }
 431 | "<*>"             { $$ = symbol_list_default_tagged_new (@1); }
 432 | "<>"             { $$ = symbol_list_default_tagless_new (@1); }
 433 ;
 434
 435 /* One token definition.  */
 436 symbol_def:
 437   TYPE
 438      {
 439        current_type = $1;
 440        tag_seen = true;
 441      }
 442 | id
 443      {
 444        symbol_class_set ($1, current_class, @1, true);
 445        symbol_type_set ($1, current_type, @1);
 446      }
 447 | id INT
 448     {
 449       symbol_class_set ($1, current_class, @1, true);
 450       symbol_type_set ($1, current_type, @1);
 451       symbol_user_token_number_set ($1, $2, @2);
 452     }
 453 | id string_as_id
 454     {
 455       symbol_class_set ($1, current_class, @1, true);
 456       symbol_type_set ($1, current_type, @1);
 457       symbol_make_alias ($1, $2, @$);
 458     }
 459 | id INT string_as_id
 460     {
 461       symbol_class_set ($1, current_class, @1, true);
 462       symbol_type_set ($1, current_type, @1);
 463       symbol_user_token_number_set ($1, $2, @2);
 464       symbol_make_alias ($1, $3, @$);
 465     }
 466 ;
 467
 468 /* One or more symbol definitions. */
 469 symbol_defs.1:
 470   symbol_def
 471 | symbol_defs.1 symbol_def
 472 ;
 473
 474
 475         /*------------------------------------------.
 476         | The grammar section: between the two %%.  |
 477         `------------------------------------------*/
 478
 479 grammar:
 480   rules_or_grammar_declaration
 481 | grammar rules_or_grammar_declaration
 482 ;
 483
 484 /* As a Bison extension, one can use the grammar declarations in the
 485    body of the grammar.  */
 486 rules_or_grammar_declaration:
 487   rules
 488 | grammar_declaration ";"
 489 | error ";"
 490     {
 491       yyerrok;
 492     }
 493 ;
 494
 495 rules:
 496   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 497 ;
 498
 499 rhses.1:
 500   rhs                { grammar_current_rule_end (@1); }
 501 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 502 | rhses.1 ";"
 503 ;
 504
 505 rhs:
 506   /* Nothing.  */
 507     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 508 | rhs symbol
 509     { grammar_current_rule_symbol_append ($2, @2); }
 510 | rhs "{...}"
 511     { grammar_current_rule_action_append ($2, @2); }
 512 | rhs "%prec" symbol
 513     { grammar_current_rule_prec_set ($3, @3); }
 514 | rhs "%dprec" INT
 515     { grammar_current_rule_dprec_set ($3, @3); }
 516 | rhs "%merge" TYPE
 517     { grammar_current_rule_merge_set ($3, @3); }
 518 ;
 519
 520
 521 /*----------------------------*
 522  | variable and content.opt.  |
 523  *---------------------------*/
 524
 525 variable:
 526   ID
 527   | STRING { $$ = uniqstr_new ($1); } /* deprecated and not M4-friendly */
 528   ;
 529
 530 /* Some content or empty by default. */
 531 content.opt:
 532   /* Nothing. */
 533     {
 534       $$ = "";
 535     }
 536 | STRING
 537 ;
 538
 539
 540 /*-------------*
 541  | braceless.  |
 542  *-------------*/
 543
 544 braceless:
 545   "{...}"
 546     {
 547       code_props plain_code;
 548       $1[strlen ($1) - 1] = '\n';
 549       code_props_plain_init (&plain_code, $1+1, @1);
 550       code_props_translate_code (&plain_code);
 551       gram_scanner_last_string_free ();
 552       $$ = plain_code.code;
 553     }
 554 ;
 555
 556
 557 /*---------------*
 558  | Identifiers.  |
 559  *---------------*/
 560
 561 /* Identifiers are returned as uniqstr values by the scanner.
 562    Depending on their use, we may need to make them genuine symbols.  */
 563
 564 id:
 565   ID
 566     { $$ = symbol_from_uniqstr ($1, @1); }
 567 | CHAR
 568     {
 569       $$ = symbol_get (char_name ($1), @1);
 570       symbol_class_set ($$, token_sym, @1, false);
 571       symbol_user_token_number_set ($$, $1, @1);
 572     }
 573 ;
 574
 575 id_colon:
 576   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 577 ;
 578
 579
 580 symbol:
 581   id
 582 | string_as_id
 583 ;
 584
 585 /* A string used as an ID: quote it.  */
 586 string_as_id:
 587   STRING
 588     {
 589       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 590       symbol_class_set ($$, token_sym, @1, false);
 591     }
 592 ;
 593
 594 epilogue.opt:
 595   /* Nothing.  */
 596 | "%%" EPILOGUE
 597     {
 598       code_props plain_code;
 599       code_props_plain_init (&plain_code, $2, @2);
 600       code_props_translate_code (&plain_code);
 601       gram_scanner_last_string_free ();
 602       muscle_code_grow ("epilogue", plain_code.code, @2);
 603       code_scanner_last_string_free ();
 604     }
 605 ;
 606
 607 %%
 608
 609
 610 /* Return the location of the left-hand side of a rule whose
 611    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 612    the right-hand side, and return an empty location equal to the end
 613    boundary of RHS[0] if the right-hand side is empty.  */
 614
 615 static YYLTYPE
 616 lloc_default (YYLTYPE const *rhs, int n)
 617 {
 618   int i;
 619   YYLTYPE loc;
 620
 621   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 622      The bug is fixed in 7.4.2m, but play it safe for now.  */
 623   loc.start = rhs[n].end;
 624   loc.end = rhs[n].end;
 625
 626   /* Ignore empty nonterminals the start of the the right-hand side.
 627      Do not bother to ignore them at the end of the right-hand side,
 628      since empty nonterminals have the same end as their predecessors.  */
 629   for (i = 1; i <= n; i++)
 630     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 631       {
 632         loc.start = rhs[i].start;
 633         break;
 634       }
 635
 636   return loc;
 637 }
 638
 639
 640 /* Add a lex-param or a parse-param (depending on TYPE) with
 641    declaration DECL and location LOC.  */
 642
 643 static void
 644 add_param (char const *type, char *decl, location loc)
 645 {
 646   static char const alphanum[26 + 26 + 1 + 10] =
 647     "abcdefghijklmnopqrstuvwxyz"
 648     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 649     "_"
 650     "0123456789";
 651   char const *name_start = NULL;
 652   char *p;
 653
 654   /* Stop on last actual character.  */
 655   for (p = decl; p[1]; p++)
 656     if ((p == decl
 657          || ! memchr (alphanum, p[-1], sizeof alphanum))
 658         && memchr (alphanum, p[0], sizeof alphanum - 10))
 659       name_start = p;
 660
 661   /* Strip the surrounding '{' and '}', and any blanks just inside
 662      the braces.  */
 663   while (*--p == ' ' || *p == '\t')
 664     continue;
 665   p[1] = '\0';
 666   while (*++decl == ' ' || *decl == '\t')
 667     continue;
 668
 669   if (! name_start)
 670     complain_at (loc, _("missing identifier in parameter declaration"));
 671   else
 672     {
 673       char *name;
 674       size_t name_len;
 675
 676       for (name_len = 1;
 677            memchr (alphanum, name_start[name_len], sizeof alphanum);
 678            name_len++)
 679         continue;
 680
 681       name = xmalloc (name_len + 1);
 682       memcpy (name, name_start, name_len);
 683       name[name_len] = '\0';
 684       muscle_pair_list_grow (type, decl, name);
 685       free (name);
 686     }
 687
 688   gram_scanner_last_string_free ();
 689 }
 690
 691
 692 static void
 693 version_check (location const *loc, char const *version)
 694 {
 695   if (strverscmp (version, PACKAGE_VERSION) > 0)
 696     {
 697       complain_at (*loc, "require bison %s, but have %s",
 698                    version, PACKAGE_VERSION);
 699       exit (63);
 700     }
 701 }
 702
 703 static void
 704 gram_error (location const *loc, char const *msg)
 705 {
 706   complain_at (*loc, "%s", msg);
 707 }
 708
 709 char const *
 710 token_name (int type)
 711 {
 712   return yytname[YYTRANSLATE (type)];
 713 }
 714
 715 static char const *
 716 char_name (char c)
 717 {
 718   if (c == '\'')
 719     return "'\\''";
 720   else
 721     {
 722       char buf[4];
 723       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 724       return quotearg_style (escape_quoting_style, buf);
 725     }
 726 }