m4/m4.m4

   1 # m4.m4 serial 10
   2
   3 # Copyright (C) 2000, 2006-2010 Free Software Foundation, Inc.
   4
   5 # Copying and distribution of this file, with or without modification,
   6 # are permitted in any medium without royalty provided the copyright
   7 # notice and this notice are preserved.  This file is offered as-is,
   8 # without warranty of any kind.
   9
  10 # AC_PROG_GNU_M4
  11 # --------------
  12 # Check for GNU M4, at least 1.4.6 (all earlier versions had bugs in
  13 # trace support and regexp support):
  14 # http://lists.gnu.org/archive/html/bug-gnu-utils/2006-11/msg00096.html
  15 # http://lists.gnu.org/archive/html/bug-autoconf/2009-07/msg00023.html
  16 # Also, check whether --error-output (through 1.4.x) or --debugfile (2.0)
  17 # is supported, and AC_SUBST M4_DEBUGFILE accordingly.
  18 AC_DEFUN([AC_PROG_GNU_M4],
  19   [AC_ARG_VAR([M4], [Location of GNU M4 1.4.6 or later.  Defaults to the first
  20     program of `m4', `gm4', or `gnum4' on PATH that meets Autoconf needs.])
  21   AC_CACHE_CHECK([for GNU M4 that supports accurate traces], [ac_cv_path_M4],
  22     [rm -f conftest.m4f
  23 ac_had_posixly_correct=${POSIXLY_CORRECT:+yes}
  24 AS_UNSET([POSIXLY_CORRECT])
  25 AC_PATH_PROGS_FEATURE_CHECK([M4], [m4 gm4 gnum4],
  26       [dnl Creative quoting here to avoid raw dnl and ifdef in configure.
  27       # Root out GNU M4 1.4.5, as well as non-GNU m4 that ignore -t, -F.
  28       ac_snippet=change'quote(<,>)in''dir(<if''def>,mac,bug)'
  29       ac_snippet=${ac_snippet}pat'subst(a,\(b\)\|\(a\),\1)d'nl
  30       test -z "`$ac_path_M4 -F conftest.m4f </dev/null 2>&1`" \
  31       && test -z "`AS_ECHO([$ac_snippet]) | $ac_path_M4 --trace=mac 2>&1`" \
  32       && test -f conftest.m4f \
  33       && ac_cv_path_M4=$ac_path_M4 ac_path_M4_found=:
  34       rm -f conftest.m4f],
  35       [AC_MSG_ERROR([no acceptable m4 could be found in \$PATH.
  36 GNU M4 1.4.6 or later is required; 1.4.13 is recommended])])])
  37   M4=$ac_cv_path_M4
  38   AC_CACHE_CHECK([whether $ac_cv_path_M4 accepts --gnu],
  39     [ac_cv_prog_gnu_m4_gnu],
  40     [case `$M4 --help < /dev/null 2>&1` in
  41       *--gnu*) ac_cv_prog_gnu_m4_gnu=yes ;;
  42       *) ac_cv_prog_gnu_m4_gnu=no ;;
  43     esac])
  44   if test "$ac_cv_prog_gnu_m4_gnu" = yes; then
  45     M4_GNU=--gnu
  46   else
  47     M4_GNU=
  48   fi
  49   AC_SUBST([M4_GNU])
  50   if test x$ac_had_posixly_correct = xyes; then
  51     POSIXLY_CORRECT=:
  52     if test $ac_cv_prog_gnu_m4_gnu = no; then
  53       AC_MSG_WARN([The version of M4 that was found does not support -g.])
  54       AC_MSG_WARN([Using it with POSIXLY_CORRECT set may cause problems.])
  55     fi
  56   fi
  57   AC_CACHE_CHECK([how m4 supports trace files], [ac_cv_prog_gnu_m4_debugfile],
  58     [case `$M4 --help < /dev/null 2>&1` in
  59       *debugfile*) ac_cv_prog_gnu_m4_debugfile=--debugfile ;;
  60       *) ac_cv_prog_gnu_m4_debugfile=--error-output ;;
  61     esac])
  62   AC_SUBST([M4_DEBUGFILE], [$ac_cv_prog_gnu_m4_debugfile])
  63 ])
  64
  65 # Compatibility for bootstrapping with Autoconf 2.61.
  66 dnl FIXME - replace this with AC_PREREQ([2.62]) after the release.
  67 # AC_PATH_PROGS_FEATURE_CHECK was added the same time the slightly broken,
  68 # undocumented _AC_PATH_PROG_FEATURE_CHECK was deleted.
  69 m4_ifndef([AC_PATH_PROGS_FEATURE_CHECK],
  70   [m4_define([AC_PATH_PROGS_FEATURE_CHECK],
  71     [_AC_PATH_PROG_FEATURE_CHECK([$1], [$2], [$3], [$5])
  72 ])])