tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 ## ------------- ##
  24 ## Basic tests.  ##
  25 ## ------------- ##
  26
  27 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  28 # ------------------------------------------
  29 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  30 # taken in "slurp" mode, i.e., one can match end-of-lines.
  31 m4_define([AT_MATCHES_CHECK],
  32 [AT_CHECK([perl -0777 -ne '
  33 my $count = 0;
  34 s{$2}{ ++$count; "" }gem;
  35 printf "$count\n";' $1], [0], [$3
  36 ])])
  37
  38
  39 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  40 # ------------------------------------------------
  41 # Don't interfere with caller's files.
  42 m4_divert_text([PREPARE_TESTS],
  43 [at_save_special_files ()
  44 {
  45   for at_save_file in stderr experr expout
  46   do
  47     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  48   done
  49 }
  50
  51 at_restore_special_files ()
  52 {
  53   for at_save_file in stderr experr expout
  54   do
  55     test ! -f at-bison-check-$at_save_file.bak ||
  56       mv at-bison-check-$at_save_file.bak $at_save_file
  57   done
  58 }
  59 ])
  60
  61 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  62 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  63
  64
  65
  66 ## ------------------------------- ##
  67 ## Macros decoding Bison options.  ##
  68 ## ------------------------------- ##
  69
  70 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  71 # ----------------------------------------------------------------
  72 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  73 m4_define([AT_LOC_PUSHDEF],
  74 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  75 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  76 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  77 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  78
  79 # AT_LOC_POPDEF
  80 # -------------
  81 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  82 m4_define([AT_LOC_POPDEF],
  83 [m4_popdef([AT_LOC_FIRST_LINE])
  84 m4_popdef([AT_LOC_FIRST_COLUMN])
  85 m4_popdef([AT_LOC_LAST_LINE])
  86 m4_popdef([AT_LOC_LAST_COLUMN])])
  87
  88
  89
  90 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  91 # -----------------------------------------
  92 m4_define([AT_BISON_OPTION_PUSHDEFS],
  93 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  94
  95
  96 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  97 # --------------------------------------------------
  98 # This macro works around the impossibility to define macros
  99 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 100 # This sucks hard, GNU M4 should really provide M5 like $$1.
 101 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 102 [m4_if([$1$2], $[1]$[2], [],
 103        [m4_fatal([$0: Invalid arguments: $@])])dnl
 104 m4_pushdef([AT_DEFINES_IF],
 105 [m4_bmatch([$3], [%defines], [$1], [$2])])
 106 m4_pushdef([AT_SKEL_CC_IF],
 107 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 108 m4_pushdef([AT_SKEL_JAVA_IF],
 109 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 110 m4_pushdef([AT_LANG],
 111 [AT_SKEL_JAVA_IF([java],
 112                  [AT_SKEL_CC_IF([c++],
 113                                 [c])])])
 114 m4_pushdef([AT_GLR_IF],
 115 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 116 m4_pushdef([AT_LALR1_CC_IF],
 117 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 118 m4_pushdef([AT_GLR_CC_IF],
 119 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 120 # Using yacc.c?
 121 m4_pushdef([AT_YACC_IF],
 122 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 123 m4_pushdef([AT_LEXPARAM_IF],
 124 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 125 m4_pushdef([AT_LOCATION_IF],
 126 [m4_bmatch([$3], [%locations], [$1], [$2])])
 127 m4_pushdef([AT_LOCATION_TYPE_IF],
 128 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
 129 m4_pushdef([AT_PARAM_IF],
 130 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 131 m4_pushdef([AT_PURE_IF],
 132 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 133            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 134            [$2])])
 135 m4_pushdef([AT_PURE_AND_LOC_IF],
 136 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 137 m4_pushdef([AT_GLR_OR_PARAM_IF],
 138 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 139 m4_pushdef([AT_NAME_PREFIX],
 140 [m4_bmatch([$3], [\(%define api\.prefix\|%name-prefix\) ".*"],
 141            [m4_bregexp([$3], [\(%define api\.prefix\|%name-prefix\) "\([^""]*\)"], [\2])],
 142            [yy])])
 143 m4_pushdef([AT_API_prefix],
 144 [m4_bmatch([$3], [%define api\.prefix ".*"],
 145            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 146            [yy])])
 147 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 148 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 149 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 150                     [$2])])
 151 # yyerror always sees the locations (when activated), except if
 152 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 153 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 154 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 155                                         [$1])],
 156                             [$1])],
 157                 [$2])])
 158
 159 # The interface is pure: either because %define api.pure, or because we
 160 # are using the C++ parsers.
 161 m4_pushdef([AT_PURE_LEX_IF],
 162 [AT_PURE_IF([$1],
 163             [AT_SKEL_CC_IF([$1], [$2])])])
 164
 165 AT_PURE_LEX_IF(
 166 [m4_pushdef([AT_LOC], [(*llocp)])
 167  m4_pushdef([AT_VAL], [(*lvalp)])
 168  m4_pushdef([AT_YYLEX_FORMALS],
 169             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 170  m4_pushdef([AT_YYLEX_ARGS],
 171             [lvalp[]AT_LOCATION_IF([, llocp])])
 172  m4_pushdef([AT_USE_LEX_ARGS],
 173             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 174  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 175             [AT_YYLEX_FORMALS, ])
 176  m4_pushdef([AT_YYLEX_PRE_ARGS],
 177             [AT_YYLEX_ARGS, ])
 178 ],
 179 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 180  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 181  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 182  m4_pushdef([AT_YYLEX_ARGS],        [])
 183  m4_pushdef([AT_USE_LEX_ARGS],    [])
 184  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 185  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 186 ])
 187
 188 # Handle the different types of location components.
 189
 190 AT_SKEL_CC_IF(
 191   [AT_LOCATION_TYPE_IF(
 192     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 193     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 194   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 195
 196 ])# _AT_BISON_OPTION_PUSHDEFS
 197
 198
 199 # AT_BISON_OPTION_POPDEFS
 200 # -----------------------
 201 m4_define([AT_BISON_OPTION_POPDEFS],
 202 [m4_popdef([AT_YYLEX_PRE_ARGS])
 203 m4_popdef([AT_YYLEX_PRE_FORMALS])
 204 m4_popdef([AT_USE_LEX_ARGS])
 205 m4_popdef([AT_YYLEX_ARGS])
 206 m4_popdef([AT_YYLEX_FORMALS])
 207 m4_popdef([AT_VAL])
 208 m4_popdef([AT_LOC])
 209 m4_popdef([AT_PURE_LEX_IF])
 210 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 211 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 212 m4_popdef([AT_API_prefix])
 213 m4_popdef([AT_NAME_PREFIX])
 214 m4_popdef([AT_GLR_OR_PARAM_IF])
 215 m4_popdef([AT_PURE_AND_LOC_IF])
 216 m4_popdef([AT_LOCATION_TYPE_IF])
 217 m4_popdef([AT_LOCATION_IF])
 218 m4_popdef([AT_PARAM_IF])
 219 m4_popdef([AT_LEXPARAM_IF])
 220 m4_popdef([AT_YACC_IF])
 221 m4_popdef([AT_GLR_IF])
 222 m4_popdef([AT_SKEL_CC_IF])
 223 m4_popdef([AT_LANG])
 224 m4_popdef([AT_SKEL_JAVA_IF])
 225 m4_popdef([AT_GLR_CC_IF])
 226 m4_popdef([AT_LALR1_CC_IF])
 227 m4_popdef([AT_DEFINES_IF])
 228 AT_LOC_POPDEF
 229 ])# AT_BISON_OPTION_POPDEFS
 230
 231
 232
 233 ## -------------------------- ##
 234 ## Generating Grammar Files.  ##
 235 ## -------------------------- ##
 236
 237 # AT_DATA_SOURCE_PROLOGUE
 238 # ------------------------
 239 # The prologue that should be included in any source code that is
 240 # meant to be compiled.
 241 m4_define([AT_DATA_SOURCE_PROLOGUE],
 242 [[#include <config.h>
 243 /* We don't need perfect functions for these tests. */
 244 #undef malloc
 245 #undef memcmp
 246 #undef realloc
 247 ]])
 248
 249 # AT_DATA_GRAMMAR_PROLOGUE
 250 # ------------------------
 251 # The prologue that should be included in any grammar which parser is
 252 # meant to be compiled.
 253 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 254 [[%code top {
 255 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 256 [}
 257 ]])
 258
 259 # AT_DATA_SOURCE(NAME, CONTENT)
 260 # -----------------------------
 261 # Generate the file NAME, which CONTENT is preceded by
 262 # AT_DATA_SOURCE_PROLOGUE.
 263 m4_define([AT_DATA_SOURCE],
 264 [AT_DATA([$1],
 265 [AT_DATA_SOURCE_PROLOGUE
 266 $2])
 267 ])
 268
 269 # AT_DATA_GRAMMAR(NAME, CONTENT)
 270 # ------------------------------
 271 # Generate the file NAME, which CONTENT is preceded by
 272 # AT_DATA_GRAMMAR_PROLOGUE.
 273 m4_define([AT_DATA_GRAMMAR],
 274 [AT_DATA([$1],
 275 [AT_DATA_GRAMMAR_PROLOGUE
 276 $2])
 277 ])
 278
 279 # AT_YYLEX_PROTOTYPE
 280 # AT_YYLEX_DECLARE_EXTERN
 281 # AT_YYLEX_DECLARE
 282 # AT_YYLEX_DEFINE(INPUT-STRING, [ACTION])
 283 # ---------------------------------------
 284 m4_define([AT_YYLEX_PROTOTYPE],
 285 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 286 ])
 287
 288 m4_define([AT_YYLEX_DECLARE_EXTERN],
 289 [AT_YYLEX_PROTOTYPE;dnl
 290 ])
 291
 292 m4_define([AT_YYLEX_DECLARE],
 293 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 294 ])
 295
 296 m4_define([AT_YYLEX_DEFINE],
 297 [[#include <stdlib.h> /* abort */
 298 static
 299 ]AT_YYLEX_PROTOTYPE[
 300 {
 301   static char const input[] = "$1";
 302   static size_t toknum = 0;
 303   int res;
 304   if (! (toknum < sizeof input))
 305     abort ();
 306   res = input[toknum++];
 307   ]$2;[]AT_LOCATION_IF([[
 308   ]AT_NAME_PREFIX[lloc.first_line = ]AT_NAME_PREFIX[lloc.last_line = 1;
 309   ]AT_NAME_PREFIX[lloc.first_column = ]AT_NAME_PREFIX[lloc.last_column = toknum;]])[
 310   return res;
 311 }]dnl
 312 ])
 313
 314 # AT_YYERROR_PROTOTYPE
 315 # AT_YYERROR_DECLARE_EXTERN
 316 # AT_YYERROR_DECLARE
 317 # AT_YYERROR_DEFINE
 318 # -------------------------
 319 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 320 m4_define([AT_YYERROR_FORMALS],
 321 [m4_case(AT_LANG,
 322 [c], [AT_YYERROR_ARG_LOC_IF([YYLTYPE *llocp, ])[const char *msg]])[]dnl
 323 ])
 324
 325 m4_define([AT_YYERROR_PROTOTYPE],
 326 [m4_case(AT_LANG,
 327 [c], [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])[]dnl
 328 ])
 329
 330 m4_define([AT_YYERROR_DECLARE_EXTERN],
 331 [m4_case(AT_LANG,
 332 [c], [AT_YYERROR_PROTOTYPE;])[]dnl
 333 ])
 334
 335 m4_define([AT_YYERROR_DECLARE],
 336 [m4_case(AT_LANG,
 337 [c], [static AT_YYERROR_DECLARE_EXTERN])[]dnl
 338 ])
 339
 340 m4_define([AT_YYERROR_DEFINE],
 341 [m4_case(AT_LANG,
 342 [c], [[#include <stdio.h>
 343 /* A C error reporting function.  */
 344 static
 345 ]AT_YYERROR_PROTOTYPE[
 346 {
 347 ]AT_YYERROR_SEES_LOC_IF([[
 348   fprintf (stderr, "%d.%d",
 349            ]AT_LOC_FIRST_LINE[, ]AT_LOC_FIRST_COLUMN[);
 350   if (]AT_LOC_FIRST_LINE[ != ]AT_LOC_LAST_LINE[)
 351     fprintf (stderr, "-%d.%d",
 352              ]AT_LOC_LAST_LINE[,  ]AT_LOC_LAST_COLUMN[ - 1);
 353   else if (]AT_LOC_FIRST_COLUMN[ != ]AT_LOC_LAST_COLUMN[ - 1)
 354     fprintf (stderr, "-%d",
 355              ]AT_LOC_LAST_COLUMN[ - 1);
 356   fprintf (stderr, ": ");]])[
 357   fprintf (stderr, "%s\n", msg);
 358 }]],
 359 [c++], [[/* A C++ error reporting function.  */
 360 void
 361 ]AT_NAME_PREFIX[::parser::error (const location_type& l, const std::string& m)
 362 {
 363   (void) l;
 364   std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 365 }]],
 366 [java], [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 367   {
 368     if (l == null)
 369       System.err.println (s);
 370     else
 371       System.err.println (l + ": " + s);
 372   }
 373 ]], [[
 374   public void yyerror (String s)
 375   {
 376     System.err.println (s);
 377   }]])])dnl
 378 ])
 379
 380
 381 ## --------------- ##
 382 ## Running Bison.  ##
 383 ## --------------- ##
 384
 385 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 386 # -------------------------------------------------
 387 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 388 # shell constructs (such as redirection or pipes) that would prevent
 389 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 390 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 391 #
 392 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 393 # Bison in the test suite.  For now it ensures that:
 394 #
 395 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 396 #      a non-zero exit status since Bison doesn't always try to free all memory
 397 #      in that case.
 398 #
 399 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 400 #      --graph and --report=all output for every working grammar.
 401 #
 402 #   3. If stderr contains a warning, -Werror and --warnings=error
 403 #      convert the warning to an error.
 404 #
 405 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 406 m4_define([AT_BISON_CHECK],
 407 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 408        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 409 AT_BISON_CHECK_NO_XML($@)])
 410
 411 m4_define([AT_BISON_WERROR_MSG],
 412           [[bison: warnings being treated as errors]])
 413
 414 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 415 # --------------------------------------------------------
 416 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 417 # when a tortured grammar's XML is known to be too large for xsltproc to
 418 # handle.
 419 m4_define([AT_BISON_CHECK_NO_XML],
 420 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 421                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 422 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 423       m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0], [[
 424         # Defining POSIXLY_CORRECT causes bison to complain if options
 425         # are added after the grammar file name, so skip these checks
 426         # in that case.
 427         if test -z "${POSIXLY_CORRECT+set}"; then
 428           ]AT_SAVE_SPECIAL_FILES[
 429
 430           # To avoid expanding it repeatedly, store specified stdout.
 431           ]AT_DATA([expout], [$3])[
 432
 433           # Run with -Werror.
 434           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Werror]],
 435                     [[1]], [expout], [stderr])[
 436
 437           # Build expected stderr up to and including the "warnings being
 438           # treated as errors" message.
 439           ]AT_DATA([[at-bison-check-warnings]], [$4])[
 440           at_bison_check_first=`sed -n \
 441             '/: warning: /{=;q;}' at-bison-check-warnings`
 442           : ${at_bison_check_first:=1}
 443           at_bison_check_first_tmp=`sed -n \
 444             '/conflicts: [0-9].*reduce$/{=;q;}' at-bison-check-warnings`
 445           : ${at_bison_check_first_tmp:=1}
 446           if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 447             at_bison_check_first=$at_bison_check_first_tmp
 448           fi
 449           if test $at_bison_check_first -gt 1; then
 450             sed -n "1,`expr $at_bison_check_first - 1`"p \
 451               at-bison-check-warnings > experr
 452           fi
 453           echo ']AT_BISON_WERROR_MSG[' >> experr
 454
 455           # Finish building expected stderr and check.  Unlike warnings,
 456           # complaints cause bison to exit early.  Thus, with -Werror, bison
 457           # does not necessarily report all warnings that it does without
 458           # -Werror, but it at least reports one.
 459           at_bison_check_last=`sed -n '$=' stderr`
 460           : ${at_bison_check_last:=1}
 461           at_bison_check_last=`expr $at_bison_check_last - 1`
 462           sed -n "$at_bison_check_first,$at_bison_check_last"p \
 463             at-bison-check-warnings >> experr
 464           ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 465                       stderr 1>&2]], [[0]], [[]], [experr])[
 466
 467           # Now check --warnings=error.
 468           cp stderr experr
 469           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=error]],
 470                     [[1]], [expout], [experr])[
 471
 472           # Now check -Wnone and --warnings=none by making sure that
 473           # -Werror doesn't change the exit status when -Wnone or
 474           # --warnings=none is specified.
 475           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Wnone -Werror]],
 476                     [[0]], [expout])[
 477           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=none \
 478                     -Werror]], [[0]], [expout])[
 479
 480           ]AT_RESTORE_SPECIAL_FILES[
 481         fi
 482       ]])
 483 ])
 484
 485 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 486 # -----------------------------------------------------
 487 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 488 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 489 # have a non-zero exit status.
 490 m4_define([AT_BISON_CHECK_XML],
 491 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 492   AT_SAVE_SPECIAL_FILES
 493   [mkdir xml-tests]
 494   m4_pushdef([AT_BISON_ARGS],
 495              [m4_bpatsubsts([[$1]],
 496                             [--report(-file)?=[^][ ]*], [],
 497                             [--graph=[^][ ]*], [],
 498                             [--xml=[^][ ]*], [])])dnl
 499   # Don't combine these Bison invocations since we want to be sure that
 500   # --report=all isn't required to get the full XML file.
 501   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 502              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 503            [[0]], [ignore], [ignore])
 504   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 505            [[0]], [ignore], [ignore])
 506   m4_popdef([AT_BISON_ARGS])dnl
 507   [cp xml-tests/test.output expout]
 508   AT_CHECK([[$XSLTPROC \
 509              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 510              xml-tests/test.xml]], [[0]], [expout])
 511   [cp xml-tests/test.dot expout]
 512   AT_CHECK([[$XSLTPROC \
 513              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 514              xml-tests/test.xml]], [[0]], [expout])
 515   [rm -rf xml-tests expout]
 516   AT_RESTORE_SPECIAL_FILES
 517 [fi]])
 518
 519 # AT_QUELL_VALGRIND
 520 # -----------------
 521 # Put this before a Bison invocation to keep Valgrind from complaining about
 522 # reachable memory.
 523 #
 524 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 525 # The triple quoting below will cause test cases to fail if you do.  If you do
 526 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 527 # will then fail to shell-escape its contents when attempting to print them.
 528 # The testsuite verbose output, at least, will be incorrect, but nothing may
 529 # fail to make sure you notice.
 530 m4_define([AT_QUELL_VALGRIND],
 531 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 532
 533 ## ------------------------ ##
 534 ## Compiling C, C++ Files.  ##
 535 ## ------------------------ ##
 536
 537
 538 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 539 # ----------------------------------------
 540 # Compile SOURCES into OUTPUT.
 541 #
 542 # If OUTPUT does not contain '.', assume that we are linking too,
 543 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 544 # with trailing .o removed, and ".c" appended.
 545 m4_define([AT_COMPILE],
 546 [AT_CHECK(m4_join([ ],
 547                   [$CC $CFLAGS $CPPFLAGS],
 548                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 549                   [-o $1],
 550                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 551                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 552            0, [ignore], [ignore])])
 553
 554 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 555 # ---------------------------------------------
 556 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 557 # ignore the test.
 558 #
 559 # If OUTPUT does not contain '.', assume that we are linking too,
 560 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 561 # with trailing .o removed, and ".cc" appended.
 562 m4_define([AT_COMPILE_CXX],
 563 [AT_KEYWORDS(c++)
 564 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 565 AT_CHECK(m4_join([ ],
 566                  [$CXX $CXXFLAGS $CPPFLAGS],
 567                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 568                  [-o $1],
 569                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 570                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 571          0, [ignore], [ignore])])
 572
 573 # AT_JAVA_COMPILE(SOURCES)
 574 # ------------------------
 575 # Compile SOURCES into Java class files.  Skip the test if java or javac
 576 # is not installed.
 577 m4_define([AT_JAVA_COMPILE],
 578 [AT_KEYWORDS(java)
 579 AT_SKIP_IF([[test -z "$CONF_JAVA$CONF_JAVAC"]])
 580 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 581          [[0]], [ignore], [ignore])])
 582
 583 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 584 # --------------------------------------------
 585 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 586 #
 587 # If OUTPUT does not contain '.', assume that we are linking too,
 588 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 589 # with trailing .o removed, and ".c"/".cc" appended.
 590 m4_define([AT_LANG_COMPILE],
 591 [m4_case(AT_LANG,
 592 [c],    [AT_COMPILE([$1], [$2])],
 593 [c++],  [AT_COMPILE_CXX([$1], [$2])],
 594 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 595         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 596 ])
 597
 598 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 599 # -------------------------------------------
 600 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 601 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 602 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 603 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 604 # AT_SKEL_JAVA_IF.
 605 m4_define([AT_FULL_COMPILE],
 606 [m4_case(AT_LANG,
 607 [java],
 608   [AT_BISON_CHECK([-o $1.java $1.y])
 609    AT_LANG_COMPILE([$1],
 610                    m4_join([ ],
 611                            [$1.java],
 612                            m4_ifval($2, [[$1-$2.java]]),
 613                            m4_ifval($3, [[$1-$3.java]])))],
 614 [c++],
 615   [AT_BISON_CHECK([-o $1.cc $1.y])
 616    AT_LANG_COMPILE([$1],
 617                    m4_join([ ],
 618                            [$1.cc],
 619                            m4_ifval($2, [[$1-$2.cc]]),
 620                            m4_ifval($3, [[$1-$3.cc]])))],
 621 [c],
 622   [AT_BISON_CHECK([-o $1.c $1.y])
 623    AT_LANG_COMPILE([$1],
 624                    m4_join([ ],
 625                            [$1.c],
 626                            m4_ifval($2, [[$1-$2.c]]),
 627                            m4_ifval($3, [[$1-$3.c]])))])
 628 ])
 629
 630
 631 ## ---------------------------- ##
 632 ## Running a generated parser.  ##
 633 ## ---------------------------- ##
 634
 635
 636 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 637 # ------------------------------------------------------------
 638 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 639 #
 640 # Get rid of spurious messages when compiled with --coverage:
 641 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 642 m4_define([AT_PARSER_CHECK],
 643 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 644 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 645          [0], [], [$4])
 646 ])
 647
 648
 649 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 650 # -----------------------------------------------------------------
 651 m4_define([AT_JAVA_PARSER_CHECK],
 652 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 653
 654
 655 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 656 #                          DECLS, GRAMMAR, INPUT,
 657 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 658 #                          [OTHER-CHECKS],
 659 #                          [PARSER-EXIT-VALUE],
 660 #                          [PARSER-STDOUT], [PARSER-STDERR])
 661 # -------------------------------------------------------------
 662 # Using TITLE as the test group title, check the generated parser tables
 663 # and parser for a specified grammar file under a condition labeled by
 664 # COND-VALUE.
 665 #
 666 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 667 # recognized attribute is described below where it is relevant.
 668 #
 669 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 670 # the grammar file.  Insert basic yyerror, yylex, and main function
 671 # definitions as well.  Hardcode yylex to return the (possibly empty)
 672 # comma-delimited series of tokens in INPUT followed by token 0.
 673 #
 674 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 675 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 676 # On the bison command-line, specify `--report=all --defines'.  Check
 677 # that Bison exits with value 0, has no stdout, and has stderr
 678 # BISON-STDERR.
 679 #
 680 # If TEST-SPEC contains the attribute `last-state', check that the value
 681 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 682 # the grammar; in other words, check the number of states (minus one).
 683 # Otherwise, check that everything in the `.output' file starting with
 684 # the definition of state 0 is the same as the entire value of
 685 # TABLES-OR-LAST-STATE.
 686 #
 687 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 688 # `.output' file, which is named `input.output', and/or grammar file,
 689 # which is named `input.y'.
 690 #
 691 # Finally, compile the generated parser and then run it using
 692 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 693 # PARSER-STDERR as the 2nd-4th arguments.
 694 #
 695 # As a precondition, you must properly double-quote all arguments that
 696 # are to be interpreted as strings.
 697 #
 698 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 699 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 700 # first argument.  This is useful, for example, when wrapping multiple
 701 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 702 # condition, in another macro.
 703 #
 704 # For example:
 705 #
 706 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 707 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 708 #   # ---------------------------------------------------------------------
 709 #   m4_define([AT_TEST_SYNTAX_ERROR],
 710 #   [
 711 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 712 #                              [[last-state]],
 713 #                              [[%error-verbose ]$2], [$3], [$4],
 714 #                              [[]], [$5], [], [$6], [$7], [$8])
 715 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 716 #                              [[last-state]],
 717 #                              [$2], [$3], [$4],
 718 #                              [[]], [$5], [], [$6], [$7], [$8])
 719 #   ])
 720 #
 721 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 722 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 723 #                        [[3]],
 724 #                        [[1]], [[]],
 725 #                        [AT_COND_CASE([[no verbose]],
 726 #                                      [[syntax error
 727 #   ]],
 728 #                                      [[syntax error, unexpected 'b', expecting $end
 729 #   ]])])
 730 m4_define([AT_TEST_TABLES_AND_PARSE],
 731 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 732
 733 AT_SETUP([$1])
 734 AT_BISON_OPTION_PUSHDEFS([$4])
 735 AT_DATA_GRAMMAR([[input.y]],
 736 [[%code {
 737   #include <stdio.h>
 738   ]AT_YYERROR_DECLARE[
 739   ]AT_YYLEX_DECLARE[
 740 }
 741
 742 ]$4[
 743
 744 %%
 745
 746 ]$5[
 747
 748 %%
 749 ]AT_YYERROR_DEFINE[
 750 static int
 751 yylex (void)
 752 {
 753   static int const input[] = {
 754     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 755   };
 756   static int const *inputp = input;
 757   return *inputp++;
 758 }
 759
 760 int
 761 main (void)
 762 {
 763   return yyparse ();
 764 }
 765 ]])
 766
 767 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 768 # expanding macros, so it corrupts some special characters in the
 769 # macros.  To avoid this, expand now and pass it the result with proper
 770 # string quotation.  Assume args 7 through 12 expand to properly quoted
 771 # strings.
 772
 773 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 774       [AT_BISON_CHECK],
 775       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 776                                [0], [], m4_dquote($7))
 777
 778 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 779       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 780                 m4_dquote($8))],
 781       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 782                 m4_dquote($8)[[
 783 ]])])
 784
 785 $9
 786
 787 # Canonical LR generates very large tables, resulting in very long
 788 # files with #line directives that may overflow what the standards
 789 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 790 # will issue an error.
 791 #
 792 # There is no "" around `wc` since some indent the result.
 793 m4_bmatch([$4], [%define lr.type canonical-lr],
 794 [if test 32767 -lt `wc -l < input.c`; then
 795   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 796   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 797 fi])
 798 AT_COMPILE([[input]])
 799
 800 AT_PARSER_CHECK([[./input]],
 801                 m4_ifval([$10], [m4_dquote($10)]),
 802                 m4_ifval([$11], [m4_dquote($11)]),
 803                 m4_ifval([$12], [m4_dquote($12)]))
 804
 805 AT_BISON_OPTION_POPDEFS
 806 AT_CLEANUP
 807
 808 m4_popdef([AT_COND_CASE])])
 809
 810
 811
 812 ## ----------------------- ##
 813 ## Launch the test suite.  ##
 814 ## ----------------------- ##
 815
 816 AT_INIT
 817
 818 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 819 # options are processed, so we don't know the value of CXX and
 820 # CXXFLAGS yet.
 821 #
 822 # Note that it also means that command line values for CXX and
 823 # CXXFLAGS will not be propagated to CC and CFLAGS.
 824 AT_ARG_OPTION([compile-c-with-cxx],
 825               [compile C parsers with the C++ compiler])
 826
 827 AT_COLOR_TESTS
 828
 829 AT_TESTED([bison])