tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free
   6 # Software Foundation, Inc.
   7
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # We want a recent Autotest.
  22 m4_version_prereq([2.58])
  23
  24
  25 ## ------------- ##
  26 ## Basic tests.  ##
  27 ## ------------- ##
  28
  29 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  30 # ------------------------------------------
  31 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  32 # taken in "slurp" mode, i.e., one can match end-of-lines.
  33 m4_define([AT_MATCHES_CHECK],
  34 [AT_CHECK([perl -0777 -ne '
  35 my $count = 0;
  36 s{$2}{ ++$count; "" }gem;
  37 printf "$count\n";' $1], [0], [$3
  38 ])])
  39
  40
  41 ## ------------------------------- ##
  42 ## Macros decoding Bison options.  ##
  43 ## ------------------------------- ##
  44
  45 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  46 # ----------------------------------------------------------------
  47 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  48 m4_define([AT_LOC_PUSHDEF],
  49 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  50 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  51 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  52 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  53
  54 # AT_LOC_POPDEF
  55 # -------------
  56 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  57 m4_define([AT_LOC_POPDEF],
  58 [m4_popdef([AT_LOC_FIRST_LINE])
  59 m4_popdef([AT_LOC_FIRST_COLUMN])
  60 m4_popdef([AT_LOC_LAST_LINE])
  61 m4_popdef([AT_LOC_LAST_COLUMN])])
  62
  63
  64
  65 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  66 # -----------------------------------------
  67 m4_define([AT_BISON_OPTION_PUSHDEFS],
  68 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  69
  70
  71 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  72 # --------------------------------------------------
  73 # This macro works around the impossibility to define macros
  74 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  75 # This sucks hard, GNU M4 should really provide M5-like $$1.
  76 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  77 [m4_if([$1$2], $[1]$[2], [],
  78        [m4_fatal([$0: Invalid arguments: $@])])dnl
  79 m4_pushdef([AT_DEFINES_IF],
  80 [m4_bmatch([$3], [%defines], [$1], [$2])])
  81 m4_pushdef([AT_SKEL_CC_IF],
  82 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  83 m4_pushdef([AT_GLR_IF],
  84 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  85 m4_pushdef([AT_LALR1_CC_IF],
  86 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  87 m4_pushdef([AT_GLR_CC_IF],
  88 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  89 # Using yacc.c?
  90 m4_pushdef([AT_YACC_IF],
  91 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  92 m4_pushdef([AT_LEXPARAM_IF],
  93 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  94 m4_pushdef([AT_LOCATION_IF],
  95 [m4_bmatch([$3], [%locations], [$1], [$2])])
  96 m4_pushdef([AT_LOCATION_TYPE_IF],
  97 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
  98 m4_pushdef([AT_PARAM_IF],
  99 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 100 m4_pushdef([AT_PURE_IF],
 101 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 102            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 103            [$2])])
 104 m4_pushdef([AT_PURE_AND_LOC_IF],
 105 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 106 m4_pushdef([AT_GLR_OR_PARAM_IF],
 107 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 108 m4_pushdef([AT_NAME_PREFIX],
 109 [m4_bmatch([$3], [%name-prefix ".*"],
 110            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
 111            [yy])])
 112 m4_pushdef([AT_TOKEN_PREFIX],
 113 [m4_bmatch([$3], [%define api.tokens.prefix ".*"],
 114            [m4_bregexp([$3], [%define api.tokens.prefix "\(.*\)"], [\1])])])
 115 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 116 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 117 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 118                     [$2])])
 119 # yyerror always sees the locations (when activated), except if
 120 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 121 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 122 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 123                                         [$1])],
 124                             [$1])],
 125                 [$2])])
 126
 127 # The interface is pure: either because %define api.pure, or because we
 128 # are using the C++ parsers.
 129 m4_pushdef([AT_PURE_LEX_IF],
 130 [AT_PURE_IF([$1],
 131             [AT_SKEL_CC_IF([$1], [$2])])])
 132
 133 AT_PURE_LEX_IF(
 134 [m4_pushdef([AT_LOC], [(*llocp)])
 135  m4_pushdef([AT_VAL], [(*lvalp)])
 136  m4_pushdef([AT_LEX_FORMALS],
 137             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 138  m4_pushdef([AT_LEX_ARGS],
 139             [lvalp[]AT_LOCATION_IF([, llocp])])
 140  m4_pushdef([AT_USE_LEX_ARGS],
 141             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 142  m4_pushdef([AT_LEX_PRE_FORMALS],
 143             [AT_LEX_FORMALS, ])
 144  m4_pushdef([AT_LEX_PRE_ARGS],
 145             [AT_LEX_ARGS, ])
 146 ],
 147 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 148  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 149  m4_pushdef([AT_LEX_FORMALS],     [void])
 150  m4_pushdef([AT_LEX_ARGS],        [])
 151  m4_pushdef([AT_USE_LEX_ARGS],    [])
 152  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 153  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 154 ])
 155
 156 # Handle the different types of location components.
 157
 158 AT_SKEL_CC_IF(
 159   [AT_LOCATION_TYPE_IF(
 160     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 161     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 162   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 163
 164
 165 AT_GLR_IF([AT_KEYWORDS([glr])])
 166 ])# _AT_BISON_OPTION_PUSHDEFS
 167
 168
 169 # AT_BISON_OPTION_POPDEFS
 170 # -----------------------
 171 m4_define([AT_BISON_OPTION_POPDEFS],
 172 [m4_popdef([AT_LEX_PRE_ARGS])
 173 m4_popdef([AT_LEX_PRE_FORMALS])
 174 m4_popdef([AT_USE_LEX_ARGS])
 175 m4_popdef([AT_LEX_ARGS])
 176 m4_popdef([AT_LEX_FORMALS])
 177 m4_popdef([AT_VAL])
 178 m4_popdef([AT_LOC])
 179 m4_popdef([AT_PURE_LEX_IF])
 180 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 181 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 182 m4_popdef([AT_NAME_PREFIX])
 183 m4_popdef([AT_GLR_OR_PARAM_IF])
 184 m4_popdef([AT_PURE_AND_LOC_IF])
 185 m4_popdef([AT_LOCATION_TYPE_IF])
 186 m4_popdef([AT_LOCATION_IF])
 187 m4_popdef([AT_PARAM_IF])
 188 m4_popdef([AT_LEXPARAM_IF])
 189 m4_popdef([AT_YACC_IF])
 190 m4_popdef([AT_GLR_IF])
 191 m4_popdef([AT_SKEL_CC_IF])
 192 m4_popdef([AT_GLR_CC_IF])
 193 m4_popdef([AT_LALR1_CC_IF])
 194 m4_popdef([AT_DEFINES_IF])
 195 AT_LOC_POPDEF
 196 ])# AT_BISON_OPTION_POPDEFS
 197
 198
 199
 200 ## -------------------------- ##
 201 ## Generating Grammar Files.  ##
 202 ## -------------------------- ##
 203
 204 # AT_DATA_SOURCE_PROLOGUE
 205 # ------------------------
 206 # The prologue that should be included in any source code that is
 207 # meant to be compiled.
 208 m4_define([AT_DATA_SOURCE_PROLOGUE],
 209 [[#include <config.h>
 210 /* We don't need perfect functions for these tests. */
 211 #undef malloc
 212 #undef memcmp
 213 #undef realloc
 214 ]])
 215
 216 # AT_DATA_GRAMMAR_PROLOGUE
 217 # ------------------------
 218 # The prologue that should be included in any grammar which parser is
 219 # meant to be compiled.
 220 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 221 [[%code top {
 222 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 223 [}
 224 ]])
 225
 226 # AT_DATA_SOURCE(NAME, CONTENT)
 227 # -----------------------------
 228 # Generate the file NAME, which CONTENT is preceded by
 229 # AT_DATA_SOURCE_PROLOGUE.
 230 m4_define([AT_DATA_SOURCE],
 231 [AT_DATA([$1],
 232 [AT_DATA_SOURCE_PROLOGUE
 233 $2])
 234 ])
 235
 236 # AT_DATA_GRAMMAR(NAME, CONTENT)
 237 # ------------------------------
 238 # Generate the file NAME, which CONTENT is preceded by
 239 # AT_DATA_GRAMMAR_PROLOGUE.
 240 m4_define([AT_DATA_GRAMMAR],
 241 [AT_DATA([$1],
 242 [AT_DATA_GRAMMAR_PROLOGUE
 243 $2])
 244 ])
 245
 246 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 247 # -------------------------------------------------
 248 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 249 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 250 #
 251 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 252 # Bison in the test suite.  For now it ensures that:
 253 #
 254 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 255 #      a non-zero exit status since Bison doesn't always try to free all memory
 256 #      in that case.
 257 #
 258 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 259 #      --graph and --report=all output for every working grammar.
 260 #
 261 #   3. If stderr contains a warning, -Werror and --warnings=error
 262 #      convert the warning to an error.
 263 m4_define([AT_BISON_CHECK],
 264 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 265        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 266 AT_BISON_CHECK_NO_XML($@)])
 267
 268 m4_define([AT_BISON_WERROR_MSG],
 269           [[bison: warnings being treated as errors]])
 270
 271 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 272 # --------------------------------------------------------
 273 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 274 # when a tortured grammar's XML is known to be too large for xsltproc to
 275 # handle.
 276 m4_define([AT_BISON_CHECK_NO_XML],
 277 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 278                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 279 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 280       [m4_if(m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0],
 281              [[# Don't interfere with caller's files.
 282               if test -f stderr; then
 283                 mv stderr at-bison-check-stderr.bak
 284               fi
 285               if test -f experr; then
 286                 mv experr at-bison-check-experr.bak
 287               fi
 288
 289               # Run with -Werror.
 290               ]AT_CHECK(AT_QUELL_VALGRIND[[ bison -Werror ]$1],
 291                         [[1]], [$3], [stderr])[
 292
 293               # Build expected stderr up to and including the "warnings
 294               # being treated as errors" message.
 295               ]AT_DATA([[at-bison-check-warnings]], [$4])[
 296               at_bison_check_first="` \
 297                 sed -n '/: warning: /=' at-bison-check-warnings \
 298                 | sed -n 1p \
 299               `"
 300               if test $at_bison_check_first -gt 1; then
 301                 sed -n "1,`expr $at_bison_check_first - 1`"p \
 302                   at-bison-check-warnings > experr
 303               fi
 304               echo ']AT_BISON_WERROR_MSG[' >> experr
 305
 306               # Finish building expected stderr and check.  Unlike
 307               # warnings, complaints cause bison to exit early.  Thus,
 308               # with -Werror, bison does not necessarily report all
 309               # warnings that it does without -Werror, but it at least
 310               # reports one.
 311               at_bison_check_last="`sed -n '$=' stderr`"
 312               if test x"$at_bison_check_last" = x; then
 313                 at_bison_check_last=1
 314               fi
 315               at_bison_check_last="`expr $at_bison_check_last - 1`"
 316               sed -n "$at_bison_check_first,$at_bison_check_last"p \
 317                 at-bison-check-warnings >> experr
 318               ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 319                           stderr 1>&2]], [[0]], [[]], [experr])[
 320
 321               # Now check --warnings=error.
 322               cp stderr experr
 323               ]AT_CHECK(AT_QUELL_VALGRIND[[ bison --warnings=error ]$1],
 324                         [[1]], [$3], [experr])[
 325
 326               # Restore caller's files.
 327               if test -f at-bison-check-experr.bak; then
 328                 mv at-bison-check-experr.bak experr
 329               fi
 330               if test -f at-bison-check-stderr.bak; then
 331                 mv at-bison-check-stderr.bak stderr
 332               fi
 333              ]])
 334       ])
 335 ])
 336
 337 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 338 # -----------------------------------------------------
 339 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 340 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 341 # have a non-zero exit status.
 342 m4_define([AT_BISON_CHECK_XML],
 343 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 344   mkdir xml-tests]
 345   m4_pushdef([AT_BISON_ARGS],
 346              [m4_bpatsubsts([[$1]],
 347                             [--report(-file)?=[^][ ]*], [],
 348                             [--graph=[^][ ]*], [],
 349                             [--xml=[^][ ]*], [])])dnl
 350   # Don't combine these Bison invocations since we want to be sure that
 351   # --report=all isn't required to get the full XML file.
 352   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 353              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 354            [[0]], [ignore], [ignore])
 355   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 356            [[0]], [ignore], [ignore])
 357   m4_popdef([AT_BISON_ARGS])dnl
 358   [cp xml-tests/test.output expout]
 359   AT_CHECK([[$XSLTPROC \
 360              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 361              xml-tests/test.xml]], [[0]], [expout])
 362   [cp xml-tests/test.dot expout]
 363   AT_CHECK([[$XSLTPROC \
 364              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 365              xml-tests/test.xml]], [[0]], [expout])
 366   [rm -rf xml-tests expout
 367 fi]])
 368
 369 # AT_QUELL_VALGRIND
 370 # -----------------
 371 # Put this before a Bison invocation to keep Valgrind from complaining about
 372 # reachable memory.
 373 #
 374 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 375 # The triple quoting below will cause test cases to fail if you do.  If you do
 376 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 377 # will then fail to shell-escape its contents when attempting to print them.
 378 # The testsuite verbose output, at least, will be incorrect, but nothing may
 379 # fail to make sure you notice.
 380 m4_define([AT_QUELL_VALGRIND],
 381 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 382
 383 ## ------------------------ ##
 384 ## Compiling C, C++ Files.  ##
 385 ## ------------------------ ##
 386
 387
 388 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 389 # ----------------------------------------
 390 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 391 # assume that we are linking too; this is a hack.
 392 m4_define([AT_COMPILE],
 393 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 394            0, [ignore], [ignore])])
 395
 396 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 397 # --------------------------------------------
 398 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 399 # assume that we are linking too; this is a hack.
 400 # If the C++ compiler does not work, ignore the test.
 401 m4_define([AT_COMPILE_CXX],
 402 [AT_KEYWORDS(c++)
 403 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 404 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 405          0, [ignore], [ignore])])
 406
 407
 408 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 409 # --------------------------------
 410 # Compile OUTPUT.y to OUTPUT.c or OUTPUT.cc, and compile it to OUTPUT.
 411 # If OTHER is specified, compile OUTPUT-OTHER.c or OUTPUT-OTHER.cc to OUTPUT
 412 # along with it.
 413 # Relies on AT_SKEL_CC_IF.
 414 m4_define([AT_FULL_COMPILE],
 415 [AT_SKEL_CC_IF(
 416   [AT_BISON_CHECK([-o $1.cc $1.y])
 417    AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1.cc $1-$2.cc]]))],
 418   [AT_BISON_CHECK([-o $1.c $1.y])
 419    AT_COMPILE([$1]m4_ifval($2, [, [$1.c $1-$2.c]]))])
 420 ])
 421
 422
 423 ## ---------------------------- ##
 424 ## Running a generated parser.  ##
 425 ## ---------------------------- ##
 426
 427 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 428 # ------------------------------------------------------------
 429 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 430 m4_define([AT_PARSER_CHECK],
 431 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 432
 433 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 434 #                          DECLS, GRAMMAR, INPUT,
 435 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 436 #                          [OTHER-CHECKS],
 437 #                          [PARSER-EXIT-VALUE],
 438 #                          [PARSER-STDOUT], [PARSER-STDERR])
 439 # -------------------------------------------------------------
 440 # Using TITLE as the test group title, check the generated parser tables
 441 # and parser for a specified grammar file under a condition labeled by
 442 # COND-VALUE.
 443 #
 444 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 445 # recognized attribute is described below where it is relevant.
 446 #
 447 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 448 # the grammar file.  Insert basic yyerror, yylex, and main function
 449 # definitions as well.  Hardcode yylex to return the (possibly empty)
 450 # comma-delimited series of tokens in INPUT followed by token 0.
 451 #
 452 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 453 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 454 # On the bison command-line, specify `--report=all --defines'.  Check
 455 # that Bison exits with value 0, has no stdout, and has stderr
 456 # BISON-STDERR.
 457 #
 458 # If TEST-SPEC contains the attribute `last-state', check that the value
 459 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 460 # the grammar; in other words, check the number of states (minus one).
 461 # Otherwise, check that everything in the `.output' file starting with
 462 # the definition of state 0 is the same as the entire value of
 463 # TABLES-OR-LAST-STATE.
 464 #
 465 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 466 # `.output' file, which is named `input.output', and/or grammar file,
 467 # which is named `input.y'.
 468 #
 469 # Finally, compile the generated parser and then run it using
 470 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 471 # PARSER-STDERR as the 2nd-4th arguments.
 472 #
 473 # As a precondition, you must properly double-quote all arguments that
 474 # are to be interpreted as strings.
 475 #
 476 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 477 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 478 # first argument.  This is useful, for example, when wrapping multiple
 479 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 480 # condition, in another macro.
 481 #
 482 # For example:
 483 #
 484 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 485 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 486 #   # ---------------------------------------------------------------------
 487 #   m4_define([AT_TEST_SYNTAX_ERROR],
 488 #   [
 489 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 490 #                              [[last-state]],
 491 #                              [[%error-verbose ]$2], [$3], [$4],
 492 #                              [[]], [$5], [], [$6], [$7], [$8])
 493 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 494 #                              [[last-state]],
 495 #                              [$2], [$3], [$4],
 496 #                              [[]], [$5], [], [$6], [$7], [$8])
 497 #   ])
 498 #
 499 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 500 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 501 #                        [[3]],
 502 #                        [[1]], [[]],
 503 #                        [AT_COND_CASE([[no verbose]],
 504 #                                      [[syntax error
 505 #   ]],
 506 #                                      [[syntax error, unexpected 'b', expecting $end
 507 #   ]])])
 508 m4_define([AT_TEST_TABLES_AND_PARSE],
 509 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 510
 511 AT_SETUP([$1])
 512
 513 AT_DATA_GRAMMAR([[input.y]],
 514 [[%code {
 515   #include <stdio.h>
 516   static void yyerror (char const *msg);
 517   static int yylex (void);
 518 }
 519
 520 ]$4[
 521
 522 %%
 523
 524 ]$5[
 525
 526 %%
 527
 528 static void
 529 yyerror (char const *msg)
 530 {
 531   fprintf (stderr, "%s\n", msg);
 532 }
 533
 534 static int
 535 yylex (void)
 536 {
 537   static int const input[] = {
 538     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 539   };
 540   static int const *inputp = input;
 541   return *inputp++;
 542 }
 543
 544 int
 545 main (void)
 546 {
 547   return yyparse ();
 548 }
 549 ]])
 550
 551 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 552 # expanding macros, so it corrupts some special characters in the
 553 # macros.  To avoid this, expand now and pass it the result with proper
 554 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 555 # strings.
 556
 557 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 558       [AT_BISON_CHECK],
 559       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 560                                [0], [], m4_dquote($7))
 561
 562 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 563       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 564                 m4_dquote($8))],
 565       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 566                 m4_dquote($8)[[
 567 ]])])
 568
 569 $9
 570
 571 AT_COMPILE([[input]])
 572
 573 AT_PARSER_CHECK([[./input]],
 574                 m4_ifval([$10], [m4_dquote($10)]),
 575                 m4_ifval([$11], [m4_dquote($11)]),
 576                 m4_ifval([$12], [m4_dquote($12)]))
 577
 578 AT_CLEANUP
 579
 580 m4_popdef([AT_COND_CASE])])
 581
 582
 583
 584 ## ----------------------- ##
 585 ## Launch the test suite.  ##
 586 ## ----------------------- ##
 587
 588 AT_INIT
 589
 590 AT_TESTED([bison])