src/parse-gram.y

   1 /* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20    02111-1307  USA
  21 */
  22
  23
  24 %debug
  25 %defines
  26 %locations
  27 %pure-parser
  28 // %error-verbose
  29 %defines
  30 %name-prefix="gram_"
  31
  32 %{
  33 #include "system.h"
  34
  35 #include "complain.h"
  36 #include "conflicts.h"
  37 #include "files.h"
  38 #include "getargs.h"
  39 #include "gram.h"
  40 #include "muscle_tab.h"
  41 #include "output.h"
  42 #include "reader.h"
  43 #include "symlist.h"
  44
  45 /* Produce verbose syntax errors.  */
  46 #define YYERROR_VERBOSE 1
  47
  48 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  49 static YYLTYPE lloc_default (YYLTYPE const *, int);
  50
  51 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  52    FIXME: depends on the undocumented availability of YYLLOC.  */
  53 #undef  yyerror
  54 #define yyerror(Msg) \
  55         gram_error (&yylloc, Msg)
  56 static void gram_error (location const *, char const *);
  57
  58 #define YYPRINT(File, Type, Value) \
  59         print_token_value (File, Type, &Value)
  60 static void print_token_value (FILE *, int, YYSTYPE const *);
  61
  62 static void add_param (char const *, char *, location);
  63
  64 symbol_class current_class = unknown_sym;
  65 uniqstr current_type = 0;
  66 symbol *current_lhs;
  67 location current_lhs_location;
  68 assoc current_assoc;
  69 int current_prec = 0;
  70 %}
  71
  72
  73 /* Only NUMBERS have a value.  */
  74 %union
  75 {
  76   symbol *symbol;
  77   symbol_list *list;
  78   int integer;
  79   char *chars;
  80   assoc assoc;
  81   uniqstr uniqstr;
  82 };
  83
  84 /* Define the tokens together with their human representation.  */
  85 %token GRAM_EOF 0 "end of file"
  86 %token STRING     "string"
  87 %token INT        "integer"
  88
  89 %token PERCENT_TOKEN       "%token"
  90 %token PERCENT_NTERM       "%nterm"
  91
  92 %token PERCENT_TYPE        "%type"
  93 %token PERCENT_DESTRUCTOR  "%destructor {...}"
  94 %token PERCENT_PRINTER     "%printer {...}"
  95
  96 %token PERCENT_UNION       "%union {...}"
  97
  98 %token PERCENT_LEFT        "%left"
  99 %token PERCENT_RIGHT       "%right"
 100 %token PERCENT_NONASSOC    "%nonassoc"
 101
 102 %token PERCENT_PREC          "%prec"
 103 %token PERCENT_DPREC         "%dprec"
 104 %token PERCENT_MERGE         "%merge"
 105
 106
 107 /*----------------------.
 108 | Global Declarations.  |
 109 `----------------------*/
 110
 111 %token
 112   PERCENT_DEBUG         "%debug"
 113   PERCENT_DEFINE        "%define"
 114   PERCENT_DEFINES       "%defines"
 115   PERCENT_ERROR_VERBOSE "%error-verbose"
 116   PERCENT_EXPECT        "%expect"
 117   PERCENT_FILE_PREFIX   "%file-prefix"
 118   PERCENT_GLR_PARSER    "%glr-parser"
 119   PERCENT_LEX_PARAM     "%lex-param {...}"
 120   PERCENT_LOCATIONS     "%locations"
 121   PERCENT_NAME_PREFIX   "%name-prefix"
 122   PERCENT_NO_LINES      "%no-lines"
 123   PERCENT_NONDETERMINISTIC_PARSER    "%nondeterministic-parser"
 124   PERCENT_OUTPUT        "%output"
 125   PERCENT_PARSE_PARAM   "%parse-param {...}"
 126   PERCENT_PURE_PARSER   "%pure-parser"
 127   PERCENT_SKELETON      "%skeleton"
 128   PERCENT_START         "%start"
 129   PERCENT_TOKEN_TABLE   "%token-table"
 130   PERCENT_VERBOSE       "%verbose"
 131   PERCENT_YACC          "%yacc"
 132 ;
 133
 134 %token TYPE            "type"
 135 %token EQUAL           "="
 136 %token SEMICOLON       ";"
 137 %token PIPE            "|"
 138 %token ID              "identifier"
 139 %token ID_COLON        "identifier:"
 140 %token PERCENT_PERCENT "%%"
 141 %token PROLOGUE        "%{...%}"
 142 %token EPILOGUE        "epilogue"
 143 %token BRACED_CODE     "{...}"
 144
 145
 146 %type <chars> STRING string_content
 147               "%destructor {...}"
 148               "%lex-param {...}"
 149               "%parse-param {...}"
 150               "%printer {...}"
 151               "%union {...}"
 152               BRACED_CODE action
 153               PROLOGUE EPILOGUE
 154 %type <uniqstr> TYPE
 155 %type <integer> INT
 156 %type <symbol> ID ID_COLON symbol string_as_id
 157 %type <assoc> precedence_declarator
 158 %type <list>  symbols.1
 159 %%
 160
 161 input:
 162   declarations "%%" grammar epilogue.opt
 163 ;
 164
 165
 166         /*------------------------------------.
 167         | Declarations: before the first %%.  |
 168         `------------------------------------*/
 169
 170 declarations:
 171   /* Nothing */
 172 | declarations declaration
 173 ;
 174
 175 declaration:
 176   grammar_declaration
 177 | PROLOGUE                                 { prologue_augment ($1, @1); }
 178 | "%debug"                                 { debug_flag = 1; }
 179 | "%define" string_content string_content  { muscle_insert ($2, $3); }
 180 | "%defines"                               { defines_flag = 1; }
 181 | "%error-verbose"                         { error_verbose = 1; }
 182 | "%expect" INT                            { expected_conflicts = $2; }
 183 | "%file-prefix" "=" string_content        { spec_file_prefix = $3; }
 184 | "%glr-parser"                            { nondeterministic_parser = true;
 185                                              glr_parser = true; }
 186 | "%lex-param {...}"                       { add_param ("lex_param", $1, @1); }
 187 | "%locations"                             { locations_flag = 1; }
 188 | "%name-prefix" "=" string_content        { spec_name_prefix = $3; }
 189 | "%no-lines"                              { no_lines_flag = 1; }
 190 | "%nondeterministic-parser"               { nondeterministic_parser = true; }
 191 | "%output" "=" string_content             { spec_outfile = $3; }
 192 | "%parse-param {...}"                   { add_param ("parse_param", $1, @1); }
 193 | "%pure-parser"                           { pure_parser = true; }
 194 | "%skeleton" string_content               { skeleton = $2; }
 195 | "%token-table"                           { token_table_flag = 1; }
 196 | "%verbose"                               { report_flag = report_states; }
 197 | "%yacc"                                  { yacc_flag = 1; }
 198 | ";"
 199 ;
 200
 201 grammar_declaration:
 202   precedence_declaration
 203 | symbol_declaration
 204 | "%start" symbol
 205     {
 206       grammar_start_symbol_set ($2, @2);
 207     }
 208 | "%union {...}"
 209     {
 210       typed = 1;
 211       MUSCLE_INSERT_INT ("stype_line", @1.start.line);
 212       muscle_insert ("stype", $1);
 213     }
 214 | "%destructor {...}" symbols.1
 215     {
 216       symbol_list *list;
 217       for (list = $2; list; list = list->next)
 218         symbol_destructor_set (list->sym, $1, @1);
 219       symbol_list_free ($2);
 220     }
 221 | "%printer {...}" symbols.1
 222     {
 223       symbol_list *list;
 224       for (list = $2; list; list = list->next)
 225         symbol_printer_set (list->sym, $1, list->location);
 226       symbol_list_free ($2);
 227     }
 228 ;
 229
 230 symbol_declaration:
 231   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 232     {
 233       current_class = unknown_sym;
 234       current_type = NULL;
 235     }
 236 | "%token" { current_class = token_sym; } symbol_defs.1
 237     {
 238       current_class = unknown_sym;
 239       current_type = NULL;
 240     }
 241 | "%type" TYPE symbols.1
 242     {
 243       symbol_list *list;
 244       for (list = $3; list; list = list->next)
 245         symbol_type_set (list->sym, $2, @2);
 246       symbol_list_free ($3);
 247     }
 248 ;
 249
 250 precedence_declaration:
 251   precedence_declarator type.opt symbols.1
 252     {
 253       symbol_list *list;
 254       ++current_prec;
 255       for (list = $3; list; list = list->next)
 256         {
 257           symbol_type_set (list->sym, current_type, @2);
 258           symbol_precedence_set (list->sym, current_prec, $1, @1);
 259         }
 260       symbol_list_free ($3);
 261       current_type = NULL;
 262     }
 263 ;
 264
 265 precedence_declarator:
 266   "%left"     { $$ = left_assoc; }
 267 | "%right"    { $$ = right_assoc; }
 268 | "%nonassoc" { $$ = non_assoc; }
 269 ;
 270
 271 type.opt:
 272   /* Nothing. */ { current_type = NULL; }
 273 | TYPE           { current_type = $1; }
 274 ;
 275
 276 /* One or more nonterminals to be %typed. */
 277
 278 symbols.1:
 279   symbol            { $$ = symbol_list_new ($1, @1); }
 280 | symbols.1 symbol  { $$ = symbol_list_prepend ($1, $2, @2); }
 281 ;
 282
 283 /* One token definition.  */
 284 symbol_def:
 285   TYPE
 286      {
 287        current_type = $1;
 288      }
 289 | ID
 290      {
 291        symbol_class_set ($1, current_class, @1);
 292        symbol_type_set ($1, current_type, @1);
 293      }
 294 | ID INT
 295     {
 296       symbol_class_set ($1, current_class, @1);
 297       symbol_type_set ($1, current_type, @1);
 298       symbol_user_token_number_set ($1, $2, @2);
 299     }
 300 | ID string_as_id
 301     {
 302       symbol_class_set ($1, current_class, @1);
 303       symbol_type_set ($1, current_type, @1);
 304       symbol_make_alias ($1, $2, @$);
 305     }
 306 | ID INT string_as_id
 307     {
 308       symbol_class_set ($1, current_class, @1);
 309       symbol_type_set ($1, current_type, @1);
 310       symbol_user_token_number_set ($1, $2, @2);
 311       symbol_make_alias ($1, $3, @$);
 312     }
 313 ;
 314
 315 /* One or more symbol definitions. */
 316 symbol_defs.1:
 317   symbol_def
 318 | symbol_defs.1 symbol_def
 319 ;
 320
 321
 322         /*------------------------------------------.
 323         | The grammar section: between the two %%.  |
 324         `------------------------------------------*/
 325
 326 grammar:
 327   rules_or_grammar_declaration
 328 | grammar rules_or_grammar_declaration
 329 ;
 330
 331 /* As a Bison extension, one can use the grammar declarations in the
 332    body of the grammar.  */
 333 rules_or_grammar_declaration:
 334   rules
 335 | grammar_declaration ";"
 336     {
 337       if (yacc_flag)
 338         complain_at (@$, _("POSIX forbids declarations in the grammar"));
 339     }
 340 | error ";"
 341     {
 342       yyerrok;
 343     }
 344 ;
 345
 346 rules:
 347   ID_COLON { current_lhs = $1; current_lhs_location = @1; } rhses.1
 348 ;
 349
 350 rhses.1:
 351   rhs                { grammar_rule_end (@1); }
 352 | rhses.1 "|" rhs    { grammar_rule_end (@3); }
 353 | rhses.1 ";"
 354 ;
 355
 356 rhs:
 357   /* Nothing.  */
 358     { grammar_rule_begin (current_lhs, current_lhs_location); }
 359 | rhs symbol
 360     { grammar_current_rule_symbol_append ($2, @2); }
 361 | rhs action
 362     { grammar_current_rule_action_append ($2, @2); }
 363 | rhs "%prec" symbol
 364     { grammar_current_rule_prec_set ($3, @3); }
 365 | rhs "%dprec" INT
 366     { grammar_current_rule_dprec_set ($3, @3); }
 367 | rhs "%merge" TYPE
 368     { grammar_current_rule_merge_set ($3, @3); }
 369 ;
 370
 371 symbol:
 372   ID              { $$ = $1; }
 373 | string_as_id    { $$ = $1; }
 374 ;
 375
 376 action:
 377   BRACED_CODE
 378    { $$ = $1; }
 379 ;
 380
 381 /* A string used as an ID: we have to keep the quotes. */
 382 string_as_id:
 383   STRING
 384     {
 385       $$ = symbol_get ($1, @1);
 386       symbol_class_set ($$, token_sym, @1);
 387     }
 388 ;
 389
 390 /* A string used for its contents.  Strip the quotes. */
 391 string_content:
 392   STRING
 393     {
 394       $$ = $1 + 1;
 395       $$[strlen ($$) - 1] = '\0';
 396     };
 397
 398
 399 epilogue.opt:
 400   /* Nothing.  */
 401 | "%%" EPILOGUE
 402     {
 403       epilogue_augment ($2, @2);
 404       scanner_last_string_free ();
 405     }
 406 ;
 407
 408 %%
 409
 410
 411 /* Return the location of the left-hand side of a rule whose
 412    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 413    the right-hand side, and return an empty location equal to the end
 414    boundary of RHS[0] if the right-hand side is empty.  */
 415
 416 static YYLTYPE
 417 lloc_default (YYLTYPE const *rhs, int n)
 418 {
 419   int i;
 420   YYLTYPE loc;
 421   loc.start = loc.end = rhs[n].end;
 422
 423   /* Ignore empty nonterminals the start of the the right-hand side.
 424      Do not bother to ignore them at the end of the right-hand side,
 425      since empty nonterminals have the same end as their predecessors.  */
 426   for (i = 1; i <= n; i++)
 427     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 428       {
 429         loc.start = rhs[i].start;
 430         break;
 431       }
 432
 433   return loc;
 434 }
 435
 436
 437 /* Add a lex-param or a parse-param (depending on TYPE) with
 438    declaration DECL and location LOC.  */
 439
 440 static void
 441 add_param (char const *type, char *decl, location loc)
 442 {
 443   static char const alphanum[] =
 444     "0123456789"
 445     "abcdefghijklmnopqrstuvwxyz"
 446     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 447     "_";
 448   char const *alpha = alphanum + 10;
 449   char const *name_start = NULL;
 450   char *p;
 451
 452   for (p = decl; *p; p++)
 453     if ((p == decl || ! strchr (alphanum, p[-1])) && strchr (alpha, p[0]))
 454       name_start = p;
 455
 456   /* Strip the surrounding '{' and '}'.  */
 457   decl++;
 458   p[-1] = '\0';
 459
 460   if (! name_start)
 461     complain_at (loc, _("missing identifier in parameter declaration"));
 462   else
 463     {
 464       char *name;
 465       size_t name_len;
 466
 467       for (name_len = 1;
 468            name_start[name_len] && strchr (alphanum, name_start[name_len]);
 469            name_len++)
 470         continue;
 471
 472       name = xmalloc (name_len + 1);
 473       memcpy (name, name_start, name_len);
 474       name[name_len] = '\0';
 475       muscle_pair_list_grow (type, decl, name);
 476       free (name);
 477     }
 478
 479   scanner_last_string_free ();
 480 }
 481
 482 /*----------------------------------------------------.
 483 | When debugging the parser, display tokens' values.  |
 484 `----------------------------------------------------*/
 485
 486 static void
 487 print_token_value (FILE *file, int type, YYSTYPE const *value)
 488 {
 489   fputc (' ', file);
 490   switch (type)
 491     {
 492     case ID:
 493       fprintf (file, " = %s", value->symbol->tag);
 494       break;
 495
 496     case INT:
 497       fprintf (file, " = %d", value->integer);
 498       break;
 499
 500     case STRING:
 501       fprintf (file, " = \"%s\"", value->chars);
 502       break;
 503
 504     case TYPE:
 505       fprintf (file, " = <%s>", value->uniqstr);
 506       break;
 507
 508     case BRACED_CODE:
 509     case PERCENT_DESTRUCTOR:
 510     case PERCENT_LEX_PARAM:
 511     case PERCENT_PARSE_PARAM:
 512     case PERCENT_PRINTER:
 513     case PERCENT_UNION:
 514     case PROLOGUE:
 515     case EPILOGUE:
 516       fprintf (file, " = {{ %s }}", value->chars);
 517       break;
 518
 519     default:
 520       fprintf (file, "unknown token type");
 521       break;
 522     }
 523 }
 524
 525 static void
 526 gram_error (location const *loc, char const *msg)
 527 {
 528   complain_at (*loc, "%s", msg);
 529 }
 530
 531 char const *
 532 token_name (int type)
 533 {
 534   return yytname[type];
 535 }