configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2013 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.  We need Autoconf 2.68 or
  21 # better to avoid a typo in the 'configure --help' entry for the YACC
  22 # environment variable.
  23 AC_PREREQ([2.68])
  24 m4_pattern_forbid([^gl_[A-Z]])
  25
  26 AC_INIT([GNU Bison],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-bison@gnu.org])
  29 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2013])
  30 AC_DEFINE_UNQUOTED([PACKAGE_COPYRIGHT_YEAR], [$PACKAGE_COPYRIGHT_YEAR],
  31                    [The copyright year for this package])
  32
  33 AC_CONFIG_AUX_DIR([build-aux])
  34 AC_CONFIG_MACRO_DIR([m4])
  35
  36 # We use Automake 1.14's %D% and %C%.
  37 #
  38 # We want gnits strictness only when rolling a stable release.  For
  39 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  40 # doesn't like that, so we let the underscore disable gnits.  Between
  41 # releases, we want to be able run make dist without being required to
  42 # add a bogus NEWS entry.  In that case, the version string
  43 # automatically contains a dash, which we also let disable gnits.
  44 AM_INIT_AUTOMAKE([1.14 dist-xz nostdinc
  45                  color-tests parallel-tests
  46                  silent-rules]
  47                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  48                            [gnu], [gnits]))
  49 AM_SILENT_RULES([yes])
  50 AC_CONFIG_HEADERS([lib/config.h:lib/config.in.h])
  51
  52 # Checks for the compiler.
  53 AC_PROG_CC_STDC
  54 AC_PROG_CXX
  55
  56 # Gnulib (early checks).
  57 gl_EARLY
  58
  59 # Gnulib uses '#pragma GCC diagnostic push' to silence some
  60 # warnings, but older gcc doesn't support this.
  61 AC_CACHE_CHECK([whether pragma GCC diagnostic push works],
  62   [lv_cv_gcc_pragma_push_works], [
  63   save_CFLAGS=$CFLAGS
  64   CFLAGS='-Wunknown-pragmas -Werror'
  65   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  66     #pragma GCC diagnostic push
  67     #pragma GCC diagnostic pop
  68   ]])],
  69   [lv_cv_gcc_pragma_push_works=yes],
  70   [lv_cv_gcc_pragma_push_works=no])
  71   CFLAGS=$save_CFLAGS])
  72
  73 AC_ARG_ENABLE([gcc-warnings],
  74 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended).
  75                            Also, issue synclines from the examples/ to
  76                            the corresponding source in the Texinfo doc.],
  77 [case $enable_gcc_warnings in
  78    yes|no) ;;
  79    *)  AC_MSG_ERROR([invalid value for --gcc-warnings: $enable_gcc_warnings]);;
  80  esac],
  81               [enable_gcc_warnings=no])
  82 AM_CONDITIONAL([ENABLE_GCC_WARNINGS], [test "$enable_gcc_warnings" = yes])
  83 if test "$enable_gcc_warnings" = yes; then
  84   warn_common='-Wall-Wextra -Wno-sign-compare -Wcast-align -Wdocumentation
  85     -Wformat -Wpointer-arith -Wwrite-strings'
  86   warn_c='-Wbad-function-cast -Wshadow -Wstrict-prototypes'
  87   warn_cxx='-Wnoexcept'
  88   # Warnings for the test suite only.
  89   #
  90   # -fno-color-diagnostics: Clang's use of colors in the error
  91   # messages is confusing the tests looking at the compiler's output
  92   # (e.g., synclines.at).
  93   warn_tests='-Wundef -pedantic -Wsign-compare -fno-color-diagnostics'
  94
  95   AC_LANG_PUSH([C])
  96   # Clang supports many of GCC's -W options, but only issues warnings
  97   # on the ones it does not recognize.  In that case, gl_WARN_ADD
  98   # thinks the option is supported, and unknown options are then added
  99   # to CFLAGS.  But then, when -Werror is added in the test suite for
 100   # instance, the warning about the unknown option turns into an
 101   # error.
 102   #
 103   # This should be addressed by gnulib's gl_WARN_ADD, but in the
 104   # meanwhile, turn warnings about unknown options into errors in
 105   # CFLAGS, and restore CFLAGS after the tests.
 106   save_CFLAGS=$CFLAGS
 107   gl_WARN_ADD([-Werror=unknown-warning-option], [CFLAGS])
 108   for i in $warn_common $warn_c;
 109   do
 110     gl_WARN_ADD([$i], [WARN_CFLAGS])
 111   done
 112   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 113
 114   # Warnings for the test suite, and maybe for bison if GCC is modern
 115   # enough.
 116   gl_WARN_ADD([-Wmissing-declarations], [WARN_CFLAGS_TEST])
 117   gl_WARN_ADD([-Wmissing-prototypes], [WARN_CFLAGS_TEST])
 118   test $lv_cv_gcc_pragma_push_works = yes &&
 119     AS_VAR_APPEND([WARN_CFLAGS], [" $WARN_CFLAGS_TEST"])
 120
 121   # Warnings for the test suite only.
 122   for i in $warn_tests;
 123   do
 124     gl_WARN_ADD([$i], [WARN_CFLAGS_TEST])
 125   done
 126   CFLAGS=$save_CFLAGS
 127   AC_LANG_POP([C])
 128
 129   AC_LANG_PUSH([C++])
 130   save_CXXFLAGS=$CXXFLAGS
 131   gl_WARN_ADD([-Werror=unknown-warning-option], [CXXFLAGS])
 132   for i in $warn_common $warn_cxx;
 133   do
 134     gl_WARN_ADD([$i], [WARN_CXXFLAGS])
 135   done
 136   gl_WARN_ADD([-Wzero-as-null-pointer-constant], [WARN_CXXFLAGS],
 137               [AC_LANG_PROGRAM([], [nullptr])])
 138   gl_WARN_ADD([-Werror], [WERROR_CXXFLAGS])
 139   # Warnings for the test suite only.
 140   for i in $warn_tests;
 141   do
 142     gl_WARN_ADD([$i], [WARN_CXXFLAGS_TEST])
 143   done
 144   # Clang++ 3.2+ reject C code generated by Flex.
 145   gl_WARN_ADD([-Wno-null-conversion], [FLEX_SCANNER_CXXFLAGS])
 146   # So does G++ 4.8...
 147   gl_WARN_ADD([-Wno-sign-compare], [FLEX_SCANNER_CXXFLAGS])
 148   # ... possiby in std=c++11 mode.
 149   gl_WARN_ADD([-Wno-zero-as-null-pointer-constant], [FLEX_SCANNER_CXXFLAGS])
 150   CXXFLAGS=$save_CXXFLAGS
 151   AC_LANG_POP([C++])
 152 fi
 153
 154 BISON_TEST_FOR_WORKING_C_COMPILER
 155 BISON_C_COMPILER_POSIXLY_CORRECT
 156 BISON_TEST_FOR_WORKING_CXX_COMPILER
 157 BISON_CXX_COMPILER_POSIXLY_CORRECT
 158
 159 AC_ARG_ENABLE([yacc],
 160   [AC_HELP_STRING([--disable-yacc],
 161      [do not build a yacc command or an -ly library])],
 162   , [enable_yacc=yes])
 163 AM_CONDITIONAL([ENABLE_YACC], [test "$enable_yacc" = yes])
 164
 165 # Checks for programs.
 166 AM_MISSING_PROG([DOT], [dot])
 167 AC_PROG_LEX
 168 $LEX_IS_FLEX || test "X$LEX" = X: || {
 169   AC_MSG_WARN([bypassing lex because flex is required])
 170   LEX=:
 171 }
 172 AM_CONDITIONAL([FLEX_CXX_WORKS],
 173   [$LEX_IS_FLEX && test $bison_cv_cxx_works = yes])
 174 AC_PROG_YACC
 175 AC_PROG_RANLIB
 176 AC_PROG_GNU_M4
 177 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 178 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 179 supports -g, otherwise to "".])
 180 AC_PATH_PROG([PERL], [perl])
 181 if test -z "$PERL"; then
 182    AC_MSG_ERROR([perl not found])
 183 fi
 184 AM_MISSING_PROG([HELP2MAN], [help2man])
 185 AC_PATH_PROG([XSLTPROC], [xsltproc])
 186 AC_SUBST([XSLTPROC])
 187
 188 # Checks for header files.
 189 AC_CHECK_HEADERS_ONCE([locale.h])
 190
 191 # Checks for compiler characteristics.
 192 AC_C_INLINE
 193
 194 # Gnulib (later checks).  Putting them here rather than right after
 195 # gl_EARLY avoids some redundant checks.
 196 gl_INIT
 197
 198 # Checks for library functions.
 199 AC_CHECK_FUNCS_ONCE([setlocale])
 200 AM_WITH_DMALLOC
 201 BISON_PREREQ_TIMEVAR
 202
 203 # Gettext.
 204 # We use gnulib, which is only guaranteed to work properly with the
 205 # latest Gettext.
 206 AM_GNU_GETTEXT([external], [need-ngettext])
 207 AM_GNU_GETTEXT_VERSION([0.18])
 208 BISON_I18N
 209
 210 # Internationalized parsers.
 211 AC_CONFIG_FILES([runtime-po/Makefile.in])
 212 # Autoconf macros for packages using internationalized parsers.
 213 aclocaldir='${datadir}/aclocal'
 214 AC_SUBST([aclocaldir])
 215
 216 # Create the benchmark script.
 217 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 218
 219 # Initialize the test suite.
 220 AC_CONFIG_TESTDIR(tests)
 221 AC_CONFIG_FILES([tests/atlocal])
 222 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 223 AC_CHECK_PROGS([VALGRIND], [valgrind])
 224 case $VALGRIND:$host_os in
 225   '':*) ;;
 226   *:darwin*)
 227     # See README-hacking.
 228     # VALGRIND+='-q --suppressions=$(abs_top_srcdir)/build-aux/darwin11.4.0.valgrind'
 229     VALGRIND=;;
 230   *:*)
 231     suppfile=build-aux/$host_os.valgrind
 232     if test -f "$srcdir/$suppfile"; then
 233       VALGRIND="$VALGRIND --gen-suppressions=all"
 234       VALGRIND="$VALGRIND --suppressions=\$(abs_top_srcdir)/$suppfile"
 235     fi
 236     AC_SUBST([VALGRIND_PREBISON], ["$VALGRIND -q"])
 237     ;;
 238 esac
 239
 240 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 241 # Needed by tests/atlocal.in.
 242 AC_SUBST([GCC])
 243
 244 gt_JAVACOMP([1.3], [1.4])
 245 gt_JAVAEXEC
 246
 247 AC_CONFIG_FILES([Makefile
 248                  po/Makefile.in
 249                  doc/yacc.1])
 250 AC_OUTPUT