data/c-like.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Common code for C-like languages (C, C++, Java, etc.)
   4
   5 # Copyright (C) 2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # b4_dollar_dollar_(VALUE, FIELD, DEFAULT-FIELD)
  21 # ----------------------------------------------
  22 # If FIELD (or DEFAULT-FIELD) is non-null, return "VALUE.FIELD",
  23 # otherwise just VALUE.  Be sure to pass "(VALUE)" is VALUE is a
  24 # pointer.
  25 m4_define([b4_dollar_dollar_],
  26 [b4_symbol_value([$1],
  27                  m4_if([$2], [[]],
  28                        [[$3]], [[$2]]))])
  29
  30 # b4_dollar_pushdef(VALUE-POINTER, DEFAULT-FIELD, LOCATION)
  31 # b4_dollar_popdef
  32 # ---------------------------------------------------------
  33 # Define b4_dollar_dollar for VALUE and DEFAULT-FIELD,
  34 # and b4_at_dollar for LOCATION.
  35 m4_define([b4_dollar_pushdef],
  36 [m4_pushdef([b4_dollar_dollar],
  37             [b4_dollar_dollar_([$1], m4_dquote($][1), [$2])])dnl
  38 m4_pushdef([b4_at_dollar], [$3])dnl
  39 ])
  40 m4_define([b4_dollar_popdef],
  41 [m4_popdef([b4_at_dollar])dnl
  42 m4_popdef([b4_dollar_dollar])dnl
  43 ])