data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4 # Copyright (C) 2002, 2004, 2005, 2006, 2007, 2008, 2009
   5 # Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 ## ---------------- ##
  22 ## Identification.  ##
  23 ## ---------------- ##
  24
  25 # b4_copyright(TITLE, [YEARS])
  26 # ----------------------------
  27 # If YEARS are not defined, use b4_copyright_years.
  28 m4_define([b4_copyright],
  29 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  30
  31 b4_comment([$1
  32
  33 ]m4_dquote(m4_text_wrap([Copyright (C)
  34 ]m4_ifval([$2], [[$2]], [m4_defn([b4_copyright_years])])[
  35 Free Software Foundation, Inc.]))[
  36
  37 This program is free software: you can redistribute it and/or modify
  38 it under the terms of the GNU General Public License as published by
  39 the Free Software Foundation, either version 3 of the License, or
  40 (at your option) any later version.
  41
  42 This program is distributed in the hope that it will be useful,
  43 but WITHOUT ANY WARRANTY; without even the implied warranty of
  44 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  45 GNU General Public License for more details.
  46
  47 You should have received a copy of the GNU General Public License
  48 along with this program.  If not, see <http://www.gnu.org/licenses/>.])
  49
  50 b4_comment([As a special exception, you may create a larger work that contains
  51 part or all of the Bison parser skeleton and distribute that work
  52 under terms of your choice, so long as that work isn't itself a
  53 parser generator using the skeleton or a modified version thereof
  54 as a parser skeleton.  Alternatively, if you modify or redistribute
  55 the parser skeleton itself, you may (at your option) remove this
  56 special exception, which will cause the skeleton and the resulting
  57 Bison output files to be licensed under the GNU General Public
  58 License without this special exception.
  59
  60 This special exception was added by the Free Software Foundation in
  61 version 2.2 of Bison.])])
  62
  63
  64 ## ---------------- ##
  65 ## Error handling.  ##
  66 ## ---------------- ##
  67
  68 # The following error handling macros print error directives that should not
  69 # become arguments of other macro invocations since they would likely then be
  70 # mangled.  Thus, they print to stdout directly.
  71
  72 # b4_cat(TEXT)
  73 # ------------
  74 # Write TEXT to stdout.  Precede the final newline with an @ so that it's
  75 # escaped.  For example:
  76 #
  77 #   b4_cat([[@complain(invalid input@)]])
  78 m4_define([b4_cat],
  79 [m4_syscmd([cat <<'_m4eof'
  80 ]m4_bpatsubst(m4_dquote($1), [_m4eof], [_m4@`eof])[@
  81 _m4eof
  82 ])dnl
  83 m4_if(m4_sysval, [0], [], [m4_fatal([$0: cannot write to stdout])])])
  84
  85 # b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
  86 # -------------------------------------------
  87 # Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to stdout.
  88 #
  89 # For example:
  90 #
  91 #   b4_error([[warn]], [[invalid value for `%s': %s]], [[foo]], [[3]])
  92 m4_define([b4_error],
  93 [b4_cat([[@]$1[(]$2[]]dnl
  94 [m4_if([$#], [2], [],
  95        [m4_foreach([b4_arg],
  96                    m4_dquote(m4_shift(m4_shift($@))),
  97                    [[@,]b4_arg])])[@)]])])
  98
  99 # b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
 100 # ----------------------------------------------------------
 101 # Write @KIND_at(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 102 #
 103 # For example:
 104 #
 105 #   b4_error_at([[complain]], [[input.y:2.3]], [[input.y:5.4]],
 106 #               [[invalid %s]], [[foo]])
 107 m4_define([b4_error_at],
 108 [b4_cat([[@]$1[_at(]$2[@,]$3[@,]$4[]]dnl
 109 [m4_if([$#], [4], [],
 110        [m4_foreach([b4_arg],
 111                    m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
 112                    [[@,]b4_arg])])[@)]])])
 113
 114 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
 115 # ------------------------------------
 116 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 117 #
 118 # For example:
 119 #
 120 #   b4_warn([[invalid value for `%s': %s]], [[foo]], [[3]])
 121 #
 122 # As a simple test suite, this:
 123 #
 124 #   m4_divert(-1)
 125 #   m4_define([asdf], [ASDF])
 126 #   m4_define([fsa], [FSA])
 127 #   m4_define([fdsa], [FDSA])
 128 #   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
 129 #   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
 130 #   b4_warn()
 131 #   b4_warn(1)
 132 #   b4_warn(1, 2)
 133 #
 134 # Should produce this without newlines:
 135 #
 136 #   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
 137 #   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
 138 #   @warn(@)
 139 #   @warn(1@)
 140 #   @warn(1@,2@)
 141 m4_define([b4_warn],
 142 [b4_error([[warn]], $@)])
 143
 144 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 145 # ---------------------------------------------------
 146 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 147 #
 148 # For example:
 149 #
 150 #   b4_warn_at([[input.y:2.3]], [[input.y:5.4]], [[invalid %s]], [[foo]])
 151 m4_define([b4_warn_at],
 152 [b4_error_at([[warn]], $@)])
 153
 154 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 155 # ----------------------------------------
 156 # Write @complain(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 157 #
 158 # See b4_warn example.
 159 m4_define([b4_complain],
 160 [b4_error([[complain]], $@)])
 161
 162 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 163 # -------------------------------------------------------
 164 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 165 #
 166 # See b4_warn_at example.
 167 m4_define([b4_complain_at],
 168 [b4_error_at([[complain]], $@)])
 169
 170 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 171 # -------------------------------------
 172 # Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 173 #
 174 # See b4_warn example.
 175 m4_define([b4_fatal],
 176 [b4_error([[fatal]], $@)dnl
 177 m4_exit(1)])
 178
 179 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 180 # ----------------------------------------------------
 181 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 182 #
 183 # See b4_warn_at example.
 184 m4_define([b4_fatal_at],
 185 [b4_error_at([[fatal]], $@)dnl
 186 m4_exit(1)])
 187
 188
 189 ## ---------------- ##
 190 ## Default values.  ##
 191 ## ---------------- ##
 192
 193 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 194 m4_define_default([b4_pre_prologue], [])
 195 m4_define_default([b4_post_prologue], [])
 196 m4_define_default([b4_epilogue], [])
 197 m4_define_default([b4_parse_param], [])
 198
 199 # The initial column and line.
 200 m4_define_default([b4_location_initial_column], [1])
 201 m4_define_default([b4_location_initial_line],   [1])
 202
 203
 204 ## ------------ ##
 205 ## Data Types.  ##
 206 ## ------------ ##
 207
 208 # b4_ints_in(INT1, INT2, LOW, HIGH)
 209 # ---------------------------------
 210 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 211 m4_define([b4_ints_in],
 212 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 213
 214
 215 # b4_subtract(LHS, RHS)
 216 # ---------------------
 217 # Evaluate LHS - RHS if they are integer literals, otherwise expand
 218 # to (LHS) - (RHS).
 219 m4_define([b4_subtract],
 220 [m4_bmatch([$1$2], [^[0123456789]*$],
 221            [m4_eval([$1 - $2])],
 222            [($1) - ($2)])])
 223
 224 # b4_args(ARG1, ...)
 225 # _b4_args(ARG1, ...)
 226 # -------------------
 227 # Join with comma, skipping empty arguments.
 228 # b4_args calls itself recursively until it sees the first non-empty
 229 # argument, then calls _b4_args which prepends each non-empty argument
 230 # with a comma.
 231 m4_define([b4_args],
 232 [m4_if([$#$1],
 233        [1], [],
 234        [m4_ifval([$1],
 235                  [$1[]_$0(m4_shift($@))],
 236                  [$0(m4_shift($@))])])])
 237
 238 # _b4_args(ARGS1, ...)
 239 # --------------------
 240 m4_define([_b4_args],
 241 [m4_if([$#$1],
 242        [1], [],
 243        [m4_ifval([$1], [, $1])[]$0(m4_shift($@))])])
 244
 245
 246
 247
 248 # b4_integral_parser_tables_map(MACRO)
 249 # -------------------------------------
 250 # Map MACRO on all the integral tables.  MACRO is expected to have
 251 # the signature MACRO(TABLE-NAME, CONTENT, COMMENT).
 252 m4_define([b4_integral_parser_tables_map],
 253 [$1([pact], [b4_pact],
 254     [[YYPACT[STATE-NUM] -- Index in YYTABLE of the portion describing
 255 STATE-NUM.]])
 256
 257 $1([defact], [b4_defact],
 258    [[YYDEFACT[S] -- default reduction number in state S.  Performed when
 259 YYTABLE does not specify something else to do.  Zero means the default
 260 is an error.]])
 261
 262 $1([pgoto], [b4_pgoto], [[YYPGOTO[NTERM-NUM].]])
 263
 264 $1([defgoto], [b4_defgoto], [[YYDEFGOTO[NTERM-NUM].]])
 265
 266 $1([table], [b4_table],
 267    [[YYTABLE[YYPACT[STATE-NUM]].  What to do in state STATE-NUM.  If
 268 positive, shift that token.  If negative, reduce the rule which
 269 number is the opposite.  If zero, do what YYDEFACT says.
 270 If YYTABLE_NINF, syntax error.]])
 271
 272 $1([check], [b4_check])
 273
 274 $1([stos], [b4_stos],
 275    [[STOS_[STATE-NUM] -- The (internal number of the) accessing
 276 symbol of state STATE-NUM.]])
 277
 278 $1([r1], [b4_r1],
 279    [[YYR1[YYN] -- Symbol number of symbol that rule YYN derives.]])
 280
 281 $1([r2], [b4_r2],
 282    [[YYR2[YYN] -- Number of symbols composing right hand side of rule YYN.]])
 283 ])
 284
 285
 286 # b4_parser_tables_declare
 287 # b4_parser_tables_define
 288 # ------------------------
 289 # Define/declare the (deterministic) parser tables.
 290 m4_define([b4_parser_tables_declare],
 291 [b4_integral_parser_tables_map([b4_integral_parser_table_declare])])
 292
 293 m4_define([b4_parser_tables_define],
 294 [b4_integral_parser_tables_map([b4_integral_parser_table_define])])
 295
 296
 297
 298 ## ------------------ ##
 299 ## Decoding options.  ##
 300 ## ------------------ ##
 301
 302 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 303 # -----------------------------------
 304 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 305 m4_define([b4_flag_if],
 306 [m4_case(b4_$1_flag,
 307          [0], [$3],
 308          [1], [$2],
 309          [m4_fatal([invalid $1 value: ]$1)])])
 310
 311
 312 # b4_define_flag_if(FLAG)
 313 # -----------------------
 314 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 315 # value of the Boolean FLAG.
 316 m4_define([b4_define_flag_if],
 317 [_b4_define_flag_if($[1], $[2], [$1])])
 318
 319 # _b4_define_flag_if($1, $2, FLAG)
 320 # --------------------------------
 321 # This macro works around the impossibility to define macros
 322 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 323 # This sucks hard, GNU M4 should really provide M5 like $$1.
 324 m4_define([_b4_define_flag_if],
 325 [m4_if([$1$2], $[1]$[2], [],
 326        [m4_fatal([$0: Invalid arguments: $@])])dnl
 327 m4_define([b4_$3_if],
 328           [b4_flag_if([$3], [$1], [$2])])])
 329
 330
 331 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 332 # -----------------------------
 333 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 334 b4_define_flag_if([defines])            # Whether headers are requested.
 335 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 336 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 337 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 338
 339
 340 ## --------- ##
 341 ## Symbols.  ##
 342 ## --------- ##
 343
 344 # b4_symbol_(NUM, FIELD)
 345 # ----------------------
 346 # Recover a FIELD about symbol #NUM.  Thanks to m4_indir, fails if
 347 # undefined.
 348 m4_define([b4_symbol_],
 349 [m4_indir([b4_symbol($1, $2)])])
 350
 351
 352 # b4_symbol(NUM, FIELD)
 353 # ---------------------
 354 # Recover a FIELD about symbol #NUM.  Thanks to m4_indir, fails if
 355 # undefined.  If FIELD = id, prepend the prefix.
 356 m4_define([b4_symbol],
 357 [m4_case([$2],
 358          [id],    [m4_do([b4_percent_define_get([token.prefix])],
 359                          [b4_symbol_([$1], [id])])],
 360          [b4_symbol_($@)])])
 361
 362
 363 # b4_symbol_if(NUM, FIELD, IF-TRUE, IF-FALSE)
 364 # -------------------------------------------
 365 # If FIELD about symbol #NUM is 1 expand IF-TRUE, if is 0, expand IF-FALSE.
 366 # Otherwise an error.
 367 m4_define([b4_symbol_if],
 368 [m4_case(b4_symbol([$1], [$2]),
 369          [1], [$3],
 370          [0], [$4],
 371          [m4_fatal([$0: field $2 of $1 is not a Boolean:] b4_symbol([$1], [$2]))])])
 372
 373
 374 # b4_symbol_action_location(SYMBOL-NUM, KIND)
 375 # -------------------------------------------
 376 # Report the location of the KIND action as FILE:LINE.
 377 m4_define([b4_symbol_action_location],
 378 [b4_symbol([$1], [$2_file]):b4_syncline([b4_symbol([$1], [$2_line])])])
 379
 380
 381 # b4_symbol_action(SYMBOL-NUM, KIND)
 382 # ----------------------------------
 383 # Run the action KIND (destructor or printer) for SYMBOL-NUM.
 384 # Same as in C, but using references instead of pointers.
 385 m4_define([b4_symbol_action],
 386 [b4_symbol_if([$1], [has_$2],
 387 [m4_pushdef([b4_dollar_dollar],
 388     [b4_symbol_value([(*yyvaluep)],
 389                      b4_symbol_if([$1], [has_type],
 390                                   [b4_symbol([$1], [type])]))])dnl
 391 m4_pushdef([b4_at_dollar], [(*yylocationp)])dnl
 392       b4_symbol_case_([$1])
 393 b4_syncline([b4_symbol([$1], [$2_line])], ["b4_symbol([$1], [$2_file])"])
 394         b4_symbol([$1], [$2])
 395 b4_syncline([@oline@], [@ofile@])
 396         break;
 397
 398 m4_popdef([b4_at_dollar])dnl
 399 m4_popdef([b4_dollar_dollar])dnl
 400 ])])
 401
 402
 403 # b4_symbol_destructor(SYMBOL-NUM)
 404 # b4_symbol_printer(SYMBOL-NUM)
 405 # --------------------------------
 406 m4_define([b4_symbol_destructor], [b4_symbol_action([$1], [destructor])])
 407 m4_define([b4_symbol_printer],    [b4_symbol_action([$1], [printer])])
 408
 409
 410 # b4_symbol_case_(SYMBOL-NUM)
 411 # ---------------------------
 412 # Issue a "case NUM" for SYMBOL-NUM.
 413 m4_define([b4_symbol_case_],
 414 [      case b4_symbol([$1], [number]): // b4_symbol([$1], [tag])
 415 ])
 416
 417
 418 # b4_symbol_foreach(MACRO)
 419 # ------------------------
 420 # Invoke MACRO(SYMBOL-NUM) for each SYMBOL-NUM.
 421 m4_define([b4_symbol_foreach],
 422           [m4_map([$1], m4_defn([b4_symbol_numbers]))])
 423
 424
 425 ## ------- ##
 426 ## Types.  ##
 427 ## ------- ##
 428
 429 # b4_type_action_(NUMS)
 430 # ---------------------
 431 # Run actions for the symbol NUMS that all have the same type-name.
 432 # Skip NUMS that have no type-name.
 433 m4_define([b4_type_action_],
 434 [b4_symbol_if([$1], [has_type],
 435 [m4_map([b4_symbol_case_], [$@])[]dnl
 436         b4_dollar_dollar([b4_symbol([$1], [number])],
 437                          [b4_symbol([$1], [tag])],
 438                          [b4_symbol([$1], [type])]);
 439         break;
 440
 441 ])])
 442
 443 # b4_type_foreach(MACRO)
 444 # ----------------------
 445 # Invoke MACRO(SYMBOL-NUMS) for each set of SYMBOL-NUMS for each type set.
 446 m4_define([b4_type_foreach],
 447           [m4_map([$1], m4_defn([b4_type_names]))])
 448
 449
 450
 451 ## ----------- ##
 452 ## Synclines.  ##
 453 ## ----------- ##
 454
 455 # b4_basename(NAME)
 456 # -----------------
 457 # Similar to POSIX basename; the differences don't matter here.
 458 # Beware that NAME is not evaluated.
 459 m4_define([b4_basename],
 460 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 461
 462
 463 # b4_syncline(LINE, FILE)
 464 # -----------------------
 465 m4_define([b4_syncline],
 466 [b4_flag_if([synclines],
 467 [b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 468 b4_sync_start([$1], [$2])])])
 469
 470 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 471 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 472
 473 # b4_user_code(USER-CODE)
 474 # -----------------------
 475 # Emit code from the user, ending it with synclines.
 476 m4_define([b4_user_code],
 477 [$1
 478 b4_syncline([@oline@], [@ofile@])])
 479
 480
 481 # b4_define_user_code(MACRO)
 482 # --------------------------
 483 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 484 m4_define([b4_define_user_code],
 485 [m4_define([b4_user_$1],
 486 [b4_user_code([b4_$1])])])
 487
 488
 489 # b4_user_actions
 490 # b4_user_initial_action
 491 # b4_user_post_prologue
 492 # b4_user_pre_prologue
 493 # b4_user_stype
 494 # ----------------------
 495 # Macros that issue user code, ending with synclines.
 496 b4_define_user_code([actions])
 497 b4_define_user_code([initial_action])
 498 b4_define_user_code([post_prologue])
 499 b4_define_user_code([pre_prologue])
 500 b4_define_user_code([stype])
 501
 502
 503 # b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
 504 # --------------------------------------------------------
 505 # Warn if any name of type WHAT is used by the user (as recorded in USER-LIST)
 506 # but is not used by Bison (as recorded by macros in the namespace
 507 # BISON-NAMESPACE).
 508 #
 509 # USER-LIST must expand to a list specifying all grammar occurrences of all
 510 # names of type WHAT.   Each item in the list must be a triplet specifying one
 511 # occurrence: name, start boundary, and end boundary.  Empty string names are
 512 # fine.  An empty list is fine.
 513 #
 514 # For example, to define b4_foo_user_names to be used for USER-LIST with three
 515 # name occurrences and with correct quoting:
 516 #
 517 #   m4_define([b4_foo_user_names],
 518 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 519 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 520 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 521 #
 522 # The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
 523 # is used by Bison (in the front-end or in the skeleton).  Empty string names
 524 # are fine, but it would be ugly for Bison to actually use one.
 525 #
 526 # For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
 527 # the names bar and baz are used by Bison:
 528 #
 529 #   m4_define([b4_foo_bison_names(bar)])
 530 #   m4_define([b4_foo_bison_names(baz)])
 531 #
 532 # To invoke b4_check_user_names with TYPE foo, with USER-LIST
 533 # b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
 534 # quoting:
 535 #
 536 #   b4_check_user_names([[foo]], [b4_foo_user_names],
 537 #                       [[b4_foo_bison_names]])
 538 m4_define([b4_check_user_names],
 539 [m4_foreach([b4_occurrence], $2,
 540 [m4_pushdef([b4_occurrence], b4_occurrence)dnl
 541 m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
 542 m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
 543 m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
 544 m4_ifndef($3[(]m4_quote(b4_user_name)[)],
 545           [b4_warn_at([b4_start], [b4_end],
 546                       [[%s `%s' is not used]],
 547                       [$1], [b4_user_name])])[]dnl
 548 m4_popdef([b4_occurrence])dnl
 549 m4_popdef([b4_user_name])dnl
 550 m4_popdef([b4_start])dnl
 551 m4_popdef([b4_end])dnl
 552 ])])
 553
 554 # b4_percent_define_get(VARIABLE)
 555 # -------------------------------
 556 # Mimic muscle_percent_define_get in ../src/muscle_tab.h exactly.  That is, if
 557 # the %define variable VARIABLE is defined, emit its value.  Also, record
 558 # Bison's usage of VARIABLE by defining
 559 # b4_percent_define_bison_variables(VARIABLE).
 560 #
 561 # For example:
 562 #
 563 #   b4_percent_define_get([[foo]])
 564 m4_define([b4_percent_define_get],
 565 [m4_define([b4_percent_define_bison_variables(]$1[)])dnl
 566 m4_ifdef([b4_percent_define(]$1[)], [m4_indir([b4_percent_define(]$1[)])])])
 567
 568 # b4_percent_define_get_loc(VARIABLE)
 569 # -----------------------------------
 570 # Mimic muscle_percent_define_get_loc in ../src/muscle_tab.h exactly.  That is,
 571 # if the %define variable VARIABLE is undefined, complain fatally since that's
 572 # a Bison or skeleton error.  Otherwise, return its definition location in a
 573 # form approriate for the first two arguments of b4_warn_at, b4_complain_at, or
 574 # b4_fatal_at.  Don't record this as a Bison usage of VARIABLE as there's no
 575 # reason to suspect that the user-supplied value has yet influenced the output.
 576 #
 577 # For example:
 578 #
 579 #   b4_complain_at(b4_percent_define_get_loc([[foo]]), [[invalid foo]])
 580 m4_define([b4_percent_define_get_loc],
 581 [m4_ifdef([b4_percent_define_loc(]$1[)],
 582           [m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
 583 b4_loc[]dnl
 584 m4_popdef([b4_loc])],
 585           [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_get_loc]], [$1])])])
 586
 587 # b4_percent_define_get_syncline(VARIABLE)
 588 # ----------------------------------------
 589 # Mimic muscle_percent_define_get_syncline in ../src/muscle_tab.h exactly.
 590 # That is, if the %define variable VARIABLE is undefined, complain fatally
 591 # since that's a Bison or skeleton error.  Otherwise, return its definition
 592 # location as a b4_syncline invocation.  Don't record this as a Bison usage of
 593 # VARIABLE as there's no reason to suspect that the user-supplied value has yet
 594 # influenced the output.
 595 #
 596 # For example:
 597 #
 598 #   b4_percent_define_get_syncline([[foo]])
 599 m4_define([b4_percent_define_get_syncline],
 600 [m4_ifdef([b4_percent_define_syncline(]$1[)],
 601           [m4_indir([b4_percent_define_syncline(]$1[)])],
 602           [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_get_syncline]], [$1])])])
 603
 604 # b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
 605 # ------------------------------------------------------
 606 # Mimic muscle_percent_define_ifdef in ../src/muscle_tab.h exactly.  That is,
 607 # if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
 608 # IF-FALSE.  Also, record Bison's usage of VARIABLE by defining
 609 # b4_percent_define_bison_variables(VARIABLE).
 610 #
 611 # For example:
 612 #
 613 #   b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
 614 m4_define([b4_percent_define_ifdef],
 615 [m4_ifdef([b4_percent_define(]$1[)],
 616           [m4_define([b4_percent_define_bison_variables(]$1[)])$2],
 617           [$3])])
 618
 619
 620 ## --------- ##
 621 ## Options.  ##
 622 ## --------- ##
 623
 624
 625 # b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
 626 # --------------------------------------------------------
 627 # Mimic muscle_percent_define_flag_if in ../src/muscle_tab.h exactly.  That is,
 628 # if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
 629 # If it is defined to "false", expand IF-FALSE.  Complain if it is undefined
 630 # (a Bison or skeleton error since the default value should have been set
 631 # already) or defined to any other value (possibly a user error).  Also, record
 632 # Bison's usage of VARIABLE by defining
 633 # b4_percent_define_bison_variables(VARIABLE).
 634 #
 635 # For example:
 636 #
 637 #   b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
 638 m4_define([b4_percent_define_flag_if],
 639 [b4_percent_define_ifdef([$1],
 640   [m4_case(b4_percent_define_get([$1]),
 641            [], [$2], [true], [$2], [false], [$3],
 642            [m4_expand_once([b4_complain_at(b4_percent_define_get_loc([$1]),
 643                                            [[invalid value for %%define Boolean variable `%s']],
 644                                            [$1])],
 645                            [[b4_percent_define_flag_if($1)]])])],
 646   [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_flag_if]], [$1])])])
 647
 648
 649 # b4_percent_define_default(VARIABLE, DEFAULT)
 650 # --------------------------------------------
 651 # Mimic muscle_percent_define_default in ../src/muscle_tab.h exactly.  That is,
 652 # if the %define variable VARIABLE is undefined, set its value to DEFAULT.
 653 # Don't record this as a Bison usage of VARIABLE as there's no reason to
 654 # suspect that the value has yet influenced the output.
 655 #
 656 # For example:
 657 #
 658 #   b4_percent_define_default([[foo]], [[default value]])
 659 m4_define([b4_percent_define_default],
 660 [m4_ifndef([b4_percent_define(]$1[)],
 661            [m4_define([b4_percent_define(]$1[)], [$2])dnl
 662             m4_define([b4_percent_define_loc(]$1[)],
 663                       [[[[<skeleton default value>:-1.-1]],
 664                         [[<skeleton default value>:-1.-1]]]])dnl
 665             m4_define([b4_percent_define_syncline(]$1[)], [[]])])])
 666
 667
 668 # b4_percent_define_if_define(VARIABLE)
 669 # -------------------------------------
 670 # Define b4_VARIABLE_if that executes its $1 or $2 depending whether
 671 # VARIABLE was %defined.  The characters `.' and `-' in VARIABLE are mapped
 672 # to `_'.
 673 m4_define([b4_percent_define_if_define_],
 674 [m4_define(m4_bpatsubst([b4_$1_if], [[-.]], [_]),
 675            [b4_percent_define_flag_if([$1], [$2], [$3])])])
 676 m4_define([b4_percent_define_if_define],
 677 [b4_percent_define_default([[$1]], [[false]])
 678 b4_percent_define_if_define_([$1], $[1], $[2])])
 679
 680
 681 # b4_parse_assert_if([IF-ASSERTIONS-ARE-USED], [IF-NOT])
 682 # b4_parse_trace_if([IF-DEBUG-TRACES-ARE-ENABLED], [IF-NOT])
 683 # b4_error_verbose_if([IF-ERRORS-ARE-VERBOSE], [IF-NOT])
 684 # b4_lex_symbol_if([IF-YYLEX-RETURNS-A-COMPLETE-SYMBOL], [IF-NOT])
 685 # b4_variant_if([IF-VARIANT-ARE-USED], [IF-NOT])
 686 # ----------------------------------------------
 687 b4_percent_define_if_define([error-verbose])
 688 b4_percent_define_if_define([lex_symbol])
 689 b4_percent_define_if_define([locations])     # Whether locations are tracked.
 690 b4_percent_define_if_define([parse.assert])
 691 b4_percent_define_if_define([parse.trace])
 692 b4_percent_define_if_define([variant])
 693
 694
 695
 696 # b4_percent_define_check_values(VALUES)
 697 # --------------------------------------
 698 # Mimic muscle_percent_define_check_values in ../src/muscle_tab.h exactly
 699 # except that the VALUES structure is more appropriate for M4.  That is, VALUES
 700 # is a list of sublists of strings.  For each sublist, the first string is the
 701 # name of a %define variable, and all remaining strings in that sublist are the
 702 # valid values for that variable.  Complain if such a variable is undefined (a
 703 # Bison error since the default value should have been set already) or defined
 704 # to any other value (possibly a user error).  Don't record this as a Bison
 705 # usage of the variable as there's no reason to suspect that the value has yet
 706 # influenced the output.
 707 #
 708 # For example:
 709 #
 710 #   b4_percent_define_check_values([[[[foo]], [[foo-value1]], [[foo-value2]]]],
 711 #                                  [[[[bar]], [[bar-value1]]]])
 712 m4_define([b4_percent_define_check_values],
 713 [m4_foreach([b4_sublist], m4_quote($@),
 714             [_b4_percent_define_check_values(b4_sublist)])])
 715
 716 m4_define([_b4_percent_define_check_values],
 717 [m4_ifdef([b4_percent_define(]$1[)],
 718   [m4_pushdef([b4_good_value], [0])dnl
 719    m4_if($#, 1, [],
 720          [m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 721                      [m4_if(m4_indir([b4_percent_define(]$1[)]), b4_value,
 722                             [m4_define([b4_good_value], [1])])])])dnl
 723    m4_if(b4_good_value, [0],
 724          [b4_complain_at(b4_percent_define_get_loc([$1]),
 725                          [[invalid value for %%define variable `%s': `%s']],
 726                          [$1],
 727                          m4_dquote(m4_indir([b4_percent_define(]$1[)])))
 728           m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 729                      [b4_complain_at(b4_percent_define_get_loc([$1]),
 730                                      [[accepted value: `%s']],
 731                                      m4_dquote(b4_value))])])dnl
 732    m4_popdef([b4_good_value])],
 733   [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_check_values]], [$1])])])
 734
 735 # b4_percent_code_get([QUALIFIER])
 736 # --------------------------------
 737 # If any %code blocks for QUALIFIER are defined, emit them beginning with a
 738 # comment and ending with synclines and a newline.  If QUALIFIER is not
 739 # specified or empty, do this for the unqualified %code blocks.  Also, record
 740 # Bison's usage of QUALIFIER (if specified) by defining
 741 # b4_percent_code_bison_qualifiers(QUALIFIER).
 742 #
 743 # For example, to emit any unqualified %code blocks followed by any %code
 744 # blocks for the qualifier foo:
 745 #
 746 #   b4_percent_code_get
 747 #   b4_percent_code_get([[foo]])
 748 m4_define([b4_percent_code_get],
 749 [m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
 750 m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
 751 m4_ifdef(b4_macro_name,
 752 [b4_comment([m4_if([$#], [0], [[Unqualified %code]],
 753                    [["%code ]$1["]])[ blocks.]])
 754 b4_user_code([m4_indir(b4_macro_name)])
 755 ])dnl
 756 m4_popdef([b4_macro_name])])
 757
 758 # b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
 759 # -----------------------------------------------------
 760 # If any %code blocks for QUALIFIER (or unqualified %code blocks if
 761 # QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
 762 # Also, record Bison's usage of QUALIFIER (if specified) by defining
 763 # b4_percent_code_bison_qualifiers(QUALIFIER).
 764 m4_define([b4_percent_code_ifdef],
 765 [m4_ifdef([b4_percent_code(]$1[)],
 766           [m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
 767           [$3])])
 768
 769
 770 # Default values for %define.
 771 # ---------------------------
 772 # If the %token.prefix, it is empty.
 773 m4_percent_define_default([[token.prefix]], [[]])
 774
 775
 776
 777 ## ----------------------------------------------------------- ##
 778 ## After processing the skeletons, check that all the user's   ##
 779 ## %define variables and %code qualifiers were used by Bison.  ##
 780 ## ----------------------------------------------------------- ##
 781
 782 m4_define([b4_check_user_names_wrap],
 783 [m4_ifdef([b4_percent_]$1[_user_]$2[s],
 784           [b4_check_user_names([[%]$1 $2],
 785                                [b4_percent_]$1[_user_]$2[s],
 786                                [[b4_percent_]$1[_bison_]$2[s]])])])
 787
 788 m4_wrap_lifo([
 789 b4_check_user_names_wrap([[define]], [[variable]])
 790 b4_check_user_names_wrap([[code]], [[qualifier]])
 791 ])