configure.in

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright 2001  Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19
  20 # We need a recent Autoconf to run a recent Autotest.
  21 AC_PREREQ(2.52e)
  22
  23 AC_INIT([GNU Bison], [1.49a], [bug-bison@gnu.org])
  24 AC_CONFIG_AUX_DIR(config)
  25
  26 AM_INIT_AUTOMAKE([bison], [1.49a])
  27 AM_CONFIG_HEADER(config.h:config.hin)
  28
  29 # Initialize the test suite.
  30 AC_CONFIG_TESTDIR(tests)
  31 AC_CONFIG_FILES(tests/Makefile tests/atlocal)
  32 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
  33 # Needed by tests/atlocal.in.
  34 AC_SUBST([GCC])
  35
  36 # Checks for programs.
  37 AC_PROG_CC
  38 AC_MINIX
  39 AC_ISC_POSIX
  40 AM_PROG_CC_STDC
  41 AC_PROG_RANLIB
  42 # GNU M4 is needed to build the testsuite.
  43 BISON_AC_PROG_GNU_M4
  44 if test "$ac_cv_prog_gnu_m4" != yes; then
  45   missing_dir=`cd $ac_aux_dir && pwd`
  46   M4="$missing_dir/missing m4"
  47 fi
  48
  49 AC_ARG_ENABLE(gcc-warnings,
  50 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  51 [case "${enableval}" in
  52    yes|no) ;;
  53    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  54  esac],
  55               [enableval=no])
  56 if test "${enableval}" = yes; then
  57   BISON_WARNING(-Wall)
  58   BISON_WARNING(-W)
  59   BISON_WARNING(-Wbad-function-cast)
  60   BISON_WARNING(-Wcast-align)
  61   BISON_WARNING(-Wcast-qual)
  62   BISON_WARNING(-Wformat)
  63   BISON_WARNING(-Wmissing-declarations)
  64   BISON_WARNING(-Wmissing-prototypes)
  65   BISON_WARNING(-Wnested-externs)
  66   BISON_WARNING(-Wshadow)
  67   BISON_WARNING(-Wstrict-prototypes)
  68   BISON_WARNING(-Wwrite-strings)
  69   BISON_WARNING(-Werror)
  70 fi
  71
  72 # Checks for libraries.
  73 AC_DEFINE([_GNU_SOURCE],1,[Define to 1 for GNU C library extensions.])
  74
  75 # Checks for header files.
  76 AC_HEADER_STDC
  77 AC_CHECK_HEADERS(ctype.h locale.h memory.h stdlib.h string.h unistd.h)
  78
  79 # Checks for typedefs.
  80
  81 # Checks for structures.
  82
  83 # Checks for compiler characteristics.
  84 AC_C_CONST
  85 AC_C_INLINE
  86 AM_C_PROTOTYPES
  87
  88 # Checks for library functions.
  89 AC_FUNC_ALLOCA
  90 AC_FUNC_OBSTACK
  91 AC_FUNC_ERROR_AT_LINE
  92 AC_CHECK_FUNCS(mkstemp setlocale)
  93 AC_CHECK_DECLS([stpcpy, strndup, strnlen, memchr])
  94 AC_REPLACE_FUNCS(stpcpy strndup strnlen strspn memchr)
  95 jm_FUNC_MALLOC
  96 jm_FUNC_REALLOC
  97 jm_PREREQ_QUOTEARG
  98 jm_PREREQ_ERROR
  99 AM_WITH_DMALLOC
 100
 101 ALL_LINGUAS="de es et fr ja nl ru sv tr"
 102 AM_GNU_GETTEXT(, need-ngettext)
 103
 104 # This is necessary so that .o files in LIBOBJS are also built via
 105 # the ANSI2KNR-filtering rules.
 106 LIB@&t@OBJS=`echo $LIB@&t@OBJS|sed 's/\.o /\$U.o /g;s/\.o$/\$U.o/'`
 107 AC_SUBST(LIB@&t@OBJS)
 108
 109 AC_OUTPUT([Makefile
 110            config/Makefile
 111            intl/Makefile po/Makefile.in
 112            lib/Makefile src/Makefile doc/Makefile
 113            m4/Makefile])