configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2011 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.  We need Autoconf 2.68 or
  21 # better to avoid a typo in the `configure --help' entry for the YACC
  22 # environment variable.
  23 AC_PREREQ(2.68)
  24
  25 AC_INIT([GNU Bison],
  26         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  27         [bug-bison@gnu.org])
  28 AC_DEFINE([PACKAGE_COPYRIGHT_YEAR], [2011],
  29           [The copyright year for this package])
  30 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2011])
  31
  32 AC_CONFIG_AUX_DIR([build-aux])
  33 AC_CONFIG_MACRO_DIR([m4])
  34
  35 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  36 #
  37 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  38 #
  39 # To avoid 1.11, we make 1.11.1 the minimum version.
  40 #
  41 # We want gnits strictness only when rolling a stable release.  For
  42 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  43 # doesn't like that, so we let the underscore disable gnits.  Between
  44 # releases, we want to be able run make dist without being required to
  45 # add a bogus NEWS entry.  In that case, the version string
  46 # automatically contains a dash, which we also let disable gnits.
  47 AM_INIT_AUTOMAKE([1.11.1 dist-xz]
  48                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  49                            [gnu], [gnits]))
  50 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  51
  52 # Checks for the compiler.
  53 AC_PROG_CC_STDC
  54
  55 # Gnulib (early checks).
  56 gl_EARLY
  57
  58 AC_ARG_ENABLE(gcc-warnings,
  59 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  60 [case "${enableval}" in
  61    yes|no) ;;
  62    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  63  esac],
  64               [enableval=no])
  65 if test "${enableval}" = yes; then
  66   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  67   AC_SUBST([WERROR_CFLAGS])
  68   gl_WARN_ADD([-Wall])
  69   gl_WARN_ADD([-Wextra -Wno-sign-compare])
  70   gl_WARN_ADD([-Wcast-align])
  71   gl_WARN_ADD([-Wcast-qual])
  72   gl_WARN_ADD([-Wformat])
  73   gl_WARN_ADD([-Wpointer-arith])
  74   gl_WARN_ADD([-Wwrite-strings])
  75   AC_SUBST([WARN_CXXFLAGS], [$WARN_CFLAGS])
  76   # The following warnings are not suitable for C++.
  77   gl_WARN_ADD([-Wbad-function-cast])
  78   gl_WARN_ADD([-Wmissing-declarations])
  79   gl_WARN_ADD([-Wmissing-prototypes])
  80   gl_WARN_ADD([-Wshadow])
  81   gl_WARN_ADD([-Wstrict-prototypes])
  82   AC_SUBST([WARN_CFLAGS])
  83   # Warnings for the test suite only.
  84   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
  85   gl_WARN_ADD([-pedantic], [WARN_CFLAGS_TEST])
  86   AC_SUBST([WARN_CXXFLAGS_TEST], ["$WARN_CXXFLAGS $WARN_CFLAGS_TEST"])
  87   AC_SUBST([WARN_CFLAGS_TEST], ["$WARN_CFLAGS $WARN_CFLAGS_TEST"])
  88 fi
  89
  90 BISON_TEST_FOR_WORKING_C_COMPILER
  91
  92 AC_ARG_ENABLE([yacc],
  93   [AC_HELP_STRING([--disable-yacc],
  94      [do not build a yacc command or an -ly library])],
  95   , [enable_yacc=yes])
  96 case $enable_yacc in
  97 yes)
  98   YACC_SCRIPT=yacc
  99   YACC_LIBRARY=liby.a;;
 100 *)
 101   YACC_SCRIPT=
 102   YACC_LIBRARY=;;
 103 esac
 104 AC_SUBST([YACC_SCRIPT])
 105 AC_SUBST([YACC_LIBRARY])
 106
 107 # Checks for programs.
 108 AC_PROG_LEX
 109 AC_PROG_YACC
 110 AC_PROG_RANLIB
 111 AC_PROG_GNU_M4
 112 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 113 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 114 supports -g, otherwise to "".])
 115 AM_MISSING_PROG([HELP2MAN], [help2man])
 116 AC_PATH_PROG([XSLTPROC], [xsltproc])
 117 AC_SUBST([XSLTPROC])
 118
 119 # Checks for header files.
 120 AC_CHECK_HEADERS_ONCE([locale.h])
 121
 122 # Checks for compiler characteristics.
 123 AC_C_INLINE
 124
 125 # Gnulib (later checks).  Putting them here rather than right after
 126 # gl_EARLY avoids some redundant checks.
 127 gl_INIT
 128
 129 # Checks for library functions.
 130 AC_CHECK_FUNCS_ONCE([setlocale])
 131 AM_WITH_DMALLOC
 132 BISON_PREREQ_SUBPIPE
 133 BISON_PREREQ_TIMEVAR
 134
 135 # Gettext.
 136 # We use gnulib, which is only guaranteed to work properly with the
 137 # latest Gettext.
 138 AM_GNU_GETTEXT([external], [need-ngettext])
 139 AM_GNU_GETTEXT_VERSION([0.18])
 140 BISON_I18N
 141
 142 # Internationalized parsers.
 143 AC_CONFIG_FILES([runtime-po/Makefile.in])
 144 # Autoconf macros for packages using internationalized parsers.
 145 aclocaldir='${datadir}/aclocal'
 146 AC_SUBST([aclocaldir])
 147
 148 # Create the benchmark script.
 149 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 150
 151 # Initialize the test suite.
 152 AC_CONFIG_TESTDIR(tests)
 153 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 154 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 155 AC_CHECK_PROGS([VALGRIND], [valgrind])
 156 AC_PROG_CXX
 157 BISON_TEST_FOR_WORKING_CXX_COMPILER
 158 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 159 # Needed by tests/atlocal.in.
 160 AC_SUBST([GCC])
 161 AC_SUBST([O0CFLAGS],   [`echo $CFLAGS   | sed 's/-O[[0-9]] *//'`])
 162 AC_SUBST([O0CXXFLAGS], [`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`])
 163
 164 gt_JAVACOMP([1.3])
 165 gt_JAVAEXEC
 166
 167 AC_CONFIG_FILES([Makefile
 168                  build-aux/Makefile
 169                  po/Makefile.in
 170                  data/Makefile
 171                  etc/Makefile
 172                  examples/Makefile
 173                     examples/calc++/Makefile
 174                  lib/Makefile src/Makefile
 175                  doc/Makefile
 176                    doc/yacc.1])
 177 AC_OUTPUT