configure.in

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001, 2002 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19
  20 # We need a recent Autoconf to run a recent Autotest.
  21 AC_PREREQ(2.53)
  22
  23 AC_INIT([GNU Bison], [1.49b], [bug-bison@gnu.org])
  24 AC_CONFIG_AUX_DIR(config)
  25
  26 AM_INIT_AUTOMAKE
  27 AM_CONFIG_HEADER(config.h:config.hin)
  28
  29 # Initialize the test suite.
  30 AC_CONFIG_TESTDIR(tests)
  31 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
  32 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
  33 # Needed by tests/atlocal.in.
  34 AC_SUBST([GCC])
  35
  36 # Checks for programs.
  37 AC_PROG_CC
  38 AM_PROG_LEX
  39 AC_PROG_YACC
  40 AC_MINIX
  41 AC_ISC_POSIX
  42 AM_PROG_CC_STDC
  43 AC_PROG_RANLIB
  44 AM_MISSING_PROG([AUTOM4TE], [autom4te])
  45 BISON_PROG_GNU_M4
  46 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  47   AC_MSG_ERROR([GNU M4 1.4 is required])
  48 fi
  49 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
  50
  51 AC_ARG_ENABLE(gcc-warnings,
  52 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  53 [case "${enableval}" in
  54    yes|no) ;;
  55    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  56  esac],
  57               [enableval=no])
  58 if test "${enableval}" = yes; then
  59   BISON_WARNING(-Werror)
  60   AC_SUBST([WERROR_CFLAGS], [$WARNING_CFLAGS])
  61   WARNING_CFLAGS=
  62   BISON_WARNING(-Wall)
  63   BISON_WARNING(-W)
  64   BISON_WARNING(-Wbad-function-cast)
  65   BISON_WARNING(-Wcast-align)
  66   BISON_WARNING(-Wcast-qual)
  67   BISON_WARNING(-Wformat)
  68   BISON_WARNING(-Wmissing-declarations)
  69   BISON_WARNING(-Wmissing-prototypes)
  70   BISON_WARNING(-Wnested-externs)
  71   BISON_WARNING(-Wshadow)
  72   BISON_WARNING(-Wstrict-prototypes)
  73   BISON_WARNING(-Wwrite-strings)
  74 fi
  75
  76 # Checks for libraries.
  77 AC_DEFINE([_GNU_SOURCE],1,[Define to 1 for GNU C library extensions.])
  78
  79 # Checks for header files.
  80 AC_HEADER_STDC
  81 AC_CHECK_HEADERS(ctype.h locale.h memory.h stdlib.h string.h unistd.h)
  82
  83
  84 # Checks for compiler characteristics.
  85 AC_C_CONST
  86 AC_C_INLINE
  87 AM_C_PROTOTYPES
  88
  89 # Checks for library functions.
  90 AC_FUNC_ALLOCA
  91 AC_FUNC_OBSTACK
  92 AC_FUNC_ERROR_AT_LINE
  93 AC_FUNC_STRNLEN
  94 UTILS_FUNC_MKSTEMP
  95 AC_CHECK_FUNCS(setlocale)
  96 AC_CHECK_DECLS([free, stpcpy, strchr, strspn, strnlen,
  97                 malloc, memchr, memrchr])
  98 AC_REPLACE_FUNCS(stpcpy strchr strspn memchr memrchr)
  99 jm_FUNC_MALLOC
 100 jm_FUNC_REALLOC
 101 jm_PREREQ_QUOTEARG
 102 jm_PREREQ_ERROR
 103 AM_WITH_DMALLOC
 104
 105 # Gettext.
 106 GETTEXT_VERSION=0.11.2
 107 AM_GNU_GETTEXT(, need-ngettext)
 108
 109 # This is necessary so that .o files in LIBOBJS are also built via
 110 # the ANSI2KNR-filtering rules.
 111 LIB@&t@OBJS=`echo $LIB@&t@OBJS|sed 's/\.o /\$U.o /g;s/\.o$/\$U.o/'`
 112 AC_SUBST(LIB@&t@OBJS)
 113
 114 AC_OUTPUT([Makefile
 115            config/Makefile
 116            intl/Makefile po/Makefile.in
 117            data/Makefile
 118            lib/Makefile src/Makefile doc/Makefile
 119            m4/Makefile])