src/scan-gram.l

   1 /* Bison Grammar Scanner                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301  USA
  21 */
  22
  23 %option debug nodefault nounput noyywrap never-interactive
  24 %option prefix="gram_" outfile="lex.yy.c"
  25
  26 %{
  27 /* Work around a bug in flex 2.5.31.  See Debian bug 333231
  28    <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
  29 #undef gram_wrap
  30 #define gram_wrap() 1
  31
  32 #define FLEX_PREFIX(Id) gram_ ## Id
  33 #include "flex-scanner.h"
  34
  35 #include "complain.h"
  36 #include "files.h"
  37 #include "gram.h"
  38 #include "quotearg.h"
  39 #include "reader.h"
  40 #include "uniqstr.h"
  41
  42 #include <mbswidth.h>
  43 #include <quote.h>
  44
  45 #include "scan-gram.h"
  46
  47 #define YY_DECL GRAM_LEX_DECL
  48
  49 #define YY_USER_INIT                                    \
  50    code_start = scanner_cursor = loc->start;            \
  51
  52 /* Location of scanner cursor.  */
  53 static boundary scanner_cursor;
  54
  55 #define YY_USER_ACTION  location_compute (loc, &scanner_cursor, yytext, yyleng);
  56
  57 static size_t no_cr_read (FILE *, char *, size_t);
  58 #define YY_INPUT(buf, result, size) ((result) = no_cr_read (yyin, buf, size))
  59
  60 /* A string representing the most recently saved token.  */
  61 char *last_string;
  62
  63 void
  64 gram_scanner_last_string_free (void)
  65 {
  66   STRING_FREE;
  67 }
  68
  69 static void handle_syncline (char *, location);
  70 static unsigned long int scan_integer (char const *p, int base, location loc);
  71 static int convert_ucn_to_byte (char const *hex_text);
  72 static void unexpected_eof (boundary, char const *);
  73 static void unexpected_newline (boundary, char const *);
  74
  75 %}
  76  /* A C-like comment in directives/rules. */
  77 %x SC_YACC_COMMENT
  78  /* Strings and characters in directives/rules. */
  79 %x SC_ESCAPED_STRING SC_ESCAPED_CHARACTER
  80  /* A identifier was just read in directives/rules.  Special state
  81     to capture the sequence `identifier :'. */
  82 %x SC_AFTER_IDENTIFIER
  83
  84  /* Three types of user code:
  85     - prologue (code between `%{' `%}' in the first section, before %%);
  86     - actions, printers, union, etc, (between braced in the middle section);
  87     - epilogue (everything after the second %%). */
  88 %x SC_PROLOGUE SC_BRACED_CODE SC_EPILOGUE
  89  /* C and C++ comments in code. */
  90 %x SC_COMMENT SC_LINE_COMMENT
  91  /* Strings and characters in code. */
  92 %x SC_STRING SC_CHARACTER
  93
  94 letter    [.abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ_]
  95 id        {letter}({letter}|[0-9])*
  96 directive %{letter}({letter}|[0-9]|-)*
  97 int       [0-9]+
  98
  99 /* POSIX says that a tag must be both an id and a C union member, but
 100    historically almost any character is allowed in a tag.  We disallow
 101    NUL and newline, as this simplifies our implementation.  */
 102 tag      [^\0\n>]+
 103
 104 /* Zero or more instances of backslash-newline.  Following GCC, allow
 105    white space between the backslash and the newline.  */
 106 splice   (\\[ \f\t\v]*\n)*
 107
 108 %%
 109 %{
 110   /* Nesting level of the current code in braces.  */
 111   int braces_level IF_LINT (= 0);
 112
 113   /* Parent context state, when applicable.  */
 114   int context_state IF_LINT (= 0);
 115
 116   /* Location of most recent identifier, when applicable.  */
 117   location id_loc IF_LINT (= empty_location);
 118
 119   /* Where containing code started, when applicable.  Its initial
 120      value is relevant only when yylex is invoked in the SC_EPILOGUE
 121      start condition.  */
 122   boundary code_start = scanner_cursor;
 123
 124   /* Where containing comment or string or character literal started,
 125      when applicable.  */
 126   boundary token_start IF_LINT (= scanner_cursor);
 127 %}
 128
 129
 130   /*-----------------------.
 131   | Scanning white space.  |
 132   `-----------------------*/
 133
 134 <INITIAL,SC_AFTER_IDENTIFIER>
 135 {
 136   /* Comments and white space.  */
 137   ","          warn_at (*loc, _("stray `,' treated as white space"));
 138   [ \f\n\t\v]  |
 139   "//".*       ;
 140   "/*" {
 141     token_start = loc->start;
 142     context_state = YY_START;
 143     BEGIN SC_YACC_COMMENT;
 144   }
 145
 146   /* #line directives are not documented, and may be withdrawn or
 147      modified in future versions of Bison.  */
 148   ^"#line "{int}" \"".*"\"\n" {
 149     handle_syncline (yytext + sizeof "#line " - 1, *loc);
 150   }
 151 }
 152
 153
 154   /*----------------------------.
 155   | Scanning Bison directives.  |
 156   `----------------------------*/
 157 <INITIAL>
 158 {
 159   "%after-header"                   return PERCENT_AFTER_HEADER;
 160   "%before-header"                  return PERCENT_BEFORE_HEADER;
 161   "%binary"                         return PERCENT_NONASSOC;
 162   "%debug"                          return PERCENT_DEBUG;
 163   "%default"[-_]"prec"              return PERCENT_DEFAULT_PREC;
 164   "%define"                         return PERCENT_DEFINE;
 165   "%defines"                        return PERCENT_DEFINES;
 166   "%destructor"                     return PERCENT_DESTRUCTOR;
 167   "%dprec"                          return PERCENT_DPREC;
 168   "%end-header"                     return PERCENT_END_HEADER;
 169   "%error"[-_]"verbose"             return PERCENT_ERROR_VERBOSE;
 170   "%expect"                         return PERCENT_EXPECT;
 171   "%expect"[-_]"rr"                 return PERCENT_EXPECT_RR;
 172   "%file-prefix"                    return PERCENT_FILE_PREFIX;
 173   "%fixed"[-_]"output"[-_]"files"   return PERCENT_YACC;
 174   "%initial-action"                 return PERCENT_INITIAL_ACTION;
 175   "%glr-parser"                     return PERCENT_GLR_PARSER;
 176   "%left"                           return PERCENT_LEFT;
 177   "%lex-param"                      return PERCENT_LEX_PARAM;
 178   "%locations"                      return PERCENT_LOCATIONS;
 179   "%merge"                          return PERCENT_MERGE;
 180   "%name"[-_]"prefix"               return PERCENT_NAME_PREFIX;
 181   "%no"[-_]"default"[-_]"prec"      return PERCENT_NO_DEFAULT_PREC;
 182   "%no"[-_]"lines"                  return PERCENT_NO_LINES;
 183   "%nonassoc"                       return PERCENT_NONASSOC;
 184   "%nondeterministic-parser"        return PERCENT_NONDETERMINISTIC_PARSER;
 185   "%nterm"                          return PERCENT_NTERM;
 186   "%output"                         return PERCENT_OUTPUT;
 187   "%parse-param"                    return PERCENT_PARSE_PARAM;
 188   "%prec"                           return PERCENT_PREC;
 189   "%printer"                        return PERCENT_PRINTER;
 190   "%pure"[-_]"parser"               return PERCENT_PURE_PARSER;
 191   "%require"                        return PERCENT_REQUIRE;
 192   "%right"                          return PERCENT_RIGHT;
 193   "%skeleton"                       return PERCENT_SKELETON;
 194   "%start"                          return PERCENT_START;
 195   "%start-header"                   return PERCENT_START_HEADER;
 196   "%symbol-default"                 return PERCENT_SYMBOL_DEFAULT;
 197   "%term"                           return PERCENT_TOKEN;
 198   "%token"                          return PERCENT_TOKEN;
 199   "%token"[-_]"table"               return PERCENT_TOKEN_TABLE;
 200   "%type"                           return PERCENT_TYPE;
 201   "%union"                          return PERCENT_UNION;
 202   "%verbose"                        return PERCENT_VERBOSE;
 203   "%yacc"                           return PERCENT_YACC;
 204
 205   {directive} {
 206     complain_at (*loc, _("invalid directive: %s"), quote (yytext));
 207   }
 208
 209   "="                     return EQUAL;
 210   "|"                     return PIPE;
 211   ";"                     return SEMICOLON;
 212
 213   {id} {
 214     val->uniqstr = uniqstr_new (yytext);
 215     id_loc = *loc;
 216     BEGIN SC_AFTER_IDENTIFIER;
 217   }
 218
 219   {int} {
 220     val->integer = scan_integer (yytext, 10, *loc);
 221     return INT;
 222   }
 223   0[xX][0-9abcdefABCDEF]+ {
 224     val->integer = scan_integer (yytext, 16, *loc);
 225     return INT;
 226   }
 227
 228   /* Characters.  We don't check there is only one.  */
 229   "'"         STRING_GROW; token_start = loc->start; BEGIN SC_ESCAPED_CHARACTER;
 230
 231   /* Strings. */
 232   "\""        token_start = loc->start; BEGIN SC_ESCAPED_STRING;
 233
 234   /* Prologue. */
 235   "%{"        code_start = loc->start; BEGIN SC_PROLOGUE;
 236
 237   /* Code in between braces.  */
 238   "{" {
 239     STRING_GROW;
 240     braces_level = 0;
 241     code_start = loc->start;
 242     BEGIN SC_BRACED_CODE;
 243   }
 244
 245   /* A type. */
 246   "<"{tag}">" {
 247     obstack_grow (&obstack_for_string, yytext + 1, yyleng - 2);
 248     STRING_FINISH;
 249     val->uniqstr = uniqstr_new (last_string);
 250     STRING_FREE;
 251     return TYPE;
 252   }
 253
 254   "%%" {
 255     static int percent_percent_count;
 256     if (++percent_percent_count == 2)
 257       BEGIN SC_EPILOGUE;
 258     return PERCENT_PERCENT;
 259   }
 260
 261   . {
 262     complain_at (*loc, _("invalid character: %s"), quote (yytext));
 263   }
 264
 265   <<EOF>> {
 266     loc->start = loc->end = scanner_cursor;
 267     yyterminate ();
 268   }
 269 }
 270
 271
 272   /*-----------------------------------------------------------------.
 273   | Scanning after an identifier, checking whether a colon is next.  |
 274   `-----------------------------------------------------------------*/
 275
 276 <SC_AFTER_IDENTIFIER>
 277 {
 278   ":" {
 279     *loc = id_loc;
 280     BEGIN INITIAL;
 281     return ID_COLON;
 282   }
 283   . {
 284     scanner_cursor.column -= mbsnwidth (yytext, yyleng, 0);
 285     yyless (0);
 286     *loc = id_loc;
 287     BEGIN INITIAL;
 288     return ID;
 289   }
 290   <<EOF>> {
 291     *loc = id_loc;
 292     BEGIN INITIAL;
 293     return ID;
 294   }
 295 }
 296
 297
 298   /*---------------------------------------------------------------.
 299   | Scanning a Yacc comment.  The initial `/ *' is already eaten.  |
 300   `---------------------------------------------------------------*/
 301
 302 <SC_YACC_COMMENT>
 303 {
 304   "*/"     BEGIN context_state;
 305   .|\n     ;
 306   <<EOF>>  unexpected_eof (token_start, "*/"); BEGIN context_state;
 307 }
 308
 309
 310   /*------------------------------------------------------------.
 311   | Scanning a C comment.  The initial `/ *' is already eaten.  |
 312   `------------------------------------------------------------*/
 313
 314 <SC_COMMENT>
 315 {
 316   "*"{splice}"/"  STRING_GROW; BEGIN context_state;
 317   <<EOF>>         unexpected_eof (token_start, "*/"); BEGIN context_state;
 318 }
 319
 320
 321   /*--------------------------------------------------------------.
 322   | Scanning a line comment.  The initial `//' is already eaten.  |
 323   `--------------------------------------------------------------*/
 324
 325 <SC_LINE_COMMENT>
 326 {
 327   "\n"           STRING_GROW; BEGIN context_state;
 328   {splice}       STRING_GROW;
 329   <<EOF>>        BEGIN context_state;
 330 }
 331
 332
 333   /*------------------------------------------------.
 334   | Scanning a Bison string, including its escapes. |
 335   | The initial quote is already eaten.             |
 336   `------------------------------------------------*/
 337
 338 <SC_ESCAPED_STRING>
 339 {
 340   "\""|"\n" {
 341     if (yytext[0] == '\n')
 342       unexpected_newline (token_start, "\"");
 343     STRING_FINISH;
 344     loc->start = token_start;
 345     val->chars = last_string;
 346     BEGIN INITIAL;
 347     return STRING;
 348   }
 349   <<EOF>> {
 350     unexpected_eof (token_start, "\"");
 351     STRING_FINISH;
 352     loc->start = token_start;
 353     val->chars = last_string;
 354     BEGIN INITIAL;
 355     return STRING;
 356   }
 357 }
 358
 359   /*----------------------------------------------------------.
 360   | Scanning a Bison character literal, decoding its escapes. |
 361   | The initial quote is already eaten.                       |
 362   `----------------------------------------------------------*/
 363
 364 <SC_ESCAPED_CHARACTER>
 365 {
 366   "'"|"\n" {
 367     if (yytext[0] == '\n')
 368       unexpected_newline (token_start, "'");
 369     STRING_GROW;
 370     STRING_FINISH;
 371     loc->start = token_start;
 372     val->character = last_string[1];
 373     STRING_FREE;
 374     BEGIN INITIAL;
 375     return CHAR;
 376   }
 377   <<EOF>> {
 378     unexpected_eof (token_start, "'");
 379     STRING_FINISH;
 380     loc->start = token_start;
 381     if (strlen(last_string) > 1)
 382       val->character = last_string[1];
 383     else
 384       val->character = last_string[0];
 385     STRING_FREE;
 386     BEGIN INITIAL;
 387     return CHAR;
 388   }
 389 }
 390
 391 <SC_ESCAPED_CHARACTER,SC_ESCAPED_STRING>
 392 {
 393   \0        complain_at (*loc, _("invalid null character"));
 394 }
 395
 396
 397   /*----------------------------.
 398   | Decode escaped characters.  |
 399   `----------------------------*/
 400
 401 <SC_ESCAPED_STRING,SC_ESCAPED_CHARACTER>
 402 {
 403   \\[0-7]{1,3} {
 404     unsigned long int c = strtoul (yytext + 1, NULL, 8);
 405     if (UCHAR_MAX < c)
 406       complain_at (*loc, _("invalid escape sequence: %s"), quote (yytext));
 407     else if (! c)
 408       complain_at (*loc, _("invalid null character: %s"), quote (yytext));
 409     else
 410       obstack_1grow (&obstack_for_string, c);
 411   }
 412
 413   \\x[0-9abcdefABCDEF]+ {
 414     verify (UCHAR_MAX < ULONG_MAX);
 415     unsigned long int c = strtoul (yytext + 2, NULL, 16);
 416     if (UCHAR_MAX < c)
 417       complain_at (*loc, _("invalid escape sequence: %s"), quote (yytext));
 418     else if (! c)
 419       complain_at (*loc, _("invalid null character: %s"), quote (yytext));
 420     else
 421       obstack_1grow (&obstack_for_string, c);
 422   }
 423
 424   \\a   obstack_1grow (&obstack_for_string, '\a');
 425   \\b   obstack_1grow (&obstack_for_string, '\b');
 426   \\f   obstack_1grow (&obstack_for_string, '\f');
 427   \\n   obstack_1grow (&obstack_for_string, '\n');
 428   \\r   obstack_1grow (&obstack_for_string, '\r');
 429   \\t   obstack_1grow (&obstack_for_string, '\t');
 430   \\v   obstack_1grow (&obstack_for_string, '\v');
 431
 432   /* \\[\"\'?\\] would be shorter, but it confuses xgettext.  */
 433   \\("\""|"'"|"?"|"\\")  obstack_1grow (&obstack_for_string, yytext[1]);
 434
 435   \\(u|U[0-9abcdefABCDEF]{4})[0-9abcdefABCDEF]{4} {
 436     int c = convert_ucn_to_byte (yytext);
 437     if (c < 0)
 438       complain_at (*loc, _("invalid escape sequence: %s"), quote (yytext));
 439     else if (! c)
 440       complain_at (*loc, _("invalid null character: %s"), quote (yytext));
 441     else
 442       obstack_1grow (&obstack_for_string, c);
 443   }
 444   \\(.|\n)      {
 445     complain_at (*loc, _("unrecognized escape sequence: %s"), quote (yytext));
 446     STRING_GROW;
 447   }
 448 }
 449
 450   /*--------------------------------------------.
 451   | Scanning user-code characters and strings.  |
 452   `--------------------------------------------*/
 453
 454 <SC_CHARACTER,SC_STRING>
 455 {
 456   {splice}|\\{splice}[^\n\[\]]  STRING_GROW;
 457 }
 458
 459 <SC_CHARACTER>
 460 {
 461   "'"           STRING_GROW; BEGIN context_state;
 462   \n            unexpected_newline (token_start, "'"); BEGIN context_state;
 463   <<EOF>>       unexpected_eof (token_start, "'"); BEGIN context_state;
 464 }
 465
 466 <SC_STRING>
 467 {
 468   "\""          STRING_GROW; BEGIN context_state;
 469   \n            unexpected_newline (token_start, "\""); BEGIN context_state;
 470   <<EOF>>       unexpected_eof (token_start, "\""); BEGIN context_state;
 471 }
 472
 473
 474   /*---------------------------------------------------.
 475   | Strings, comments etc. can be found in user code.  |
 476   `---------------------------------------------------*/
 477
 478 <SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE>
 479 {
 480   "'" {
 481     STRING_GROW;
 482     context_state = YY_START;
 483     token_start = loc->start;
 484     BEGIN SC_CHARACTER;
 485   }
 486   "\"" {
 487     STRING_GROW;
 488     context_state = YY_START;
 489     token_start = loc->start;
 490     BEGIN SC_STRING;
 491   }
 492   "/"{splice}"*" {
 493     STRING_GROW;
 494     context_state = YY_START;
 495     token_start = loc->start;
 496     BEGIN SC_COMMENT;
 497   }
 498   "/"{splice}"/" {
 499     STRING_GROW;
 500     context_state = YY_START;
 501     BEGIN SC_LINE_COMMENT;
 502   }
 503 }
 504
 505
 506
 507   /*-----------------------------------------------------------.
 508   | Scanning some code in braces (actions). The initial "{" is |
 509   | already eaten.                                             |
 510   `-----------------------------------------------------------*/
 511
 512 <SC_BRACED_CODE>
 513 {
 514   "{"|"<"{splice}"%"  STRING_GROW; braces_level++;
 515   "%"{splice}">"      STRING_GROW; braces_level--;
 516   "}" {
 517     obstack_1grow (&obstack_for_string, '}');
 518
 519     --braces_level;
 520     if (braces_level < 0)
 521       {
 522         STRING_FINISH;
 523         loc->start = code_start;
 524         val->chars = last_string;
 525         BEGIN INITIAL;
 526         return BRACED_CODE;
 527       }
 528   }
 529
 530   /* Tokenize `<<%' correctly (as `<<' `%') rather than incorrrectly
 531      (as `<' `<%').  */
 532   "<"{splice}"<"  STRING_GROW;
 533
 534   <<EOF>> {
 535     unexpected_eof (code_start, "}");
 536     STRING_FINISH;
 537     loc->start = code_start;
 538     val->chars = last_string;
 539     BEGIN INITIAL;
 540     return BRACED_CODE;
 541   }
 542 }
 543
 544
 545   /*--------------------------------------------------------------.
 546   | Scanning some prologue: from "%{" (already scanned) to "%}".  |
 547   `--------------------------------------------------------------*/
 548
 549 <SC_PROLOGUE>
 550 {
 551   "%}" {
 552     STRING_FINISH;
 553     loc->start = code_start;
 554     val->chars = last_string;
 555     BEGIN INITIAL;
 556     return PROLOGUE;
 557   }
 558
 559   <<EOF>> {
 560     unexpected_eof (code_start, "%}");
 561     STRING_FINISH;
 562     loc->start = code_start;
 563     val->chars = last_string;
 564     BEGIN INITIAL;
 565     return PROLOGUE;
 566   }
 567 }
 568
 569
 570   /*---------------------------------------------------------------.
 571   | Scanning the epilogue (everything after the second "%%", which |
 572   | has already been eaten).                                       |
 573   `---------------------------------------------------------------*/
 574
 575 <SC_EPILOGUE>
 576 {
 577   <<EOF>> {
 578     STRING_FINISH;
 579     loc->start = code_start;
 580     val->chars = last_string;
 581     BEGIN INITIAL;
 582     return EPILOGUE;
 583   }
 584 }
 585
 586
 587   /*-----------------------------------------------------.
 588   | By default, grow the string obstack with the input.  |
 589   `-----------------------------------------------------*/
 590
 591 <SC_COMMENT,SC_LINE_COMMENT,SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE,SC_STRING,SC_CHARACTER,SC_ESCAPED_STRING,SC_ESCAPED_CHARACTER>.      |
 592 <SC_COMMENT,SC_LINE_COMMENT,SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE>\n   STRING_GROW;
 593
 594 %%
 595
 596 /* Read bytes from FP into buffer BUF of size SIZE.  Return the
 597    number of bytes read.  Remove '\r' from input, treating \r\n
 598    and isolated \r as \n.  */
 599
 600 static size_t
 601 no_cr_read (FILE *fp, char *buf, size_t size)
 602 {
 603   size_t bytes_read = fread (buf, 1, size, fp);
 604   if (bytes_read)
 605     {
 606       char *w = memchr (buf, '\r', bytes_read);
 607       if (w)
 608         {
 609           char const *r = ++w;
 610           char const *lim = buf + bytes_read;
 611
 612           for (;;)
 613             {
 614               /* Found an '\r'.  Treat it like '\n', but ignore any
 615                  '\n' that immediately follows.  */
 616               w[-1] = '\n';
 617               if (r == lim)
 618                 {
 619                   int ch = getc (fp);
 620                   if (ch != '\n' && ungetc (ch, fp) != ch)
 621                     break;
 622                 }
 623               else if (*r == '\n')
 624                 r++;
 625
 626               /* Copy until the next '\r'.  */
 627               do
 628                 {
 629                   if (r == lim)
 630                     return w - buf;
 631                 }
 632               while ((*w++ = *r++) != '\r');
 633             }
 634
 635           return w - buf;
 636         }
 637     }
 638
 639   return bytes_read;
 640 }
 641
 642
 643
 644 /*------------------------------------------------------.
 645 | Scan NUMBER for a base-BASE integer at location LOC.  |
 646 `------------------------------------------------------*/
 647
 648 static unsigned long int
 649 scan_integer (char const *number, int base, location loc)
 650 {
 651   verify (INT_MAX < ULONG_MAX);
 652   unsigned long int num = strtoul (number, NULL, base);
 653
 654   if (INT_MAX < num)
 655     {
 656       complain_at (loc, _("integer out of range: %s"), quote (number));
 657       num = INT_MAX;
 658     }
 659
 660   return num;
 661 }
 662
 663
 664 /*------------------------------------------------------------------.
 665 | Convert universal character name UCN to a single-byte character,  |
 666 | and return that character.  Return -1 if UCN does not correspond  |
 667 | to a single-byte character.                                       |
 668 `------------------------------------------------------------------*/
 669
 670 static int
 671 convert_ucn_to_byte (char const *ucn)
 672 {
 673   verify (UCHAR_MAX <= INT_MAX);
 674   unsigned long int code = strtoul (ucn + 2, NULL, 16);
 675
 676   /* FIXME: Currently we assume Unicode-compatible unibyte characters
 677      on ASCII hosts (i.e., Latin-1 on hosts with 8-bit bytes).  On
 678      non-ASCII hosts we support only the portable C character set.
 679      These limitations should be removed once we add support for
 680      multibyte characters.  */
 681
 682   if (UCHAR_MAX < code)
 683     return -1;
 684
 685 #if ! ('$' == 0x24 && '@' == 0x40 && '`' == 0x60 && '~' == 0x7e)
 686   {
 687     /* A non-ASCII host.  Use CODE to index into a table of the C
 688        basic execution character set, which is guaranteed to exist on
 689        all Standard C platforms.  This table also includes '$', '@',
 690        and '`', which are not in the basic execution character set but
 691        which are unibyte characters on all the platforms that we know
 692        about.  */
 693     static signed char const table[] =
 694       {
 695         '\0',   -1,   -1,   -1,   -1,   -1,   -1, '\a',
 696         '\b', '\t', '\n', '\v', '\f', '\r',   -1,   -1,
 697           -1,   -1,   -1,   -1,   -1,   -1,   -1,   -1,
 698           -1,   -1,   -1,   -1,   -1,   -1,   -1,   -1,
 699          ' ',  '!',  '"',  '#',  '$',  '%',  '&', '\'',
 700          '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
 701          '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
 702          '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
 703          '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
 704          'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
 705          'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
 706          'X',  'Y',  'Z',  '[', '\\',  ']',  '^',  '_',
 707          '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
 708          'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
 709          'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
 710          'x',  'y',  'z',  '{',  '|',  '}',  '~'
 711       };
 712
 713     code = code < sizeof table ? table[code] : -1;
 714   }
 715 #endif
 716
 717   return code;
 718 }
 719
 720
 721 /*----------------------------------------------------------------.
 722 | Handle `#line INT "FILE"'.  ARGS has already skipped `#line '.  |
 723 `----------------------------------------------------------------*/
 724
 725 static void
 726 handle_syncline (char *args, location loc)
 727 {
 728   char *after_num;
 729   unsigned long int lineno = strtoul (args, &after_num, 10);
 730   char *file = strchr (after_num, '"') + 1;
 731   *strchr (file, '"') = '\0';
 732   if (INT_MAX <= lineno)
 733     {
 734       warn_at (loc, _("line number overflow"));
 735       lineno = INT_MAX;
 736     }
 737   current_file = uniqstr_new (file);
 738   boundary_set (&scanner_cursor, current_file, lineno, 1);
 739 }
 740
 741
 742 /*----------------------------------------------------------------.
 743 | For a token or comment starting at START, report message MSGID, |
 744 | which should say that an end marker was found before            |
 745 | the expected TOKEN_END.                                         |
 746 `----------------------------------------------------------------*/
 747
 748 static void
 749 unexpected_end (boundary start, char const *msgid, char const *token_end)
 750 {
 751   location loc;
 752   loc.start = start;
 753   loc.end = scanner_cursor;
 754   complain_at (loc, _(msgid), token_end);
 755 }
 756
 757
 758 /*------------------------------------------------------------------------.
 759 | Report an unexpected EOF in a token or comment starting at START.       |
 760 | An end of file was encountered and the expected TOKEN_END was missing.  |
 761 `------------------------------------------------------------------------*/
 762
 763 static void
 764 unexpected_eof (boundary start, char const *token_end)
 765 {
 766   unexpected_end (start, N_("missing `%s' at end of file"), token_end);
 767 }
 768
 769
 770 /*----------------------------------------.
 771 | Likewise, but for unexpected newlines.  |
 772 `----------------------------------------*/
 773
 774 static void
 775 unexpected_newline (boundary start, char const *token_end)
 776 {
 777   unexpected_end (start, N_("missing `%s' at end of line"), token_end);
 778 }
 779
 780
 781 /*-------------------------.
 782 | Initialize the scanner.  |
 783 `-------------------------*/
 784
 785 void
 786 gram_scanner_initialize (void)
 787 {
 788   obstack_init (&obstack_for_string);
 789 }
 790
 791
 792 /*-----------------------------------------------.
 793 | Free all the memory allocated to the scanner.  |
 794 `-----------------------------------------------*/
 795
 796 void
 797 gram_scanner_free (void)
 798 {
 799   obstack_free (&obstack_for_string, 0);
 800   /* Reclaim Flex's buffers.  */
 801   yy_delete_buffer (YY_CURRENT_BUFFER);
 802 }