data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4
   5 # Copyright (C) 2002, 2004-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 ## ---------------- ##
  22 ## Identification.  ##
  23 ## ---------------- ##
  24
  25 # b4_copyright(TITLE, [YEARS])
  26 # ----------------------------
  27 # If YEARS are not defined, use b4_copyright_years.
  28 m4_define([b4_copyright],
  29 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  30
  31 b4_comment([$1
  32
  33 ]m4_dquote(m4_text_wrap([Copyright (C)
  34 ]m4_ifval([$2], [[$2]], [m4_defn([b4_copyright_years])])[
  35 Free Software Foundation, Inc.]))[
  36
  37 This program is free software: you can redistribute it and/or modify
  38 it under the terms of the GNU General Public License as published by
  39 the Free Software Foundation, either version 3 of the License, or
  40 (at your option) any later version.
  41
  42 This program is distributed in the hope that it will be useful,
  43 but WITHOUT ANY WARRANTY; without even the implied warranty of
  44 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  45 GNU General Public License for more details.
  46
  47 You should have received a copy of the GNU General Public License
  48 along with this program.  If not, see <http://www.gnu.org/licenses/>.])
  49
  50 b4_comment([As a special exception, you may create a larger work that contains
  51 part or all of the Bison parser skeleton and distribute that work
  52 under terms of your choice, so long as that work isn't itself a
  53 parser generator using the skeleton or a modified version thereof
  54 as a parser skeleton.  Alternatively, if you modify or redistribute
  55 the parser skeleton itself, you may (at your option) remove this
  56 special exception, which will cause the skeleton and the resulting
  57 Bison output files to be licensed under the GNU General Public
  58 License without this special exception.
  59
  60 This special exception was added by the Free Software Foundation in
  61 version 2.2 of Bison.])])
  62
  63
  64 ## ---------------- ##
  65 ## Error handling.  ##
  66 ## ---------------- ##
  67
  68 # The following error handling macros print error directives that should not
  69 # become arguments of other macro invocations since they would likely then be
  70 # mangled.  Thus, they print to stdout directly.
  71
  72 # b4_cat(TEXT)
  73 # ------------
  74 # Write TEXT to stdout.  Precede the final newline with an @ so that it's
  75 # escaped.  For example:
  76 #
  77 #   b4_cat([[@complain(invalid input@)]])
  78 m4_define([b4_cat],
  79 [m4_syscmd([cat <<'_m4eof'
  80 ]m4_bpatsubst(m4_dquote($1), [_m4eof], [_m4@`eof])[@
  81 _m4eof
  82 ])dnl
  83 m4_if(m4_sysval, [0], [], [m4_fatal([$0: cannot write to stdout])])])
  84
  85 # b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
  86 # -------------------------------------------
  87 # Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to stdout.
  88 #
  89 # For example:
  90 #
  91 #   b4_error([[warn]], [[invalid value for '%s': %s]], [[foo]], [[3]])
  92 m4_define([b4_error],
  93 [b4_cat([[@]$1[(]$2[]]dnl
  94 [m4_if([$#], [2], [],
  95        [m4_foreach([b4_arg],
  96                    m4_dquote(m4_shift(m4_shift($@))),
  97                    [[@,]b4_arg])])[@)]])])
  98
  99 # b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
 100 # ----------------------------------------------------------
 101 # Write @KIND_at(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 102 #
 103 # For example:
 104 #
 105 #   b4_error_at([[complain]], [[input.y:2.3]], [[input.y:5.4]],
 106 #               [[invalid %s]], [[foo]])
 107 m4_define([b4_error_at],
 108 [b4_cat([[@]$1[_at(]$2[@,]$3[@,]$4[]]dnl
 109 [m4_if([$#], [4], [],
 110        [m4_foreach([b4_arg],
 111                    m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
 112                    [[@,]b4_arg])])[@)]])])
 113
 114 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
 115 # ------------------------------------
 116 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 117 #
 118 # For example:
 119 #
 120 #   b4_warn([[invalid value for '%s': %s]], [[foo]], [[3]])
 121 #
 122 # As a simple test suite, this:
 123 #
 124 #   m4_divert(-1)
 125 #   m4_define([asdf], [ASDF])
 126 #   m4_define([fsa], [FSA])
 127 #   m4_define([fdsa], [FDSA])
 128 #   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
 129 #   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
 130 #   b4_warn()
 131 #   b4_warn(1)
 132 #   b4_warn(1, 2)
 133 #
 134 # Should produce this without newlines:
 135 #
 136 #   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
 137 #   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
 138 #   @warn(@)
 139 #   @warn(1@)
 140 #   @warn(1@,2@)
 141 m4_define([b4_warn],
 142 [b4_error([[warn]], $@)])
 143
 144 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 145 # ---------------------------------------------------
 146 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 147 #
 148 # For example:
 149 #
 150 #   b4_warn_at([[input.y:2.3]], [[input.y:5.4]], [[invalid %s]], [[foo]])
 151 m4_define([b4_warn_at],
 152 [b4_error_at([[warn]], $@)])
 153
 154 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 155 # ----------------------------------------
 156 # Write @complain(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 157 #
 158 # See b4_warn example.
 159 m4_define([b4_complain],
 160 [b4_error([[complain]], $@)])
 161
 162 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 163 # -------------------------------------------------------
 164 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 165 #
 166 # See b4_warn_at example.
 167 m4_define([b4_complain_at],
 168 [b4_error_at([[complain]], $@)])
 169
 170 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 171 # -------------------------------------
 172 # Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 173 #
 174 # See b4_warn example.
 175 m4_define([b4_fatal],
 176 [b4_error([[fatal]], $@)dnl
 177 m4_exit(1)])
 178
 179 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 180 # ----------------------------------------------------
 181 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 182 #
 183 # See b4_warn_at example.
 184 m4_define([b4_fatal_at],
 185 [b4_error_at([[fatal]], $@)dnl
 186 m4_exit(1)])
 187
 188
 189 ## ---------------- ##
 190 ## Default values.  ##
 191 ## ---------------- ##
 192
 193 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 194 m4_define_default([b4_pre_prologue], [])
 195 m4_define_default([b4_post_prologue], [])
 196 m4_define_default([b4_epilogue], [])
 197 m4_define_default([b4_parse_param], [])
 198
 199 # The initial column and line.
 200 m4_define_default([b4_location_initial_column], [1])
 201 m4_define_default([b4_location_initial_line],   [1])
 202
 203
 204 ## ------------ ##
 205 ## Data Types.  ##
 206 ## ------------ ##
 207
 208 # b4_ints_in(INT1, INT2, LOW, HIGH)
 209 # ---------------------------------
 210 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 211 m4_define([b4_ints_in],
 212 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 213
 214
 215 # b4_subtract(LHS, RHS)
 216 # ---------------------
 217 # Evaluate LHS - RHS if they are integer literals, otherwise expand
 218 # to (LHS) - (RHS).
 219 m4_define([b4_subtract],
 220 [m4_bmatch([$1$2], [^[0123456789]*$],
 221            [m4_eval([$1 - $2])],
 222            [($1) - ($2)])])
 223
 224 # b4_args(ARG1, ...)
 225 # _b4_args(ARG1, ...)
 226 # -------------------
 227 # Join with comma, skipping empty arguments.
 228 # b4_args calls itself recursively until it sees the first non-empty
 229 # argument, then calls _b4_args which prepends each non-empty argument
 230 # with a comma.
 231 m4_define([b4_args],
 232 [m4_if([$#$1],
 233        [1], [],
 234        [m4_ifval([$1],
 235                  [$1[]_$0(m4_shift($@))],
 236                  [$0(m4_shift($@))])])])
 237
 238 # _b4_args(ARGS1, ...)
 239 # --------------------
 240 m4_define([_b4_args],
 241 [m4_if([$#$1],
 242        [1], [],
 243        [m4_ifval([$1], [, $1])[]$0(m4_shift($@))])])
 244
 245
 246
 247
 248 # b4_integral_parser_tables_map(MACRO)
 249 # -------------------------------------
 250 # Map MACRO on all the integral tables.  MACRO is expected to have
 251 # the signature MACRO(TABLE-NAME, CONTENT, COMMENT).
 252 m4_define([b4_integral_parser_tables_map],
 253 [$1([pact], [b4_pact],
 254     [[YYPACT[STATE-NUM] -- Index in YYTABLE of the portion describing
 255 STATE-NUM.]])
 256
 257 $1([defact], [b4_defact],
 258    [[YYDEFACT[S] -- default reduction number in state S.  Performed when
 259 YYTABLE does not specify something else to do.  Zero means the default
 260 is an error.]])
 261
 262 $1([pgoto], [b4_pgoto], [[YYPGOTO[NTERM-NUM].]])
 263
 264 $1([defgoto], [b4_defgoto], [[YYDEFGOTO[NTERM-NUM].]])
 265
 266 $1([table], [b4_table],
 267    [[YYTABLE[YYPACT[STATE-NUM]].  What to do in state STATE-NUM.  If
 268 positive, shift that token.  If negative, reduce the rule which
 269 number is the opposite.  If YYTABLE_NINF, syntax error.]])
 270
 271 $1([check], [b4_check])
 272
 273 $1([stos], [b4_stos],
 274    [[STOS_[STATE-NUM] -- The (internal number of the) accessing
 275 symbol of state STATE-NUM.]])
 276
 277 $1([r1], [b4_r1],
 278    [[YYR1[YYN] -- Symbol number of symbol that rule YYN derives.]])
 279
 280 $1([r2], [b4_r2],
 281    [[YYR2[YYN] -- Number of symbols composing right hand side of rule YYN.]])
 282 ])
 283
 284
 285 # b4_parser_tables_declare
 286 # b4_parser_tables_define
 287 # ------------------------
 288 # Define/declare the (deterministic) parser tables.
 289 m4_define([b4_parser_tables_declare],
 290 [b4_integral_parser_tables_map([b4_integral_parser_table_declare])])
 291
 292 m4_define([b4_parser_tables_define],
 293 [b4_integral_parser_tables_map([b4_integral_parser_table_define])])
 294
 295
 296
 297 ## ------------------ ##
 298 ## Decoding options.  ##
 299 ## ------------------ ##
 300
 301 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 302 # -----------------------------------
 303 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 304 m4_define([b4_flag_if],
 305 [m4_case(b4_$1_flag,
 306          [0], [$3],
 307          [1], [$2],
 308          [m4_fatal([invalid $1 value: ]$1)])])
 309
 310
 311 # b4_define_flag_if(FLAG)
 312 # -----------------------
 313 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 314 # value of the Boolean FLAG.
 315 m4_define([b4_define_flag_if],
 316 [_b4_define_flag_if($[1], $[2], [$1])])
 317
 318 # _b4_define_flag_if($1, $2, FLAG)
 319 # --------------------------------
 320 # Work around the impossibility to define macros inside macros,
 321 # because issuing `[$1]' is not possible in M4.  GNU M4 should provide
 322 # $$1 a la M5/TeX.
 323 m4_define([_b4_define_flag_if],
 324 [m4_if([$1$2], $[1]$[2], [],
 325        [m4_fatal([$0: Invalid arguments: $@])])dnl
 326 m4_define([b4_$3_if],
 327           [b4_flag_if([$3], [$1], [$2])])])
 328
 329
 330 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 331 # -----------------------------
 332 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 333 b4_define_flag_if([defines])            # Whether headers are requested.
 334 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 335 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 336 b4_define_flag_if([token_table])        # Whether yytoken_table is demanded.
 337 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 338
 339 # yytoken_table is needed to support verbose errors.
 340 b4_error_verbose_if([m4_define([b4_token_table_flag], [1])])
 341
 342
 343 ## --------- ##
 344 ## Symbols.  ##
 345 ## --------- ##
 346
 347 # b4_symbol_(NUM, FIELD)
 348 # ----------------------
 349 # Recover a FIELD about symbol #NUM.  Thanks to m4_indir, fails if
 350 # undefined.
 351 m4_define([b4_symbol_],
 352 [m4_indir([b4_symbol($1, $2)])])
 353
 354
 355 # b4_symbol(NUM, FIELD)
 356 # ---------------------
 357 # Recover a FIELD about symbol #NUM.  Thanks to m4_indir, fails if
 358 # undefined.  If FIELD = id, prepend the prefix.
 359 m4_define([b4_symbol],
 360 [m4_case([$2],
 361          [id],    [m4_do([b4_percent_define_get([api.tokens.prefix])],
 362                          [b4_symbol_([$1], [id])])],
 363          [b4_symbol_($@)])])
 364
 365
 366 # b4_symbol_if(NUM, FIELD, IF-TRUE, IF-FALSE)
 367 # -------------------------------------------
 368 # If FIELD about symbol #NUM is 1 expand IF-TRUE, if is 0, expand IF-FALSE.
 369 # Otherwise an error.
 370 m4_define([b4_symbol_if],
 371 [m4_case(b4_symbol([$1], [$2]),
 372          [1], [$3],
 373          [0], [$4],
 374          [m4_fatal([$0: field $2 of $1 is not a Boolean:] b4_symbol([$1], [$2]))])])
 375
 376
 377 # b4_symbol_action_location(SYMBOL-NUM, KIND)
 378 # -------------------------------------------
 379 # Report the location of the KIND action as FILE:LINE.
 380 m4_define([b4_symbol_action_location],
 381 [b4_symbol([$1], [$2_file]):b4_syncline([b4_symbol([$1], [$2_line])])])
 382
 383
 384 # b4_symbol_action(SYMBOL-NUM, KIND)
 385 # ----------------------------------
 386 # Run the action KIND (destructor or printer) for SYMBOL-NUM.
 387 # Same as in C, but using references instead of pointers.
 388 m4_define([b4_symbol_action],
 389 [b4_symbol_if([$1], [has_$2],
 390 [m4_pushdef([b4_dollar_dollar],
 391     [b4_symbol_value([(*yyvaluep)],
 392                      b4_symbol_if([$1], [has_type],
 393                                   [b4_symbol([$1], [type])]))])dnl
 394 m4_pushdef([b4_at_dollar], [(*yylocationp)])dnl
 395       b4_symbol_case_([$1])
 396 b4_syncline([b4_symbol([$1], [$2_line])], ["b4_symbol([$1], [$2_file])"])
 397         b4_symbol([$1], [$2])
 398 b4_syncline([@oline@], [@ofile@])
 399         break;
 400
 401 m4_popdef([b4_at_dollar])dnl
 402 m4_popdef([b4_dollar_dollar])dnl
 403 ])])
 404
 405
 406 # b4_symbol_destructor(SYMBOL-NUM)
 407 # b4_symbol_printer(SYMBOL-NUM)
 408 # --------------------------------
 409 m4_define([b4_symbol_destructor], [b4_symbol_action([$1], [destructor])])
 410 m4_define([b4_symbol_printer],    [b4_symbol_action([$1], [printer])])
 411
 412
 413 # b4_symbol_case_(SYMBOL-NUM)
 414 # ---------------------------
 415 # Issue a "case NUM" for SYMBOL-NUM.
 416 m4_define([b4_symbol_case_],
 417 [      case b4_symbol([$1], [number]): // b4_symbol([$1], [tag])
 418 ])
 419
 420
 421 # b4_symbol_foreach(MACRO)
 422 # ------------------------
 423 # Invoke MACRO(SYMBOL-NUM) for each SYMBOL-NUM.
 424 m4_define([b4_symbol_foreach],
 425           [m4_map([$1], m4_defn([b4_symbol_numbers]))])
 426
 427
 428 ## ------- ##
 429 ## Types.  ##
 430 ## ------- ##
 431
 432 # b4_type_action_(NUMS)
 433 # ---------------------
 434 # Run actions for the symbol NUMS that all have the same type-name.
 435 # Skip NUMS that have no type-name.
 436 m4_define([b4_type_action_],
 437 [b4_symbol_if([$1], [has_type],
 438 [m4_map([b4_symbol_case_], [$@])[]dnl
 439         b4_dollar_dollar([b4_symbol([$1], [number])],
 440                          [b4_symbol([$1], [tag])],
 441                          [b4_symbol([$1], [type])]);
 442         break;
 443
 444 ])])
 445
 446 # b4_type_foreach(MACRO)
 447 # ----------------------
 448 # Invoke MACRO(SYMBOL-NUMS) for each set of SYMBOL-NUMS for each type set.
 449 m4_define([b4_type_foreach],
 450           [m4_map([$1], m4_defn([b4_type_names]))])
 451
 452
 453
 454 ## ----------- ##
 455 ## Synclines.  ##
 456 ## ----------- ##
 457
 458 # b4_basename(NAME)
 459 # -----------------
 460 # Similar to POSIX basename; the differences don't matter here.
 461 # Beware that NAME is not evaluated.
 462 m4_define([b4_basename],
 463 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 464
 465
 466 # b4_syncline(LINE, FILE)
 467 # -----------------------
 468 m4_define([b4_syncline],
 469 [b4_flag_if([synclines],
 470 [b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 471 b4_sync_start([$1], [$2])])])
 472
 473 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 474 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 475
 476 # b4_user_code(USER-CODE)
 477 # -----------------------
 478 # Emit code from the user, ending it with synclines.
 479 m4_define([b4_user_code],
 480 [$1
 481 b4_syncline([@oline@], [@ofile@])])
 482
 483
 484 # b4_define_user_code(MACRO)
 485 # --------------------------
 486 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 487 m4_define([b4_define_user_code],
 488 [m4_define([b4_user_$1],
 489 [b4_user_code([b4_$1])])])
 490
 491
 492 # b4_user_actions
 493 # b4_user_initial_action
 494 # b4_user_post_prologue
 495 # b4_user_pre_prologue
 496 # b4_user_stype
 497 # ----------------------
 498 # Macros that issue user code, ending with synclines.
 499 b4_define_user_code([actions])
 500 b4_define_user_code([initial_action])
 501 b4_define_user_code([post_prologue])
 502 b4_define_user_code([pre_prologue])
 503 b4_define_user_code([stype])
 504
 505
 506 # b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
 507 # -----------------------------------------------------
 508 # Complain if any name of type WHAT is used by the user (as recorded in
 509 # USER-LIST) but is not used by Bison (as recorded by macros in the
 510 # namespace BISON-NAMESPACE).
 511 #
 512 # USER-LIST must expand to a list specifying all user occurrences of all names
 513 # of type WHAT.   Each item in the list must be a triplet specifying one
 514 # occurrence: name, start boundary, and end boundary.  Empty string names are
 515 # fine.  An empty list is fine.
 516 #
 517 # For example, to define b4_foo_user_names to be used for USER-LIST with three
 518 # name occurrences and with correct quoting:
 519 #
 520 #   m4_define([b4_foo_user_names],
 521 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 522 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 523 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 524 #
 525 # The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
 526 # is used by Bison (in the front-end or in the skeleton).  Empty string names
 527 # are fine, but it would be ugly for Bison to actually use one.
 528 #
 529 # For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
 530 # the names bar and baz are used by Bison:
 531 #
 532 #   m4_define([b4_foo_bison_names(bar)])
 533 #   m4_define([b4_foo_bison_names(baz)])
 534 #
 535 # To invoke b4_check_user_names with TYPE foo, with USER-LIST
 536 # b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
 537 # quoting:
 538 #
 539 #   b4_check_user_names([[foo]], [b4_foo_user_names],
 540 #                       [[b4_foo_bison_names]])
 541 m4_define([b4_check_user_names],
 542 [m4_foreach([b4_occurrence], $2,
 543 [m4_pushdef([b4_occurrence], b4_occurrence)dnl
 544 m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
 545 m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
 546 m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
 547 m4_ifndef($3[(]m4_quote(b4_user_name)[)],
 548           [b4_complain_at([b4_start], [b4_end],
 549                           [[%s '%s' is not used]],
 550                           [$1], [b4_user_name])])[]dnl
 551 m4_popdef([b4_occurrence])dnl
 552 m4_popdef([b4_user_name])dnl
 553 m4_popdef([b4_start])dnl
 554 m4_popdef([b4_end])dnl
 555 ])])
 556
 557
 558
 559 ## --------------------- ##
 560 ## b4_percent_define_*.  ##
 561 ## --------------------- ##
 562
 563
 564 # b4_percent_define_use(VARIABLE)
 565 # -------------------------------
 566 # Declare that VARIABLE was used.
 567 m4_define([b4_percent_define_use],
 568 [m4_define([b4_percent_define_bison_variables(]$1[)])dnl
 569 ])
 570
 571 # b4_percent_define_get(VARIABLE, [DEFAULT])
 572 # ------------------------------------------
 573 # Mimic muscle_percent_define_get in ../src/muscle-tab.h.  That is, if
 574 # the %define variable VARIABLE is defined, emit its value.  Contrary
 575 # to its C counterpart, return DEFAULT otherwise.  Also, record
 576 # Bison's usage of VARIABLE by defining
 577 # b4_percent_define_bison_variables(VARIABLE).
 578 #
 579 # For example:
 580 #
 581 #   b4_percent_define_get([[foo]])
 582 m4_define([b4_percent_define_get],
 583 [b4_percent_define_use([$1])dnl
 584 m4_ifdef([b4_percent_define(]$1[)],
 585          [m4_indir([b4_percent_define(]$1[)])],
 586          [$2])])
 587
 588 # b4_percent_define_get_loc(VARIABLE)
 589 # -----------------------------------
 590 # Mimic muscle_percent_define_get_loc in ../src/muscle-tab.h exactly.  That is,
 591 # if the %define variable VARIABLE is undefined, complain fatally since that's
 592 # a Bison or skeleton error.  Otherwise, return its definition location in a
 593 # form approriate for the first two arguments of b4_warn_at, b4_complain_at, or
 594 # b4_fatal_at.  Don't record this as a Bison usage of VARIABLE as there's no
 595 # reason to suspect that the user-supplied value has yet influenced the output.
 596 #
 597 # For example:
 598 #
 599 #   b4_complain_at(b4_percent_define_get_loc([[foo]]), [[invalid foo]])
 600 m4_define([b4_percent_define_get_loc],
 601 [m4_ifdef([b4_percent_define_loc(]$1[)],
 602           [m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
 603 b4_loc[]dnl
 604 m4_popdef([b4_loc])],
 605           [b4_fatal([[b4_percent_define_get_loc: undefined %%define variable '%s']], [$1])])])
 606
 607 # b4_percent_define_get_syncline(VARIABLE)
 608 # ----------------------------------------
 609 # Mimic muscle_percent_define_get_syncline in ../src/muscle-tab.h exactly.
 610 # That is, if the %define variable VARIABLE is undefined, complain fatally
 611 # since that's a Bison or skeleton error.  Otherwise, return its definition
 612 # location as a b4_syncline invocation.  Don't record this as a Bison usage of
 613 # VARIABLE as there's no reason to suspect that the user-supplied value has yet
 614 # influenced the output.
 615 #
 616 # For example:
 617 #
 618 #   b4_percent_define_get_syncline([[foo]])
 619 m4_define([b4_percent_define_get_syncline],
 620 [m4_ifdef([b4_percent_define_syncline(]$1[)],
 621           [m4_indir([b4_percent_define_syncline(]$1[)])],
 622           [b4_fatal([[b4_percent_define_get_syncline: undefined %%define variable '%s']], [$1])])])
 623
 624 # b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
 625 # ------------------------------------------------------
 626 # Mimic muscle_percent_define_ifdef in ../src/muscle-tab.h exactly.  That is,
 627 # if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
 628 # IF-FALSE.  Also, record Bison's usage of VARIABLE by defining
 629 # b4_percent_define_bison_variables(VARIABLE).
 630 #
 631 # For example:
 632 #
 633 #   b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
 634 m4_define([b4_percent_define_ifdef],
 635 [m4_ifdef([b4_percent_define(]$1[)],
 636           [b4_percent_define_use([$1])$2],
 637           [$3])])
 638
 639
 640 ## --------- ##
 641 ## Options.  ##
 642 ## --------- ##
 643
 644
 645 # b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
 646 # --------------------------------------------------------
 647 # Mimic muscle_percent_define_flag_if in ../src/muscle-tab.h exactly.  That is,
 648 # if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
 649 # If it is defined to "false", expand IF-FALSE.  Complain if it is undefined
 650 # (a Bison or skeleton error since the default value should have been set
 651 # already) or defined to any other value (possibly a user error).  Also, record
 652 # Bison's usage of VARIABLE by defining
 653 # b4_percent_define_bison_variables(VARIABLE).
 654 #
 655 # For example:
 656 #
 657 #   b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
 658 m4_define([b4_percent_define_flag_if],
 659 [b4_percent_define_ifdef([$1],
 660   [m4_case(b4_percent_define_get([$1]),
 661            [], [$2], [true], [$2], [false], [$3],
 662            [m4_expand_once([b4_complain_at(b4_percent_define_get_loc([$1]),
 663                                            [[invalid value for %%define Boolean variable '%s']],
 664                                            [$1])],
 665                            [[b4_percent_define_flag_if($1)]])])],
 666   [b4_fatal([[b4_percent_define_flag_if: undefined %%define variable '%s']], [$1])])])
 667
 668
 669 # b4_percent_define_default(VARIABLE, DEFAULT)
 670 # --------------------------------------------
 671 # Mimic muscle_percent_define_default in ../src/muscle-tab.h exactly.  That is,
 672 # if the %define variable VARIABLE is undefined, set its value to DEFAULT.
 673 # Don't record this as a Bison usage of VARIABLE as there's no reason to
 674 # suspect that the value has yet influenced the output.
 675 #
 676 # For example:
 677 #
 678 #   b4_percent_define_default([[foo]], [[default value]])
 679 m4_define([b4_percent_define_default],
 680 [m4_ifndef([b4_percent_define(]$1[)],
 681            [m4_define([b4_percent_define(]$1[)], [$2])dnl
 682             m4_define([b4_percent_define_loc(]$1[)],
 683                       [[[[<skeleton default value>:-1.-1]],
 684                         [[<skeleton default value>:-1.-1]]]])dnl
 685             m4_define([b4_percent_define_syncline(]$1[)], [[]])])])
 686
 687
 688 # b4_percent_define_if_define(VARIABLE)
 689 # -------------------------------------
 690 # Define b4_VARIABLE_if that executes its $1 or $2 depending whether
 691 # VARIABLE was %defined.  The characters `.' and `-' in VARIABLE are mapped
 692 # to `_'.
 693 m4_define([b4_percent_define_if_define_],
 694 [m4_define(m4_bpatsubst([b4_$1_if], [[-.]], [_]),
 695            [b4_percent_define_flag_if([$1], [$2], [$3])])])
 696 m4_define([b4_percent_define_if_define],
 697 [b4_percent_define_default([[$1]], [[false]])
 698 b4_percent_define_if_define_([$1], $[1], $[2])])
 699
 700
 701 # b4_percent_define_check_values(VALUES)
 702 # --------------------------------------
 703 # Mimic muscle_percent_define_check_values in ../src/muscle-tab.h exactly
 704 # except that the VALUES structure is more appropriate for M4.  That is, VALUES
 705 # is a list of sublists of strings.  For each sublist, the first string is the
 706 # name of a %define variable, and all remaining strings in that sublist are the
 707 # valid values for that variable.  Complain if such a variable is undefined (a
 708 # Bison error since the default value should have been set already) or defined
 709 # to any other value (possibly a user error).  Don't record this as a Bison
 710 # usage of the variable as there's no reason to suspect that the value has yet
 711 # influenced the output.
 712 #
 713 # For example:
 714 #
 715 #   b4_percent_define_check_values([[[[foo]], [[foo-value1]], [[foo-value2]]]],
 716 #                                  [[[[bar]], [[bar-value1]]]])
 717 m4_define([b4_percent_define_check_values],
 718 [m4_foreach([b4_sublist], m4_quote($@),
 719             [_b4_percent_define_check_values(b4_sublist)])])
 720
 721 m4_define([_b4_percent_define_check_values],
 722 [m4_ifdef([b4_percent_define(]$1[)],
 723   [m4_pushdef([b4_good_value], [0])dnl
 724    m4_if($#, 1, [],
 725          [m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 726                      [m4_if(m4_indir([b4_percent_define(]$1[)]), b4_value,
 727                             [m4_define([b4_good_value], [1])])])])dnl
 728    m4_if(b4_good_value, [0],
 729          [b4_complain_at(b4_percent_define_get_loc([$1]),
 730                          [[invalid value for %%define variable '%s': '%s']],
 731                          [$1],
 732                          m4_dquote(m4_indir([b4_percent_define(]$1[)])))
 733           m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 734                      [b4_complain_at(b4_percent_define_get_loc([$1]),
 735                                      [[accepted value: '%s']],
 736                                      m4_dquote(b4_value))])])dnl
 737    m4_popdef([b4_good_value])],
 738   [b4_fatal([[b4_percent_define_check_values: undefined %%define variable '%s']], [$1])])])
 739
 740 # b4_percent_code_get([QUALIFIER])
 741 # --------------------------------
 742 # If any %code blocks for QUALIFIER are defined, emit them beginning with a
 743 # comment and ending with synclines and a newline.  If QUALIFIER is not
 744 # specified or empty, do this for the unqualified %code blocks.  Also, record
 745 # Bison's usage of QUALIFIER (if specified) by defining
 746 # b4_percent_code_bison_qualifiers(QUALIFIER).
 747 #
 748 # For example, to emit any unqualified %code blocks followed by any %code
 749 # blocks for the qualifier foo:
 750 #
 751 #   b4_percent_code_get
 752 #   b4_percent_code_get([[foo]])
 753 m4_define([b4_percent_code_get],
 754 [m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
 755 m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
 756 m4_ifdef(b4_macro_name,
 757 [b4_comment([m4_if([$#], [0], [[Unqualified %code]],
 758                    [["%code ]$1["]])[ blocks.]])
 759 b4_user_code([m4_indir(b4_macro_name)])
 760 ])dnl
 761 m4_popdef([b4_macro_name])])
 762
 763 # b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
 764 # -----------------------------------------------------
 765 # If any %code blocks for QUALIFIER (or unqualified %code blocks if
 766 # QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
 767 # Also, record Bison's usage of QUALIFIER (if specified) by defining
 768 # b4_percent_code_bison_qualifiers(QUALIFIER).
 769 m4_define([b4_percent_code_ifdef],
 770 [m4_ifdef([b4_percent_code(]$1[)],
 771           [m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
 772           [$3])])
 773
 774
 775 ## ------------------ ##
 776 ## Common variables.  ##
 777 ## ------------------ ##
 778
 779 # Default values for %define.
 780 # ---------------------------
 781 # If the api.tokens.prefix, it is empty.
 782 m4_percent_define_default([[api.tokens.prefix]], [[]])
 783
 784 # b4_parse_assert_if([IF-ASSERTIONS-ARE-USED], [IF-NOT])
 785 # b4_parse_trace_if([IF-DEBUG-TRACES-ARE-ENABLED], [IF-NOT])
 786 # b4_lex_symbol_if([IF-YYLEX-RETURNS-A-COMPLETE-SYMBOL], [IF-NOT])
 787 # b4_variant_if([IF-VARIANT-ARE-USED], [IF-NOT])
 788 # ----------------------------------------------
 789 b4_percent_define_if_define([lex_symbol])
 790 b4_percent_define_if_define([locations])     # Whether locations are tracked.
 791 b4_percent_define_if_define([parse.assert])
 792 b4_percent_define_if_define([parse.trace])
 793 b4_percent_define_if_define([variant])
 794
 795
 796 # b4_error_verbose_if([IF-ERRORS-ARE-VERBOSE], [IF-NOT])
 797 # ------------------------------------------------------
 798 # Map %define parse.error "(simple|verbose)" to b4_error_verbose_if and
 799 # b4_error_verbose_flag.
 800 b4_percent_define_default([[parse.error]], [[simple]])
 801 b4_percent_define_check_values([[[[parse.error]],
 802                                  [[simple]], [[verbose]]]])
 803 m4_define([b4_error_verbose_flag],
 804           [m4_case(b4_percent_define_get([[parse.error]]),
 805                    [simple],  [[0]],
 806                    [verbose], [[1]])])
 807 b4_define_flag_if([error_verbose])
 808
 809
 810 ## ----------------------------------------------------------- ##
 811 ## After processing the skeletons, check that all the user's   ##
 812 ## %define variables and %code qualifiers were used by Bison.  ##
 813 ## ----------------------------------------------------------- ##
 814
 815 m4_define([b4_check_user_names_wrap],
 816 [m4_ifdef([b4_percent_]$1[_user_]$2[s],
 817           [b4_check_user_names([[%]$1 $2],
 818                                [b4_percent_]$1[_user_]$2[s],
 819                                [[b4_percent_]$1[_bison_]$2[s]])])])
 820
 821 m4_wrap_lifo([
 822 b4_check_user_names_wrap([[define]], [[variable]])
 823 b4_check_user_names_wrap([[code]], [[qualifier]])
 824 ])