configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2010 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # We have strange test case titles, so we need Autoconf 2.61 or better.
  19 AC_PREREQ(2.61)
  20
  21 AC_INIT([GNU Bison],
  22         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  23         [bug-bison@gnu.org])
  24 AC_DEFINE([PACKAGE_COPYRIGHT_YEAR], [2008],
  25           [The copyright year for this package])
  26 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2008])
  27
  28 AC_CONFIG_AUX_DIR([build-aux])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # We don't have a file m4/Makefile.am, so we need Automake 1.8 or later.
  32 # We want gnits strictness only when rolling a formal release so that we can,
  33 # for example, run make dist at other times without being required to add a
  34 # bogus NEWS entry.
  35 AM_INIT_AUTOMAKE([1.8 dist-bzip2]
  36                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [-], [gnu], [gnits]))
  37 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  38
  39 # Checks for the compiler.
  40 AC_PROG_CC_STDC
  41
  42 # Gnulib (early checks).
  43 gl_EARLY
  44
  45 AC_ARG_ENABLE(gcc-warnings,
  46 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  47 [case "${enableval}" in
  48    yes|no) ;;
  49    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  50  esac],
  51               [enableval=no])
  52 if test "${enableval}" = yes; then
  53   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  54   AC_SUBST([WERROR_CFLAGS])
  55   gl_WARN_ADD([-Wall])
  56   gl_WARN_ADD([-Wextra -Wno-sign-compare])
  57   gl_WARN_ADD([-Wcast-align])
  58   gl_WARN_ADD([-Wcast-qual])
  59   gl_WARN_ADD([-Wformat])
  60   gl_WARN_ADD([-Wpointer-arith])
  61   gl_WARN_ADD([-Wwrite-strings])
  62   AC_SUBST([WARN_CXXFLAGS], [$WARN_CFLAGS])
  63   # The following warnings are not suitable for C++.
  64   gl_WARN_ADD([-Wbad-function-cast])
  65   gl_WARN_ADD([-Wmissing-declarations])
  66   gl_WARN_ADD([-Wmissing-prototypes])
  67   gl_WARN_ADD([-Wshadow])
  68   gl_WARN_ADD([-Wstrict-prototypes])
  69   AC_SUBST([WARN_CFLAGS])
  70   # Warnings for the test suite only.
  71   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
  72   WARN_CXXFLAGS_TEST="$WARN_CXXFLAGS $WARN_CFLAGS_TEST"
  73   WARN_CFLAGS_TEST="$WARN_CFLAGS $WARN_CFLAGS_TEST"
  74   AC_SUBST([WARN_CXXFLAGS_TEST])
  75   AC_SUBST([WARN_CFLAGS_TEST])
  76   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  77 fi
  78
  79 BISON_TEST_FOR_WORKING_C_COMPILER
  80
  81 AC_ARG_ENABLE([yacc],
  82   [AC_HELP_STRING([--disable-yacc],
  83      [do not build a yacc command or an -ly library])],
  84   , [enable_yacc=yes])
  85 case $enable_yacc in
  86 yes)
  87   YACC_SCRIPT=yacc
  88   YACC_LIBRARY=liby.a;;
  89 *)
  90   YACC_SCRIPT=
  91   YACC_LIBRARY=;;
  92 esac
  93 AC_SUBST([YACC_SCRIPT])
  94 AC_SUBST([YACC_LIBRARY])
  95
  96 # Checks for programs.
  97 AC_PROG_LEX
  98 AC_PROG_YACC
  99 AC_PROG_RANLIB
 100 AC_PROG_GNU_M4
 101 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 102 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 103 supports -g, otherwise to "".])
 104 AM_MISSING_PROG([HELP2MAN], [help2man])
 105 AC_PATH_PROG([XSLTPROC], [xsltproc])
 106 AC_SUBST([XSLTPROC])
 107
 108 # Checks for header files.
 109 AC_CHECK_HEADERS_ONCE([locale.h])
 110
 111 # Checks for compiler characteristics.
 112 AC_C_INLINE
 113
 114 # Gnulib (later checks).  Putting them here rather than right after
 115 # gl_EARLY avoids some redundant checks.
 116 gl_INIT
 117
 118 # Checks for library functions.
 119 AC_CHECK_FUNCS_ONCE([setlocale])
 120 AM_WITH_DMALLOC
 121 BISON_PREREQ_SUBPIPE
 122 BISON_PREREQ_TIMEVAR
 123
 124 # Gettext.
 125 # We use gnulib, which is only guaranteed to work properly with the
 126 # latest Gettext.
 127 AM_GNU_GETTEXT([external], [need-ngettext])
 128 AM_GNU_GETTEXT_VERSION([0.17])
 129 BISON_I18N
 130
 131 # Internationalized parsers.
 132 AC_CONFIG_FILES([runtime-po/Makefile.in])
 133 # Autoconf macros for packages using internationalized parsers.
 134 aclocaldir='${datadir}/aclocal'
 135 AC_SUBST([aclocaldir])
 136
 137 # Create the benchmark script.
 138 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 139
 140 # Initialize the test suite.
 141 AC_CONFIG_TESTDIR(tests)
 142 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 143 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 144 AC_CHECK_PROGS([VALGRIND], [valgrind])
 145 AC_PROG_CXX
 146 BISON_TEST_FOR_WORKING_CXX_COMPILER
 147 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 148 # Needed by tests/atlocal.in.
 149 AC_SUBST([GCC])
 150 AC_SUBST([O0CFLAGS],   [`echo $CFLAGS   | sed 's/-O[[0-9]] *//'`])
 151 AC_SUBST([O0CXXFLAGS], [`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`])
 152
 153 gt_JAVACOMP([1.3])
 154 gt_JAVAEXEC
 155
 156 AC_CONFIG_FILES([Makefile
 157                  build-aux/Makefile
 158                  po/Makefile.in
 159                  data/Makefile
 160                  etc/Makefile
 161                  examples/Makefile
 162                     examples/calc++/Makefile
 163                  lib/Makefile src/Makefile
 164                  doc/Makefile
 165                    doc/yacc.1])
 166 AC_OUTPUT