configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2010 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # We have strange test case titles, so we need Autoconf 2.61 or better.
  19 AC_PREREQ(2.61)
  20
  21 AC_INIT([GNU Bison],
  22         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  23         [bug-bison@gnu.org])
  24 AC_DEFINE([PACKAGE_COPYRIGHT_YEAR], [2010],
  25           [The copyright year for this package])
  26 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2010])
  27
  28 AC_CONFIG_AUX_DIR([build-aux])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  32 #
  33 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  34 #
  35 # To avoid 1.11, we make 1.11.1 the minimum version.
  36 #
  37 # We want gnits strictness only when rolling a formal release so that we can,
  38 # for example, run make dist at other times without being required to add a
  39 # bogus NEWS entry.
  40 AM_INIT_AUTOMAKE([1.11.1 dist-bzip2]
  41                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [-], [gnu], [gnits]))
  42 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  43
  44 # Checks for the compiler.
  45 AC_PROG_CC_STDC
  46
  47 # Gnulib (early checks).
  48 gl_EARLY
  49
  50 AC_ARG_ENABLE(gcc-warnings,
  51 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  52 [case "${enableval}" in
  53    yes|no) ;;
  54    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  55  esac],
  56               [enableval=no])
  57 if test "${enableval}" = yes; then
  58   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  59   AC_SUBST([WERROR_CFLAGS])
  60   gl_WARN_ADD([-Wall])
  61   gl_WARN_ADD([-Wextra -Wno-sign-compare])
  62   gl_WARN_ADD([-Wcast-align])
  63   gl_WARN_ADD([-Wcast-qual])
  64   gl_WARN_ADD([-Wformat])
  65   gl_WARN_ADD([-Wpointer-arith])
  66   gl_WARN_ADD([-Wwrite-strings])
  67   AC_SUBST([WARN_CXXFLAGS], [$WARN_CFLAGS])
  68   # The following warnings are not suitable for C++.
  69   gl_WARN_ADD([-Wbad-function-cast])
  70   gl_WARN_ADD([-Wmissing-declarations])
  71   gl_WARN_ADD([-Wmissing-prototypes])
  72   gl_WARN_ADD([-Wshadow])
  73   gl_WARN_ADD([-Wstrict-prototypes])
  74   AC_SUBST([WARN_CFLAGS])
  75   # Warnings for the test suite only.
  76   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
  77   WARN_CXXFLAGS_TEST="$WARN_CXXFLAGS $WARN_CFLAGS_TEST"
  78   WARN_CFLAGS_TEST="$WARN_CFLAGS $WARN_CFLAGS_TEST"
  79   AC_SUBST([WARN_CXXFLAGS_TEST])
  80   AC_SUBST([WARN_CFLAGS_TEST])
  81   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  82 fi
  83
  84 BISON_TEST_FOR_WORKING_C_COMPILER
  85
  86 AC_ARG_ENABLE([yacc],
  87   [AC_HELP_STRING([--disable-yacc],
  88      [do not build a yacc command or an -ly library])],
  89   , [enable_yacc=yes])
  90 case $enable_yacc in
  91 yes)
  92   YACC_SCRIPT=yacc
  93   YACC_LIBRARY=liby.a;;
  94 *)
  95   YACC_SCRIPT=
  96   YACC_LIBRARY=;;
  97 esac
  98 AC_SUBST([YACC_SCRIPT])
  99 AC_SUBST([YACC_LIBRARY])
 100
 101 # Checks for programs.
 102 AC_PROG_LEX
 103 AC_PROG_YACC
 104 AC_PROG_RANLIB
 105 AC_PROG_GNU_M4
 106 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 107 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 108 supports -g, otherwise to "".])
 109 AM_MISSING_PROG([HELP2MAN], [help2man])
 110 AC_PATH_PROG([XSLTPROC], [xsltproc])
 111 AC_SUBST([XSLTPROC])
 112
 113 # Checks for header files.
 114 AC_CHECK_HEADERS_ONCE([locale.h])
 115
 116 # Checks for compiler characteristics.
 117 AC_C_INLINE
 118
 119 # Gnulib (later checks).  Putting them here rather than right after
 120 # gl_EARLY avoids some redundant checks.
 121 gl_INIT
 122
 123 # Checks for library functions.
 124 AC_CHECK_FUNCS_ONCE([setlocale])
 125 AM_WITH_DMALLOC
 126 BISON_PREREQ_SUBPIPE
 127 BISON_PREREQ_TIMEVAR
 128
 129 # Gettext.
 130 # We use gnulib, which is only guaranteed to work properly with the
 131 # latest Gettext.
 132 AM_GNU_GETTEXT([external], [need-ngettext])
 133 AM_GNU_GETTEXT_VERSION([0.17])
 134 BISON_I18N
 135
 136 # Internationalized parsers.
 137 AC_CONFIG_FILES([runtime-po/Makefile.in])
 138 # Autoconf macros for packages using internationalized parsers.
 139 aclocaldir='${datadir}/aclocal'
 140 AC_SUBST([aclocaldir])
 141
 142 # Create the benchmark script.
 143 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 144
 145 # Initialize the test suite.
 146 AC_CONFIG_TESTDIR(tests)
 147 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 148 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 149 AC_CHECK_PROGS([VALGRIND], [valgrind])
 150 AC_PROG_CXX
 151 BISON_TEST_FOR_WORKING_CXX_COMPILER
 152 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 153 # Needed by tests/atlocal.in.
 154 AC_SUBST([GCC])
 155 AC_SUBST([O0CFLAGS],   [`echo $CFLAGS   | sed 's/-O[[0-9]] *//'`])
 156 AC_SUBST([O0CXXFLAGS], [`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`])
 157
 158 gt_JAVACOMP([1.3])
 159 gt_JAVAEXEC
 160
 161 AC_CONFIG_FILES([Makefile
 162                  build-aux/Makefile
 163                  po/Makefile.in
 164                  data/Makefile
 165                  etc/Makefile
 166                  examples/Makefile
 167                     examples/calc++/Makefile
 168                  lib/Makefile src/Makefile
 169                  doc/Makefile
 170                    doc/yacc.1])
 171 AC_OUTPUT