tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4 # Copyright (C) 2003-2010 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 # We want a recent Autotest.
  20 m4_version_prereq([2.58])
  21
  22
  23 ## ------------- ##
  24 ## Basic tests.  ##
  25 ## ------------- ##
  26
  27 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  28 # ------------------------------------------
  29 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  30 # taken in "slurp" mode, i.e., one can match end-of-lines.
  31 m4_define([AT_MATCHES_CHECK],
  32 [AT_CHECK([perl -0777 -ne '
  33 my $count = 0;
  34 s{$2}{ ++$count; "" }gem;
  35 printf "$count\n";' $1], [0], [$3
  36 ])])
  37
  38
  39 ## ------------------------------- ##
  40 ## Macros decoding Bison options.  ##
  41 ## ------------------------------- ##
  42
  43
  44 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  45 # -----------------------------------------
  46 m4_define([AT_BISON_OPTION_PUSHDEFS],
  47 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  48
  49
  50 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  51 # --------------------------------------------------
  52 # This macro works around the impossibility to define macros
  53 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  54 # This sucks hard, GNU M4 should really provide M5 like $$1.
  55 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  56 [m4_if([$1$2], $[1]$[2], [],
  57        [m4_fatal([$0: Invalid arguments: $@])])dnl
  58 m4_pushdef([AT_DEFINES_IF],
  59 [m4_bmatch([$3], [%defines], [$1], [$2])])
  60 m4_pushdef([AT_SKEL_CC_IF],
  61 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  62 m4_pushdef([AT_GLR_IF],
  63 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  64 m4_pushdef([AT_LALR1_CC_IF],
  65 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  66 m4_pushdef([AT_GLR_CC_IF],
  67 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  68 # Using yacc.c?
  69 m4_pushdef([AT_YACC_IF],
  70 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  71 m4_pushdef([AT_LEXPARAM_IF],
  72 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  73 m4_pushdef([AT_PARAM_IF],
  74 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  75 m4_pushdef([AT_LOCATION_IF],
  76 [m4_bmatch([$3], [%locations], [$1], [$2])])
  77 m4_pushdef([AT_PURE_IF],
  78 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
  79            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
  80            [$2])])
  81 m4_pushdef([AT_PURE_AND_LOC_IF],
  82 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
  83 m4_pushdef([AT_GLR_OR_PARAM_IF],
  84 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
  85 m4_pushdef([AT_NAME_PREFIX],
  86 [m4_bmatch([$3], [%name-prefix ".*"],
  87            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
  88            [yy])])
  89 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
  90 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
  91 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
  92                     [$2])])
  93 # yyerror always sees the locations (when activated), except if
  94 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
  95 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
  96 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
  97                                         [$1])],
  98                             [$1])],
  99                 [$2])])
 100
 101 # The interface is pure: either because %define api.pure, or because we
 102 # are using the C++ parsers.
 103 m4_pushdef([AT_PURE_LEX_IF],
 104 [AT_PURE_IF([$1],
 105             [AT_SKEL_CC_IF([$1], [$2])])])
 106
 107 AT_PURE_LEX_IF(
 108 [m4_pushdef([AT_LOC], [(*llocp)])
 109  m4_pushdef([AT_VAL], [(*lvalp)])
 110  m4_pushdef([AT_LEX_FORMALS],
 111             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 112  m4_pushdef([AT_LEX_ARGS],
 113             [lvalp[]AT_LOCATION_IF([, llocp])])
 114  m4_pushdef([AT_USE_LEX_ARGS],
 115             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 116  m4_pushdef([AT_LEX_PRE_FORMALS],
 117             [AT_LEX_FORMALS, ])
 118  m4_pushdef([AT_LEX_PRE_ARGS],
 119             [AT_LEX_ARGS, ])
 120 ],
 121 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 122  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 123  m4_pushdef([AT_LEX_FORMALS],     [void])
 124  m4_pushdef([AT_LEX_ARGS],        [])
 125  m4_pushdef([AT_USE_LEX_ARGS],    [])
 126  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 127  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 128 ])
 129 ])# _AT_BISON_OPTION_PUSHDEFS
 130
 131
 132 # AT_BISON_OPTION_POPDEFS
 133 # -----------------------
 134 m4_define([AT_BISON_OPTION_POPDEFS],
 135 [m4_popdef([AT_LEX_PRE_ARGS])
 136 m4_popdef([AT_LEX_PRE_FORMALS])
 137 m4_popdef([AT_USE_LEX_ARGS])
 138 m4_popdef([AT_LEX_ARGS])
 139 m4_popdef([AT_LEX_FORMALS])
 140 m4_popdef([AT_VAL])
 141 m4_popdef([AT_LOC])
 142 m4_popdef([AT_PURE_LEX_IF])
 143 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 144 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 145 m4_popdef([AT_NAME_PREFIX])
 146 m4_popdef([AT_GLR_OR_PARAM_IF])
 147 m4_popdef([AT_PURE_AND_LOC_IF])
 148 m4_popdef([AT_LOCATION_IF])
 149 m4_popdef([AT_PARAM_IF])
 150 m4_popdef([AT_LEXPARAM_IF])
 151 m4_popdef([AT_YACC_IF])
 152 m4_popdef([AT_GLR_IF])
 153 m4_popdef([AT_SKEL_CC_IF])
 154 m4_popdef([AT_GLR_CC_IF])
 155 m4_popdef([AT_LALR1_CC_IF])
 156 m4_popdef([AT_DEFINES_IF])
 157 ])# AT_BISON_OPTION_POPDEFS
 158
 159
 160
 161 ## -------------------------- ##
 162 ## Generating Grammar Files.  ##
 163 ## -------------------------- ##
 164
 165 # AT_DATA_SOURCE_PROLOGUE
 166 # ------------------------
 167 # The prologue that should be included in any source code that is
 168 # meant to be compiled.
 169 m4_define([AT_DATA_SOURCE_PROLOGUE],
 170 [[#include <config.h>
 171 /* We don't need perfect functions for these tests. */
 172 #undef malloc
 173 #undef memcmp
 174 #undef realloc
 175 ]])
 176
 177 # AT_DATA_GRAMMAR_PROLOGUE
 178 # ------------------------
 179 # The prologue that should be included in any grammar which parser is
 180 # meant to be compiled.
 181 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 182 [[%code top {
 183 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 184 [}
 185 ]])
 186
 187 # AT_DATA_SOURCE(NAME, CONTENT)
 188 # -----------------------------
 189 # Generate the file NAME, which CONTENT is preceded by
 190 # AT_DATA_SOURCE_PROLOGUE.
 191 m4_define([AT_DATA_SOURCE],
 192 [AT_DATA([$1],
 193 [AT_DATA_SOURCE_PROLOGUE
 194 $2])
 195 ])
 196
 197 # AT_DATA_GRAMMAR(NAME, CONTENT)
 198 # ------------------------------
 199 # Generate the file NAME, which CONTENT is preceded by
 200 # AT_DATA_GRAMMAR_PROLOGUE.
 201 m4_define([AT_DATA_GRAMMAR],
 202 [AT_DATA([$1],
 203 [AT_DATA_GRAMMAR_PROLOGUE
 204 $2])
 205 ])
 206
 207 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 208 # -------------------------------------------------
 209 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 210 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 211 #
 212 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 213 # Bison in the test suite.  For now it ensures that:
 214 #
 215 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 216 #      a non-zero exit status since Bison doesn't always try to free all memory
 217 #      in that case.
 218 #
 219 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 220 #      --graph and --report=all output for every working grammar.
 221 m4_define([AT_BISON_CHECK],
 222 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 223        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 224 AT_BISON_CHECK_NO_XML($@)])
 225
 226 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 227 # --------------------------------------------------------
 228 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 229 # when a tortured grammar's XML is known to be too large for xsltproc to
 230 # handle.
 231 m4_define([AT_BISON_CHECK_NO_XML],
 232 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 233                 [AT_QUELL_VALGRIND ])[[bison ]]$@)])
 234
 235 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 236 # -----------------------------------------------------
 237 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 238 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 239 # have a non-zero exit status.
 240 m4_define([AT_BISON_CHECK_XML],
 241 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 242   mkdir xml-tests]
 243   m4_pushdef([AT_BISON_ARGS],
 244              [m4_bpatsubsts([[$1]],
 245                             [--report(-file)?=[^][ ]*], [],
 246                             [--graph=[^][ ]*], [],
 247                             [--xml=[^][ ]*], [])])dnl
 248   # Don't combine these Bison invocations since we want to be sure that
 249   # --report=all isn't required to get the full XML file.
 250   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 251              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 252            [[0]], [ignore], [ignore])
 253   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 254            [[0]], [ignore], [ignore])
 255   m4_popdef([AT_BISON_ARGS])dnl
 256   [cp xml-tests/test.output expout]
 257   AT_CHECK([[$XSLTPROC \
 258              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 259              xml-tests/test.xml]], [[0]], [expout])
 260   [cp xml-tests/test.dot expout]
 261   AT_CHECK([[$XSLTPROC \
 262              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 263              xml-tests/test.xml]], [[0]], [expout])
 264   [rm -rf xml-tests expout
 265 fi]])
 266
 267 # AT_QUELL_VALGRIND
 268 # -----------------
 269 # Put this before a Bison invocation to keep Valgrind from complaining about
 270 # reachable memory.
 271 #
 272 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 273 # The triple quoting below will cause test cases to fail if you do.  If you do
 274 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 275 # will then fail to shell-escape its contents when attempting to print them.
 276 # The testsuite verbose output, at least, will be incorrect, but nothing may
 277 # fail to make sure you notice.
 278 m4_define([AT_QUELL_VALGRIND],
 279 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 280
 281 ## ------------------------ ##
 282 ## Compiling C, C++ Files.  ##
 283 ## ------------------------ ##
 284
 285
 286 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 287 # ----------------------------------------
 288 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 289 # assume that we are linking too; this is a hack.
 290 m4_define([AT_COMPILE],
 291 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 292            0, [ignore], [ignore])])
 293
 294 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 295 # --------------------------------------------
 296 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 297 # assume that we are linking too; this is a hack.
 298 # If the C++ compiler does not work, ignore the test.
 299 m4_define([AT_COMPILE_CXX],
 300 [AT_KEYWORDS(c++)
 301 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 302 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 303          0, [ignore], [ignore])])
 304
 305
 306 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 307 # --------------------------------
 308 # Compile OUTPUT.y to OUTPUT.c or OUTPUT.cc, and compile it to OUTPUT.
 309 # If OTHER is specified, compile OUTPUT-OTHER.c or OUTPUT-OTHER.cc to OUTPUT
 310 # along with it.
 311 # Relies on AT_SKEL_CC_IF.
 312 m4_define([AT_FULL_COMPILE],
 313 [AT_SKEL_CC_IF(
 314   [AT_BISON_CHECK([-o $1.cc $1.y])
 315    AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1.cc $1-$2.cc]]))],
 316   [AT_BISON_CHECK([-o $1.c $1.y])
 317    AT_COMPILE([$1]m4_ifval($2, [, [$1.c $1-$2.c]]))])
 318 ])
 319
 320
 321 ## ---------------------------- ##
 322 ## Running a generated parser.  ##
 323 ## ---------------------------- ##
 324
 325 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 326 # ------------------------------------------------------------
 327 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 328 m4_define([AT_PARSER_CHECK],
 329 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 330
 331 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 332 #                          DECLS, GRAMMAR, INPUT,
 333 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 334 #                          [OTHER-CHECKS],
 335 #                          [PARSER-EXIT-VALUE],
 336 #                          [PARSER-STDOUT], [PARSER-STDERR])
 337 # -------------------------------------------------------------
 338 # Using TITLE as the test group title, check the generated parser tables
 339 # and parser for a specified grammar file under a condition labeled by
 340 # COND-VALUE.
 341 #
 342 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 343 # recognized attribute is described below where it is relevant.
 344 #
 345 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 346 # the grammar file.  Insert basic yyerror, yylex, and main function
 347 # definitions as well.  Hardcode yylex to return the (possibly empty)
 348 # comma-delimited series of tokens in INPUT followed by token 0.
 349 #
 350 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 351 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 352 # On the bison command-line, specify `--report=all --defines'.  Check
 353 # that Bison exits with value 0, has no stdout, and has stderr
 354 # BISON-STDERR.
 355 #
 356 # If TEST-SPEC contains the attribute `last-state', check that the value
 357 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 358 # the grammar; in other words, check the number of states (minus one).
 359 # Otherwise, check that everything in the `.output' file starting with
 360 # the definition of state 0 is the same as the entire value of
 361 # TABLES-OR-LAST-STATE.
 362 #
 363 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 364 # `.output' file, which is named `input.output', and/or grammar file,
 365 # which is named `input.y'.
 366 #
 367 # Finally, compile the generated parser and then run it using
 368 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 369 # PARSER-STDERR as the 2nd-4th arguments.
 370 #
 371 # As a precondition, you must properly double-quote all arguments that
 372 # are to be interpreted as strings.
 373 #
 374 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 375 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 376 # first argument.  This is useful, for example, when wrapping multiple
 377 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 378 # condition, in another macro.
 379 #
 380 # For example:
 381 #
 382 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 383 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 384 #   # ---------------------------------------------------------------------
 385 #   m4_define([AT_TEST_SYNTAX_ERROR],
 386 #   [
 387 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 388 #                              [[last-state]],
 389 #                              [[%error-verbose ]$2], [$3], [$4],
 390 #                              [[]], [$5], [], [$6], [$7], [$8])
 391 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 392 #                              [[last-state]],
 393 #                              [$2], [$3], [$4],
 394 #                              [[]], [$5], [], [$6], [$7], [$8])
 395 #   ])
 396 #
 397 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 398 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 399 #                        [[3]],
 400 #                        [[1]], [[]],
 401 #                        [AT_COND_CASE([[no verbose]],
 402 #                                      [[syntax error
 403 #   ]],
 404 #                                      [[syntax error, unexpected 'b', expecting $end
 405 #   ]])])
 406 m4_define([AT_TEST_TABLES_AND_PARSE],
 407 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 408
 409 AT_SETUP([$1])
 410
 411 AT_DATA_GRAMMAR([[input.y]],
 412 [[%code {
 413   #include <stdio.h>
 414   static void yyerror (char const *msg);
 415   static int yylex (void);
 416 }
 417
 418 ]$4[
 419
 420 %%
 421
 422 ]$5[
 423
 424 %%
 425
 426 static void
 427 yyerror (char const *msg)
 428 {
 429   fprintf (stderr, "%s\n", msg);
 430 }
 431
 432 static int
 433 yylex (void)
 434 {
 435   static int const input[] = {
 436     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 437   };
 438   static int const *inputp = input;
 439   return *inputp++;
 440 }
 441
 442 int
 443 main (void)
 444 {
 445   return yyparse ();
 446 }
 447 ]])
 448
 449 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 450 # expanding macros, so it corrupts some special characters in the
 451 # macros.  To avoid this, expand now and pass it the result with proper
 452 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 453 # strings.
 454
 455 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 456       [AT_BISON_CHECK],
 457       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 458                                [0], [], m4_dquote($7))
 459
 460 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 461       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 462                 m4_dquote($8))],
 463       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 464                 m4_dquote($8)[[
 465 ]])])
 466
 467 $9
 468
 469 AT_COMPILE([[input]])
 470
 471 AT_PARSER_CHECK([[./input]],
 472                 m4_ifval([$10], [m4_dquote($10)]),
 473                 m4_ifval([$11], [m4_dquote($11)]),
 474                 m4_ifval([$12], [m4_dquote($12)]))
 475
 476 AT_CLEANUP
 477
 478 m4_popdef([AT_COND_CASE])])
 479
 480
 481
 482 ## ----------------------- ##
 483 ## Launch the test suite.  ##
 484 ## ----------------------- ##
 485
 486 AT_INIT
 487
 488 AT_TESTED([bison])