configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001, 2002, 2003 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19
  20 # We need a recent Autoconf to run a recent Autotest.
  21 AC_PREREQ(2.57)
  22
  23 AC_INIT([GNU Bison], [1.875c], [bug-bison@gnu.org])
  24 AC_CONFIG_AUX_DIR(config)
  25
  26 AM_INIT_AUTOMAKE([1.7 check-news readme-alpha dist-bzip2])
  27 AC_CONFIG_HEADERS([config.h:config.hin])
  28
  29 # Checks for the compiler.
  30 AC_PROG_CC
  31 # Remove with Automake 1.8.
  32 AC_ISC_POSIX
  33 AC_GNU_SOURCE
  34 AC_MINIX
  35 AM_PROG_CC_STDC
  36 AC_ARG_ENABLE(gcc-warnings,
  37 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  38 [case "${enableval}" in
  39    yes|no) ;;
  40    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  41  esac],
  42               [enableval=no])
  43 if test "${enableval}" = yes; then
  44   BISON_WARNING(-Werror)
  45   AC_SUBST([WERROR_CFLAGS], [$WARNING_CFLAGS])
  46   WARNING_CFLAGS=
  47   BISON_WARNING(-Wall)
  48   BISON_WARNING(-W)
  49   BISON_WARNING(-Wcast-align)
  50   BISON_WARNING(-Wcast-qual)
  51   BISON_WARNING(-Wformat)
  52   BISON_WARNING(-Wmissing-prototypes)
  53   BISON_WARNING(-Wshadow)
  54   BISON_WARNING(-Wstrict-prototypes)
  55   BISON_WARNING(-Wwrite-strings)
  56   AC_SUBST([WARNING_CXXFLAGS], [$WARNING_CFLAGS])
  57   # The following warnings are not suitable for C++.
  58   BISON_WARNING(-Wbad-function-cast)
  59   BISON_WARNING(-Wmissing-declarations)
  60   BISON_WARNING(-Wnested-externs)
  61   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  62 fi
  63
  64 AC_ARG_ENABLE([yacc],
  65   [AC_HELP_STRING([--disable-yacc],
  66      [do not build a yacc command or an -ly library])],
  67   , [enable_yacc=yes])
  68 case $enable_yacc in
  69 yes)
  70   YACC_SCRIPT=yacc
  71   YACC_LIBRARY=liby.a;;
  72 *)
  73   YACC_SCRIPT=
  74   YACC_LIBRARY=;;
  75 esac
  76 AC_SUBST([YACC_SCRIPT])
  77 AC_SUBST([YACC_LIBRARY])
  78
  79 # Checks for programs.
  80 AC_PROG_LEX
  81 AC_PROG_YACC
  82 AC_PROG_RANLIB
  83 BISON_PROG_GNU_M4
  84 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  85   AC_MSG_ERROR([GNU M4 1.4 is required])
  86 fi
  87 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
  88
  89 # Checks for header files.
  90 AC_HEADER_STDC
  91 AC_CHECK_HEADERS([ctype.h locale.h memory.h stdlib.h string.h unistd.h])
  92 AM_STDBOOL_H
  93
  94 # Checks for compiler characteristics.
  95 AC_C_INLINE
  96
  97 # Checks for types.
  98 AC_CHECK_TYPES([uintptr_t])
  99
 100 # Checks for library functions.
 101 AC_CHECK_FUNCS(setlocale)
 102 AC_CHECK_DECLS([free, getenv, getopt,
 103                 stpcpy, strchr, strspn, strnlen,
 104                 malloc, memchr, memrchr])
 105 AC_REPLACE_FUNCS(strchr strrchr strspn)
 106 AM_WITH_DMALLOC
 107 BISON_PREREQ_SUBPIPE
 108 BISON_PREREQ_TIMEVAR
 109 gl_DIRNAME
 110 gl_ERROR
 111 gl_FUNC_ALLOCA
 112 gl_FUNC_MEMCHR
 113 gl_FUNC_MEMRCHR
 114 gl_FUNC_STPCPY
 115 gl_FUNC_STRNLEN
 116 gl_FUNC_STRTOL
 117 gl_GETOPT
 118 gl_HASH
 119 gl_MBSWIDTH
 120 gl_OBSTACK
 121 gl_QUOTE
 122 gl_QUOTEARG
 123 gl_XALLOC
 124 jm_FUNC_GLIBC_UNLOCKED_IO
 125 jm_FUNC_MALLOC
 126 jm_FUNC_REALLOC
 127
 128 # Gettext.
 129 AM_GNU_GETTEXT([external], [need-ngettext])
 130 AM_GNU_GETTEXT_VERSION(0.12.1)
 131
 132 # Initialize the test suite.
 133 AC_CONFIG_TESTDIR(tests)
 134 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 135 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 136 AC_CHECK_PROGS([VALGRIND], [valgrind])
 137 AC_PROG_CXX
 138 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 139 # Needed by tests/atlocal.in.
 140 AC_SUBST([GCC])
 141 O0CFLAGS=`echo $CFLAGS | sed 's/-O[0-9] *//'`
 142 AC_SUBST([O0CFLAGS])
 143
 144 AC_CONFIG_FILES([Makefile
 145                  config/Makefile
 146                  po/Makefile.in
 147                  data/Makefile
 148                  lib/Makefile src/Makefile doc/Makefile
 149                  m4/Makefile])
 150 AC_OUTPUT