tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4 # Copyright (C) 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software
   5 # Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # We want a recent Autotest.
  21 m4_version_prereq([2.58])
  22
  23
  24 ## ------------- ##
  25 ## Basic tests.  ##
  26 ## ------------- ##
  27
  28 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  29 # ------------------------------------------
  30 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  31 # taken in "slurp" mode, i.e., one can match end-of-lines.
  32 m4_define([AT_MATCHES_CHECK],
  33 [AT_CHECK([perl -0777 -ne '
  34 my $count = 0;
  35 s{$2}{ ++$count; "" }gem;
  36 printf "$count\n";' $1], [0], [$3
  37 ])])
  38
  39
  40 ## ------------------------------- ##
  41 ## Macros decoding Bison options.  ##
  42 ## ------------------------------- ##
  43
  44
  45 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  46 # -----------------------------------------
  47 m4_define([AT_BISON_OPTION_PUSHDEFS],
  48 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  49
  50
  51 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  52 # --------------------------------------------------
  53 # This macro works around the impossibility to define macros
  54 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  55 # This sucks hard, GNU M4 should really provide M5-like $$1.
  56 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  57 [m4_if([$1$2], $[1]$[2], [],
  58        [m4_fatal([$0: Invalid arguments: $@])])dnl
  59 m4_pushdef([AT_DEFINES_IF],
  60 [m4_bmatch([$3], [%defines], [$1], [$2])])
  61 m4_pushdef([AT_SKEL_CC_IF],
  62 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  63 m4_pushdef([AT_GLR_IF],
  64 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  65 m4_pushdef([AT_LALR1_CC_IF],
  66 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  67 m4_pushdef([AT_GLR_CC_IF],
  68 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  69 # Using yacc.c?
  70 m4_pushdef([AT_YACC_IF],
  71 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  72 m4_pushdef([AT_LEXPARAM_IF],
  73 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  74 m4_pushdef([AT_PARAM_IF],
  75 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  76 m4_pushdef([AT_LOCATION_IF],
  77 [m4_bmatch([$3], [%locations], [$1], [$2])])
  78 m4_pushdef([AT_PURE_IF],
  79 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
  80            [m4_bmatch([$3], [%define  *api\.pure *"false"], [$2], [$1])],
  81            [$2])])
  82 m4_pushdef([AT_PURE_AND_LOC_IF],
  83 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
  84 m4_pushdef([AT_GLR_OR_PARAM_IF],
  85 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
  86 m4_pushdef([AT_NAME_PREFIX],
  87 [m4_bmatch([$3], [%name-prefix ".*"],
  88            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
  89            [yy])])
  90 m4_pushdef([AT_TOKEN_PREFIX],
  91 [m4_bmatch([$3], [%define token.prefix ".*"],
  92            [m4_bregexp([$3], [%define token.prefix "\(.*\)"], [\1])])])
  93 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
  94 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
  95 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
  96                     [$2])])
  97 # yyerror always sees the locations (when activated), except if
  98 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
  99 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 100 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 101                                         [$1])],
 102                             [$1])],
 103                 [$2])])
 104
 105 # The interface is pure: either because %define api.pure, or because we
 106 # are using the C++ parsers.
 107 m4_pushdef([AT_PURE_LEX_IF],
 108 [AT_PURE_IF([$1],
 109             [AT_SKEL_CC_IF([$1], [$2])])])
 110
 111 AT_PURE_LEX_IF(
 112 [m4_pushdef([AT_LOC], [(*llocp)])
 113  m4_pushdef([AT_VAL], [(*lvalp)])
 114  m4_pushdef([AT_LEX_FORMALS],
 115             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 116  m4_pushdef([AT_LEX_ARGS],
 117             [lvalp[]AT_LOCATION_IF([, llocp])])
 118  m4_pushdef([AT_USE_LEX_ARGS],
 119             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 120  m4_pushdef([AT_LEX_PRE_FORMALS],
 121             [AT_LEX_FORMALS, ])
 122  m4_pushdef([AT_LEX_PRE_ARGS],
 123             [AT_LEX_ARGS, ])
 124 ],
 125 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 126  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 127  m4_pushdef([AT_LEX_FORMALS],     [void])
 128  m4_pushdef([AT_LEX_ARGS],        [])
 129  m4_pushdef([AT_USE_LEX_ARGS],    [])
 130  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 131  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 132 ])
 133 AT_GLR_IF([AT_KEYWORDS([glr])])
 134 ])# _AT_BISON_OPTION_PUSHDEFS
 135
 136
 137 # AT_BISON_OPTION_POPDEFS
 138 # -----------------------
 139 m4_define([AT_BISON_OPTION_POPDEFS],
 140 [m4_popdef([AT_LEX_PRE_ARGS])
 141 m4_popdef([AT_LEX_PRE_FORMALS])
 142 m4_popdef([AT_USE_LEX_ARGS])
 143 m4_popdef([AT_LEX_ARGS])
 144 m4_popdef([AT_LEX_FORMALS])
 145 m4_popdef([AT_VAL])
 146 m4_popdef([AT_LOC])
 147 m4_popdef([AT_PURE_LEX_IF])
 148 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 149 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 150 m4_popdef([AT_NAME_PREFIX])
 151 m4_popdef([AT_GLR_OR_PARAM_IF])
 152 m4_popdef([AT_PURE_AND_LOC_IF])
 153 m4_popdef([AT_LOCATION_IF])
 154 m4_popdef([AT_PARAM_IF])
 155 m4_popdef([AT_LEXPARAM_IF])
 156 m4_popdef([AT_YACC_IF])
 157 m4_popdef([AT_GLR_IF])
 158 m4_popdef([AT_SKEL_CC_IF])
 159 m4_popdef([AT_GLR_CC_IF])
 160 m4_popdef([AT_LALR1_CC_IF])
 161 m4_popdef([AT_DEFINES_IF])
 162 ])# AT_BISON_OPTION_POPDEFS
 163
 164
 165
 166 ## -------------------------- ##
 167 ## Generating Grammar Files.  ##
 168 ## -------------------------- ##
 169
 170 # AT_DATA_SOURCE_PROLOGUE
 171 # ------------------------
 172 # The prologue that should be included in any source code that is
 173 # meant to be compiled.
 174 m4_define([AT_DATA_SOURCE_PROLOGUE],
 175 [[#include <config.h>
 176 /* We don't need perfect functions for these tests. */
 177 #undef malloc
 178 #undef memcmp
 179 #undef realloc
 180 ]])
 181
 182 # AT_DATA_GRAMMAR_PROLOGUE
 183 # ------------------------
 184 # The prologue that should be included in any grammar which parser is
 185 # meant to be compiled.
 186 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 187 [[%code top {
 188 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 189 [}
 190 ]])
 191
 192 # AT_DATA_SOURCE(NAME, CONTENT)
 193 # -----------------------------
 194 # Generate the file NAME, which CONTENT is preceded by
 195 # AT_DATA_SOURCE_PROLOGUE.
 196 m4_define([AT_DATA_SOURCE],
 197 [AT_DATA([$1],
 198 [AT_DATA_SOURCE_PROLOGUE
 199 $2])
 200 ])
 201
 202 # AT_DATA_GRAMMAR(NAME, CONTENT)
 203 # ------------------------------
 204 # Generate the file NAME, which CONTENT is preceded by
 205 # AT_DATA_GRAMMAR_PROLOGUE.
 206 m4_define([AT_DATA_GRAMMAR],
 207 [AT_DATA([$1],
 208 [AT_DATA_GRAMMAR_PROLOGUE
 209 $2])
 210 ])
 211
 212 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 213 # -------------------------------------------------
 214 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 215 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 216 #
 217 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 218 # Bison in the test suite.  For now it ensures that:
 219 #
 220 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 221 #      a non-zero exit status since Bison doesn't always try to free all memory
 222 #      in that case.
 223 #
 224 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 225 #      --graph and --report=all output for every working grammar.
 226 m4_define([AT_BISON_CHECK],
 227 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 228        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 229 AT_BISON_CHECK_NO_XML($@)])
 230
 231 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 232 # --------------------------------------------------------
 233 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 234 # when a tortured grammar's XML is known to be too large for xsltproc to
 235 # handle.
 236 m4_define([AT_BISON_CHECK_NO_XML],
 237 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 238                 [AT_QUELL_VALGRIND ])[[bison ]]$@)])
 239
 240 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 241 # -----------------------------------------------------
 242 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 243 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 244 # have a non-zero exit status.
 245 m4_define([AT_BISON_CHECK_XML],
 246 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 247   mkdir xml-tests]
 248   m4_pushdef([AT_BISON_ARGS],
 249              [m4_bpatsubsts([[$1]],
 250                             [--report(-file)?=[^][ ]*], [],
 251                             [--graph=[^][ ]*], [],
 252                             [--xml=[^][ ]*], [])])dnl
 253   # Don't combine these Bison invocations since we want to be sure that
 254   # --report=all isn't required to get the full XML file.
 255   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 256              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 257            [[0]], [ignore], [ignore])
 258   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 259            [[0]], [ignore], [ignore])
 260   m4_popdef([AT_BISON_ARGS])dnl
 261   [cp xml-tests/test.output expout]
 262   AT_CHECK([[$XSLTPROC \
 263              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 264              xml-tests/test.xml]], [[0]], [expout])
 265   [cp xml-tests/test.dot expout]
 266   AT_CHECK([[$XSLTPROC \
 267              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 268              xml-tests/test.xml]], [[0]], [expout])
 269   [rm -rf xml-tests expout
 270 fi]])
 271
 272 # AT_QUELL_VALGRIND
 273 # -----------------
 274 # Put this before a Bison invocation to keep Valgrind from complaining about
 275 # reachable memory.
 276 #
 277 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 278 # The triple quoting below will cause test cases to fail if you do.  If you do
 279 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 280 # will then fail to shell-escape its contents when attempting to print them.
 281 # The testsuite verbose output, at least, will be incorrect, but nothing may
 282 # fail to make sure you notice.
 283 m4_define([AT_QUELL_VALGRIND],
 284 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 285
 286 ## ------------------------ ##
 287 ## Compiling C, C++ Files.  ##
 288 ## ------------------------ ##
 289
 290
 291 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 292 # ----------------------------------------
 293 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 294 # assume that we are linking too; this is a hack.
 295 m4_define([AT_COMPILE],
 296 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 297            0, [ignore], [ignore])])
 298
 299 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 300 # --------------------------------------------
 301 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 302 # assume that we are linking too; this is a hack.
 303 # If the C++ compiler does not work, ignore the test.
 304 m4_define([AT_COMPILE_CXX],
 305 [AT_KEYWORDS(c++)
 306 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 307 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 308          0, [ignore], [ignore])])
 309
 310
 311 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 312 # --------------------------------
 313 # Compile OUTPUT.y to OUTPUT.c or OUTPUT.cc, and compile it to OUTPUT.
 314 # If OTHER is specified, compile OUTPUT-OTHER.c or OUTPUT-OTHER.cc to OUTPUT
 315 # along with it.
 316 # Relies on AT_SKEL_CC_IF.
 317 m4_define([AT_FULL_COMPILE],
 318 [AT_SKEL_CC_IF(
 319   [AT_BISON_CHECK([-o $1.cc $1.y])
 320    AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1.cc $1-$2.cc]]))],
 321   [AT_BISON_CHECK([-o $1.c $1.y])
 322    AT_COMPILE([$1]m4_ifval($2, [, [$1.c $1-$2.c]]))])
 323 ])
 324
 325
 326 ## ---------------------------- ##
 327 ## Running a generated parser.  ##
 328 ## ---------------------------- ##
 329
 330 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 331 # ------------------------------------------------------------
 332 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 333 m4_define([AT_PARSER_CHECK],
 334 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 335
 336 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 337 #                          DECLS, GRAMMAR, INPUT,
 338 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 339 #                          [OTHER-CHECKS],
 340 #                          [PARSER-EXIT-VALUE],
 341 #                          [PARSER-STDOUT], [PARSER-STDERR])
 342 # -------------------------------------------------------------
 343 # Using TITLE as the test group title, check the generated parser tables
 344 # and parser for a specified grammar file under a condition labeled by
 345 # COND-VALUE.
 346 #
 347 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 348 # recognized attribute is described below where it is relevant.
 349 #
 350 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 351 # the grammar file.  Insert basic yyerror, yylex, and main function
 352 # definitions as well.  Hardcode yylex to return the (possibly empty)
 353 # comma-delimited series of tokens in INPUT followed by token 0.
 354 #
 355 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 356 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 357 # On the bison command-line, specify `--report=all --defines'.  Check
 358 # that Bison exits with value 0, has no stdout, and has stderr
 359 # BISON-STDERR.
 360 #
 361 # If TEST-SPEC contains the attribute `last-state', check that the value
 362 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 363 # the grammar; in other words, check the number of states (minus one).
 364 # Otherwise, check that everything in the `.output' file starting with
 365 # the definition of state 0 is the same as the entire value of
 366 # TABLES-OR-LAST-STATE.
 367 #
 368 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 369 # `.output' file, which is named `input.output', and/or grammar file,
 370 # which is named `input.y'.
 371 #
 372 # Finally, compile the generated parser and then run it using
 373 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 374 # PARSER-STDERR as the 2nd-4th arguments.
 375 #
 376 # As a precondition, you must properly double-quote all arguments that
 377 # are to be interpreted as strings.
 378 #
 379 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 380 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 381 # first argument.  This is useful, for example, when wrapping multiple
 382 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 383 # condition, in another macro.
 384 #
 385 # For example:
 386 #
 387 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 388 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 389 #   # ---------------------------------------------------------------------
 390 #   m4_define([AT_TEST_SYNTAX_ERROR],
 391 #   [
 392 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 393 #                              [[last-state]],
 394 #                              [[%error-verbose ]$2], [$3], [$4],
 395 #                              [[]], [$5], [], [$6], [$7], [$8])
 396 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 397 #                              [[last-state]],
 398 #                              [$2], [$3], [$4],
 399 #                              [[]], [$5], [], [$6], [$7], [$8])
 400 #   ])
 401 #
 402 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 403 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 404 #                        [[3]],
 405 #                        [[1]], [[]],
 406 #                        [AT_COND_CASE([[no verbose]],
 407 #                                      [[syntax error
 408 #   ]],
 409 #                                      [[syntax error, unexpected 'b', expecting $end
 410 #   ]])])
 411 m4_define([AT_TEST_TABLES_AND_PARSE],
 412 [_AT_TEST_TABLES_AND_PARSE($[1], $[@], $@)])
 413
 414 m4_define([_AT_TEST_TABLES_AND_PARSE],
 415 [m4_pushdef([AT_COND_CASE], [m4_case([$4], $][@)])
 416
 417 AT_SETUP([$3])
 418
 419 AT_DATA_GRAMMAR([[input.y]],
 420 [[%code {
 421   #include <stdio.h>
 422   static void yyerror (char const *msg);
 423   static int yylex (void);
 424 }
 425
 426 ]$6[
 427
 428 %%
 429
 430 ]$7[
 431
 432 %%
 433
 434 static void
 435 yyerror (char const *msg)
 436 {
 437   fprintf (stderr, "%s\n", msg);
 438 }
 439
 440 static int
 441 yylex (void)
 442 {
 443   static int const input[] = {
 444     ]m4_if([$8], [], [], [$8], [[]], [], [$8[, ]])[0
 445   };
 446   static int const *inputp = input;
 447   return *inputp++;
 448 }
 449
 450 int
 451 main (void)
 452 {
 453   return yyparse ();
 454 }
 455 ]])
 456
 457 # AT_CHECK invokes AS_ESCAPE before expanding macros, so it corrupts some
 458 # special characters in the macros.  To avoid this, expand now and pass it
 459 # the result with proper string quotation.  Assume args 9 thru 14 expand to
 460 # properly quoted strings.
 461
 462 # Pass plenty of options, to exercise plenty of code, even if we
 463 # don't actually check the output.  But SEGV is watching us, and
 464 # so might do dmalloc.
 465 m4_if(m4_index(m4_quote($5), [no-xml]), -1,
 466       [AT_BISON_CHECK],
 467       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 468                                [0], [], m4_dquote($9))
 469
 470 # Sigh.  Some M4's can't reference arg 10 directly.
 471 m4_pushdef([arg10], m4_car(m4_shiftn(9, $@)))
 472 m4_if(m4_index(m4_quote($5), [last-state]), -1,
 473       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 474                 m4_dquote(arg10))],
 475       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 476                 m4_dquote(arg10)[[
 477 ]])])
 478 m4_popdef([arg10])
 479
 480 m4_if($#, 10, [], m4_car(m4_shiftn(10, $@)))
 481
 482 AT_COMPILE([[input]])
 483
 484 m4_pushdef([AT_EXPAND_ARGS], [$][*])
 485 m4_pushdef([AT_DQUOTE_EACH], [[[$1]]m4_if($][#, 1, [], [, AT_DQUOTE_EACH(m4_shift($2))])])
 486
 487 AT_PARSER_CHECK([[./input]]m4_if($#, 10, [], $#, 11, [], [, AT_DQUOTE_EACH(AT_EXPAND_ARGS(m4_shiftn(11, $@)))]))
 488
 489 m4_popdef([AT_DQUOTE_EACH])
 490 m4_popdef([AT_EXPAND_ARGS])
 491
 492 AT_CLEANUP
 493
 494 m4_popdef([AT_COND_CASE])])
 495
 496
 497
 498 ## ----------------------- ##
 499 ## Launch the test suite.  ##
 500 ## ----------------------- ##
 501
 502 AT_INIT
 503
 504 AT_TESTED([bison])