src/scan-skel.l

   1 /* Scan Bison Skeletons.                                       -*- C -*-
   2
   3    Copyright (C) 2001, 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    Bison is free software; you can redistribute it and/or modify it
   8    under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2, or (at your option)
  10    any later version.
  11
  12    Bison is distributed in the hope that it will be useful, but
  13    WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with Bison; see the file COPYING.  If not, write to the Free
  19    Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301, USA.  */
  21
  22 %option nodefault noyywrap nounput never-interactive debug
  23 %option prefix="skel_" outfile="lex.yy.c"
  24
  25 %{
  26 /* Work around a bug in flex 2.5.31.  See Debian bug 333231
  27    <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
  28 #undef skel_wrap
  29 #define skel_wrap() 1
  30
  31 #include "system.h"
  32
  33 #include <error.h>
  34 #include <quotearg.h>
  35
  36 #include "complain.h"
  37 #include "getargs.h"
  38 #include "files.h"
  39 #include "scan-skel.h"
  40
  41 #define QPUTS(String) \
  42    fputs (quotearg_style (c_quoting_style, (String)), yyout)
  43
  44 #define BASE_QPUTS(File) \
  45    assert (File), QPUTS (base_name (File))
  46
  47 %}
  48 %%
  49
  50 %{
  51   int lineno IF_LINT (= 0);
  52   char *outname = NULL;
  53 %}
  54
  55 "@output ".*\n {
  56   char const *file_name = yytext + sizeof "@output " - 1;
  57   yytext[yyleng - 1] = '\0';
  58
  59   /* Decode special file names.  They include the directory part,
  60      contrary to their "free" occurrences, used for issuing #includes,
  61      which must not include the directory part.  */
  62
  63   if (*file_name == '@')
  64     {
  65       if (strcmp (file_name, "@output_header_name@") == 0)
  66         {
  67           assert (spec_defines_file);
  68           file_name = spec_defines_file;
  69         }
  70       else if (strcmp (file_name, "@output_parser_name@") == 0)
  71         {
  72           assert (parser_file_name);
  73           file_name = parser_file_name;
  74         }
  75       else
  76         fatal ("invalid token in skeleton: %s", yytext);
  77     }
  78   if (outname)
  79     {
  80       free (outname);
  81       xfclose (yyout);
  82     }
  83   outname = xstrdup (file_name);
  84   yyout = xfopen (outname, "w");
  85   lineno = 1;
  86 }
  87
  88 "@@"       fputc ('@', yyout);
  89 "@{"       fputc ('[', yyout);
  90 "@}"       fputc (']', yyout);
  91
  92 "@oline@"  fprintf (yyout, "%d", lineno + 1);
  93 "@ofile@"  QPUTS (outname);
  94 "@dir_prefix@" QPUTS (dir_prefix);
  95 "@output_parser_name@"  BASE_QPUTS (parser_file_name);
  96 "@output_header_name@"  BASE_QPUTS (spec_defines_file);
  97
  98   /* This pattern must not match more than the previous @ patterns. */
  99 @[^{}@\n]* fatal ("invalid @ in skeleton: %s", yytext);
 100 \n         lineno++; ECHO;
 101 [^@\n]+    ECHO;
 102
 103 <<EOF>> {
 104   if (outname)
 105     {
 106       free (outname);
 107       xfclose (yyout);
 108     }
 109   return EOF;
 110 }
 111 %%
 112
 113 /*------------------------.
 114 | Scan a Bison skeleton.  |
 115 `------------------------*/
 116
 117 void
 118 scan_skel (FILE *in)
 119 {
 120   skel_in = in;
 121   skel__flex_debug = trace_flag & trace_skeleton;
 122   skel_lex ();
 123   /* Reclaim Flex's buffers.  */
 124   yy_delete_buffer (YY_CURRENT_BUFFER);
 125 }