data/c.m4

   1                                                             -*- Autoconf -*-
   2
   3 # C M4 Macros for Bison.
   4
   5 # Copyright (C) 2002, 2004-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ## ---------------- ##
  21 ## Identification.  ##
  22 ## ---------------- ##
  23
  24 # b4_comment_(TEXT, OPEN, CONTINUE, END)
  25 # -------------------------------------
  26 # Put TEXT in comment.  Avoid trailing spaces: don't indent empty lines.
  27 # Avoid adding indentation to the first line, as the indentation comes
  28 # from OPEN.  That's why we don't patsubst([$1], [^\(.\)], [   \1]).
  29 #
  30 # Prefix all the output lines with PREFIX.
  31 m4_define([b4_comment_], [$2[]m4_bpatsubst([$1], [
  32 \(.\)], [
  33 $3\1])$4])
  34
  35
  36 # b4_c_comment(TEXT, [PREFIX])
  37 # ----------------------------
  38 # Put TEXT in comment.  Avoid trailing spaces: don't indent empty lines.
  39 # Avoid adding indentation to the first line, as the indentation comes
  40 # from "/*".  That's why we don't patsubst([$1], [^\(.\)], [   \1]).
  41 #
  42 # Prefix all the output lines with PREFIX.
  43 m4_define([b4_c_comment],
  44 [b4_comment_([$1], [$2/* ], [$2   ], [$2  */])])
  45
  46
  47 # b4_comment(TEXT, [PREFIX])
  48 # --------------------------
  49 # By default, C comments.
  50 m4_define([b4_comment], [b4_c_comment($@)])
  51
  52
  53 # b4_identification
  54 # -----------------
  55 # Depends on individual skeletons to define b4_pure_flag, b4_push_flag, or
  56 # b4_pull_flag if they use the values of the %define variables api.pure or
  57 # api.push-pull.
  58 m4_define([b4_identification],
  59 [[/* Identify Bison output.  */
  60 #define YYBISON 1
  61
  62 /* Bison version.  */
  63 #define YYBISON_VERSION "]b4_version["
  64
  65 /* Skeleton name.  */
  66 #define YYSKELETON_NAME ]b4_skeleton[]m4_ifdef([b4_pure_flag], [[
  67
  68 /* Pure parsers.  */
  69 #define YYPURE ]b4_pure_flag])[]m4_ifdef([b4_push_flag], [[
  70
  71 /* Push parsers.  */
  72 #define YYPUSH ]b4_push_flag])[]m4_ifdef([b4_pull_flag], [[
  73
  74 /* Pull parsers.  */
  75 #define YYPULL ]b4_pull_flag])[
  76
  77 /* Using locations.  */
  78 #define YYLSP_NEEDED ]b4_locations_if([1], [0])[
  79 ]])
  80
  81
  82 ## ---------------- ##
  83 ## Default values.  ##
  84 ## ---------------- ##
  85
  86 # If the %union is not named, its name is YYSTYPE.
  87 m4_define_default([b4_union_name], [YYSTYPE])
  88
  89 # If the %name-prefix is not given, it is yy.
  90 m4_define_default([b4_prefix], [yy])
  91
  92 ## ------------------------ ##
  93 ## Pure/impure interfaces.  ##
  94 ## ------------------------ ##
  95
  96 # b4_user_args
  97 # ------------
  98 m4_define([b4_user_args],
  99 [m4_ifset([b4_parse_param], [, b4_c_args(b4_parse_param)])])
 100
 101
 102 # b4_parse_param
 103 # --------------
 104 # If defined, b4_parse_param arrives double quoted, but below we prefer
 105 # it to be single quoted.
 106 m4_define([b4_parse_param],
 107 b4_parse_param)
 108
 109
 110 # b4_parse_param_for(DECL, FORMAL, BODY)
 111 # ---------------------------------------
 112 # Iterate over the user parameters, binding the declaration to DECL,
 113 # the formal name to FORMAL, and evaluating the BODY.
 114 m4_define([b4_parse_param_for],
 115 [m4_foreach([$1_$2], m4_defn([b4_parse_param]),
 116 [m4_pushdef([$1], m4_unquote(m4_car($1_$2)))dnl
 117 m4_pushdef([$2], m4_shift($1_$2))dnl
 118 $3[]dnl
 119 m4_popdef([$2])dnl
 120 m4_popdef([$1])dnl
 121 ])])
 122
 123 # b4_parse_param_use([VAL], [LOC])
 124 # --------------------------------
 125 # `YYUSE' VAL, LOC if locations are enabled, and all the parse-params.
 126 m4_define([b4_parse_param_use],
 127 [m4_ifval([$1], [  YYUSE([$1]);
 128 ])dnl
 129 m4_ifval([$2], [b4_locations_if([  YYUSE ([$2]);
 130 ])])dnl
 131 b4_parse_param_for([Decl], [Formal], [  YYUSE (Formal);
 132 ])dnl
 133 ])
 134
 135
 136 ## ------------ ##
 137 ## Data Types.  ##
 138 ## ------------ ##
 139
 140 # b4_int_type(MIN, MAX)
 141 # ---------------------
 142 # Return the smallest int type able to handle numbers ranging from
 143 # MIN to MAX (included).
 144 m4_define([b4_int_type],
 145 [m4_if(b4_ints_in($@,      [0],   [255]), [1], [unsigned char],
 146        b4_ints_in($@,   [-128],   [127]), [1], [signed char],
 147
 148        b4_ints_in($@,      [0], [65535]), [1], [unsigned short int],
 149        b4_ints_in($@, [-32768], [32767]), [1], [short int],
 150
 151        m4_eval([0 <= $1]),                [1], [unsigned int],
 152
 153                                                [int])])
 154
 155
 156 # b4_int_type_for(NAME)
 157 # ---------------------
 158 # Return the smallest int type able to handle numbers ranging from
 159 # `NAME_min' to `NAME_max' (included).
 160 m4_define([b4_int_type_for],
 161 [b4_int_type($1_min, $1_max)])
 162
 163
 164 # b4_table_value_equals(TABLE, VALUE, LITERAL)
 165 # --------------------------------------------
 166 # Without inducing a comparison warning from the compiler, check if the
 167 # literal value LITERAL equals VALUE from table TABLE, which must have
 168 # TABLE_min and TABLE_max defined.  YYID must be defined as an identity
 169 # function that suppresses warnings about constant conditions.
 170 m4_define([b4_table_value_equals],
 171 [m4_if(m4_eval($3 < m4_indir([b4_]$1[_min])
 172                || m4_indir([b4_]$1[_max]) < $3), [1],
 173        [[YYID (0)]],
 174        [[((]$2[) == (]$3[))]])])
 175
 176 ## ---------##
 177 ## Values.  ##
 178 ## ---------##
 179
 180 # b4_null
 181 ---------
 182 # Return a null pointer constant.  NULL infringes on the user name
 183 # space in C, so use 0 rather than NULL.
 184 m4_define([b4_null], [0])
 185
 186
 187 # b4_integral_parser_table_define(TABLE-NAME, CONTENT, COMMENT)
 188 # -------------------------------------------------------------
 189 # Define "yy<TABLE-NAME>" which contents is CONTENT.
 190 m4_define([b4_integral_parser_table_define],
 191 [m4_ifval([$3], [b4_c_comment([$3], [  ])
 192 ])dnl
 193 static const b4_int_type_for([$2]) yy$1[[]] =
 194 {
 195   $2
 196 };dnl
 197 ])
 198
 199
 200 ## ------------------------- ##
 201 ## Assigning token numbers.  ##
 202 ## ------------------------- ##
 203
 204 # b4_token_define(TOKEN-NAME, TOKEN-NUMBER)
 205 # -----------------------------------------
 206 # Output the definition of this token as #define.
 207 m4_define([b4_token_define],
 208 [#define b4_percent_define_get([api.tokens.prefix])$1 $2
 209 ])
 210
 211
 212 # b4_token_defines(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 213 # -------------------------------------------------------
 214 # Output the definition of the tokens (if there are) as #defines.
 215 m4_define([b4_token_defines],
 216 [m4_if([$#$1], [1], [],
 217 [/* Tokens.  */
 218 m4_map([b4_token_define], [$@])])
 219 ])
 220
 221
 222 # b4_token_enum(TOKEN-NAME, TOKEN-NUMBER)
 223 # ---------------------------------------
 224 # Output the definition of this token as an enum.
 225 m4_define([b4_token_enum],
 226 [b4_percent_define_get([api.tokens.prefix])$1 = $2])
 227
 228
 229 # b4_token_enums(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 230 # -----------------------------------------------------
 231 # Output the definition of the tokens (if there are) as enums.
 232 m4_define([b4_token_enums],
 233 [m4_if([$#$1], [1], [],
 234 [/* Tokens.  */
 235 #ifndef YYTOKENTYPE
 236 # define YYTOKENTYPE
 237    /* Put the tokens into the symbol table, so that GDB and other debuggers
 238       know about them.  */
 239    enum yytokentype {
 240 m4_map_sep([     b4_token_enum], [,
 241 ],
 242            [$@])
 243    };
 244 #endif
 245 ])])
 246
 247
 248 # b4_token_enums_defines(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 249 # -------------------------------------------------------------
 250 # Output the definition of the tokens (if there are any) as enums and, if POSIX
 251 # Yacc is enabled, as #defines.
 252 m4_define([b4_token_enums_defines],
 253 [b4_token_enums($@)b4_yacc_if([b4_token_defines($@)], [])
 254 ])
 255
 256
 257 ## ----------------- ##
 258 ## Semantic Values.  ##
 259 ## ----------------- ##
 260
 261
 262 # b4_symbol_value(VAL, [TYPE])
 263 # ----------------------------
 264 # Given a semantic value VAL ($$, $1 etc.), extract its value of type
 265 # TYPE if TYPE is given, otherwise just return VAL.  The result can be
 266 # used safetly, it is put in parens to avoid nasty precedence issues.
 267 # TYPE is *not* put in braces, provide some if needed.
 268 m4_define([b4_symbol_value],
 269 [($1[]m4_ifval([$2], [.$2]))])
 270
 271
 272
 273 ## --------------------------------------------- ##
 274 ## Defining C functions in both K&R and ANSI-C.  ##
 275 ## --------------------------------------------- ##
 276
 277
 278 # b4_modern_c
 279 # -----------
 280 # A predicate useful in #if to determine whether C is ancient or modern.
 281 #
 282 # If __STDC__ is defined, the compiler is modern.  IBM xlc 7.0 when run
 283 # as 'cc' doesn't define __STDC__ (or __STDC_VERSION__) for pedantic
 284 # reasons, but it defines __C99__FUNC__ so check that as well.
 285 # Microsoft C normally doesn't define these macros, but it defines _MSC_VER.
 286 # Consider a C++ compiler to be modern if it defines __cplusplus.
 287 #
 288 m4_define([b4_c_modern],
 289   [[(defined __STDC__ || defined __C99__FUNC__ \
 290      || defined __cplusplus || defined _MSC_VER)]])
 291
 292 # b4_c_function_def(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 293 # ----------------------------------------------------------
 294 # Declare the function NAME.
 295 m4_define([b4_c_function_def],
 296 [#if b4_c_modern
 297 b4_c_ansi_function_def($@)
 298 #else
 299 $2
 300 $1 (b4_c_knr_formal_names(m4_shift2($@)))
 301 b4_c_knr_formal_decls(m4_shift2($@))
 302 #endif[]dnl
 303 ])
 304
 305
 306 # b4_c_ansi_function_def(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 307 # ---------------------------------------------------------------
 308 # Declare the function NAME in ANSI.
 309 m4_define([b4_c_ansi_function_def],
 310 [$2
 311 $1 (b4_c_ansi_formals(m4_shift2($@)))[]dnl
 312 ])
 313
 314
 315 # b4_c_ansi_formals([DECL1, NAME1], ...)
 316 # --------------------------------------
 317 # Output the arguments ANSI-C definition.
 318 m4_define([b4_c_ansi_formals],
 319 [m4_if([$#], [0], [void],
 320        [$#$1], [1], [void],
 321                [m4_map_sep([b4_c_ansi_formal], [, ], [$@])])])
 322
 323 m4_define([b4_c_ansi_formal],
 324 [$1])
 325
 326
 327 # b4_c_knr_formal_names([DECL1, NAME1], ...)
 328 # ------------------------------------------
 329 # Output the argument names.
 330 m4_define([b4_c_knr_formal_names],
 331 [m4_map_sep([b4_c_knr_formal_name], [, ], [$@])])
 332
 333 m4_define([b4_c_knr_formal_name],
 334 [$2])
 335
 336
 337 # b4_c_knr_formal_decls([DECL1, NAME1], ...)
 338 # ------------------------------------------
 339 # Output the K&R argument declarations.
 340 m4_define([b4_c_knr_formal_decls],
 341 [m4_map_sep([b4_c_knr_formal_decl],
 342             [
 343 ],
 344             [$@])])
 345
 346 m4_define([b4_c_knr_formal_decl],
 347 [    $1;])
 348
 349
 350
 351 ## ------------------------------------------------------------ ##
 352 ## Declaring (prototyping) C functions in both K&R and ANSI-C.  ##
 353 ## ------------------------------------------------------------ ##
 354
 355
 356 # b4_c_function_decl(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 357 # -----------------------------------------------------------
 358 # Declare the function NAME.
 359 m4_define([b4_c_function_decl],
 360 [#if b4_c_modern
 361 b4_c_ansi_function_decl($@)
 362 #else
 363 $2 $1 ();
 364 #endif[]dnl
 365 ])
 366
 367
 368 # b4_c_ansi_function_decl(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 369 # ----------------------------------------------------------------
 370 # Declare the function NAME.
 371 m4_define([b4_c_ansi_function_decl],
 372 [$2 $1 (b4_c_ansi_formals(m4_shift2($@)));[]dnl
 373 ])
 374
 375
 376
 377
 378 ## --------------------- ##
 379 ## Calling C functions.  ##
 380 ## --------------------- ##
 381
 382
 383 # b4_c_function_call(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 384 # -----------------------------------------------------------
 385 # Call the function NAME with arguments NAME1, NAME2 etc.
 386 m4_define([b4_c_function_call],
 387 [$1 (b4_c_args(m4_shift2($@)))[]dnl
 388 ])
 389
 390
 391 # b4_c_args([DECL1, NAME1], ...)
 392 # ------------------------------
 393 # Output the arguments NAME1, NAME2...
 394 m4_define([b4_c_args],
 395 [m4_map_sep([b4_c_arg], [, ], [$@])])
 396
 397 m4_define([b4_c_arg],
 398 [$2])
 399
 400
 401 ## ----------- ##
 402 ## Synclines.  ##
 403 ## ----------- ##
 404
 405 # b4_sync_start(LINE, FILE)
 406 # -----------------------
 407 m4_define([b4_sync_start], [[#]line $1 $2])
 408
 409
 410 ## -------------- ##
 411 ## User actions.  ##
 412 ## -------------- ##
 413
 414 # b4_case(LABEL, STATEMENTS)
 415 # --------------------------
 416 m4_define([b4_case],
 417 [  case $1:
 418 $2
 419 b4_syncline([@oline@], [@ofile@])
 420     break;])
 421
 422
 423 # b4_predicate_case(LABEL, CONDITIONS)
 424 # ------------------------------------
 425 m4_define([b4_predicate_case],
 426 [  case $1:
 427     if (! ($2)) YYERROR;
 428 b4_syncline([@oline@], [@ofile@])
 429     break;])
 430
 431
 432 # b4_yydestruct_generate(FUNCTION-DECLARATOR)
 433 # -------------------------------------------
 434 # Generate the "yydestruct" function, which declaration is issued using
 435 # FUNCTION-DECLARATOR, which may be "b4_c_ansi_function_def" for ISO C
 436 # or "b4_c_function_def" for K&R.
 437 m4_define_default([b4_yydestruct_generate],
 438 [[/*-----------------------------------------------.
 439 | Release the memory associated to this symbol.  |
 440 `-----------------------------------------------*/
 441
 442 /*ARGSUSED*/
 443 ]$1([yydestruct],
 444     [static void],
 445     [[const char *yymsg],    [yymsg]],
 446     [[int yytype],           [yytype]],
 447     [[YYSTYPE *yyvaluep],    [yyvaluep]][]dnl
 448 b4_locations_if(            [, [[YYLTYPE *yylocationp], [yylocationp]]])[]dnl
 449 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 450 {
 451 ]b4_parse_param_use([yyvaluep], [yylocationp])[
 452   if (!yymsg)
 453     yymsg = "Deleting";
 454   YY_SYMBOL_PRINT (yymsg, yytype, yyvaluep, yylocationp);
 455
 456   switch (yytype)
 457     {
 458 ]b4_symbol_foreach([b4_symbol_destructor])dnl
 459 [      default:
 460         break;
 461     }
 462 }]dnl
 463 ])
 464
 465
 466 # b4_yy_symbol_print_generate(FUNCTION-DECLARATOR)
 467 # ------------------------------------------------
 468 # Generate the "yy_symbol_print" function, which declaration is issued using
 469 # FUNCTION-DECLARATOR, which may be "b4_c_ansi_function_def" for ISO C
 470 # or "b4_c_function_def" for K&R.
 471 m4_define_default([b4_yy_symbol_print_generate],
 472 [[
 473 /*--------------------------------.
 474 | Print this symbol on YYOUTPUT.  |
 475 `--------------------------------*/
 476
 477 /*ARGSUSED*/
 478 ]$1([yy_symbol_value_print],
 479     [static void],
 480                [[FILE *yyoutput],                       [yyoutput]],
 481                [[int yytype],                           [yytype]],
 482                [[YYSTYPE const * const yyvaluep],       [yyvaluep]][]dnl
 483 b4_locations_if([, [[YYLTYPE const * const yylocationp], [yylocationp]]])[]dnl
 484 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 485 {
 486 ]b4_parse_param_use([yyoutput], [yylocationp])[
 487   if (!yyvaluep)
 488     return;
 489 # ifdef YYPRINT
 490   if (yytype < YYNTOKENS)
 491     YYPRINT (yyoutput, yytoknum[yytype], *yyvaluep);
 492 # endif
 493   switch (yytype)
 494     {
 495 ]b4_symbol_foreach([b4_symbol_printer])dnl
 496 [      default:
 497         break;
 498     }
 499 }
 500
 501
 502 /*--------------------------------.
 503 | Print this symbol on YYOUTPUT.  |
 504 `--------------------------------*/
 505
 506 ]$1([yy_symbol_print],
 507     [static void],
 508                [[FILE *yyoutput],                       [yyoutput]],
 509                [[int yytype],                           [yytype]],
 510                [[YYSTYPE const * const yyvaluep],       [yyvaluep]][]dnl
 511 b4_locations_if([, [[YYLTYPE const * const yylocationp], [yylocationp]]])[]dnl
 512 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 513 {
 514   if (yytype < YYNTOKENS)
 515     YYFPRINTF (yyoutput, "token %s (", yytname[yytype]);
 516   else
 517     YYFPRINTF (yyoutput, "nterm %s (", yytname[yytype]);
 518
 519 ]b4_locations_if([  YY_LOCATION_PRINT (yyoutput, *yylocationp);
 520   YYFPRINTF (yyoutput, ": ");
 521 ])dnl
 522 [  yy_symbol_value_print (yyoutput, yytype, yyvaluep]dnl
 523 b4_locations_if([, yylocationp])[]b4_user_args[);
 524   YYFPRINTF (yyoutput, ")");
 525 }]dnl
 526 ])