configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2010 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.
  21 AC_PREREQ(2.64)
  22
  23 AC_INIT([GNU Bison],
  24         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  25         [bug-bison@gnu.org])
  26 AC_DEFINE([PACKAGE_COPYRIGHT_YEAR], [2010],
  27           [The copyright year for this package])
  28 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2010])
  29
  30 AC_CONFIG_AUX_DIR([build-aux])
  31 AC_CONFIG_MACRO_DIR([m4])
  32
  33 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  34 #
  35 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  36 #
  37 # To avoid 1.11, we make 1.11.1 the minimum version.
  38 #
  39 # We want gnits strictness only when rolling a formal release so that we can,
  40 # for example, run make dist at other times without being required to add a
  41 # bogus NEWS entry.
  42 AM_INIT_AUTOMAKE([1.11.1 dist-bzip2]
  43                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [-], [gnu], [gnits]))
  44 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  45
  46 # Checks for the compiler.
  47 AC_PROG_CC_STDC
  48
  49 # Gnulib (early checks).
  50 gl_EARLY
  51
  52 AC_ARG_ENABLE(gcc-warnings,
  53 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  54 [case "${enableval}" in
  55    yes|no) ;;
  56    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  57  esac],
  58               [enableval=no])
  59 if test "${enableval}" = yes; then
  60   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  61   AC_SUBST([WERROR_CFLAGS])
  62   gl_WARN_ADD([-Wall])
  63   gl_WARN_ADD([-Wextra -Wno-sign-compare])
  64   gl_WARN_ADD([-Wcast-align])
  65   gl_WARN_ADD([-Wcast-qual])
  66   gl_WARN_ADD([-Wformat])
  67   gl_WARN_ADD([-Wpointer-arith])
  68   gl_WARN_ADD([-Wwrite-strings])
  69   AC_SUBST([WARN_CXXFLAGS], [$WARN_CFLAGS])
  70   # The following warnings are not suitable for C++.
  71   gl_WARN_ADD([-Wbad-function-cast])
  72   gl_WARN_ADD([-Wmissing-declarations])
  73   gl_WARN_ADD([-Wmissing-prototypes])
  74   gl_WARN_ADD([-Wshadow])
  75   gl_WARN_ADD([-Wstrict-prototypes])
  76   AC_SUBST([WARN_CFLAGS])
  77   # Warnings for the test suite only.
  78   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
  79   WARN_CXXFLAGS_TEST="$WARN_CXXFLAGS $WARN_CFLAGS_TEST"
  80   WARN_CFLAGS_TEST="$WARN_CFLAGS $WARN_CFLAGS_TEST"
  81   AC_SUBST([WARN_CXXFLAGS_TEST])
  82   AC_SUBST([WARN_CFLAGS_TEST])
  83   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  84 fi
  85
  86 BISON_TEST_FOR_WORKING_C_COMPILER
  87
  88 AC_ARG_ENABLE([yacc],
  89   [AC_HELP_STRING([--disable-yacc],
  90      [do not build a yacc command or an -ly library])],
  91   , [enable_yacc=yes])
  92 case $enable_yacc in
  93 yes)
  94   YACC_SCRIPT=yacc
  95   YACC_LIBRARY=liby.a;;
  96 *)
  97   YACC_SCRIPT=
  98   YACC_LIBRARY=;;
  99 esac
 100 AC_SUBST([YACC_SCRIPT])
 101 AC_SUBST([YACC_LIBRARY])
 102
 103 # Checks for programs.
 104 AC_PROG_LEX
 105 AC_PROG_YACC
 106 AC_PROG_RANLIB
 107 AC_PROG_GNU_M4
 108 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 109 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 110 supports -g, otherwise to "".])
 111 AM_MISSING_PROG([HELP2MAN], [help2man])
 112 AC_PATH_PROG([XSLTPROC], [xsltproc])
 113 AC_SUBST([XSLTPROC])
 114
 115 # Checks for header files.
 116 AC_CHECK_HEADERS_ONCE([locale.h])
 117
 118 # Checks for compiler characteristics.
 119 AC_C_INLINE
 120
 121 # Gnulib (later checks).  Putting them here rather than right after
 122 # gl_EARLY avoids some redundant checks.
 123 gl_INIT
 124
 125 # Checks for library functions.
 126 AC_CHECK_FUNCS_ONCE([setlocale])
 127 AM_WITH_DMALLOC
 128 BISON_PREREQ_SUBPIPE
 129 BISON_PREREQ_TIMEVAR
 130
 131 # Gettext.
 132 # We've never tested with gettext versions before 0.15, so play it safe.
 133 AM_GNU_GETTEXT([external], [need-ngettext])
 134 AM_GNU_GETTEXT_VERSION([0.15])
 135 BISON_I18N
 136
 137 # Internationalized parsers.
 138 AC_CONFIG_FILES([runtime-po/Makefile.in])
 139 # Autoconf macros for packages using internationalized parsers.
 140 aclocaldir='${datadir}/aclocal'
 141 AC_SUBST([aclocaldir])
 142
 143 # Create the benchmark script.
 144 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 145
 146 # Initialize the test suite.
 147 AC_CONFIG_TESTDIR(tests)
 148 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 149 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 150 AC_CHECK_PROGS([VALGRIND], [valgrind])
 151 AC_PROG_CXX
 152 BISON_TEST_FOR_WORKING_CXX_COMPILER
 153 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 154 # Needed by tests/atlocal.in.
 155 AC_SUBST([GCC])
 156 AC_SUBST([O0CFLAGS],   [`echo $CFLAGS   | sed 's/-O[[0-9]] *//'`])
 157 AC_SUBST([O0CXXFLAGS], [`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`])
 158
 159 gt_JAVACOMP([1.3])
 160 gt_JAVAEXEC
 161
 162 AC_CONFIG_FILES([Makefile
 163                  build-aux/Makefile
 164                  po/Makefile.in
 165                  data/Makefile
 166                  etc/Makefile
 167                  examples/Makefile
 168                     examples/calc++/Makefile
 169                  lib/Makefile src/Makefile
 170                  doc/Makefile
 171                    doc/yacc.1])
 172 AC_OUTPUT