tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 ## ------------- ##
  24 ## Basic tests.  ##
  25 ## ------------- ##
  26
  27 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  28 # ------------------------------------------
  29 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  30 # taken in "slurp" mode, i.e., one can match end-of-lines.
  31 m4_define([AT_MATCHES_CHECK],
  32 [AT_CHECK([perl -0777 -ne '
  33 my $count = 0;
  34 s{$2}{ ++$count; "" }gem;
  35 printf "$count\n";' $1], [0], [$3
  36 ])])
  37
  38
  39 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  40 # ------------------------------------------------
  41 # Don't interfere with caller's files.
  42 m4_divert_text([PREPARE_TESTS],
  43 [at_save_special_files ()
  44 {
  45   for at_save_file in stderr experr expout
  46   do
  47     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  48   done
  49 }
  50
  51 at_restore_special_files ()
  52 {
  53   for at_save_file in stderr experr expout
  54   do
  55     test ! -f at-bison-check-$at_save_file.bak ||
  56       mv at-bison-check-$at_save_file.bak $at_save_file
  57   done
  58 }
  59 ])
  60
  61 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  62 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  63
  64
  65
  66 ## ------------------------------- ##
  67 ## Macros decoding Bison options.  ##
  68 ## ------------------------------- ##
  69
  70 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  71 # ----------------------------------------------------------------
  72 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  73 m4_define([AT_LOC_PUSHDEF],
  74 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  75 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  76 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  77 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  78
  79 # AT_LOC_POPDEF
  80 # -------------
  81 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  82 m4_define([AT_LOC_POPDEF],
  83 [m4_popdef([AT_LOC_FIRST_LINE])
  84 m4_popdef([AT_LOC_FIRST_COLUMN])
  85 m4_popdef([AT_LOC_LAST_LINE])
  86 m4_popdef([AT_LOC_LAST_COLUMN])])
  87
  88
  89
  90 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  91 # -----------------------------------------
  92 m4_define([AT_BISON_OPTION_PUSHDEFS],
  93 [m4_divert_text([KILL],
  94                 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])])
  95
  96
  97 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  98 # --------------------------------------------------
  99 # This macro works around the impossibility to define macros
 100 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 101 # This sucks hard, GNU M4 should really provide M5 like $$1.
 102 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 103 [m4_if([$1$2], $[1]$[2], [],
 104        [m4_fatal([$0: Invalid arguments: $@])])dnl
 105 m4_pushdef([AT_DEFINES_IF],
 106 [m4_bmatch([$3], [%defines], [$1], [$2])])
 107 m4_pushdef([AT_SKEL_CC_IF],
 108 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 109 m4_pushdef([AT_SKEL_JAVA_IF],
 110 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 111 m4_pushdef([AT_LANG],
 112 [AT_SKEL_JAVA_IF([java],
 113                  [AT_SKEL_CC_IF([c++],
 114                                 [c])])])
 115 m4_pushdef([AT_GLR_IF],
 116 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 117 m4_pushdef([AT_LALR1_CC_IF],
 118 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 119 m4_pushdef([AT_GLR_CC_IF],
 120 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 121 # Using yacc.c?
 122 m4_pushdef([AT_YACC_IF],
 123 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 124 m4_pushdef([AT_LEXPARAM_IF],
 125 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 126 m4_pushdef([AT_LOCATION_IF],
 127 [m4_bmatch([$3], [%locations], [$1], [$2])])
 128 m4_pushdef([AT_LOCATION_TYPE_IF],
 129 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
 130 m4_pushdef([AT_PARAM_IF],
 131 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 132 m4_pushdef([AT_PURE_IF],
 133 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 134            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 135            [$2])])
 136 m4_pushdef([AT_PURE_AND_LOC_IF],
 137 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 138 m4_pushdef([AT_GLR_OR_PARAM_IF],
 139 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 140 m4_pushdef([AT_NAME_PREFIX],
 141 [m4_bmatch([$3], [\(%define api\.prefix\|%name-prefix\) ".*"],
 142            [m4_bregexp([$3], [\(%define api\.prefix\|%name-prefix\) "\([^""]*\)"], [\2])],
 143            [yy])])
 144 m4_pushdef([AT_API_prefix],
 145 [m4_bmatch([$3], [%define api\.prefix ".*"],
 146            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 147            [yy])])
 148 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 149 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 150 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 151                     [$2])])
 152 # yyerror always sees the locations (when activated), except if
 153 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 154 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 155 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 156                                         [$1])],
 157                             [$1])],
 158                 [$2])])
 159
 160 # The interface is pure: either because %define api.pure, or because we
 161 # are using the C++ parsers.
 162 m4_pushdef([AT_PURE_LEX_IF],
 163 [AT_PURE_IF([$1],
 164             [AT_SKEL_CC_IF([$1], [$2])])])
 165
 166 m4_pushdef([AT_YYSTYPE],
 167 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 168                [[YYSTYPE]])])
 169 m4_pushdef([AT_YYLTYPE],
 170 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 171                [[YYLTYPE]])])
 172
 173
 174 AT_PURE_LEX_IF(
 175 [m4_pushdef([AT_LOC], [(*llocp)])
 176  m4_pushdef([AT_VAL], [(*lvalp)])
 177  m4_pushdef([AT_YYLEX_FORMALS],
 178             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 179  m4_pushdef([AT_YYLEX_ARGS],
 180             [lvalp[]AT_LOCATION_IF([, llocp])])
 181  m4_pushdef([AT_USE_LEX_ARGS],
 182             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 183  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 184             [AT_YYLEX_FORMALS, ])
 185  m4_pushdef([AT_YYLEX_PRE_ARGS],
 186             [AT_YYLEX_ARGS, ])
 187 ],
 188 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 189  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 190  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 191  m4_pushdef([AT_YYLEX_ARGS],        [])
 192  m4_pushdef([AT_USE_LEX_ARGS],    [])
 193  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 194  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 195 ])
 196
 197 # Handle the different types of location components.
 198
 199 AT_SKEL_CC_IF(
 200   [AT_LOCATION_TYPE_IF(
 201     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 202     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 203   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 204
 205 ])# _AT_BISON_OPTION_PUSHDEFS
 206
 207
 208 # AT_BISON_OPTION_POPDEFS
 209 # -----------------------
 210 m4_define([AT_BISON_OPTION_POPDEFS],
 211 [m4_divert_text([KILL],
 212 [m4_popdef([AT_YYLEX_PRE_ARGS])
 213 m4_popdef([AT_YYLEX_PRE_FORMALS])
 214 m4_popdef([AT_USE_LEX_ARGS])
 215 m4_popdef([AT_YYLEX_ARGS])
 216 m4_popdef([AT_YYLEX_FORMALS])
 217 m4_popdef([AT_YYLTYPE])
 218 m4_popdef([AT_YYSTYPE])
 219 m4_popdef([AT_VAL])
 220 m4_popdef([AT_LOC])
 221 m4_popdef([AT_PURE_LEX_IF])
 222 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 223 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 224 m4_popdef([AT_API_prefix])
 225 m4_popdef([AT_NAME_PREFIX])
 226 m4_popdef([AT_GLR_OR_PARAM_IF])
 227 m4_popdef([AT_PURE_AND_LOC_IF])
 228 m4_popdef([AT_LOCATION_TYPE_IF])
 229 m4_popdef([AT_LOCATION_IF])
 230 m4_popdef([AT_PARAM_IF])
 231 m4_popdef([AT_LEXPARAM_IF])
 232 m4_popdef([AT_YACC_IF])
 233 m4_popdef([AT_GLR_IF])
 234 m4_popdef([AT_SKEL_CC_IF])
 235 m4_popdef([AT_LANG])
 236 m4_popdef([AT_SKEL_JAVA_IF])
 237 m4_popdef([AT_GLR_CC_IF])
 238 m4_popdef([AT_LALR1_CC_IF])
 239 m4_popdef([AT_DEFINES_IF])
 240 AT_LOC_POPDEF])dnl
 241 ])# AT_BISON_OPTION_POPDEFS
 242
 243
 244
 245 ## -------------------------- ##
 246 ## Generating Grammar Files.  ##
 247 ## -------------------------- ##
 248
 249 # AT_DATA_SOURCE_PROLOGUE
 250 # ------------------------
 251 # The prologue that should be included in any source code that is
 252 # meant to be compiled.
 253 m4_define([AT_DATA_SOURCE_PROLOGUE],
 254 [[#include <config.h>
 255 /* We don't need perfect functions for these tests. */
 256 #undef malloc
 257 #undef memcmp
 258 #undef realloc
 259 ]])
 260
 261 # AT_DATA_GRAMMAR_PROLOGUE
 262 # ------------------------
 263 # The prologue that should be included in any grammar which parser is
 264 # meant to be compiled.
 265 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 266 [[%code top {
 267 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 268 [}
 269 ]])
 270
 271 # AT_DATA_SOURCE(NAME, CONTENT)
 272 # -----------------------------
 273 # Generate the file NAME, which CONTENT is preceded by
 274 # AT_DATA_SOURCE_PROLOGUE.
 275 m4_define([AT_DATA_SOURCE],
 276 [AT_DATA([$1],
 277 [AT_DATA_SOURCE_PROLOGUE
 278 $2])
 279 ])
 280
 281 # AT_DATA_GRAMMAR(NAME, CONTENT)
 282 # ------------------------------
 283 # Generate the file NAME, which CONTENT is preceded by
 284 # AT_DATA_GRAMMAR_PROLOGUE.
 285 m4_define([AT_DATA_GRAMMAR],
 286 [AT_DATA([$1],
 287 [AT_DATA_GRAMMAR_PROLOGUE
 288 $2])
 289 ])
 290
 291 # AT_YYLEX_PROTOTYPE
 292 # AT_YYLEX_DECLARE_EXTERN
 293 # AT_YYLEX_DECLARE
 294 # AT_YYLEX_DEFINE(INPUT-STRING, [ACTION])
 295 # ---------------------------------------
 296 m4_define([AT_YYLEX_PROTOTYPE],
 297 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 298 ])
 299
 300 m4_define([AT_YYLEX_DECLARE_EXTERN],
 301 [AT_YYLEX_PROTOTYPE;dnl
 302 ])
 303
 304 m4_define([AT_YYLEX_DECLARE],
 305 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 306 ])
 307
 308 m4_define([AT_YYLEX_DEFINE],
 309 [[#include <assert.h>
 310 static
 311 ]AT_YYLEX_PROTOTYPE[
 312 {
 313   static char const input[] = "$1";
 314   static size_t toknum = 0;
 315   int res;
 316   ]AT_USE_LEX_ARGS[;
 317   assert (toknum < sizeof input);
 318   res = input[toknum++];
 319   ]$2[;]AT_LOCATION_IF([[
 320   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 321   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 322   return res;
 323 }]dnl
 324 ])
 325
 326 # AT_YYERROR_PROTOTYPE
 327 # AT_YYERROR_DECLARE_EXTERN
 328 # AT_YYERROR_DECLARE
 329 # AT_YYERROR_DEFINE
 330 # -------------------------
 331 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 332 m4_define([AT_YYERROR_FORMALS],
 333 [m4_case(AT_LANG,
 334 [c], [AT_YYERROR_ARG_LOC_IF([YYLTYPE *llocp, ])[const char *msg]])[]dnl
 335 ])
 336
 337 m4_define([AT_YYERROR_PROTOTYPE],
 338 [m4_case(AT_LANG,
 339 [c], [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])[]dnl
 340 ])
 341
 342 m4_define([AT_YYERROR_DECLARE_EXTERN],
 343 [m4_case(AT_LANG,
 344 [c], [AT_YYERROR_PROTOTYPE;])[]dnl
 345 ])
 346
 347 m4_define([AT_YYERROR_DECLARE],
 348 [m4_case(AT_LANG,
 349 [c], [static AT_YYERROR_DECLARE_EXTERN])[]dnl
 350 ])
 351
 352 m4_define([AT_YYERROR_DEFINE],
 353 [m4_case(AT_LANG,
 354 [c], [[#include <stdio.h>
 355 /* A C error reporting function.  */
 356 static
 357 ]AT_YYERROR_PROTOTYPE[
 358 {
 359 ]AT_YYERROR_SEES_LOC_IF([[
 360   fprintf (stderr, "%d.%d",
 361            ]AT_LOC_FIRST_LINE[, ]AT_LOC_FIRST_COLUMN[);
 362   if (]AT_LOC_FIRST_LINE[ != ]AT_LOC_LAST_LINE[)
 363     fprintf (stderr, "-%d.%d",
 364              ]AT_LOC_LAST_LINE[,  ]AT_LOC_LAST_COLUMN[ - 1);
 365   else if (]AT_LOC_FIRST_COLUMN[ != ]AT_LOC_LAST_COLUMN[ - 1)
 366     fprintf (stderr, "-%d",
 367              ]AT_LOC_LAST_COLUMN[ - 1);
 368   fprintf (stderr, ": ");]])[
 369   fprintf (stderr, "%s\n", msg);
 370 }]],
 371 [c++], [[/* A C++ error reporting function.  */
 372 void
 373 ]AT_NAME_PREFIX[::parser::error (const location_type& l, const std::string& m)
 374 {
 375   (void) l;
 376   std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 377 }]],
 378 [java], [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 379   {
 380     if (l == null)
 381       System.err.println (s);
 382     else
 383       System.err.println (l + ": " + s);
 384   }
 385 ]], [[
 386   public void yyerror (String s)
 387   {
 388     System.err.println (s);
 389   }]])])dnl
 390 ])
 391
 392
 393 ## --------------- ##
 394 ## Running Bison.  ##
 395 ## --------------- ##
 396
 397 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 398 # -------------------------------------------------
 399 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 400 # shell constructs (such as redirection or pipes) that would prevent
 401 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 402 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 403 #
 404 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 405 # Bison in the test suite.  For now it ensures that:
 406 #
 407 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 408 #      a non-zero exit status since Bison doesn't always try to free all memory
 409 #      in that case.
 410 #
 411 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 412 #      --graph and --report=all output for every working grammar.
 413 #
 414 #   3. If stderr contains a warning, -Werror and --warnings=error
 415 #      convert the warning to an error.
 416 #
 417 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 418 m4_define([AT_BISON_CHECK],
 419 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 420        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 421 AT_BISON_CHECK_NO_XML($@)])
 422
 423 m4_define([AT_BISON_WERROR_MSG],
 424           [[bison: warnings being treated as errors]])
 425
 426 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 427 # --------------------------------------------------------
 428 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 429 # when a tortured grammar's XML is known to be too large for xsltproc to
 430 # handle.
 431 m4_define([AT_BISON_CHECK_NO_XML],
 432 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 433                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 434 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 435       m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0], [[
 436         # Defining POSIXLY_CORRECT causes bison to complain if options
 437         # are added after the grammar file name, so skip these checks
 438         # in that case.
 439         if test -z "${POSIXLY_CORRECT+set}"; then
 440           ]AT_SAVE_SPECIAL_FILES[
 441
 442           # To avoid expanding it repeatedly, store specified stdout.
 443           ]AT_DATA([expout], [$3])[
 444
 445           # Run with -Werror.
 446           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Werror]],
 447                     [[1]], [expout], [stderr])[
 448
 449           # Build expected stderr up to and including the "warnings being
 450           # treated as errors" message.
 451           ]AT_DATA([[at-bison-check-warnings]], [$4])[
 452           at_bison_check_first=`sed -n \
 453             '/: warning: /{=;q;}' at-bison-check-warnings`
 454           : ${at_bison_check_first:=1}
 455           at_bison_check_first_tmp=`sed -n \
 456             '/conflicts: [0-9].*reduce$/{=;q;}' at-bison-check-warnings`
 457           : ${at_bison_check_first_tmp:=1}
 458           if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 459             at_bison_check_first=$at_bison_check_first_tmp
 460           fi
 461           if test $at_bison_check_first -gt 1; then
 462             sed -n "1,`expr $at_bison_check_first - 1`"p \
 463               at-bison-check-warnings > experr
 464           fi
 465           echo ']AT_BISON_WERROR_MSG[' >> experr
 466
 467           # Finish building expected stderr and check.  Unlike warnings,
 468           # complaints cause bison to exit early.  Thus, with -Werror, bison
 469           # does not necessarily report all warnings that it does without
 470           # -Werror, but it at least reports one.
 471           at_bison_check_last=`sed -n '$=' stderr`
 472           : ${at_bison_check_last:=1}
 473           at_bison_check_last=`expr $at_bison_check_last - 1`
 474           sed -n "$at_bison_check_first,$at_bison_check_last"p \
 475             at-bison-check-warnings >> experr
 476           ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 477                       stderr 1>&2]], [[0]], [[]], [experr])[
 478
 479           # Now check --warnings=error.
 480           cp stderr experr
 481           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=error]],
 482                     [[1]], [expout], [experr])[
 483
 484           # Now check -Wnone and --warnings=none by making sure that
 485           # -Werror doesn't change the exit status when -Wnone or
 486           # --warnings=none is specified.
 487           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Wnone -Werror]],
 488                     [[0]], [expout])[
 489           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=none \
 490                     -Werror]], [[0]], [expout])[
 491
 492           ]AT_RESTORE_SPECIAL_FILES[
 493         fi
 494       ]])
 495 ])
 496
 497 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 498 # -----------------------------------------------------
 499 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 500 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 501 # have a non-zero exit status.
 502 m4_define([AT_BISON_CHECK_XML],
 503 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 504   AT_SAVE_SPECIAL_FILES
 505   [mkdir xml-tests]
 506   m4_pushdef([AT_BISON_ARGS],
 507              [m4_bpatsubsts([[$1]],
 508                             [--report(-file)?=[^][ ]*], [],
 509                             [--graph=[^][ ]*], [],
 510                             [--xml=[^][ ]*], [])])dnl
 511   # Don't combine these Bison invocations since we want to be sure that
 512   # --report=all isn't required to get the full XML file.
 513   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 514              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 515            [[0]], [ignore], [ignore])
 516   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 517            [[0]], [ignore], [ignore])
 518   m4_popdef([AT_BISON_ARGS])dnl
 519   [cp xml-tests/test.output expout]
 520   AT_CHECK([[$XSLTPROC \
 521              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 522              xml-tests/test.xml]], [[0]], [expout])
 523   [cp xml-tests/test.dot expout]
 524   AT_CHECK([[$XSLTPROC \
 525              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 526              xml-tests/test.xml]], [[0]], [expout])
 527   [rm -rf xml-tests expout]
 528   AT_RESTORE_SPECIAL_FILES
 529 [fi]])
 530
 531 # AT_QUELL_VALGRIND
 532 # -----------------
 533 # Put this before a Bison invocation to keep Valgrind from complaining about
 534 # reachable memory.
 535 #
 536 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 537 # The triple quoting below will cause test cases to fail if you do.  If you do
 538 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 539 # will then fail to shell-escape its contents when attempting to print them.
 540 # The testsuite verbose output, at least, will be incorrect, but nothing may
 541 # fail to make sure you notice.
 542 m4_define([AT_QUELL_VALGRIND],
 543 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 544
 545 ## ------------------------ ##
 546 ## Compiling C, C++ Files.  ##
 547 ## ------------------------ ##
 548
 549
 550 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 551 # ----------------------------------------
 552 # Compile SOURCES into OUTPUT.
 553 #
 554 # If OUTPUT does not contain '.', assume that we are linking too,
 555 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 556 # with trailing .o removed, and ".c" appended.
 557 m4_define([AT_COMPILE],
 558 [AT_CHECK(m4_join([ ],
 559                   [$CC $CFLAGS $CPPFLAGS],
 560                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 561                   [-o $1],
 562                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 563                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 564            0, [ignore], [ignore])])
 565
 566 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 567 # ---------------------------------------------
 568 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 569 # ignore the test.
 570 #
 571 # If OUTPUT does not contain '.', assume that we are linking too,
 572 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 573 # with trailing .o removed, and ".cc" appended.
 574 m4_define([AT_COMPILE_CXX],
 575 [AT_KEYWORDS(c++)
 576 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 577 AT_CHECK(m4_join([ ],
 578                  [$CXX $CXXFLAGS $CPPFLAGS],
 579                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 580                  [-o $1],
 581                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 582                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 583          0, [ignore], [ignore])])
 584
 585 # AT_JAVA_COMPILE(SOURCES)
 586 # ------------------------
 587 # Compile SOURCES into Java class files.  Skip the test if java or javac
 588 # is not installed.
 589 m4_define([AT_JAVA_COMPILE],
 590 [AT_KEYWORDS(java)
 591 AT_SKIP_IF([[test -z "$CONF_JAVA$CONF_JAVAC"]])
 592 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 593          [[0]], [ignore], [ignore])])
 594
 595 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 596 # --------------------------------------------
 597 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 598 #
 599 # If OUTPUT does not contain '.', assume that we are linking too,
 600 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 601 # with trailing .o removed, and ".c"/".cc" appended.
 602 m4_define([AT_LANG_COMPILE],
 603 [m4_case(AT_LANG,
 604 [c],    [AT_COMPILE([$1], [$2])],
 605 [c++],  [AT_COMPILE_CXX([$1], [$2])],
 606 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 607         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 608 ])
 609
 610 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 611 # -------------------------------------------
 612 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 613 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 614 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 615 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 616 # AT_SKEL_JAVA_IF.
 617 m4_define([AT_FULL_COMPILE],
 618 [m4_case(AT_LANG,
 619 [java],
 620   [AT_BISON_CHECK([-o $1.java $1.y])
 621    AT_LANG_COMPILE([$1],
 622                    m4_join([ ],
 623                            [$1.java],
 624                            m4_ifval($2, [[$1-$2.java]]),
 625                            m4_ifval($3, [[$1-$3.java]])))],
 626 [c++],
 627   [AT_BISON_CHECK([-o $1.cc $1.y])
 628    AT_LANG_COMPILE([$1],
 629                    m4_join([ ],
 630                            [$1.cc],
 631                            m4_ifval($2, [[$1-$2.cc]]),
 632                            m4_ifval($3, [[$1-$3.cc]])))],
 633 [c],
 634   [AT_BISON_CHECK([-o $1.c $1.y])
 635    AT_LANG_COMPILE([$1],
 636                    m4_join([ ],
 637                            [$1.c],
 638                            m4_ifval($2, [[$1-$2.c]]),
 639                            m4_ifval($3, [[$1-$3.c]])))])
 640 ])
 641
 642
 643 ## ---------------------------- ##
 644 ## Running a generated parser.  ##
 645 ## ---------------------------- ##
 646
 647
 648 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 649 # ------------------------------------------------------------
 650 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 651 #
 652 # Get rid of spurious messages when compiled with --coverage:
 653 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 654 m4_define([AT_PARSER_CHECK],
 655 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 656 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 657          [0], [], [$4])
 658 ])
 659
 660
 661 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 662 # -----------------------------------------------------------------
 663 m4_define([AT_JAVA_PARSER_CHECK],
 664 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 665
 666
 667 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 668 #                          DECLS, GRAMMAR, INPUT,
 669 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 670 #                          [OTHER-CHECKS],
 671 #                          [PARSER-EXIT-VALUE],
 672 #                          [PARSER-STDOUT], [PARSER-STDERR])
 673 # -------------------------------------------------------------
 674 # Using TITLE as the test group title, check the generated parser tables
 675 # and parser for a specified grammar file under a condition labeled by
 676 # COND-VALUE.
 677 #
 678 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 679 # recognized attribute is described below where it is relevant.
 680 #
 681 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 682 # the grammar file.  Insert basic yyerror, yylex, and main function
 683 # definitions as well.  Hardcode yylex to return the (possibly empty)
 684 # comma-delimited series of tokens in INPUT followed by token 0.
 685 #
 686 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 687 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 688 # On the bison command-line, specify `--report=all --defines'.  Check
 689 # that Bison exits with value 0, has no stdout, and has stderr
 690 # BISON-STDERR.
 691 #
 692 # If TEST-SPEC contains the attribute `last-state', check that the value
 693 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 694 # the grammar; in other words, check the number of states (minus one).
 695 # Otherwise, check that everything in the `.output' file starting with
 696 # the definition of state 0 is the same as the entire value of
 697 # TABLES-OR-LAST-STATE.
 698 #
 699 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 700 # `.output' file, which is named `input.output', and/or grammar file,
 701 # which is named `input.y'.
 702 #
 703 # Finally, compile the generated parser and then run it using
 704 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 705 # PARSER-STDERR as the 2nd-4th arguments.
 706 #
 707 # As a precondition, you must properly double-quote all arguments that
 708 # are to be interpreted as strings.
 709 #
 710 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 711 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 712 # first argument.  This is useful, for example, when wrapping multiple
 713 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 714 # condition, in another macro.
 715 #
 716 # For example:
 717 #
 718 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 719 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 720 #   # ---------------------------------------------------------------------
 721 #   m4_define([AT_TEST_SYNTAX_ERROR],
 722 #   [
 723 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 724 #                              [[last-state]],
 725 #                              [[%error-verbose ]$2], [$3], [$4],
 726 #                              [[]], [$5], [], [$6], [$7], [$8])
 727 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 728 #                              [[last-state]],
 729 #                              [$2], [$3], [$4],
 730 #                              [[]], [$5], [], [$6], [$7], [$8])
 731 #   ])
 732 #
 733 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 734 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 735 #                        [[3]],
 736 #                        [[1]], [[]],
 737 #                        [AT_COND_CASE([[no verbose]],
 738 #                                      [[syntax error
 739 #   ]],
 740 #                                      [[syntax error, unexpected 'b', expecting $end
 741 #   ]])])
 742 m4_define([AT_TEST_TABLES_AND_PARSE],
 743 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 744
 745 AT_SETUP([$1])
 746 AT_BISON_OPTION_PUSHDEFS([$4])
 747 AT_DATA_GRAMMAR([[input.y]],
 748 [[%code {
 749   #include <stdio.h>
 750   ]AT_YYERROR_DECLARE[
 751   ]AT_YYLEX_DECLARE[
 752 }
 753
 754 ]$4[
 755
 756 %%
 757
 758 ]$5[
 759
 760 %%
 761 ]AT_YYERROR_DEFINE[
 762 static int
 763 yylex (void)
 764 {
 765   static int const input[] = {
 766     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 767   };
 768   static int const *inputp = input;
 769   return *inputp++;
 770 }
 771
 772 int
 773 main (void)
 774 {
 775   return yyparse ();
 776 }
 777 ]])
 778
 779 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 780 # expanding macros, so it corrupts some special characters in the
 781 # macros.  To avoid this, expand now and pass it the result with proper
 782 # string quotation.  Assume args 7 through 12 expand to properly quoted
 783 # strings.
 784
 785 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 786       [AT_BISON_CHECK],
 787       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 788                                [0], [], m4_dquote($7))
 789
 790 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 791       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 792                 m4_dquote($8))],
 793       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 794                 m4_dquote($8)[[
 795 ]])])
 796
 797 $9
 798
 799 # Canonical LR generates very large tables, resulting in very long
 800 # files with #line directives that may overflow what the standards
 801 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 802 # will issue an error.
 803 #
 804 # There is no "" around `wc` since some indent the result.
 805 m4_bmatch([$4], [%define lr.type canonical-lr],
 806 [if test 32767 -lt `wc -l < input.c`; then
 807   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 808   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 809 fi])
 810 AT_COMPILE([[input]])
 811
 812 AT_PARSER_CHECK([[./input]],
 813                 m4_ifval([$10], [m4_dquote($10)]),
 814                 m4_ifval([$11], [m4_dquote($11)]),
 815                 m4_ifval([$12], [m4_dquote($12)]))
 816
 817 AT_BISON_OPTION_POPDEFS
 818 AT_CLEANUP
 819
 820 m4_popdef([AT_COND_CASE])])
 821
 822
 823
 824 ## ----------------------- ##
 825 ## Launch the test suite.  ##
 826 ## ----------------------- ##
 827
 828 AT_INIT
 829
 830 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 831 # options are processed, so we don't know the value of CXX and
 832 # CXXFLAGS yet.
 833 #
 834 # Note that it also means that command line values for CXX and
 835 # CXXFLAGS will not be propagated to CC and CFLAGS.
 836 AT_ARG_OPTION([compile-c-with-cxx],
 837               [compile C parsers with the C++ compiler])
 838
 839 AT_COLOR_TESTS
 840
 841 AT_TESTED([bison])