data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4 # Copyright (C) 2002, 2004, 2005, 2006, 2007, 2008, 2009
   5 # Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 ## ---------------- ##
  22 ## Identification.  ##
  23 ## ---------------- ##
  24
  25 # b4_copyright(TITLE, [YEARS])
  26 # ----------------------------
  27 # If YEARS are not defined, use b4_copyright_years.
  28 m4_define([b4_copyright],
  29 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  30
  31 b4_comment([$1
  32
  33 ]m4_dquote(m4_text_wrap([Copyright (C)
  34 ]m4_ifval([$2], [[$2]], [m4_defn([b4_copyright_years])])[
  35 Free Software Foundation, Inc.]))[
  36
  37 This program is free software: you can redistribute it and/or modify
  38 it under the terms of the GNU General Public License as published by
  39 the Free Software Foundation, either version 3 of the License, or
  40 (at your option) any later version.
  41
  42 This program is distributed in the hope that it will be useful,
  43 but WITHOUT ANY WARRANTY; without even the implied warranty of
  44 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  45 GNU General Public License for more details.
  46
  47 You should have received a copy of the GNU General Public License
  48 along with this program.  If not, see <http://www.gnu.org/licenses/>.])
  49
  50 b4_comment([As a special exception, you may create a larger work that contains
  51 part or all of the Bison parser skeleton and distribute that work
  52 under terms of your choice, so long as that work isn't itself a
  53 parser generator using the skeleton or a modified version thereof
  54 as a parser skeleton.  Alternatively, if you modify or redistribute
  55 the parser skeleton itself, you may (at your option) remove this
  56 special exception, which will cause the skeleton and the resulting
  57 Bison output files to be licensed under the GNU General Public
  58 License without this special exception.
  59
  60 This special exception was added by the Free Software Foundation in
  61 version 2.2 of Bison.])])
  62
  63
  64 ## ---------------- ##
  65 ## Error handling.  ##
  66 ## ---------------- ##
  67
  68 # The following error handling macros print error directives that should not
  69 # become arguments of other macro invocations since they would likely then be
  70 # mangled.  Thus, they print to stdout directly.
  71
  72 # b4_cat(TEXT)
  73 # ------------
  74 # Write TEXT to stdout.  Precede the final newline with an @ so that it's
  75 # escaped.  For example:
  76 #
  77 #   b4_cat([[@complain(invalid input@)]])
  78 m4_define([b4_cat],
  79 [m4_syscmd([cat <<'_m4eof'
  80 ]m4_bpatsubst(m4_dquote($1), [_m4eof], [_m4@`eof])[@
  81 _m4eof
  82 ])dnl
  83 m4_if(m4_sysval, [0], [], [m4_fatal([$0: cannot write to stdout])])])
  84
  85 # b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
  86 # -------------------------------------------
  87 # Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to stdout.
  88 #
  89 # For example:
  90 #
  91 #   b4_error([[warn]], [[invalid value for `%s': %s]], [[foo]], [[3]])
  92 m4_define([b4_error],
  93 [b4_cat([[@]$1[(]$2[]]dnl
  94 [m4_if([$#], [2], [],
  95        [m4_foreach([b4_arg],
  96                    m4_dquote(m4_shift(m4_shift($@))),
  97                    [[@,]b4_arg])])[@)]])])
  98
  99 # b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
 100 # ----------------------------------------------------------
 101 # Write @KIND_at(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 102 #
 103 # For example:
 104 #
 105 #   b4_error_at([[complain]], [[input.y:2.3]], [[input.y:5.4]],
 106 #               [[invalid %s]], [[foo]])
 107 m4_define([b4_error_at],
 108 [b4_cat([[@]$1[_at(]$2[@,]$3[@,]$4[]]dnl
 109 [m4_if([$#], [4], [],
 110        [m4_foreach([b4_arg],
 111                    m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
 112                    [[@,]b4_arg])])[@)]])])
 113
 114 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
 115 # ------------------------------------
 116 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 117 #
 118 # For example:
 119 #
 120 #   b4_warn([[invalid value for `%s': %s]], [[foo]], [[3]])
 121 #
 122 # As a simple test suite, this:
 123 #
 124 #   m4_divert(-1)
 125 #   m4_define([asdf], [ASDF])
 126 #   m4_define([fsa], [FSA])
 127 #   m4_define([fdsa], [FDSA])
 128 #   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
 129 #   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
 130 #   b4_warn()
 131 #   b4_warn(1)
 132 #   b4_warn(1, 2)
 133 #
 134 # Should produce this without newlines:
 135 #
 136 #   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
 137 #   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
 138 #   @warn(@)
 139 #   @warn(1@)
 140 #   @warn(1@,2@)
 141 m4_define([b4_warn],
 142 [b4_error([[warn]], $@)])
 143
 144 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 145 # ---------------------------------------------------
 146 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 147 #
 148 # For example:
 149 #
 150 #   b4_warn_at([[input.y:2.3]], [[input.y:5.4]], [[invalid %s]], [[foo]])
 151 m4_define([b4_warn_at],
 152 [b4_error_at([[warn]], $@)])
 153
 154 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 155 # ----------------------------------------
 156 # Write @complain(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 157 #
 158 # See b4_warn example.
 159 m4_define([b4_complain],
 160 [b4_error([[complain]], $@)])
 161
 162 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 163 # -------------------------------------------------------
 164 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 165 #
 166 # See b4_warn_at example.
 167 m4_define([b4_complain_at],
 168 [b4_error_at([[complain]], $@)])
 169
 170 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 171 # -------------------------------------
 172 # Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 173 #
 174 # See b4_warn example.
 175 m4_define([b4_fatal],
 176 [b4_error([[fatal]], $@)dnl
 177 m4_exit(1)])
 178
 179 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 180 # ----------------------------------------------------
 181 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 182 #
 183 # See b4_warn_at example.
 184 m4_define([b4_fatal_at],
 185 [b4_error_at([[fatal]], $@)dnl
 186 m4_exit(1)])
 187
 188
 189 ## ---------------- ##
 190 ## Default values.  ##
 191 ## ---------------- ##
 192
 193 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 194 m4_define_default([b4_pre_prologue], [])
 195 m4_define_default([b4_post_prologue], [])
 196 m4_define_default([b4_epilogue], [])
 197 m4_define_default([b4_parse_param], [])
 198
 199 # The initial column and line.
 200 m4_define_default([b4_location_initial_column], [1])
 201 m4_define_default([b4_location_initial_line],   [1])
 202
 203
 204 ## ------------ ##
 205 ## Data Types.  ##
 206 ## ------------ ##
 207
 208 # b4_ints_in(INT1, INT2, LOW, HIGH)
 209 # ---------------------------------
 210 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 211 m4_define([b4_ints_in],
 212 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 213
 214
 215 # b4_subtract(LHS, RHS)
 216 # ---------------------
 217 # Evaluate LHS - RHS if they are integer literals, otherwise expand
 218 # to (LHS) - (RHS).
 219 m4_define([b4_subtract],
 220 [m4_bmatch([$1$2], [^[0123456789]*$],
 221            [m4_eval([$1 - $2])],
 222            [($1) - ($2)])])
 223
 224 # b4_args(ARG1, ...)
 225 # _b4_args(ARG1, ...)
 226 # -------------------
 227 # Join with comma, skipping empty arguments.
 228 # b4_args calls itself recursively until it sees the first non-empty
 229 # argument, then calls _b4_args which prepends each non-empty argument
 230 # with a comma.
 231 m4_define([b4_args],
 232 [m4_if([$#$1],
 233        [1], [],
 234        [m4_ifval([$1],
 235                  [$1[]_$0(m4_shift($@))],
 236                  [$0(m4_shift($@))])])])
 237
 238 # _b4_args(ARGS1, ...)
 239 # --------------------
 240 m4_define([_b4_args],
 241 [m4_if([$#$1],
 242        [1], [],
 243        [m4_ifval([$1], [, $1])[]$0(m4_shift($@))])])
 244
 245
 246
 247
 248 # b4_integral_parser_tables_map(MACRO)
 249 # -------------------------------------
 250 # Map MACRO on all the integral tables.  MACRO is expected to have
 251 # the signature MACRO(TABLE-NAME, CONTENT, COMMENT).
 252 m4_define([b4_integral_parser_tables_map],
 253 [$1([pact], [b4_pact],
 254     [[YYPACT[STATE-NUM] -- Index in YYTABLE of the portion describing
 255 STATE-NUM.]])
 256
 257 $1([defact], [b4_defact],
 258    [[YYDEFACT[S] -- default rule to reduce with in state S when YYTABLE
 259 does not specify something else to do.  Zero means the default is an
 260 error.]])
 261
 262 $1([pgoto], [b4_pgoto], [[YYPGOTO[NTERM-NUM].]])
 263
 264 $1([defgoto], [b4_defgoto], [[YYDEFGOTO[NTERM-NUM].]])
 265
 266 $1([table], [b4_table],
 267    [[YYTABLE[YYPACT[STATE-NUM]].  What to do in state STATE-NUM.  If
 268 positive, shift that token.  If negative, reduce the rule which
 269 number is the opposite.  If zero, do what YYDEFACT says.
 270 If YYTABLE_NINF, syntax error.]])
 271
 272 $1([check], [b4_check])
 273
 274 $1([stos], [b4_stos],
 275    [[STOS_[STATE-NUM] -- The (internal number of the) accessing
 276 symbol of state STATE-NUM.]])
 277
 278 $1([r1], [b4_r1],
 279    [[YYR1[YYN] -- Symbol number of symbol that rule YYN derives.]])
 280
 281 $1([r2], [b4_r2],
 282    [[YYR2[YYN] -- Number of symbols composing right hand side of rule YYN.]])
 283 ])
 284
 285
 286 # b4_parser_tables_declare
 287 # b4_parser_tables_define
 288 # ------------------------
 289 # Define/declare the (deterministic) parser tables.
 290 m4_define([b4_parser_tables_declare],
 291 [b4_integral_parser_tables_map([b4_integral_parser_table_declare])])
 292
 293 m4_define([b4_parser_tables_define],
 294 [b4_integral_parser_tables_map([b4_integral_parser_table_define])])
 295
 296
 297
 298 ## ------------------ ##
 299 ## Decoding options.  ##
 300 ## ------------------ ##
 301
 302 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 303 # -----------------------------------
 304 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 305 m4_define([b4_flag_if],
 306 [m4_case(b4_$1_flag,
 307          [0], [$3],
 308          [1], [$2],
 309          [m4_fatal([invalid $1 value: ]$1)])])
 310
 311
 312 # b4_define_flag_if(FLAG)
 313 # -----------------------
 314 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 315 # value of the Boolean FLAG.
 316 m4_define([b4_define_flag_if],
 317 [_b4_define_flag_if($[1], $[2], [$1])])
 318
 319 # _b4_define_flag_if($1, $2, FLAG)
 320 # --------------------------------
 321 # This macro works around the impossibility to define macros
 322 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 323 # This sucks hard, GNU M4 should really provide M5 like $$1.
 324 m4_define([_b4_define_flag_if],
 325 [m4_if([$1$2], $[1]$[2], [],
 326        [m4_fatal([$0: Invalid arguments: $@])])dnl
 327 m4_define([b4_$3_if],
 328           [b4_flag_if([$3], [$1], [$2])])])
 329
 330
 331 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 332 # -----------------------------
 333 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 334 b4_define_flag_if([defines])            # Whether headers are requested.
 335 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 336 b4_define_flag_if([locations])          # Whether locations are tracked.
 337 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 338 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 339
 340
 341 ## --------- ##
 342 ## Symbols.  ##
 343 ## --------- ##
 344
 345 # b4_symbol_(NUM, FIELD)
 346 # ----------------------
 347 # Recover a FIELD about symbol #NUM.  Thanks to m4_indir, fails if
 348 # undefined.
 349 m4_define([b4_symbol_],
 350 [m4_indir([b4_symbol($1, $2)])])
 351
 352
 353 # b4_symbol(NUM, FIELD)
 354 # ---------------------
 355 # Recover a FIELD about symbol #NUM.  Thanks to m4_indir, fails if
 356 # undefined.  If FIELD = id, prepend the prefix.
 357 m4_define([b4_symbol],
 358 [m4_case([$2],
 359          [id],    [m4_do([b4_percent_define_get([token.prefix])],
 360                          [b4_symbol_([$1], [id])])],
 361          [b4_symbol_($@)])])
 362
 363
 364 # b4_symbol_if(NUM, FIELD, IF-TRUE, IF-FALSE)
 365 # -------------------------------------------
 366 # If FIELD about symbol #NUM is 1 expand IF-TRUE, if is 0, expand IF-FALSE.
 367 # Otherwise an error.
 368 m4_define([b4_symbol_if],
 369 [m4_case(b4_symbol([$1], [$2]),
 370          [1], [$3],
 371          [0], [$4],
 372          [m4_fatal([$0: field $2 of $1 is not a Boolean:] b4_symbol([$1], [$2]))])])
 373
 374
 375 # b4_symbol_action_location(SYMBOL-NUM, KIND)
 376 # -------------------------------------------
 377 # Report the location of the KIND action as FILE:LINE.
 378 m4_define([b4_symbol_action_location],
 379 [b4_symbol([$1], [$2_file]):b4_syncline([b4_symbol([$1], [$2_line])])])
 380
 381
 382 # b4_symbol_action(SYMBOL-NUM, KIND)
 383 # ----------------------------------
 384 # Run the action KIND (destructor or printer) for SYMBOL-NUM.
 385 # Same as in C, but using references instead of pointers.
 386 m4_define([b4_symbol_action],
 387 [b4_symbol_if([$1], [has_$2],
 388 [m4_pushdef([b4_dollar_dollar],
 389     [b4_symbol_value([(*yyvaluep)],
 390                      b4_symbol_if([$1], [has_type],
 391                                   [b4_symbol([$1], [type])]))])dnl
 392 m4_pushdef([b4_at_dollar], [(*yylocationp)])dnl
 393       b4_symbol_case_([$1])
 394 b4_syncline([b4_symbol([$1], [$2_line])], ["b4_symbol([$1], [$2_file])"])
 395         b4_symbol([$1], [$2])
 396 b4_syncline([@oline@], [@ofile@])
 397         break;
 398
 399 m4_popdef([b4_at_dollar])dnl
 400 m4_popdef([b4_dollar_dollar])dnl
 401 ])])
 402
 403
 404 # b4_symbol_destructor(SYMBOL-NUM)
 405 # b4_symbol_printer(SYMBOL-NUM)
 406 # --------------------------------
 407 m4_define([b4_symbol_destructor], [b4_symbol_action([$1], [destructor])])
 408 m4_define([b4_symbol_printer],    [b4_symbol_action([$1], [printer])])
 409
 410
 411 # b4_symbol_case_(SYMBOL-NUM)
 412 # ---------------------------
 413 # Issue a "case NUM" for SYMBOL-NUM.
 414 m4_define([b4_symbol_case_],
 415 [      case b4_symbol([$1], [number]): // b4_symbol([$1], [tag])
 416 ])
 417
 418
 419 # b4_symbol_foreach(MACRO)
 420 # ------------------------
 421 # Invoke MACRO(SYMBOL-NUM) for each SYMBOL-NUM.
 422 m4_define([b4_symbol_foreach],
 423           [m4_map([$1], m4_defn([b4_symbol_numbers]))])
 424
 425
 426 ## ------- ##
 427 ## Types.  ##
 428 ## ------- ##
 429
 430 # b4_type_action_(NUMS)
 431 # ---------------------
 432 # Run actions for the symbol NUMS that all have the same type-name.
 433 # Skip NUMS that have no type-name.
 434 m4_define([b4_type_action_],
 435 [b4_symbol_if([$1], [has_type],
 436 [m4_map([b4_symbol_case_], [$@])[]dnl
 437         b4_dollar_dollar([b4_symbol([$1], [number])],
 438                          [b4_symbol([$1], [tag])],
 439                          [b4_symbol([$1], [type])]);
 440         break;
 441
 442 ])])
 443
 444 # b4_type_foreach(MACRO)
 445 # ----------------------
 446 # Invoke MACRO(SYMBOL-NUMS) for each set of SYMBOL-NUMS for each type set.
 447 m4_define([b4_type_foreach],
 448           [m4_map([$1], m4_defn([b4_type_names]))])
 449
 450
 451
 452 ## ----------- ##
 453 ## Synclines.  ##
 454 ## ----------- ##
 455
 456 # b4_basename(NAME)
 457 # -----------------
 458 # Similar to POSIX basename; the differences don't matter here.
 459 # Beware that NAME is not evaluated.
 460 m4_define([b4_basename],
 461 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 462
 463
 464 # b4_syncline(LINE, FILE)
 465 # -----------------------
 466 m4_define([b4_syncline],
 467 [b4_flag_if([synclines],
 468 [b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 469 b4_sync_start([$1], [$2])])])
 470
 471 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 472 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 473
 474 # b4_user_code(USER-CODE)
 475 # -----------------------
 476 # Emit code from the user, ending it with synclines.
 477 m4_define([b4_user_code],
 478 [$1
 479 b4_syncline([@oline@], [@ofile@])])
 480
 481
 482 # b4_define_user_code(MACRO)
 483 # --------------------------
 484 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 485 m4_define([b4_define_user_code],
 486 [m4_define([b4_user_$1],
 487 [b4_user_code([b4_$1])])])
 488
 489
 490 # b4_user_actions
 491 # b4_user_initial_action
 492 # b4_user_post_prologue
 493 # b4_user_pre_prologue
 494 # b4_user_stype
 495 # ----------------------
 496 # Macros that issue user code, ending with synclines.
 497 b4_define_user_code([actions])
 498 b4_define_user_code([initial_action])
 499 b4_define_user_code([post_prologue])
 500 b4_define_user_code([pre_prologue])
 501 b4_define_user_code([stype])
 502
 503
 504 # b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
 505 # --------------------------------------------------------
 506 # Warn if any name of type WHAT is used by the user (as recorded in USER-LIST)
 507 # but is not used by Bison (as recorded by macros in the namespace
 508 # BISON-NAMESPACE).
 509 #
 510 # USER-LIST must expand to a list specifying all grammar occurrences of all
 511 # names of type WHAT.   Each item in the list must be a triplet specifying one
 512 # occurrence: name, start boundary, and end boundary.  Empty string names are
 513 # fine.  An empty list is fine.
 514 #
 515 # For example, to define b4_foo_user_names to be used for USER-LIST with three
 516 # name occurrences and with correct quoting:
 517 #
 518 #   m4_define([b4_foo_user_names],
 519 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 520 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 521 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 522 #
 523 # The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
 524 # is used by Bison (in the front-end or in the skeleton).  Empty string names
 525 # are fine, but it would be ugly for Bison to actually use one.
 526 #
 527 # For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
 528 # the names bar and baz are used by Bison:
 529 #
 530 #   m4_define([b4_foo_bison_names(bar)])
 531 #   m4_define([b4_foo_bison_names(baz)])
 532 #
 533 # To invoke b4_check_user_names with TYPE foo, with USER-LIST
 534 # b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
 535 # quoting:
 536 #
 537 #   b4_check_user_names([[foo]], [b4_foo_user_names],
 538 #                       [[b4_foo_bison_names]])
 539 m4_define([b4_check_user_names],
 540 [m4_foreach([b4_occurrence], $2,
 541 [m4_pushdef([b4_occurrence], b4_occurrence)dnl
 542 m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
 543 m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
 544 m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
 545 m4_ifndef($3[(]m4_quote(b4_user_name)[)],
 546           [b4_warn_at([b4_start], [b4_end],
 547                       [[%s `%s' is not used]],
 548                       [$1], [b4_user_name])])[]dnl
 549 m4_popdef([b4_occurrence])dnl
 550 m4_popdef([b4_user_name])dnl
 551 m4_popdef([b4_start])dnl
 552 m4_popdef([b4_end])dnl
 553 ])])
 554
 555 # b4_percent_define_get(VARIABLE)
 556 # -------------------------------
 557 # Mimic muscle_percent_define_get in ../src/muscle_tab.h exactly.  That is, if
 558 # the %define variable VARIABLE is defined, emit its value.  Also, record
 559 # Bison's usage of VARIABLE by defining
 560 # b4_percent_define_bison_variables(VARIABLE).
 561 #
 562 # For example:
 563 #
 564 #   b4_percent_define_get([[foo]])
 565 m4_define([b4_percent_define_get],
 566 [m4_define([b4_percent_define_bison_variables(]$1[)])dnl
 567 m4_ifdef([b4_percent_define(]$1[)], [m4_indir([b4_percent_define(]$1[)])])])
 568
 569 # b4_percent_define_get_loc(VARIABLE)
 570 # -----------------------------------
 571 # Mimic muscle_percent_define_get_loc in ../src/muscle_tab.h exactly.  That is,
 572 # if the %define variable VARIABLE is undefined, complain fatally since that's
 573 # a Bison or skeleton error.  Otherwise, return its definition location in a
 574 # form approriate for the first two arguments of b4_warn_at, b4_complain_at, or
 575 # b4_fatal_at.  Don't record this as a Bison usage of VARIABLE as there's no
 576 # reason to suspect that the user-supplied value has yet influenced the output.
 577 #
 578 # For example:
 579 #
 580 #   b4_complain_at(b4_percent_define_get_loc([[foo]]), [[invalid foo]])
 581 m4_define([b4_percent_define_get_loc],
 582 [m4_ifdef([b4_percent_define_loc(]$1[)],
 583           [m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
 584 b4_loc[]dnl
 585 m4_popdef([b4_loc])],
 586           [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_get_loc]], [$1])])])
 587
 588 # b4_percent_define_get_syncline(VARIABLE)
 589 # ----------------------------------------
 590 # Mimic muscle_percent_define_get_syncline in ../src/muscle_tab.h exactly.
 591 # That is, if the %define variable VARIABLE is undefined, complain fatally
 592 # since that's a Bison or skeleton error.  Otherwise, return its definition
 593 # location as a b4_syncline invocation.  Don't record this as a Bison usage of
 594 # VARIABLE as there's no reason to suspect that the user-supplied value has yet
 595 # influenced the output.
 596 #
 597 # For example:
 598 #
 599 #   b4_percent_define_get_syncline([[foo]])
 600 m4_define([b4_percent_define_get_syncline],
 601 [m4_ifdef([b4_percent_define_syncline(]$1[)],
 602           [m4_indir([b4_percent_define_syncline(]$1[)])],
 603           [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_get_syncline]], [$1])])])
 604
 605 # b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
 606 # ------------------------------------------------------
 607 # Mimic muscle_percent_define_ifdef in ../src/muscle_tab.h exactly.  That is,
 608 # if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
 609 # IF-FALSE.  Also, record Bison's usage of VARIABLE by defining
 610 # b4_percent_define_bison_variables(VARIABLE).
 611 #
 612 # For example:
 613 #
 614 #   b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
 615 m4_define([b4_percent_define_ifdef],
 616 [m4_ifdef([b4_percent_define(]$1[)],
 617           [m4_define([b4_percent_define_bison_variables(]$1[)])$2],
 618           [$3])])
 619
 620
 621 ## --------- ##
 622 ## Options.  ##
 623 ## --------- ##
 624
 625
 626 # b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
 627 # --------------------------------------------------------
 628 # Mimic muscle_percent_define_flag_if in ../src/muscle_tab.h exactly.  That is,
 629 # if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
 630 # If it is defined to "false", expand IF-FALSE.  Complain if it is undefined
 631 # (a Bison or skeleton error since the default value should have been set
 632 # already) or defined to any other value (possibly a user error).  Also, record
 633 # Bison's usage of VARIABLE by defining
 634 # b4_percent_define_bison_variables(VARIABLE).
 635 #
 636 # For example:
 637 #
 638 #   b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
 639 m4_define([b4_percent_define_flag_if],
 640 [b4_percent_define_ifdef([$1],
 641   [m4_case(b4_percent_define_get([$1]),
 642            [], [$2], [true], [$2], [false], [$3],
 643            [m4_expand_once([b4_complain_at(b4_percent_define_get_loc([$1]),
 644                                            [[invalid value for %%define Boolean variable `%s']],
 645                                            [$1])],
 646                            [[b4_percent_define_flag_if($1)]])])],
 647   [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_flag_if]], [$1])])])
 648
 649
 650 # b4_percent_define_default(VARIABLE, DEFAULT)
 651 # --------------------------------------------
 652 # Mimic muscle_percent_define_default in ../src/muscle_tab.h exactly.  That is,
 653 # if the %define variable VARIABLE is undefined, set its value to DEFAULT.
 654 # Don't record this as a Bison usage of VARIABLE as there's no reason to
 655 # suspect that the value has yet influenced the output.
 656 #
 657 # For example:
 658 #
 659 #   b4_percent_define_default([[foo]], [[default value]])
 660 m4_define([b4_percent_define_default],
 661 [m4_ifndef([b4_percent_define(]$1[)],
 662            [m4_define([b4_percent_define(]$1[)], [$2])dnl
 663             m4_define([b4_percent_define_loc(]$1[)],
 664                       [[[[<skeleton default value>:-1.-1]],
 665                         [[<skeleton default value>:-1.-1]]]])dnl
 666             m4_define([b4_percent_define_syncline(]$1[)], [[]])])])
 667
 668
 669 # b4_percent_define_if_define(VARIABLE)
 670 # -------------------------------------
 671 # Define b4_VARIABLE_if that executes its $1 or $2 depending whether
 672 # VARIABLE was %defined.
 673 m4_define([b4_percent_define_if_define_],
 674 [m4_define([b4_$1_if], [b4_percent_define_flag_if([$1], [$2], [$3])])])
 675 m4_define([b4_percent_define_if_define],
 676 [b4_percent_define_default([[$1]], [[false]])
 677 b4_percent_define_if_define_([$1], $[1], $[2])])
 678
 679
 680 # b4_assert_if([IF-ASSERTIONS-ARE-USED], [IF-NOT])
 681 # b4_error_verbose_if([IF-ERRORS-ARE-VERBOSE], [IF-NOT])
 682 # b4_lex_symbol_if([IF-YYLEX-RETURNS-A-COMPLETE-SYMBOL], [IF-NOT])
 683 # b4_variant_if([IF-VARIANT-ARE-USED], [IF-NOT])
 684 # ----------------------------------------------
 685 b4_percent_define_if_define([assert])
 686 b4_percent_define_if_define([error_verbose])
 687 b4_percent_define_if_define([lex_symbol])
 688 b4_percent_define_if_define([variant])
 689
 690
 691
 692 # b4_percent_define_check_values(VALUES)
 693 # --------------------------------------
 694 # Mimic muscle_percent_define_check_values in ../src/muscle_tab.h exactly
 695 # except that the VALUES structure is more appropriate for M4.  That is, VALUES
 696 # is a list of sublists of strings.  For each sublist, the first string is the
 697 # name of a %define variable, and all remaining strings in that sublist are the
 698 # valid values for that variable.  Complain if such a variable is undefined (a
 699 # Bison error since the default value should have been set already) or defined
 700 # to any other value (possibly a user error).  Don't record this as a Bison
 701 # usage of the variable as there's no reason to suspect that the value has yet
 702 # influenced the output.
 703 #
 704 # For example:
 705 #
 706 #   b4_percent_define_check_values([[[[foo]], [[foo-value1]], [[foo-value2]]]],
 707 #                                  [[[[bar]], [[bar-value1]]]])
 708 m4_define([b4_percent_define_check_values],
 709 [m4_foreach([b4_sublist], m4_quote($@),
 710             [_b4_percent_define_check_values(b4_sublist)])])
 711
 712 m4_define([_b4_percent_define_check_values],
 713 [m4_ifdef([b4_percent_define(]$1[)],
 714   [m4_pushdef([b4_good_value], [0])dnl
 715    m4_if($#, 1, [],
 716          [m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 717                      [m4_if(m4_indir([b4_percent_define(]$1[)]), b4_value,
 718                             [m4_define([b4_good_value], [1])])])])dnl
 719    m4_if(b4_good_value, [0],
 720          [b4_complain_at(b4_percent_define_get_loc([$1]),
 721                          [[invalid value for %%define variable `%s': `%s']],
 722                          [$1],
 723                          m4_dquote(m4_indir([b4_percent_define(]$1[)])))])dnl
 724    m4_popdef([b4_good_value])],
 725   [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_check_values]], [$1])])])
 726
 727 # b4_percent_code_get([QUALIFIER])
 728 # --------------------------------
 729 # If any %code blocks for QUALIFIER are defined, emit them beginning with a
 730 # comment and ending with synclines and a newline.  If QUALIFIER is not
 731 # specified or empty, do this for the unqualified %code blocks.  Also, record
 732 # Bison's usage of QUALIFIER (if specified) by defining
 733 # b4_percent_code_bison_qualifiers(QUALIFIER).
 734 #
 735 # For example, to emit any unqualified %code blocks followed by any %code
 736 # blocks for the qualifier foo:
 737 #
 738 #   b4_percent_code_get
 739 #   b4_percent_code_get([[foo]])
 740 m4_define([b4_percent_code_get],
 741 [m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
 742 m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
 743 m4_ifdef(b4_macro_name,
 744 [b4_comment([m4_if([$#], [0], [[Unqualified %code]],
 745                    [["%code ]$1["]])[ blocks.]])
 746 b4_user_code([m4_indir(b4_macro_name)])
 747 ])dnl
 748 m4_popdef([b4_macro_name])])
 749
 750 # b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
 751 # -----------------------------------------------------
 752 # If any %code blocks for QUALIFIER (or unqualified %code blocks if
 753 # QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
 754 # Also, record Bison's usage of QUALIFIER (if specified) by defining
 755 # b4_percent_code_bison_qualifiers(QUALIFIER).
 756 m4_define([b4_percent_code_ifdef],
 757 [m4_ifdef([b4_percent_code(]$1[)],
 758           [m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
 759           [$3])])
 760
 761
 762 # Default values for %define.
 763 # ---------------------------
 764 # If the %token.prefix, it is empty.
 765 m4_percent_define_default([[token.prefix]], [[]])
 766
 767
 768
 769 ## ----------------------------------------------------------- ##
 770 ## After processing the skeletons, check that all the user's   ##
 771 ## %define variables and %code qualifiers were used by Bison.  ##
 772 ## ----------------------------------------------------------- ##
 773
 774 m4_define([b4_check_user_names_wrap],
 775 [m4_ifdef([b4_percent_]$1[_user_]$2[s],
 776           [b4_check_user_names([[%]$1 $2],
 777                                [b4_percent_]$1[_user_]$2[s],
 778                                [[b4_percent_]$1[_bison_]$2[s]])])])
 779
 780 m4_wrap_lifo([
 781 b4_check_user_names_wrap([[define]], [[variable]])
 782 b4_check_user_names_wrap([[code]], [[qualifier]])
 783 ])