src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation,
   4    Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software; you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation; either version 2 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program; if not, write to the Free Software
  20    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21    02110-1301  USA
  22 */
  23
  24 #include <config.h>
  25 #include "system.h"
  26
  27 #include <strverscmp.h>
  28
  29 #include "complain.h"
  30 #include "conflicts.h"
  31 #include "files.h"
  32 #include "getargs.h"
  33 #include "gram.h"
  34 #include "muscle_tab.h"
  35 #include "quotearg.h"
  36 #include "reader.h"
  37 #include "symlist.h"
  38 #include "scan-gram.h"
  39 #include "scan-code.h"
  40
  41 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  42 static YYLTYPE lloc_default (YYLTYPE const *, int);
  43
  44 #define YY_LOCATION_PRINT(File, Loc) \
  45           location_print (File, Loc)
  46
  47 static void version_check (location const *loc, char const *version);
  48
  49 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  50    FIXME: depends on the undocumented availability of YYLLOC.  */
  51 #undef  yyerror
  52 #define yyerror(Msg) \
  53         gram_error (&yylloc, Msg)
  54 static void gram_error (location const *, char const *);
  55
  56 static char const *char_name (char);
  57
  58 /** Add a lex-param or a parse-param.
  59  *
  60  * \param type  \a lex_param or \a parse_param
  61  * \param decl  the formal argument
  62  * \param loc   the location in the source.
  63  */
  64 static void add_param (char const *type, char *decl, location loc);
  65
  66
  67 static symbol_class current_class = unknown_sym;
  68 static uniqstr current_type = NULL;
  69 static symbol *current_lhs;
  70 static location current_lhs_location;
  71 static int current_prec = 0;
  72
  73 #define YYTYPE_INT16 int_fast16_t
  74 #define YYTYPE_INT8 int_fast8_t
  75 #define YYTYPE_UINT16 uint_fast16_t
  76 #define YYTYPE_UINT8 uint_fast8_t
  77 %}
  78
  79 %debug
  80 %verbose
  81 %defines
  82 %locations
  83 %pure-parser
  84 %error-verbose
  85 %name-prefix="gram_"
  86 %expect 0
  87
  88 %initial-action
  89 {
  90   /* Bison's grammar can initial empty locations, hence a default
  91      location is needed. */
  92   boundary_set (&@$.start, current_file, 1, 1);
  93   boundary_set (&@$.end, current_file, 1, 1);
  94 }
  95
  96 %union
  97 {
  98   symbol *symbol;
  99   symbol_list *list;
 100   int integer;
 101   char const *chars;
 102   char *code;
 103   assoc assoc;
 104   uniqstr uniqstr;
 105   unsigned char character;
 106 };
 107
 108 /* Define the tokens together with their human representation.  */
 109 %token GRAM_EOF 0 "end of file"
 110 %token STRING     "string"
 111 %token INT        "integer"
 112
 113 %token PERCENT_TOKEN       "%token"
 114 %token PERCENT_NTERM       "%nterm"
 115
 116 %token PERCENT_TYPE        "%type"
 117 %token PERCENT_DESTRUCTOR  "%destructor"
 118 %token PERCENT_PRINTER     "%printer"
 119
 120 %token PERCENT_LEFT        "%left"
 121 %token PERCENT_RIGHT       "%right"
 122 %token PERCENT_NONASSOC    "%nonassoc"
 123
 124 %token PERCENT_PREC          "%prec"
 125 %token PERCENT_DPREC         "%dprec"
 126 %token PERCENT_MERGE         "%merge"
 127
 128
 129 /*----------------------.
 130 | Global Declarations.  |
 131 `----------------------*/
 132
 133 %token
 134   PERCENT_CODE            "%code"
 135   PERCENT_DEBUG           "%debug"
 136   PERCENT_DEFAULT_PREC    "%default-prec"
 137   PERCENT_DEFINE          "%define"
 138   PERCENT_DEFINES         "%defines"
 139   PERCENT_ERROR_VERBOSE   "%error-verbose"
 140   PERCENT_EXPECT          "%expect"
 141   PERCENT_EXPECT_RR       "%expect-rr"
 142   PERCENT_FILE_PREFIX     "%file-prefix"
 143   PERCENT_GLR_PARSER      "%glr-parser"
 144   PERCENT_INITIAL_ACTION  "%initial-action"
 145   PERCENT_LANGUAGE        "%language"
 146   PERCENT_LEX_PARAM       "%lex-param"
 147   PERCENT_LOCATIONS       "%locations"
 148   PERCENT_NAME_PREFIX     "%name-prefix"
 149   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 150   PERCENT_NO_LINES        "%no-lines"
 151   PERCENT_NONDETERMINISTIC_PARSER
 152                           "%nondeterministic-parser"
 153   PERCENT_OUTPUT          "%output"
 154   PERCENT_PARSE_PARAM     "%parse-param"
 155   PERCENT_PURE_PARSER     "%pure-parser"
 156   PERCENT_PUSH_PARSER     "%push-parser"
 157   PERCENT_PUSH_PULL_PARSER
 158                           "%push-pull-parser"
 159   PERCENT_REQUIRE         "%require"
 160   PERCENT_SKELETON        "%skeleton"
 161   PERCENT_START           "%start"
 162   PERCENT_TOKEN_TABLE     "%token-table"
 163   PERCENT_VERBOSE         "%verbose"
 164   PERCENT_YACC            "%yacc"
 165 ;
 166
 167 %token BRACED_CODE     "{...}"
 168 %token CHAR            "char"
 169 %token EPILOGUE        "epilogue"
 170 %token EQUAL           "="
 171 %token ID              "identifier"
 172 %token ID_COLON        "identifier:"
 173 %token PERCENT_PERCENT "%%"
 174 %token PIPE            "|"
 175 %token PROLOGUE        "%{...%}"
 176 %token SEMICOLON       ";"
 177 %token TYPE            "type"
 178 %token TYPE_TAG_ANY    "<*>"
 179 %token TYPE_TAG_NONE   "<>"
 180
 181 %type <character> CHAR
 182 %printer { fputs (char_name ($$), stderr); } CHAR
 183
 184 /* braceless is not to be used for rule or symbol actions, as it
 185    calls code_props_plain_init.  */
 186 %type <chars> STRING "%{...%}" EPILOGUE braceless content content.opt
 187 %type <code> "{...}"
 188 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 189          STRING
 190 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 191          braceless content content.opt "{...}" "%{...%}" EPILOGUE
 192
 193 %type <uniqstr> TYPE ID ID_COLON
 194 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 195 %printer { fputs ($$, stderr); } ID
 196 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 197
 198 %type <integer> INT
 199 %printer { fprintf (stderr, "%d", $$); } INT
 200
 201 %type <symbol> id id_colon symbol string_as_id
 202 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 203 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 204
 205 %type <assoc> precedence_declarator
 206 %type <list>  symbols.1 generic_symlist generic_symlist_item
 207 %%
 208
 209 input:
 210   prologue_declarations "%%" grammar epilogue.opt
 211 ;
 212
 213
 214         /*------------------------------------.
 215         | Declarations: before the first %%.  |
 216         `------------------------------------*/
 217
 218 prologue_declarations:
 219   /* Nothing */
 220 | prologue_declarations prologue_declaration
 221 ;
 222
 223 prologue_declaration:
 224   grammar_declaration
 225 | "%{...%}"
 226     {
 227       code_props plain_code;
 228       code_props_plain_init (&plain_code, $1, @1);
 229       code_props_translate_code (&plain_code);
 230       gram_scanner_last_string_free ();
 231       prologue_augment (plain_code.code, @1, union_seen);
 232       code_scanner_last_string_free ();
 233     }
 234 | "%debug"                         { debug_flag = true; }
 235 | "%define" STRING content.opt
 236     {
 237       /* FIXME: Special characters in $2 may break %define.
 238          For example: `['.  */
 239       if (muscle_find_const ($2))
 240         warn_at (@2, _("%s: `%s' redefined"), "%define", $2);
 241       muscle_insert ($2, $3);
 242       muscle_grow_used_name_list ("used_percent_define_variables", $2, @2);
 243     }
 244 | "%defines"                       { defines_flag = true; }
 245 | "%defines" STRING
 246     {
 247       defines_flag = true;
 248       spec_defines_file = xstrdup ($2);
 249     }
 250 | "%error-verbose"                 { error_verbose = true; }
 251 | "%expect" INT                    { expected_sr_conflicts = $2; }
 252 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 253 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 254 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 255 | "%glr-parser"
 256     {
 257       nondeterministic_parser = true;
 258       glr_parser = true;
 259     }
 260 | "%initial-action" "{...}"
 261     {
 262       code_props action;
 263       code_props_symbol_action_init (&action, $2, @2);
 264       code_props_translate_code (&action);
 265       gram_scanner_last_string_free ();
 266       muscle_code_grow ("initial_action", action.code, @2);
 267       code_scanner_last_string_free ();
 268     }
 269 | "%language" STRING            { language_argmatch ($2, 1, &@1); }
 270 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 271 | "%locations"                  { locations_flag = true; }
 272 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 273 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 274 | "%no-lines"                   { no_lines_flag = true; }
 275 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 276 | "%output" STRING              { spec_outfile = $2; }
 277 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 278 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 279 | "%pure-parser"                { pure_parser = true; }
 280 | "%push-parser"                { push_parser = true; pull_parser = false; }
 281 | "%push-pull-parser"           { push_parser = true; pull_parser = true; }
 282 | "%require" STRING             { version_check (&@2, $2); }
 283 | "%skeleton" STRING            { skeleton_arg ($2, 1, &@1); }
 284 | "%token-table"                { token_table_flag = true; }
 285 | "%verbose"                    { report_flag = report_states; }
 286 | "%yacc"                       { yacc_flag = true; }
 287 | /*FIXME: Err?  What is this horror doing here? */ ";"
 288 ;
 289
 290 grammar_declaration:
 291   precedence_declaration
 292 | symbol_declaration
 293 | "%start" symbol
 294     {
 295       grammar_start_symbol_set ($2, @2);
 296     }
 297 | "%destructor" "{...}" generic_symlist
 298     {
 299       symbol_list *list;
 300       for (list = $3; list; list = list->next)
 301         symbol_list_destructor_set (list, $2, @2);
 302       symbol_list_free ($3);
 303     }
 304 | "%printer" "{...}" generic_symlist
 305     {
 306       symbol_list *list;
 307       for (list = $3; list; list = list->next)
 308         symbol_list_printer_set (list, $2, @2);
 309       symbol_list_free ($3);
 310     }
 311 | "%default-prec"
 312     {
 313       default_prec = true;
 314     }
 315 | "%no-default-prec"
 316     {
 317       default_prec = false;
 318     }
 319 | "%code" braceless
 320     {
 321       muscle_code_grow ("percent_code", $2, @2);
 322       code_scanner_last_string_free ();
 323     }
 324 | "%code" STRING braceless
 325     {
 326       /* FIXME: Special characters in $2 may break %code.
 327          For example: `['.  */
 328       char const name_prefix[] = "percent_code_";
 329       char *name = xmalloc (sizeof name_prefix + strlen ($2));
 330       strcpy (name, name_prefix);
 331       strcpy (name + sizeof name_prefix - 1, $2);
 332       muscle_code_grow (uniqstr_new (name), $3, @3);
 333       free (name);
 334       code_scanner_last_string_free ();
 335       muscle_grow_used_name_list ("used_percent_code_qualifiers", $2, @2);
 336     }
 337 ;
 338
 339
 340 /*----------*
 341  | %union.  |
 342  *----------*/
 343
 344 %token PERCENT_UNION "%union";
 345
 346 union_name:
 347   /* Nothing. */ {}
 348 | ID             { muscle_code_grow ("union_name", $1, @1); }
 349 ;
 350
 351 grammar_declaration:
 352   "%union" union_name "{...}"
 353     {
 354       char const *body = $3;
 355
 356       /* Concatenate the %union bodies.  If this is the first %union, make sure
 357          the synchronization line appears after the opening '{' so as not to
 358          confuse Doxygen.  Otherwise, turn the previous %union's trailing '}'
 359          into '\n', and omit the new %union's leading '{'.  */
 360       if (!union_seen)
 361         {
 362           muscle_grow ("stype", "{", "");
 363         }
 364       else
 365         {
 366           char *code = muscle_find ("stype");
 367           code[strlen (code) - 1] = '\n';
 368         }
 369       body++;
 370
 371       union_seen = true;
 372       muscle_code_grow ("stype", body, @3);
 373       gram_scanner_last_string_free ();
 374     }
 375 ;
 376
 377
 378
 379
 380 symbol_declaration:
 381   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 382     {
 383       current_class = unknown_sym;
 384       current_type = NULL;
 385     }
 386 | "%token" { current_class = token_sym; } symbol_defs.1
 387     {
 388       current_class = unknown_sym;
 389       current_type = NULL;
 390     }
 391 | "%type" TYPE symbols.1
 392     {
 393       symbol_list *list;
 394       tag_seen = true;
 395       for (list = $3; list; list = list->next)
 396         symbol_type_set (list->content.sym, $2, @2);
 397       symbol_list_free ($3);
 398     }
 399 ;
 400
 401 precedence_declaration:
 402   precedence_declarator type.opt symbols.1
 403     {
 404       symbol_list *list;
 405       ++current_prec;
 406       for (list = $3; list; list = list->next)
 407         {
 408           symbol_type_set (list->content.sym, current_type, @2);
 409           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 410         }
 411       symbol_list_free ($3);
 412       current_type = NULL;
 413     }
 414 ;
 415
 416 precedence_declarator:
 417   "%left"     { $$ = left_assoc; }
 418 | "%right"    { $$ = right_assoc; }
 419 | "%nonassoc" { $$ = non_assoc; }
 420 ;
 421
 422 type.opt:
 423   /* Nothing. */ { current_type = NULL; }
 424 | TYPE           { current_type = $1; tag_seen = true; }
 425 ;
 426
 427 /* One or more symbols to be %typed. */
 428 symbols.1:
 429   symbol
 430     { $$ = symbol_list_sym_new ($1, @1); }
 431 | symbols.1 symbol
 432     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 433 ;
 434
 435 generic_symlist:
 436   generic_symlist_item { $$ = $1; }
 437 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 438 ;
 439
 440 generic_symlist_item:
 441   symbol            { $$ = symbol_list_sym_new ($1, @1); }
 442 | TYPE              { $$ = symbol_list_type_new ($1, @1); }
 443 | "<*>"             { $$ = symbol_list_default_tagged_new (@1); }
 444 | "<>"             { $$ = symbol_list_default_tagless_new (@1); }
 445 ;
 446
 447 /* One token definition.  */
 448 symbol_def:
 449   TYPE
 450      {
 451        current_type = $1;
 452        tag_seen = true;
 453      }
 454 | id
 455      {
 456        symbol_class_set ($1, current_class, @1, true);
 457        symbol_type_set ($1, current_type, @1);
 458      }
 459 | id INT
 460     {
 461       symbol_class_set ($1, current_class, @1, true);
 462       symbol_type_set ($1, current_type, @1);
 463       symbol_user_token_number_set ($1, $2, @2);
 464     }
 465 | id string_as_id
 466     {
 467       symbol_class_set ($1, current_class, @1, true);
 468       symbol_type_set ($1, current_type, @1);
 469       symbol_make_alias ($1, $2, @$);
 470     }
 471 | id INT string_as_id
 472     {
 473       symbol_class_set ($1, current_class, @1, true);
 474       symbol_type_set ($1, current_type, @1);
 475       symbol_user_token_number_set ($1, $2, @2);
 476       symbol_make_alias ($1, $3, @$);
 477     }
 478 ;
 479
 480 /* One or more symbol definitions. */
 481 symbol_defs.1:
 482   symbol_def
 483 | symbol_defs.1 symbol_def
 484 ;
 485
 486
 487         /*------------------------------------------.
 488         | The grammar section: between the two %%.  |
 489         `------------------------------------------*/
 490
 491 grammar:
 492   rules_or_grammar_declaration
 493 | grammar rules_or_grammar_declaration
 494 ;
 495
 496 /* As a Bison extension, one can use the grammar declarations in the
 497    body of the grammar.  */
 498 rules_or_grammar_declaration:
 499   rules
 500 | grammar_declaration ";"
 501 | error ";"
 502     {
 503       yyerrok;
 504     }
 505 ;
 506
 507 rules:
 508   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 509 ;
 510
 511 rhses.1:
 512   rhs                { grammar_current_rule_end (@1); }
 513 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 514 | rhses.1 ";"
 515 ;
 516
 517 rhs:
 518   /* Nothing.  */
 519     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 520 | rhs symbol
 521     { grammar_current_rule_symbol_append ($2, @2); }
 522 | rhs "{...}"
 523     { grammar_current_rule_action_append ($2, @2); }
 524 | rhs "%prec" symbol
 525     { grammar_current_rule_prec_set ($3, @3); }
 526 | rhs "%dprec" INT
 527     { grammar_current_rule_dprec_set ($3, @3); }
 528 | rhs "%merge" TYPE
 529     { grammar_current_rule_merge_set ($3, @3); }
 530 ;
 531
 532
 533 /*-----------*
 534  | content.  |
 535  *-----------*/
 536
 537 content:
 538   STRING
 539 | braceless
 540 ;
 541
 542 /* Some content or "1" by default. */
 543 content.opt:
 544   /* Nothing. */
 545     {
 546       static char one[] = "1";
 547       $$ = one;
 548     }
 549 | content
 550 ;
 551
 552
 553 braceless:
 554   "{...}"
 555     {
 556       code_props plain_code;
 557       $1[strlen ($1) - 1] = '\n';
 558       code_props_plain_init (&plain_code, $1+1, @1);
 559       code_props_translate_code (&plain_code);
 560       gram_scanner_last_string_free ();
 561       $$ = plain_code.code;
 562     }
 563 ;
 564
 565
 566 /*---------------*
 567  | Identifiers.  |
 568  *---------------*/
 569
 570 /* Identifiers are returned as uniqstr values by the scanner.
 571    Depending on their use, we may need to make them genuine symbols.  */
 572
 573 id:
 574   ID
 575     { $$ = symbol_from_uniqstr ($1, @1); }
 576 | CHAR
 577     {
 578       $$ = symbol_get (char_name ($1), @1);
 579       symbol_class_set ($$, token_sym, @1, false);
 580       symbol_user_token_number_set ($$, $1, @1);
 581     }
 582 ;
 583
 584 id_colon:
 585   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 586 ;
 587
 588
 589 symbol:
 590   id
 591 | string_as_id
 592 ;
 593
 594 /* A string used as an ID: quote it.  */
 595 string_as_id:
 596   STRING
 597     {
 598       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 599       symbol_class_set ($$, token_sym, @1, false);
 600     }
 601 ;
 602
 603 epilogue.opt:
 604   /* Nothing.  */
 605 | "%%" EPILOGUE
 606     {
 607       code_props plain_code;
 608       code_props_plain_init (&plain_code, $2, @2);
 609       code_props_translate_code (&plain_code);
 610       gram_scanner_last_string_free ();
 611       muscle_code_grow ("epilogue", plain_code.code, @2);
 612       code_scanner_last_string_free ();
 613     }
 614 ;
 615
 616 %%
 617
 618
 619 /* Return the location of the left-hand side of a rule whose
 620    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 621    the right-hand side, and return an empty location equal to the end
 622    boundary of RHS[0] if the right-hand side is empty.  */
 623
 624 static YYLTYPE
 625 lloc_default (YYLTYPE const *rhs, int n)
 626 {
 627   int i;
 628   YYLTYPE loc;
 629
 630   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 631      The bug is fixed in 7.4.2m, but play it safe for now.  */
 632   loc.start = rhs[n].end;
 633   loc.end = rhs[n].end;
 634
 635   /* Ignore empty nonterminals the start of the the right-hand side.
 636      Do not bother to ignore them at the end of the right-hand side,
 637      since empty nonterminals have the same end as their predecessors.  */
 638   for (i = 1; i <= n; i++)
 639     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 640       {
 641         loc.start = rhs[i].start;
 642         break;
 643       }
 644
 645   return loc;
 646 }
 647
 648
 649 /* Add a lex-param or a parse-param (depending on TYPE) with
 650    declaration DECL and location LOC.  */
 651
 652 static void
 653 add_param (char const *type, char *decl, location loc)
 654 {
 655   static char const alphanum[26 + 26 + 1 + 10] =
 656     "abcdefghijklmnopqrstuvwxyz"
 657     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 658     "_"
 659     "0123456789";
 660   char const *name_start = NULL;
 661   char *p;
 662
 663   /* Stop on last actual character.  */
 664   for (p = decl; p[1]; p++)
 665     if ((p == decl
 666          || ! memchr (alphanum, p[-1], sizeof alphanum))
 667         && memchr (alphanum, p[0], sizeof alphanum - 10))
 668       name_start = p;
 669
 670   /* Strip the surrounding '{' and '}', and any blanks just inside
 671      the braces.  */
 672   while (*--p == ' ' || *p == '\t')
 673     continue;
 674   p[1] = '\0';
 675   while (*++decl == ' ' || *decl == '\t')
 676     continue;
 677
 678   if (! name_start)
 679     complain_at (loc, _("missing identifier in parameter declaration"));
 680   else
 681     {
 682       char *name;
 683       size_t name_len;
 684
 685       for (name_len = 1;
 686            memchr (alphanum, name_start[name_len], sizeof alphanum);
 687            name_len++)
 688         continue;
 689
 690       name = xmalloc (name_len + 1);
 691       memcpy (name, name_start, name_len);
 692       name[name_len] = '\0';
 693       muscle_pair_list_grow (type, decl, name);
 694       free (name);
 695     }
 696
 697   gram_scanner_last_string_free ();
 698 }
 699
 700
 701 static void
 702 version_check (location const *loc, char const *version)
 703 {
 704   if (strverscmp (version, PACKAGE_VERSION) > 0)
 705     {
 706       complain_at (*loc, "require bison %s, but have %s",
 707                    version, PACKAGE_VERSION);
 708       exit (63);
 709     }
 710 }
 711
 712 static void
 713 gram_error (location const *loc, char const *msg)
 714 {
 715   complain_at (*loc, "%s", msg);
 716 }
 717
 718 char const *
 719 token_name (int type)
 720 {
 721   return yytname[YYTRANSLATE (type)];
 722 }
 723
 724 static char const *
 725 char_name (char c)
 726 {
 727   if (c == '\'')
 728     return "'\\''";
 729   else
 730     {
 731       char buf[4];
 732       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 733       return quotearg_style (escape_quoting_style, buf);
 734     }
 735 }