src/scan-skel.l

   1 /* Scan Bison Skeletons.                                       -*- C -*-
   2
   3    Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006 Free Software
   4    Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    Bison is free software; you can redistribute it and/or modify it
   9    under the terms of the GNU General Public License as published by
  10    the Free Software Foundation; either version 2, or (at your option)
  11    any later version.
  12
  13    Bison is distributed in the hope that it will be useful, but
  14    WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16    General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with Bison; see the file COPYING.  If not, write to the Free
  20    Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21    02110-1301, USA.  */
  22
  23 %option nodefault noyywrap nounput never-interactive debug
  24 %option prefix="skel_" outfile="lex.yy.c"
  25
  26 %{
  27 /* Work around a bug in flex 2.5.31.  See Debian bug 333231
  28    <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
  29 #undef skel_wrap
  30 #define skel_wrap() 1
  31
  32 #define FLEX_NO_OBSTACK
  33 #define FLEX_PREFIX(Id) skel_ ## Id
  34 #include "flex-scanner.h"
  35
  36 #include <dirname.h>
  37 #include <error.h>
  38 #include <quotearg.h>
  39
  40 #include "complain.h"
  41 #include "getargs.h"
  42 #include "files.h"
  43 #include "scan-skel.h"
  44
  45 int skel_lex (void);
  46
  47 #define QPUTS(String) \
  48    fputs (quotearg_style (c_quoting_style, String), yyout)
  49
  50 static char *decode_at_digraphs (char *in);
  51 %}
  52 %%
  53
  54 %{
  55   int lineno IF_LINT (= 0);
  56   char *outname = NULL;
  57 %}
  58
  59 "@output ".*\n {
  60   char *file_name = yytext + sizeof "@output " - 1;
  61   yytext[yyleng - 1] = '\0';
  62   if (outname)
  63     {
  64       free (outname);
  65       xfclose (yyout);
  66     }
  67   outname = decode_at_digraphs (file_name);
  68   output_file_name_check (outname);
  69   yyout = xfopen (outname, "w");
  70   lineno = 1;
  71 }
  72
  73 "@@"       fputc ('@', yyout);
  74 "@{"       fputc ('[', yyout);
  75 "@}"       fputc (']', yyout);
  76
  77 "@oline@"  fprintf (yyout, "%d", lineno + 1);
  78 "@ofile@"  QPUTS (outname);
  79 "@dir_prefix@" QPUTS (dir_prefix);
  80
  81 "@basename(".*"@)" {
  82   char *file_name = yytext + sizeof "@basename " - 1;
  83   yytext[yyleng - 2] = '\0';
  84   file_name = decode_at_digraphs (file_name);
  85   fputs (last_component (file_name), yyout);
  86   free (file_name);
  87 }
  88
  89   /* This pattern must not match more than the previous @ patterns. */
  90 @[^{}@\n]* fatal ("invalid @ in skeleton: %s", yytext);
  91 \n         lineno++; ECHO;
  92 [^@\n]+    ECHO;
  93
  94 <<EOF>> {
  95   if (outname)
  96     {
  97       free (outname);
  98       xfclose (yyout);
  99     }
 100   return EOF;
 101 }
 102 %%
 103
 104 /*------------------------.
 105 | Scan a Bison skeleton.  |
 106 `------------------------*/
 107
 108 void
 109 scan_skel (FILE *in)
 110 {
 111   skel_in = in;
 112   skel__flex_debug = trace_flag & trace_skeleton;
 113   skel_lex ();
 114   /* Reclaim Flex's buffers.  */
 115   yylex_destroy ();
 116 }
 117
 118 static char *
 119 decode_at_digraphs (char *in)
 120 {
 121   char *out_start = xnmalloc (strlen (in)+1, sizeof *out_start);
 122   char *out;
 123   for (out = out_start; *in != '\0'; ++in, ++out)
 124     {
 125       if (*in == '@')
 126         {
 127           switch (*++in)
 128             {
 129               case '@': *out = '@'; break;
 130               case '{': *out = '['; break;
 131               case '}': *out = ']'; break;
 132               default:
 133                 if (*in != '\0')
 134                   in[1] = '\0';
 135                 fatal ("invalid @ in skeleton: %s", in-1);
 136                 break;
 137             }
 138         }
 139       else
 140         *out = *in;
 141     }
 142   *out = '\0';
 143   return out_start;
 144 }