configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2011 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.
  21 AC_PREREQ(2.64)
  22
  23 AC_INIT([GNU Bison],
  24         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  25         [bug-bison@gnu.org])
  26 AC_DEFINE([PACKAGE_COPYRIGHT_YEAR], [2011],
  27           [The copyright year for this package])
  28 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2011])
  29
  30 AC_CONFIG_AUX_DIR([build-aux])
  31 AC_CONFIG_MACRO_DIR([m4])
  32
  33 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  34 #
  35 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  36 #
  37 # To avoid 1.11, we make 1.11.1 the minimum version.
  38 #
  39 # We want gnits strictness only when rolling a stable release.  For
  40 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  41 # doesn't like that, so we let the underscore disable gnits.  Between
  42 # releases, we want to be able run make dist without being required to
  43 # add a bogus NEWS entry.  In that case, the version string
  44 # automatically contains a dash, which we also let disable gnits.
  45 AM_INIT_AUTOMAKE([1.11.1 dist-bzip2]
  46                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  47                            [gnu], [gnits]))
  48 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  49
  50 # Checks for the compiler.
  51 AC_PROG_CC_STDC
  52
  53 # Gnulib (early checks).
  54 gl_EARLY
  55
  56 AC_ARG_ENABLE(gcc-warnings,
  57 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  58 [case "${enableval}" in
  59    yes|no) ;;
  60    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  61  esac],
  62               [enableval=no])
  63 if test "${enableval}" = yes; then
  64   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  65   AC_SUBST([WERROR_CFLAGS])
  66   gl_WARN_ADD([-Wall])
  67   gl_WARN_ADD([-Wextra -Wno-sign-compare])
  68   gl_WARN_ADD([-Wcast-align])
  69   gl_WARN_ADD([-Wcast-qual])
  70   gl_WARN_ADD([-Wformat])
  71   gl_WARN_ADD([-Wpointer-arith])
  72   gl_WARN_ADD([-Wwrite-strings])
  73   AC_SUBST([WARN_CXXFLAGS], [$WARN_CFLAGS])
  74   # The following warnings are not suitable for C++.
  75   gl_WARN_ADD([-Wbad-function-cast])
  76   gl_WARN_ADD([-Wmissing-declarations])
  77   gl_WARN_ADD([-Wmissing-prototypes])
  78   gl_WARN_ADD([-Wshadow])
  79   gl_WARN_ADD([-Wstrict-prototypes])
  80   AC_SUBST([WARN_CFLAGS])
  81   # Warnings for the test suite only.
  82   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
  83   WARN_CXXFLAGS_TEST="$WARN_CXXFLAGS $WARN_CFLAGS_TEST"
  84   WARN_CFLAGS_TEST="$WARN_CFLAGS $WARN_CFLAGS_TEST"
  85   AC_SUBST([WARN_CXXFLAGS_TEST])
  86   AC_SUBST([WARN_CFLAGS_TEST])
  87   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  88 fi
  89
  90 BISON_TEST_FOR_WORKING_C_COMPILER
  91
  92 AC_ARG_ENABLE([yacc],
  93   [AC_HELP_STRING([--disable-yacc],
  94      [do not build a yacc command or an -ly library])],
  95   , [enable_yacc=yes])
  96 case $enable_yacc in
  97 yes)
  98   YACC_SCRIPT=src/yacc
  99   YACC_LIBRARY=lib/liby.a;;
 100 *)
 101   YACC_SCRIPT=
 102   YACC_LIBRARY=;;
 103 esac
 104 AC_SUBST([YACC_SCRIPT])
 105 AC_SUBST([YACC_LIBRARY])
 106
 107 # Checks for programs.
 108 AC_PROG_LEX
 109 AC_PROG_YACC
 110 AC_PROG_RANLIB
 111 AC_PROG_GNU_M4
 112 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 113 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 114 supports -g, otherwise to "".])
 115 AM_MISSING_PROG([HELP2MAN], [help2man])
 116 AC_PATH_PROG([XSLTPROC], [xsltproc])
 117 AC_SUBST([XSLTPROC])
 118
 119 # Checks for header files.
 120 AC_CHECK_HEADERS_ONCE([locale.h])
 121
 122 # Checks for compiler characteristics.
 123 AC_C_INLINE
 124
 125 # Gnulib (later checks).  Putting them here rather than right after
 126 # gl_EARLY avoids some redundant checks.
 127 gl_INIT
 128
 129 # Checks for library functions.
 130 AC_CHECK_FUNCS_ONCE([setlocale])
 131 AM_WITH_DMALLOC
 132 BISON_PREREQ_SUBPIPE
 133 BISON_PREREQ_TIMEVAR
 134
 135 # Gettext.
 136 # We use gnulib, which is only guaranteed to work properly with the
 137 # latest Gettext.
 138 AM_GNU_GETTEXT([external], [need-ngettext])
 139 AM_GNU_GETTEXT_VERSION([0.18])
 140 BISON_I18N
 141
 142 # Internationalized parsers.
 143 AC_CONFIG_FILES([runtime-po/Makefile.in])
 144 # Autoconf macros for packages using internationalized parsers.
 145 aclocaldir='${datadir}/aclocal'
 146 AC_SUBST([aclocaldir])
 147
 148 # Create the benchmark script.
 149 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 150
 151 # Initialize the test suite.
 152 AC_CONFIG_TESTDIR(tests)
 153 AC_CONFIG_FILES([tests/atlocal])
 154 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 155 AC_CHECK_PROGS([VALGRIND], [valgrind])
 156 AC_PROG_CXX
 157 BISON_TEST_FOR_WORKING_CXX_COMPILER
 158 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 159 # Needed by tests/atlocal.in.
 160 AC_SUBST([GCC])
 161 AC_SUBST([O0CFLAGS],   [`echo $CFLAGS   | sed 's/-O[[0-9]] *//'`])
 162 AC_SUBST([O0CXXFLAGS], [`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`])
 163
 164 gt_JAVACOMP([1.3], [1.4])
 165 gt_JAVAEXEC
 166
 167 # We use gnulib, but from lib/local.mk instead of lib/Makefile.am.
 168 # So prefix paths with lib/.  See also etc/prefix-gnulib-mk.
 169 gl_LIBOBJS=`echo "$gl_LIBOBJS" | sed -e 's, , lib/,g'`
 170 for ac_var in ALLOCA_H ERRNO_H FCNTL_H GETOPT_H INTTYPES_H \
 171               LIBUNISTRING_UNITYPES_H LIBUNISTRING_UNIWIDTH_H \
 172               STDBOOL_H STDINT_H SYS_WAIT_H WCHAR_H WCTYPE_H
 173 do
 174   eval "test x\$$ac_var = x || $ac_var=lib/\$$ac_var"
 175 done
 176 AC_CONFIG_FILES([Makefile
 177                  po/Makefile.in
 178                  examples/calc++/Makefile
 179                  doc/yacc.1])
 180 AC_OUTPUT