data/c.m4

   1                                                             -*- Autoconf -*-
   2
   3 # C M4 Macros for Bison.
   4
   5 # Copyright (C) 2002, 2004-2013 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_include(b4_pkgdatadir/[c-like.m4])
  21
  22 # b4_tocpp(STRING)
  23 # ----------------
  24 # Convert STRING into a valid C macro name.
  25 m4_define([b4_tocpp],
  26 [m4_toupper(m4_bpatsubst(m4_quote($1), [[^a-zA-Z0-9]+], [_]))])
  27
  28
  29 # b4_cpp_guard(FILE)
  30 # ------------------
  31 # A valid C macro name to use as a CPP header guard for FILE.
  32 m4_define([b4_cpp_guard],
  33 [[YY_]b4_tocpp(m4_defn([b4_prefix])/[$1])[_INCLUDED]])
  34
  35
  36 # b4_cpp_guard_open(FILE)
  37 # b4_cpp_guard_close(FILE)
  38 # ------------------------
  39 # If FILE does not expand to nothing, open/close CPP inclusion guards for FILE.
  40 m4_define([b4_cpp_guard_open],
  41 [m4_ifval(m4_quote($1),
  42 [#ifndef b4_cpp_guard([$1])
  43 # define b4_cpp_guard([$1])])])
  44
  45 m4_define([b4_cpp_guard_close],
  46 [m4_ifval(m4_quote($1),
  47 [#endif b4_comment([!b4_cpp_guard([$1])])])])
  48
  49
  50 ## ---------------- ##
  51 ## Identification.  ##
  52 ## ---------------- ##
  53
  54 # b4_identification
  55 # -----------------
  56 # Depends on individual skeletons to define b4_pure_flag, b4_push_flag, or
  57 # b4_pull_flag if they use the values of the %define variables api.pure or
  58 # api.push-pull.
  59 m4_define([b4_identification],
  60 [[/* Identify Bison output.  */
  61 #define YYBISON 1
  62
  63 /* Bison version.  */
  64 #define YYBISON_VERSION "]b4_version["
  65
  66 /* Skeleton name.  */
  67 #define YYSKELETON_NAME ]b4_skeleton[]m4_ifdef([b4_pure_flag], [[
  68
  69 /* Pure parsers.  */
  70 #define YYPURE ]b4_pure_flag])[]m4_ifdef([b4_push_flag], [[
  71
  72 /* Push parsers.  */
  73 #define YYPUSH ]b4_push_flag])[]m4_ifdef([b4_pull_flag], [[
  74
  75 /* Pull parsers.  */
  76 #define YYPULL ]b4_pull_flag])[
  77 ]])
  78
  79
  80 ## ---------------- ##
  81 ## Default values.  ##
  82 ## ---------------- ##
  83
  84 # b4_api_prefix, b4_api_PREFIX
  85 # ----------------------------
  86 # Corresponds to %define api.prefix
  87 b4_percent_define_default([[api.prefix]], [[yy]])
  88 m4_define([b4_api_prefix],
  89 [b4_percent_define_get([[api.prefix]])])
  90 m4_define([b4_api_PREFIX],
  91 [m4_toupper(b4_api_prefix)])
  92
  93
  94 # b4_prefix
  95 # ---------
  96 # If the %name-prefix is not given, it is api.prefix.
  97 m4_define_default([b4_prefix], [b4_api_prefix])
  98
  99 # If the %union is not named, its name is YYSTYPE.
 100 m4_define_default([b4_union_name], [b4_api_PREFIX[]STYPE])
 101
 102
 103 ## ------------------------ ##
 104 ## Pure/impure interfaces.  ##
 105 ## ------------------------ ##
 106
 107 # b4_lex_formals
 108 # --------------
 109 # All the yylex formal arguments.
 110 # b4_lex_param arrives quoted twice, but we want to keep only one level.
 111 m4_define([b4_lex_formals],
 112 [b4_pure_if([[[[YYSTYPE *yylvalp]], [[&yylval]]][]dnl
 113 b4_locations_if([, [[YYLTYPE *yyllocp], [&yylloc]]])])dnl
 114 m4_ifdef([b4_lex_param], [, ]b4_lex_param)])
 115
 116
 117 # b4_lex
 118 # ------
 119 # Call yylex.
 120 m4_define([b4_lex],
 121 [b4_function_call([yylex], [int], b4_lex_formals)])
 122
 123
 124 # b4_user_args
 125 # ------------
 126 m4_define([b4_user_args],
 127 [m4_ifset([b4_parse_param], [, b4_args(b4_parse_param)])])
 128
 129
 130 # b4_parse_param
 131 # --------------
 132 # If defined, b4_parse_param arrives double quoted, but below we prefer
 133 # it to be single quoted.
 134 m4_define([b4_parse_param],
 135 b4_parse_param)
 136
 137
 138 # b4_parse_param_for(DECL, FORMAL, BODY)
 139 # ---------------------------------------
 140 # Iterate over the user parameters, binding the declaration to DECL,
 141 # the formal name to FORMAL, and evaluating the BODY.
 142 m4_define([b4_parse_param_for],
 143 [m4_foreach([$1_$2], m4_defn([b4_parse_param]),
 144 [m4_pushdef([$1], m4_unquote(m4_car($1_$2)))dnl
 145 m4_pushdef([$2], m4_shift($1_$2))dnl
 146 $3[]dnl
 147 m4_popdef([$2])dnl
 148 m4_popdef([$1])dnl
 149 ])])
 150
 151 # b4_parse_param_use([VAL], [LOC])
 152 # --------------------------------
 153 # 'YYUSE' VAL, LOC if locations are enabled, and all the parse-params.
 154 m4_define([b4_parse_param_use],
 155 [m4_ifvaln([$1], [  YYUSE ([$1]);])dnl
 156 b4_locations_if([m4_ifvaln([$2], [  YYUSE ([$2]);])])dnl
 157 b4_parse_param_for([Decl], [Formal], [  YYUSE (Formal);
 158 ])dnl
 159 ])
 160
 161
 162 ## ------------ ##
 163 ## Data Types.  ##
 164 ## ------------ ##
 165
 166 # b4_int_type(MIN, MAX)
 167 # ---------------------
 168 # Return the smallest int type able to handle numbers ranging from
 169 # MIN to MAX (included).
 170 m4_define([b4_int_type],
 171 [m4_if(b4_ints_in($@,      [0],   [255]), [1], [unsigned char],
 172        b4_ints_in($@,   [-128],   [127]), [1], [signed char],
 173
 174        b4_ints_in($@,      [0], [65535]), [1], [unsigned short int],
 175        b4_ints_in($@, [-32768], [32767]), [1], [short int],
 176
 177        m4_eval([0 <= $1]),                [1], [unsigned int],
 178
 179                                                [int])])
 180
 181
 182 # b4_int_type_for(NAME)
 183 # ---------------------
 184 # Return the smallest int type able to handle numbers ranging from
 185 # 'NAME_min' to 'NAME_max' (included).
 186 m4_define([b4_int_type_for],
 187 [b4_int_type($1_min, $1_max)])
 188
 189
 190 # b4_table_value_equals(TABLE, VALUE, LITERAL)
 191 # --------------------------------------------
 192 # Without inducing a comparison warning from the compiler, check if the
 193 # literal value LITERAL equals VALUE from table TABLE, which must have
 194 # TABLE_min and TABLE_max defined.
 195 m4_define([b4_table_value_equals],
 196 [m4_if(m4_eval($3 < m4_indir([b4_]$1[_min])
 197                || m4_indir([b4_]$1[_max]) < $3), [1],
 198        [[0]],
 199        [(!!(($2) == ($3)))])])
 200
 201
 202 ## ---------##
 203 ## Values.  ##
 204 ## ---------##
 205
 206
 207 # b4_null_define
 208 # --------------
 209 # Portability issues: define a YY_NULL appropriate for the current
 210 # language (C, C++98, or C++11).
 211 m4_define([b4_null_define],
 212 [# ifndef YY_NULL
 213 #  if defined __cplusplus && 201103L <= __cplusplus
 214 #   define YY_NULL nullptr
 215 #  else
 216 #   define YY_NULL 0
 217 #  endif
 218 # endif[]dnl
 219 ])
 220
 221
 222 # b4_null
 223 # -------
 224 # Return a null pointer constant.
 225 m4_define([b4_null], [YY_NULL])
 226
 227 # b4_integral_parser_table_define(TABLE-NAME, CONTENT, COMMENT)
 228 # -------------------------------------------------------------
 229 # Define "yy<TABLE-NAME>" whose contents is CONTENT.
 230 m4_define([b4_integral_parser_table_define],
 231 [m4_ifvaln([$3], [b4_comment([$3], [  ])])dnl
 232 static const b4_int_type_for([$2]) yy$1[[]] =
 233 {
 234   $2
 235 };dnl
 236 ])
 237
 238
 239 ## ------------------------- ##
 240 ## Assigning token numbers.  ##
 241 ## ------------------------- ##
 242
 243 # b4_token_define(TOKEN-NUM)
 244 # --------------------------
 245 # Output the definition of this token as #define.
 246 m4_define([b4_token_define],
 247 [b4_token_format([#define %s %s], [$1])])
 248
 249 # b4_token_defines
 250 # ----------------
 251 # Output the definition of the tokens.
 252 m4_define([b4_token_defines],
 253 [b4_any_token_visible_if([/* Tokens.  */
 254 m4_join([
 255 ], b4_symbol_map([b4_token_define]))
 256 ])])
 257
 258
 259 # b4_token_enum(TOKEN-NUM)
 260 # ------------------------
 261 # Output the definition of this token as an enum.
 262 m4_define([b4_token_enum],
 263 [b4_token_format([%s = %s], [$1])])
 264
 265
 266 # b4_token_enums
 267 # --------------
 268 # Output the definition of the tokens (if there are) as enums.
 269 m4_define([b4_token_enums],
 270 [b4_any_token_visible_if([[/* Token type.  */
 271 #ifndef ]b4_api_PREFIX[TOKENTYPE
 272 # define ]b4_api_PREFIX[TOKENTYPE
 273   enum ]b4_api_prefix[tokentype
 274   {
 275     ]m4_join([,
 276     ],
 277              b4_symbol_map([b4_token_enum]))[
 278   };
 279 #endif
 280 ]])])
 281
 282
 283 # b4_token_enums_defines
 284 # ----------------------
 285 # Output the definition of the tokens (if there are any) as enums and,
 286 # if POSIX Yacc is enabled, as #defines.
 287 m4_define([b4_token_enums_defines],
 288 [b4_token_enums[]b4_yacc_if([b4_token_defines])])
 289
 290
 291 ## ----------------- ##
 292 ## Semantic Values.  ##
 293 ## ----------------- ##
 294
 295
 296 # b4_symbol_value(VAL, [TYPE])
 297 # ----------------------------
 298 # Given a semantic value VAL ($$, $1 etc.), extract its value of type
 299 # TYPE if TYPE is given, otherwise just return VAL.  The result can be
 300 # used safetly, it is put in parens to avoid nasty precedence issues.
 301 # TYPE is *not* put in braces, provide some if needed.
 302 m4_define([b4_symbol_value],
 303 [($1[]m4_ifval([$2], [.$2]))])
 304
 305
 306
 307 ## ---------------------- ##
 308 ## Defining C functions.  ##
 309 ## ---------------------- ##
 310
 311
 312 # b4_function_define(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 313 # -----------------------------------------------------------
 314 # Declare the function NAME in C.
 315 m4_define([b4_function_define],
 316 [$2
 317 $1 (b4_formals(m4_shift2($@)))[]dnl
 318 ])
 319
 320
 321 # b4_formals([DECL1, NAME1], ...)
 322 # -------------------------------
 323 # The formal arguments of a C function definition.
 324 m4_define([b4_formals],
 325 [m4_if([$#], [0], [void],
 326        [$#$1], [1], [void],
 327                [m4_map_sep([b4_formal], [, ], [$@])])])
 328
 329 m4_define([b4_formal],
 330 [$1])
 331
 332
 333
 334 ## ----------------------- ##
 335 ## Declaring C functions.  ##
 336 ## ----------------------- ##
 337
 338
 339 # b4_function_declare(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 340 # ------------------------------------------------------------
 341 # Declare the function NAME.
 342 m4_define([b4_function_declare],
 343 [$2 $1 (b4_formals(m4_shift2($@)));[]dnl
 344 ])
 345
 346
 347
 348
 349 ## --------------------- ##
 350 ## Calling C functions.  ##
 351 ## --------------------- ##
 352
 353
 354 # b4_function_call(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 355 # -----------------------------------------------------------
 356 # Call the function NAME with arguments NAME1, NAME2 etc.
 357 m4_define([b4_function_call],
 358 [$1 (b4_args(m4_shift2($@)))[]dnl
 359 ])
 360
 361
 362 # b4_args([DECL1, NAME1], ...)
 363 # ----------------------------
 364 # Output the arguments NAME1, NAME2...
 365 m4_define([b4_args],
 366 [m4_map_sep([b4_arg], [, ], [$@])])
 367
 368 m4_define([b4_arg],
 369 [$2])
 370
 371
 372 ## ----------- ##
 373 ## Synclines.  ##
 374 ## ----------- ##
 375
 376 # b4_sync_start(LINE, FILE)
 377 # -------------------------
 378 m4_define([b4_sync_start], [[#]line $1 $2])
 379
 380
 381 ## -------------- ##
 382 ## User actions.  ##
 383 ## -------------- ##
 384
 385 # b4_case(LABEL, STATEMENTS)
 386 # --------------------------
 387 m4_define([b4_case],
 388 [  case $1:
 389 $2
 390 b4_syncline([@oline@], [@ofile@])
 391     break;])
 392
 393
 394 # b4_predicate_case(LABEL, CONDITIONS)
 395 # ------------------------------------
 396 m4_define([b4_predicate_case],
 397 [  case $1:
 398     if (! ($2)) YYERROR;
 399 b4_syncline([@oline@], [@ofile@])
 400     break;])
 401
 402
 403 # b4_yydestruct_define
 404 # --------------------
 405 # Define the "yydestruct" function.
 406 m4_define_default([b4_yydestruct_define],
 407 [[/*-----------------------------------------------.
 408 | Release the memory associated to this symbol.  |
 409 `-----------------------------------------------*/
 410
 411 ]b4_function_define([yydestruct],
 412     [static void],
 413     [[const char *yymsg],    [yymsg]],
 414     [[int yytype],           [yytype]],
 415     [[YYSTYPE *yyvaluep],    [yyvaluep]][]dnl
 416 b4_locations_if(            [, [[YYLTYPE *yylocationp], [yylocationp]]])[]dnl
 417 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 418 {
 419 ]b4_parse_param_use([yyvaluep], [yylocationp])dnl
 420 [  if (!yymsg)
 421     yymsg = "Deleting";
 422   YY_SYMBOL_PRINT (yymsg, yytype, yyvaluep, yylocationp);
 423
 424   switch (yytype)
 425     {
 426 ]b4_symbol_foreach([b4_symbol_destructor])dnl
 427 [      default:
 428         break;
 429     }
 430 }]dnl
 431 ])
 432
 433
 434 # b4_yy_symbol_print_define
 435 # -------------------------
 436 # Define the "yy_symbol_print" function.
 437 m4_define_default([b4_yy_symbol_print_define],
 438 [[
 439 /*--------------------------------.
 440 | Print this symbol on YYOUTPUT.  |
 441 `--------------------------------*/
 442
 443 ]b4_function_define([yy_symbol_value_print],
 444     [static void],
 445                [[FILE *yyoutput],                       [yyoutput]],
 446                [[int yytype],                           [yytype]],
 447                [[YYSTYPE const * const yyvaluep],       [yyvaluep]][]dnl
 448 b4_locations_if([, [[YYLTYPE const * const yylocationp], [yylocationp]]])[]dnl
 449 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 450 {
 451   FILE *yyo = yyoutput;
 452 ]b4_parse_param_use([yyo], [yylocationp])dnl
 453 [  if (!yyvaluep)
 454     return;]
 455 dnl glr.c does not feature yytoknum.
 456 m4_if(b4_skeleton, ["yacc.c"],
 457 [[# ifdef YYPRINT
 458   if (yytype < YYNTOKENS)
 459     YYPRINT (yyoutput, yytoknum[yytype], *yyvaluep);
 460 # endif
 461 ]])dnl
 462 [  switch (yytype)
 463     {
 464 ]b4_symbol_foreach([b4_symbol_printer])dnl
 465 [      default:
 466         break;
 467     }
 468 }
 469
 470
 471 /*--------------------------------.
 472 | Print this symbol on YYOUTPUT.  |
 473 `--------------------------------*/
 474
 475 ]b4_function_define([yy_symbol_print],
 476     [static void],
 477                [[FILE *yyoutput],                       [yyoutput]],
 478                [[int yytype],                           [yytype]],
 479                [[YYSTYPE const * const yyvaluep],       [yyvaluep]][]dnl
 480 b4_locations_if([, [[YYLTYPE const * const yylocationp], [yylocationp]]])[]dnl
 481 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 482 {
 483   YYFPRINTF (yyoutput, "%s %s (",
 484              yytype < YYNTOKENS ? "token" : "nterm", yytname[yytype]);
 485
 486 ]b4_locations_if([  YY_LOCATION_PRINT (yyoutput, *yylocationp);
 487   YYFPRINTF (yyoutput, ": ");
 488 ])dnl
 489 [  yy_symbol_value_print (yyoutput, yytype, yyvaluep]dnl
 490 b4_locations_if([, yylocationp])[]b4_user_args[);
 491   YYFPRINTF (yyoutput, ")");
 492 }]dnl
 493 ])
 494
 495 ## -------------- ##
 496 ## Declarations.  ##
 497 ## -------------- ##
 498
 499 # b4_value_type_define
 500 # --------------------
 501 m4_define([b4_value_type_define],
 502 [[/* Value type.  */
 503 #if ! defined ]b4_api_PREFIX[STYPE && ! defined ]b4_api_PREFIX[STYPE_IS_DECLARED
 504 ]m4_ifdef([b4_union_members],
 505 [[typedef union ]b4_union_name[ ]b4_api_PREFIX[STYPE;
 506 union ]b4_union_name[
 507 {
 508 ]b4_user_union_members[
 509 };
 510 # define ]b4_api_PREFIX[STYPE_IS_TRIVIAL 1]],
 511 [m4_if(b4_tag_seen_flag, 0,
 512 [[typedef int ]b4_api_PREFIX[STYPE;
 513 # define ]b4_api_PREFIX[STYPE_IS_TRIVIAL 1]])])[
 514 # define ]b4_api_PREFIX[STYPE_IS_DECLARED 1
 515 #endif
 516 ]])
 517
 518
 519 # b4_location_type_define
 520 # -----------------------
 521 m4_define([b4_location_type_define],
 522 [[/* Location type.  */
 523 #if ! defined ]b4_api_PREFIX[LTYPE && ! defined ]b4_api_PREFIX[LTYPE_IS_DECLARED
 524 typedef struct ]b4_api_PREFIX[LTYPE ]b4_api_PREFIX[LTYPE;
 525 struct ]b4_api_PREFIX[LTYPE
 526 {
 527   int first_line;
 528   int first_column;
 529   int last_line;
 530   int last_column;
 531 };
 532 # define ]b4_api_PREFIX[LTYPE_IS_DECLARED 1
 533 # define ]b4_api_PREFIX[LTYPE_IS_TRIVIAL 1
 534 #endif
 535 ]])
 536
 537
 538 # b4_declare_yylstype
 539 # -------------------
 540 # Declarations that might either go into the header (if --defines) or
 541 # in the parser body.  Declare YYSTYPE/YYLTYPE, and yylval/yylloc.
 542 m4_define([b4_declare_yylstype],
 543 [b4_value_type_define[]b4_locations_if([
 544 b4_location_type_define])
 545
 546 b4_pure_if([], [[extern ]b4_api_PREFIX[STYPE ]b4_prefix[lval;
 547 ]b4_locations_if([[extern ]b4_api_PREFIX[LTYPE ]b4_prefix[lloc;]])])[]dnl
 548 ])
 549
 550
 551 # b4_YYDEBUG_define
 552 # ------------------
 553 m4_define([b4_YYDEBUG_define],
 554 [[/* Debug traces.  */
 555 ]m4_if(b4_api_prefix, [yy],
 556 [[#ifndef YYDEBUG
 557 # define YYDEBUG ]b4_parse_trace_if([1], [0])[
 558 #endif]],
 559 [[#ifndef ]b4_api_PREFIX[DEBUG
 560 # if defined YYDEBUG
 561 #if YYDEBUG
 562 #   define ]b4_api_PREFIX[DEBUG 1
 563 #  else
 564 #   define ]b4_api_PREFIX[DEBUG 0
 565 #  endif
 566 # else /* ! defined YYDEBUG */
 567 #  define ]b4_api_PREFIX[DEBUG ]b4_parse_trace_if([1], [0])[
 568 # endif /* ! defined YYDEBUG */
 569 #endif  /* ! defined ]b4_api_PREFIX[DEBUG */]])[]dnl
 570 ])
 571
 572 # b4_declare_yydebug
 573 # ------------------
 574 m4_define([b4_declare_yydebug],
 575 [b4_YYDEBUG_define[
 576 #if ]b4_api_PREFIX[DEBUG
 577 extern int ]b4_prefix[debug;
 578 #endif][]dnl
 579 ])
 580
 581 # b4_yylloc_default_define
 582 # ------------------------
 583 # Define YYLLOC_DEFAULT.
 584 m4_define([b4_yylloc_default_define],
 585 [[/* YYLLOC_DEFAULT -- Set CURRENT to span from RHS[1] to RHS[N].
 586    If N is 0, then set CURRENT to the empty location which ends
 587    the previous symbol: RHS[0] (always defined).  */
 588
 589 #ifndef YYLLOC_DEFAULT
 590 # define YYLLOC_DEFAULT(Current, Rhs, N)                                \
 591     do                                                                  \
 592       if (N)                                                            \
 593         {                                                               \
 594           (Current).first_line   = YYRHSLOC (Rhs, 1).first_line;        \
 595           (Current).first_column = YYRHSLOC (Rhs, 1).first_column;      \
 596           (Current).last_line    = YYRHSLOC (Rhs, N).last_line;         \
 597           (Current).last_column  = YYRHSLOC (Rhs, N).last_column;       \
 598         }                                                               \
 599       else                                                              \
 600         {                                                               \
 601           (Current).first_line   = (Current).last_line   =              \
 602             YYRHSLOC (Rhs, 0).last_line;                                \
 603           (Current).first_column = (Current).last_column =              \
 604             YYRHSLOC (Rhs, 0).last_column;                              \
 605         }                                                               \
 606     while (0)
 607 #endif
 608 ]])
 609
 610 # b4_yy_location_print_define
 611 # ---------------------------
 612 # Define YY_LOCATION_PRINT.
 613 m4_define([b4_yy_location_print_define],
 614 [b4_locations_if([[
 615 /* YY_LOCATION_PRINT -- Print the location on the stream.
 616    This macro was not mandated originally: define only if we know
 617    we won't break user code: when these are the locations we know.  */
 618
 619 #ifndef YY_LOCATION_PRINT
 620 # if defined ]b4_api_PREFIX[LTYPE_IS_TRIVIAL && ]b4_api_PREFIX[LTYPE_IS_TRIVIAL
 621
 622 /* Print *YYLOCP on YYO.  Private, do not rely on its existence. */
 623
 624 __attribute__((__unused__))
 625 ]b4_function_define([yy_location_print_],
 626     [static unsigned],
 627                [[FILE *yyo],                    [yyo]],
 628                [[YYLTYPE const * const yylocp], [yylocp]])[
 629 {
 630   unsigned res = 0;
 631   int end_col = 0 != yylocp->last_column ? yylocp->last_column - 1 : 0;
 632   if (0 <= yylocp->first_line)
 633     {
 634       res += YYFPRINTF (yyo, "%d", yylocp->first_line);
 635       if (0 <= yylocp->first_column)
 636         res += YYFPRINTF (yyo, ".%d", yylocp->first_column);
 637     }
 638   if (0 <= yylocp->last_line)
 639     {
 640       if (yylocp->first_line < yylocp->last_line)
 641         {
 642           res += YYFPRINTF (yyo, "-%d", yylocp->last_line);
 643           if (0 <= end_col)
 644             res += YYFPRINTF (yyo, ".%d", end_col);
 645         }
 646       else if (0 <= end_col && yylocp->first_column < end_col)
 647         res += YYFPRINTF (yyo, "-%d", end_col);
 648     }
 649   return res;
 650  }
 651
 652 #  define YY_LOCATION_PRINT(File, Loc)          \
 653   yy_location_print_ (File, &(Loc))
 654
 655 # else
 656 #  define YY_LOCATION_PRINT(File, Loc) ((void) 0)
 657 # endif
 658 #endif]],
 659 [[/* This macro is provided for backward compatibility. */
 660 #ifndef YY_LOCATION_PRINT
 661 # define YY_LOCATION_PRINT(File, Loc) ((void) 0)
 662 #endif]])
 663 ])
 664
 665 # b4_yyloc_default
 666 # ----------------
 667 # Expand to a possible default value for yylloc.
 668 m4_define([b4_yyloc_default],
 669 [[
 670 # if defined ]b4_api_PREFIX[LTYPE_IS_TRIVIAL && ]b4_api_PREFIX[LTYPE_IS_TRIVIAL
 671   = { ]m4_join([, ],
 672                m4_defn([b4_location_initial_line]),
 673                m4_defn([b4_location_initial_column]),
 674                m4_defn([b4_location_initial_line]),
 675                m4_defn([b4_location_initial_column]))[ }
 676 # endif
 677 ]])