src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation,
   4    Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software; you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation; either version 2 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program; if not, write to the Free Software
  20    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21    02110-1301  USA
  22 */
  23
  24 #include <config.h>
  25 #include "system.h"
  26
  27 #include <strverscmp.h>
  28
  29 #include "complain.h"
  30 #include "conflicts.h"
  31 #include "files.h"
  32 #include "getargs.h"
  33 #include "gram.h"
  34 #include "muscle_tab.h"
  35 #include "quotearg.h"
  36 #include "reader.h"
  37 #include "symlist.h"
  38 #include "scan-gram.h"
  39 #include "scan-code.h"
  40
  41 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  42 static YYLTYPE lloc_default (YYLTYPE const *, int);
  43
  44 #define YY_LOCATION_PRINT(File, Loc) \
  45           location_print (File, Loc)
  46
  47 static void version_check (location const *loc, char const *version);
  48
  49 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  50    FIXME: depends on the undocumented availability of YYLLOC.  */
  51 #undef  yyerror
  52 #define yyerror(Msg) \
  53         gram_error (&yylloc, Msg)
  54 static void gram_error (location const *, char const *);
  55
  56 static char const *char_name (char);
  57
  58 /** Add a lex-param or a parse-param.
  59  *
  60  * \param type  \a lex_param or \a parse_param
  61  * \param decl  the formal argument
  62  * \param loc   the location in the source.
  63  */
  64 static void add_param (char const *type, char *decl, location loc);
  65
  66
  67 static symbol_class current_class = unknown_sym;
  68 static uniqstr current_type = NULL;
  69 static symbol *current_lhs;
  70 static location current_lhs_location;
  71 static int current_prec = 0;
  72
  73 #define YYTYPE_INT16 int_fast16_t
  74 #define YYTYPE_INT8 int_fast8_t
  75 #define YYTYPE_UINT16 uint_fast16_t
  76 #define YYTYPE_UINT8 uint_fast8_t
  77 %}
  78
  79 %debug
  80 %verbose
  81 %defines
  82 %locations
  83 %pure-parser
  84 %error-verbose
  85 %name-prefix="gram_"
  86 %expect 0
  87
  88 %initial-action
  89 {
  90   /* Bison's grammar can initial empty locations, hence a default
  91      location is needed. */
  92   boundary_set (&@$.start, current_file, 1, 1);
  93   boundary_set (&@$.end, current_file, 1, 1);
  94 }
  95
  96 %union
  97 {
  98   symbol *symbol;
  99   symbol_list *list;
 100   int integer;
 101   char const *chars;
 102   char *code;
 103   assoc assoc;
 104   uniqstr uniqstr;
 105   unsigned char character;
 106 };
 107
 108 /* Define the tokens together with their human representation.  */
 109 %token GRAM_EOF 0 "end of file"
 110 %token STRING     "string"
 111 %token INT        "integer"
 112
 113 %token PERCENT_TOKEN       "%token"
 114 %token PERCENT_NTERM       "%nterm"
 115
 116 %token PERCENT_TYPE        "%type"
 117 %token PERCENT_DESTRUCTOR  "%destructor"
 118 %token PERCENT_PRINTER     "%printer"
 119
 120 %token PERCENT_LEFT        "%left"
 121 %token PERCENT_RIGHT       "%right"
 122 %token PERCENT_NONASSOC    "%nonassoc"
 123
 124 %token PERCENT_PREC          "%prec"
 125 %token PERCENT_DPREC         "%dprec"
 126 %token PERCENT_MERGE         "%merge"
 127
 128
 129 /*----------------------.
 130 | Global Declarations.  |
 131 `----------------------*/
 132
 133 %token
 134   PERCENT_CODE            "%code"
 135   PERCENT_DEBUG           "%debug"
 136   PERCENT_DEFAULT_PREC    "%default-prec"
 137   PERCENT_DEFINE          "%define"
 138   PERCENT_DEFINES         "%defines"
 139   PERCENT_ERROR_VERBOSE   "%error-verbose"
 140   PERCENT_EXPECT          "%expect"
 141   PERCENT_EXPECT_RR       "%expect-rr"
 142   PERCENT_FILE_PREFIX     "%file-prefix"
 143   PERCENT_GLR_PARSER      "%glr-parser"
 144   PERCENT_INITIAL_ACTION  "%initial-action"
 145   PERCENT_LANGUAGE        "%language"
 146   PERCENT_LEX_PARAM       "%lex-param"
 147   PERCENT_LOCATIONS       "%locations"
 148   PERCENT_NAME_PREFIX     "%name-prefix"
 149   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 150   PERCENT_NO_LINES        "%no-lines"
 151   PERCENT_NONDETERMINISTIC_PARSER
 152                           "%nondeterministic-parser"
 153   PERCENT_OUTPUT          "%output"
 154   PERCENT_PARSE_PARAM     "%parse-param"
 155   PERCENT_PURE_PARSER     "%pure-parser"
 156   PERCENT_PUSH_PARSER     "%push-parser"
 157   PERCENT_PUSH_PULL_PARSER
 158                           "%push-pull-parser"
 159   PERCENT_REQUIRE         "%require"
 160   PERCENT_SKELETON        "%skeleton"
 161   PERCENT_START           "%start"
 162   PERCENT_TOKEN_TABLE     "%token-table"
 163   PERCENT_VERBOSE         "%verbose"
 164   PERCENT_YACC            "%yacc"
 165 ;
 166
 167 %token BRACED_CODE     "{...}"
 168 %token CHAR            "char"
 169 %token EPILOGUE        "epilogue"
 170 %token EQUAL           "="
 171 %token ID              "identifier"
 172 %token ID_COLON        "identifier:"
 173 %token PERCENT_PERCENT "%%"
 174 %token PIPE            "|"
 175 %token PROLOGUE        "%{...%}"
 176 %token SEMICOLON       ";"
 177 %token TYPE            "type"
 178 %token TYPE_TAG_ANY    "<*>"
 179 %token TYPE_TAG_NONE   "<>"
 180
 181 %type <character> CHAR
 182 %printer { fputs (char_name ($$), stderr); } CHAR
 183
 184 /* braceless is not to be used for rule or symbol actions, as it
 185    calls code_props_plain_init.  */
 186 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 187 %type <code> "{...}"
 188 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 189          STRING
 190 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 191          braceless content.opt "{...}" "%{...%}" EPILOGUE
 192
 193 %type <uniqstr> TYPE ID ID_COLON variable
 194 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 195 %printer { fputs ($$, stderr); } ID variable
 196 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 197
 198 %type <integer> INT
 199 %printer { fprintf (stderr, "%d", $$); } INT
 200
 201 %type <symbol> id id_colon symbol string_as_id
 202 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 203 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 204
 205 %type <assoc> precedence_declarator
 206 %type <list>  symbols.1 generic_symlist generic_symlist_item
 207 %%
 208
 209 input:
 210   prologue_declarations "%%" grammar epilogue.opt
 211 ;
 212
 213
 214         /*------------------------------------.
 215         | Declarations: before the first %%.  |
 216         `------------------------------------*/
 217
 218 prologue_declarations:
 219   /* Nothing */
 220 | prologue_declarations prologue_declaration
 221 ;
 222
 223 prologue_declaration:
 224   grammar_declaration
 225 | "%{...%}"
 226     {
 227       code_props plain_code;
 228       code_props_plain_init (&plain_code, $1, @1);
 229       code_props_translate_code (&plain_code);
 230       gram_scanner_last_string_free ();
 231       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 232                         plain_code.code, @1);
 233       code_scanner_last_string_free ();
 234     }
 235 | "%debug"                         { debug_flag = true; }
 236 | "%define" variable content.opt
 237     {
 238       muscle_percent_define_insert ($2, @2, $3);
 239     }
 240 | "%defines"                       { defines_flag = true; }
 241 | "%defines" STRING
 242     {
 243       defines_flag = true;
 244       spec_defines_file = xstrdup ($2);
 245     }
 246 | "%error-verbose"                 { error_verbose = true; }
 247 | "%expect" INT                    { expected_sr_conflicts = $2; }
 248 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 249 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 250 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 251 | "%glr-parser"
 252     {
 253       nondeterministic_parser = true;
 254       glr_parser = true;
 255     }
 256 | "%initial-action" "{...}"
 257     {
 258       code_props action;
 259       code_props_symbol_action_init (&action, $2, @2);
 260       code_props_translate_code (&action);
 261       gram_scanner_last_string_free ();
 262       muscle_code_grow ("initial_action", action.code, @2);
 263       code_scanner_last_string_free ();
 264     }
 265 | "%language" STRING            { language_argmatch ($2, 1, &@1); }
 266 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 267 | "%locations"                  { locations_flag = true; }
 268 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 269 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 270 | "%no-lines"                   { no_lines_flag = true; }
 271 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 272 | "%output" STRING              { spec_outfile = $2; }
 273 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 274 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 275 | "%pure-parser"                { pure_parser = true; }
 276 | "%push-parser"                { push_parser = true; pull_parser = false; }
 277 | "%push-pull-parser"           { push_parser = true; pull_parser = true; }
 278 | "%require" STRING             { version_check (&@2, $2); }
 279 | "%skeleton" STRING
 280     {
 281       char const *skeleton_user = $2;
 282       if (strchr (skeleton_user, '/'))
 283         {
 284           size_t dir_length = strlen (current_file);
 285           char *skeleton_build;
 286           while (dir_length && current_file[dir_length - 1] != '/')
 287             --dir_length;
 288           while (dir_length && current_file[dir_length - 1] == '/')
 289             --dir_length;
 290           skeleton_build =
 291             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 292           if (dir_length > 0)
 293             {
 294               strncpy (skeleton_build, current_file, dir_length);
 295               skeleton_build[dir_length++] = '/';
 296             }
 297           strcpy (skeleton_build + dir_length, skeleton_user);
 298           skeleton_user = uniqstr_new (skeleton_build);
 299           free (skeleton_build);
 300         }
 301       skeleton_arg (skeleton_user, 1, &@1);
 302     }
 303 | "%token-table"                { token_table_flag = true; }
 304 | "%verbose"                    { report_flag = report_states; }
 305 | "%yacc"                       { yacc_flag = true; }
 306 | /*FIXME: Err?  What is this horror doing here? */ ";"
 307 ;
 308
 309 grammar_declaration:
 310   precedence_declaration
 311 | symbol_declaration
 312 | "%start" symbol
 313     {
 314       grammar_start_symbol_set ($2, @2);
 315     }
 316 | "%destructor" "{...}" generic_symlist
 317     {
 318       symbol_list *list;
 319       for (list = $3; list; list = list->next)
 320         symbol_list_destructor_set (list, $2, @2);
 321       symbol_list_free ($3);
 322     }
 323 | "%printer" "{...}" generic_symlist
 324     {
 325       symbol_list *list;
 326       for (list = $3; list; list = list->next)
 327         symbol_list_printer_set (list, $2, @2);
 328       symbol_list_free ($3);
 329     }
 330 | "%default-prec"
 331     {
 332       default_prec = true;
 333     }
 334 | "%no-default-prec"
 335     {
 336       default_prec = false;
 337     }
 338 | "%code" braceless
 339     {
 340       /* Do not invoke muscle_percent_code_grow here since it invokes
 341          muscle_user_name_list_grow.  */
 342       muscle_code_grow ("percent_code()", $2, @2);
 343       code_scanner_last_string_free ();
 344     }
 345 | "%code" ID braceless
 346     {
 347       muscle_percent_code_grow ($2, @2, $3, @3);
 348       code_scanner_last_string_free ();
 349     }
 350 ;
 351
 352
 353 /*----------*
 354  | %union.  |
 355  *----------*/
 356
 357 %token PERCENT_UNION "%union";
 358
 359 union_name:
 360   /* Nothing. */ {}
 361 | ID             { muscle_code_grow ("union_name", $1, @1); }
 362 ;
 363
 364 grammar_declaration:
 365   "%union" union_name braceless
 366     {
 367       union_seen = true;
 368       muscle_code_grow ("stype", $3, @3);
 369       code_scanner_last_string_free ();
 370     }
 371 ;
 372
 373
 374
 375
 376 symbol_declaration:
 377   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 378     {
 379       current_class = unknown_sym;
 380       current_type = NULL;
 381     }
 382 | "%token" { current_class = token_sym; } symbol_defs.1
 383     {
 384       current_class = unknown_sym;
 385       current_type = NULL;
 386     }
 387 | "%type" TYPE symbols.1
 388     {
 389       symbol_list *list;
 390       tag_seen = true;
 391       for (list = $3; list; list = list->next)
 392         symbol_type_set (list->content.sym, $2, @2);
 393       symbol_list_free ($3);
 394     }
 395 ;
 396
 397 precedence_declaration:
 398   precedence_declarator type.opt symbols.1
 399     {
 400       symbol_list *list;
 401       ++current_prec;
 402       for (list = $3; list; list = list->next)
 403         {
 404           symbol_type_set (list->content.sym, current_type, @2);
 405           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 406         }
 407       symbol_list_free ($3);
 408       current_type = NULL;
 409     }
 410 ;
 411
 412 precedence_declarator:
 413   "%left"     { $$ = left_assoc; }
 414 | "%right"    { $$ = right_assoc; }
 415 | "%nonassoc" { $$ = non_assoc; }
 416 ;
 417
 418 type.opt:
 419   /* Nothing. */ { current_type = NULL; }
 420 | TYPE           { current_type = $1; tag_seen = true; }
 421 ;
 422
 423 /* One or more symbols to be %typed. */
 424 symbols.1:
 425   symbol
 426     { $$ = symbol_list_sym_new ($1, @1); }
 427 | symbols.1 symbol
 428     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 429 ;
 430
 431 generic_symlist:
 432   generic_symlist_item { $$ = $1; }
 433 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 434 ;
 435
 436 generic_symlist_item:
 437   symbol            { $$ = symbol_list_sym_new ($1, @1); }
 438 | TYPE              { $$ = symbol_list_type_new ($1, @1); }
 439 | "<*>"             { $$ = symbol_list_default_tagged_new (@1); }
 440 | "<>"             { $$ = symbol_list_default_tagless_new (@1); }
 441 ;
 442
 443 /* One token definition.  */
 444 symbol_def:
 445   TYPE
 446      {
 447        current_type = $1;
 448        tag_seen = true;
 449      }
 450 | id
 451      {
 452        symbol_class_set ($1, current_class, @1, true);
 453        symbol_type_set ($1, current_type, @1);
 454      }
 455 | id INT
 456     {
 457       symbol_class_set ($1, current_class, @1, true);
 458       symbol_type_set ($1, current_type, @1);
 459       symbol_user_token_number_set ($1, $2, @2);
 460     }
 461 | id string_as_id
 462     {
 463       symbol_class_set ($1, current_class, @1, true);
 464       symbol_type_set ($1, current_type, @1);
 465       symbol_make_alias ($1, $2, @$);
 466     }
 467 | id INT string_as_id
 468     {
 469       symbol_class_set ($1, current_class, @1, true);
 470       symbol_type_set ($1, current_type, @1);
 471       symbol_user_token_number_set ($1, $2, @2);
 472       symbol_make_alias ($1, $3, @$);
 473     }
 474 ;
 475
 476 /* One or more symbol definitions. */
 477 symbol_defs.1:
 478   symbol_def
 479 | symbol_defs.1 symbol_def
 480 ;
 481
 482
 483         /*------------------------------------------.
 484         | The grammar section: between the two %%.  |
 485         `------------------------------------------*/
 486
 487 grammar:
 488   rules_or_grammar_declaration
 489 | grammar rules_or_grammar_declaration
 490 ;
 491
 492 /* As a Bison extension, one can use the grammar declarations in the
 493    body of the grammar.  */
 494 rules_or_grammar_declaration:
 495   rules
 496 | grammar_declaration ";"
 497 | error ";"
 498     {
 499       yyerrok;
 500     }
 501 ;
 502
 503 rules:
 504   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 505 ;
 506
 507 rhses.1:
 508   rhs                { grammar_current_rule_end (@1); }
 509 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 510 | rhses.1 ";"
 511 ;
 512
 513 rhs:
 514   /* Nothing.  */
 515     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 516 | rhs symbol
 517     { grammar_current_rule_symbol_append ($2, @2); }
 518 | rhs "{...}"
 519     { grammar_current_rule_action_append ($2, @2); }
 520 | rhs "%prec" symbol
 521     { grammar_current_rule_prec_set ($3, @3); }
 522 | rhs "%dprec" INT
 523     { grammar_current_rule_dprec_set ($3, @3); }
 524 | rhs "%merge" TYPE
 525     { grammar_current_rule_merge_set ($3, @3); }
 526 ;
 527
 528
 529 /*----------------------------*
 530  | variable and content.opt.  |
 531  *---------------------------*/
 532
 533 variable:
 534   ID
 535   | STRING { $$ = uniqstr_new ($1); } /* deprecated and not M4-friendly */
 536   ;
 537
 538 /* Some content or empty by default. */
 539 content.opt:
 540   /* Nothing. */
 541     {
 542       $$ = "";
 543     }
 544 | STRING
 545 ;
 546
 547
 548 /*-------------*
 549  | braceless.  |
 550  *-------------*/
 551
 552 braceless:
 553   "{...}"
 554     {
 555       code_props plain_code;
 556       $1[strlen ($1) - 1] = '\n';
 557       code_props_plain_init (&plain_code, $1+1, @1);
 558       code_props_translate_code (&plain_code);
 559       gram_scanner_last_string_free ();
 560       $$ = plain_code.code;
 561     }
 562 ;
 563
 564
 565 /*---------------*
 566  | Identifiers.  |
 567  *---------------*/
 568
 569 /* Identifiers are returned as uniqstr values by the scanner.
 570    Depending on their use, we may need to make them genuine symbols.  */
 571
 572 id:
 573   ID
 574     { $$ = symbol_from_uniqstr ($1, @1); }
 575 | CHAR
 576     {
 577       $$ = symbol_get (char_name ($1), @1);
 578       symbol_class_set ($$, token_sym, @1, false);
 579       symbol_user_token_number_set ($$, $1, @1);
 580     }
 581 ;
 582
 583 id_colon:
 584   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 585 ;
 586
 587
 588 symbol:
 589   id
 590 | string_as_id
 591 ;
 592
 593 /* A string used as an ID: quote it.  */
 594 string_as_id:
 595   STRING
 596     {
 597       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 598       symbol_class_set ($$, token_sym, @1, false);
 599     }
 600 ;
 601
 602 epilogue.opt:
 603   /* Nothing.  */
 604 | "%%" EPILOGUE
 605     {
 606       code_props plain_code;
 607       code_props_plain_init (&plain_code, $2, @2);
 608       code_props_translate_code (&plain_code);
 609       gram_scanner_last_string_free ();
 610       muscle_code_grow ("epilogue", plain_code.code, @2);
 611       code_scanner_last_string_free ();
 612     }
 613 ;
 614
 615 %%
 616
 617
 618 /* Return the location of the left-hand side of a rule whose
 619    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 620    the right-hand side, and return an empty location equal to the end
 621    boundary of RHS[0] if the right-hand side is empty.  */
 622
 623 static YYLTYPE
 624 lloc_default (YYLTYPE const *rhs, int n)
 625 {
 626   int i;
 627   YYLTYPE loc;
 628
 629   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 630      The bug is fixed in 7.4.2m, but play it safe for now.  */
 631   loc.start = rhs[n].end;
 632   loc.end = rhs[n].end;
 633
 634   /* Ignore empty nonterminals the start of the the right-hand side.
 635      Do not bother to ignore them at the end of the right-hand side,
 636      since empty nonterminals have the same end as their predecessors.  */
 637   for (i = 1; i <= n; i++)
 638     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 639       {
 640         loc.start = rhs[i].start;
 641         break;
 642       }
 643
 644   return loc;
 645 }
 646
 647
 648 /* Add a lex-param or a parse-param (depending on TYPE) with
 649    declaration DECL and location LOC.  */
 650
 651 static void
 652 add_param (char const *type, char *decl, location loc)
 653 {
 654   static char const alphanum[26 + 26 + 1 + 10] =
 655     "abcdefghijklmnopqrstuvwxyz"
 656     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 657     "_"
 658     "0123456789";
 659   char const *name_start = NULL;
 660   char *p;
 661
 662   /* Stop on last actual character.  */
 663   for (p = decl; p[1]; p++)
 664     if ((p == decl
 665          || ! memchr (alphanum, p[-1], sizeof alphanum))
 666         && memchr (alphanum, p[0], sizeof alphanum - 10))
 667       name_start = p;
 668
 669   /* Strip the surrounding '{' and '}', and any blanks just inside
 670      the braces.  */
 671   while (*--p == ' ' || *p == '\t')
 672     continue;
 673   p[1] = '\0';
 674   while (*++decl == ' ' || *decl == '\t')
 675     continue;
 676
 677   if (! name_start)
 678     complain_at (loc, _("missing identifier in parameter declaration"));
 679   else
 680     {
 681       char *name;
 682       size_t name_len;
 683
 684       for (name_len = 1;
 685            memchr (alphanum, name_start[name_len], sizeof alphanum);
 686            name_len++)
 687         continue;
 688
 689       name = xmalloc (name_len + 1);
 690       memcpy (name, name_start, name_len);
 691       name[name_len] = '\0';
 692       muscle_pair_list_grow (type, decl, name);
 693       free (name);
 694     }
 695
 696   gram_scanner_last_string_free ();
 697 }
 698
 699
 700 static void
 701 version_check (location const *loc, char const *version)
 702 {
 703   if (strverscmp (version, PACKAGE_VERSION) > 0)
 704     {
 705       complain_at (*loc, "require bison %s, but have %s",
 706                    version, PACKAGE_VERSION);
 707       exit (63);
 708     }
 709 }
 710
 711 static void
 712 gram_error (location const *loc, char const *msg)
 713 {
 714   complain_at (*loc, "%s", msg);
 715 }
 716
 717 char const *
 718 token_name (int type)
 719 {
 720   return yytname[YYTRANSLATE (type)];
 721 }
 722
 723 static char const *
 724 char_name (char c)
 725 {
 726   if (c == '\'')
 727     return "'\\''";
 728   else
 729     {
 730       char buf[4];
 731       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 732       return quotearg_style (escape_quoting_style, buf);
 733     }
 734 }