configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006 Free Software
   4 # Foundation, Inc.
   5 #
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 # We have strange test case titles, so we need Autoconf 2.61 or better.
  20 AC_PREREQ(2.61)
  21
  22 AC_INIT([GNU Bison], [2.3a+], [bug-bison@gnu.org])
  23 AC_CONFIG_AUX_DIR([build-aux])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 # We don't have a file m4/Makefile.am, so we need Automake 1.8 or later.
  27 AM_INIT_AUTOMAKE([1.8 check-news readme-alpha dist-bzip2])
  28 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  29
  30 # Checks for the compiler.
  31 AC_PROG_CC_STDC
  32
  33 # Gnulib (early checks).
  34 gl_EARLY
  35
  36 AC_ARG_ENABLE(gcc-warnings,
  37 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  38 [case "${enableval}" in
  39    yes|no) ;;
  40    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  41  esac],
  42               [enableval=no])
  43 if test "${enableval}" = yes; then
  44   gl_WARNING_CFLAGS([-Werror])
  45   AC_SUBST([WERROR_CFLAGS], [$WARNING_CFLAGS])
  46   WARNING_CFLAGS=
  47   gl_WARNING_CFLAGS([-Wall])
  48   gl_WARNING_CFLAGS([-Wextra -Wno-sign-compare])
  49   gl_WARNING_CFLAGS([-Wcast-align])
  50   gl_WARNING_CFLAGS([-Wcast-qual])
  51   gl_WARNING_CFLAGS([-Wformat])
  52   gl_WARNING_CFLAGS([-Wpointer-arith])
  53   gl_WARNING_CFLAGS([-Wwrite-strings])
  54   AC_SUBST([WARNING_CXXFLAGS], [$WARNING_CFLAGS])
  55   # The following warnings are not suitable for C++.
  56   gl_WARNING_CFLAGS([-Wbad-function-cast])
  57   gl_WARNING_CFLAGS([-Wmissing-declarations])
  58   gl_WARNING_CFLAGS([-Wmissing-prototypes])
  59   gl_WARNING_CFLAGS([-Wshadow])
  60   gl_WARNING_CFLAGS([-Wstrict-prototypes])
  61   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  62 fi
  63
  64 BISON_TEST_FOR_WORKING_C_COMPILER
  65
  66 AC_ARG_ENABLE([yacc],
  67   [AC_HELP_STRING([--disable-yacc],
  68      [do not build a yacc command or an -ly library])],
  69   , [enable_yacc=yes])
  70 case $enable_yacc in
  71 yes)
  72   YACC_SCRIPT=yacc
  73   YACC_LIBRARY=liby.a;;
  74 *)
  75   YACC_SCRIPT=
  76   YACC_LIBRARY=;;
  77 esac
  78 AC_SUBST([YACC_SCRIPT])
  79 AC_SUBST([YACC_LIBRARY])
  80
  81 # Checks for programs.
  82 AC_PROG_LEX
  83 AC_PROG_YACC
  84 AC_PROG_RANLIB
  85 BISON_PROG_GNU_M4
  86 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  87   AC_MSG_ERROR([GNU M4 1.4 is required])
  88 fi
  89 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
  90
  91 # Checks for header files.
  92 AC_CHECK_HEADERS_ONCE([locale.h])
  93
  94 # Checks for compiler characteristics.
  95 AC_C_INLINE
  96
  97 # Gnulib (later checks).  Putting them here rather than right after
  98 # gl_EARLY avoids some redundant checks.
  99 gl_INIT
 100
 101 # Checks for library functions.
 102 AC_CHECK_FUNCS_ONCE([setlocale])
 103 AM_WITH_DMALLOC
 104 BISON_PREREQ_SUBPIPE
 105 BISON_PREREQ_TIMEVAR
 106
 107 # Gettext.
 108 # We've never tested with gettext versions before 0.15, so play it safe.
 109 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 110 AM_GNU_GETTEXT_VERSION([0.15])
 111 BISON_I18N
 112
 113 # Internationalized parsers.
 114 AC_CONFIG_FILES([runtime-po/Makefile.in])
 115 # Autoconf macros for packages using internationalized parsers.
 116 aclocaldir='${datadir}/aclocal'
 117 AC_SUBST([aclocaldir])
 118
 119 # Create the benchmark script.
 120 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 121
 122 # Initialize the test suite.
 123 AC_CONFIG_TESTDIR(tests)
 124 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 125 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 126 AC_CHECK_PROGS([VALGRIND], [valgrind])
 127 AC_PROG_CXX
 128 BISON_TEST_FOR_WORKING_CXX_COMPILER
 129 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 130 # Needed by tests/atlocal.in.
 131 AC_SUBST([GCC])
 132 O0CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]] *//'`
 133 AC_SUBST([O0CFLAGS])
 134 O0CXXFLAGS=`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`
 135 AC_SUBST([O0CXXFLAGS])
 136
 137 gt_JAVACOMP([1.3])
 138 gt_JAVAEXEC
 139
 140 AC_CONFIG_FILES([Makefile
 141                  build-aux/Makefile
 142                  po/Makefile.in
 143                  data/Makefile
 144                  etc/Makefile
 145                  examples/Makefile
 146                     examples/calc++/Makefile
 147                  lib/Makefile src/Makefile doc/Makefile])
 148 AC_OUTPUT